autoconf: Error out on --without-shell and --without-perl
[git/git.git] / configure.ac
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
3
4 AC_PREREQ(2.59)
5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
6
7 AC_CONFIG_SRCDIR([git.c])
8
9 config_file=config.mak.autogen
10 config_append=config.mak.append
11 config_in=config.mak.in
12
13 echo "# ${config_append}. Generated by configure." > "${config_append}"
14
15
16 ## Definitions of macros
17 # GIT_CONF_APPEND_LINE(LINE)
18 # --------------------------
19 # Append LINE to file ${config_append}
20 AC_DEFUN([GIT_CONF_APPEND_LINE],
21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
22 #
23 # GIT_ARG_SET_PATH(PROGRAM)
24 # -------------------------
25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
26 AC_DEFUN([GIT_ARG_SET_PATH],
27 [AC_ARG_WITH([$1],
28 [AS_HELP_STRING([--with-$1=PATH],
29 [provide PATH to $1])],
30 [GIT_CONF_APPEND_PATH($1)],[])
31 ])# GIT_ARG_SET_PATH
32 #
33 # GIT_CONF_APPEND_PATH(PROGRAM)
34 # ------------------------------
35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
36 # Used by GIT_ARG_SET_PATH(PROGRAM)
37 AC_DEFUN([GIT_CONF_APPEND_PATH],
38 [PROGRAM=m4_toupper($1); \
39 if test "$withval" = "no"; then \
40 AC_MSG_ERROR([You cannot use git without $1]); \
41 else \
42 if test "$withval" = "yes"; then \
43 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
44 else \
45 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
46 fi; \
47 fi; \
48 ]) # GIT_CONF_APPEND_PATH
49
50
51 ## Site configuration
52 ## --with-PACKAGE[=ARG] and --without-PACKAGE
53 #
54 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
55 # tests. These tests take up a significant amount of the total test time
56 # but are not needed unless you plan to talk to SVN repos.
57 #
58 # Define MOZILLA_SHA1 environment variable when running make to make use of
59 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
60 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
61 # choice) has very fast version optimized for i586.
62 #
63 # Define PPC_SHA1 environment variable when running make to make use of
64 # a bundled SHA1 routine optimized for PowerPC.
65 #
66 # Define ARM_SHA1 environment variable when running make to make use of
67 # a bundled SHA1 routine optimized for ARM.
68 #
69 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
70 # This also implies MOZILLA_SHA1.
71 #
72 # Define NO_CURL if you do not have curl installed. git-http-pull and
73 # git-http-push are not built, and you cannot use http:// and https://
74 # transports.
75 #
76 # Define CURLDIR=/foo/bar if your curl header and library files are in
77 # /foo/bar/include and /foo/bar/lib directories.
78 #
79 # Define NO_EXPAT if you do not have expat installed. git-http-push is
80 # not built, and you cannot push using http:// and https:// transports.
81 #
82 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
83 # installed in /sw, but don't want GIT to link against any libraries
84 # installed there. If defined you may specify your own (or Fink's)
85 # include directories and library directories by defining CFLAGS
86 # and LDFLAGS appropriately.
87 #
88 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
89 # have DarwinPorts installed in /opt/local, but don't want GIT to
90 # link against any libraries installed there. If defined you may
91 # specify your own (or DarwinPort's) include directories and
92 # library directories by defining CFLAGS and LDFLAGS appropriately.
93 #
94 # Define NO_MMAP if you want to avoid mmap.
95 #
96 # Define SHELL_PATH to provide path to shell.
97 GIT_ARG_SET_PATH(shell)
98 #
99 # Define PERL_PATH to provide path to Perl.
100 GIT_ARG_SET_PATH(perl)
101 #
102 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
103 # Define PYTHON_PATH to provide path to Python.
104 AC_ARG_WITH(python,[AS_HELP_STRING([--with-python=PATH], [provide PATH to python])
105 AS_HELP_STRING([--no-python], [don't use python scripts])],
106 [if test "$withval" = "no"; then \
107 NO_PYTHON=YesPlease; \
108 elif test "$withval" != "yes"; then \
109 PYTHON_PATH=$withval; \
110 fi; \
111 ])
112 AC_SUBST(NO_PYTHON)
113 AC_SUBST(PYTHON_PATH)
114 #
115 ## --enable-FEATURE[=ARG] and --disable-FEATURE
116 # Define COLLISION_CHECK below if you believe that SHA1's
117 # 1461501637330902918203684832716283019655932542976 hashes do not give you
118 # sufficient guarantee that no collisions between objects will ever happen.
119 #
120 # Define USE_NSEC below if you want git to care about sub-second file mtimes
121 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
122 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
123 # randomly break unless your underlying filesystem supports those sub-second
124 # times (my ext3 doesn't).
125 #
126 # Define USE_STDEV below if you want git to care about the underlying device
127 # change being considered an inode change from the update-cache perspective.
128
129
130 ## Checks for programs.
131 AC_MSG_NOTICE([CHECKS for programs])
132 #
133 AC_PROG_CC
134 #AC_PROG_INSTALL # needs install-sh or install.sh in sources
135 AC_CHECK_TOOL(AR, ar, :)
136 AC_CHECK_PROGS(TAR, [gtar tar])
137 #
138 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
139 # Define PYTHON_PATH to provide path to Python.
140 if test -z "$NO_PYTHON"; then
141 AC_PATH_PROGS(PYTHON_PATH, [python2.4 python2.3 python2 python])
142 if test -n "$PYTHON_PATH"; then
143 GIT_CONF_APPEND_LINE([PYTHON_PATH=@PYTHON_PATH@])
144 else
145 GIT_CONF_APPEND_LINE([NO_PYTHON=@NO_PYTHON@])
146 fi
147 else
148 GIT_CONF_APPEND_LINE([NO_PYTHON=@NO_PYTHON@])
149 fi
150
151
152 ## Checks for libraries.
153 AC_MSG_NOTICE([CHECKS for libraries])
154 #
155 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
156 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
157 AC_CHECK_LIB([crypto], [SHA1_Init],
158 [GIT_CONF_APPEND_LINE(NEEDS_SSL_WITH_CRYPTO=)],
159 [AC_CHECK_LIB([ssl], [SHA1_Init],
160 [GIT_CONF_APPEND_LINE(NEEDS_SSL_WITH_CRYPTO=YesPlease)
161 GIT_CONF_APPEND_LINE(NEEDS_SSL_WITH_CRYPTO=)],
162 [GIT_CONF_APPEND_LINE(NO_OPENSSL=YesPlease)])])
163 #
164 # Define NO_CURL if you do not have curl installed. git-http-pull and
165 # git-http-push are not built, and you cannot use http:// and https://
166 # transports.
167 AC_CHECK_LIB([curl], [curl_global_init],
168 [GIT_CONF_APPEND_LINE(NO_CURL=)],
169 [GIT_CONF_APPEND_LINE(NO_CURL=YesPlease)])
170 #
171 # Define NO_EXPAT if you do not have expat installed. git-http-push is
172 # not built, and you cannot push using http:// and https:// transports.
173 AC_CHECK_LIB([expat], [XML_ParserCreate],
174 [GIT_CONF_APPEND_LINE(NO_EXPAT=)],
175 [GIT_CONF_APPEND_LINE(NO_EXPAT=YesPlease)])
176 #
177 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin).
178 AC_CHECK_LIB([c], [iconv],
179 [GIT_CONF_APPEND_LINE(NEEDS_LIBICONV=)],
180 [GIT_CONF_APPEND_LINE(NEEDS_LIBICONV=YesPlease)])
181 #
182 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
183 # Patrick Mauritz).
184 AC_CHECK_LIB([c], [socket],
185 [GIT_CONF_APPEND_LINE(NEEDS_SOCKET=)],
186 [GIT_CONF_APPEND_LINE(NEEDS_SOCKET=YesPlease)])
187
188
189 ## Checks for header files.
190
191
192 ## Checks for typedefs, structures, and compiler characteristics.
193 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
194 #
195 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
196 AC_CHECK_MEMBER(struct dirent.d_ino,
197 [GIT_CONF_APPEND_LINE(NO_D_INO_IN_DIRENT=)],
198 [GIT_CONF_APPEND_LINE(NO_D_INO_IN_DIRENT=YesPlease)],
199 [#include <dirent.h>])
200 #
201 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
202 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
203 AC_CHECK_MEMBER(struct dirent.d_type,
204 [GIT_CONF_APPEND_LINE(NO_D_TYPE_IN_DIRENT=)],
205 [GIT_CONF_APPEND_LINE(NO_D_TYPE_IN_DIRENT=YesPlease)],
206 [#include <dirent.h>])
207 #
208 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
209 # sockaddr_storage.
210 AC_CHECK_TYPE(struct sockaddr_storage,
211 [GIT_CONF_APPEND_LINE(NO_SOCKADDR_STORAGE=)],
212 [GIT_CONF_APPEND_LINE(NO_SOCKADDR_STORAGE=YesPlease)],
213 [#include <netinet/in.h>])
214 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
215 AC_CHECK_TYPE([struct addrinfo],[
216 AC_CHECK_FUNC([getaddrinfo],
217 [GIT_CONF_APPEND_LINE(NO_IPV6=)],
218 [GIT_CONF_APPEND_LINE(NO_IPV6=YesPlease)])
219 ],[GIT_CONF_APPEND_LINE(NO_IPV6=YesPlease)],[
220 #include <sys/types.h>
221 #include <sys/socket.h>
222 #include <netdb.h>
223 ])
224 #
225 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
226 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
227 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
228 # some C compilers supported these specifiers prior to C99 as an extension.
229 AC_CACHE_CHECK(whether formatted IO functions support C99 size specifiers,
230 ac_cv_c_c99_format,
231 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
232 AC_RUN_IFELSE(
233 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
234 [[char buf[64];
235 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
236 exit(1);
237 else if (strcmp(buf, "12345"))
238 exit(2);]])],
239 [ac_cv_c_c99_format=yes],
240 [ac_cv_c_c99_format=no])
241 ])
242 if test $ac_cv_c_c99_format = no; then
243 GIT_CONF_APPEND_LINE(NO_C99_FORMAT=YesPlease)
244 else
245 GIT_CONF_APPEND_LINE(NO_C99_FORMAT=)
246 fi
247
248
249 ## Checks for library functions.
250 ## (in default C library and libraries checked by AC_CHECK_LIB)
251 AC_MSG_NOTICE([CHECKS for library functions])
252 #
253 # Define NO_STRCASESTR if you don't have strcasestr.
254 AC_CHECK_FUNC(strcasestr,
255 [GIT_CONF_APPEND_LINE(NO_STRCASESTR=)],
256 [GIT_CONF_APPEND_LINE(NO_STRCASESTR=YesPlease)])
257 #
258 # Define NO_STRLCPY if you don't have strlcpy.
259 AC_CHECK_FUNC(strlcpy,
260 [GIT_CONF_APPEND_LINE(NO_STRLCPY=)],
261 [GIT_CONF_APPEND_LINE(NO_STRLCPY=YesPlease)])
262 #
263 # Define NO_SETENV if you don't have setenv in the C library.
264 AC_CHECK_FUNC(setenv,
265 [GIT_CONF_APPEND_LINE(NO_SETENV=)],
266 [GIT_CONF_APPEND_LINE(NO_SETENV=YesPlease)])
267 #
268 # Define NO_MMAP if you want to avoid mmap.
269 #
270 # Define NO_ICONV if your libc does not properly support iconv.
271
272
273 ## Other checks.
274 # Define USE_PIC if you need the main git objects to be built with -fPIC
275 # in order to build and link perl/Git.so. x86-64 seems to need this.
276 #
277 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
278 # Enable it on Windows. By default, symrefs are still used.
279 #
280 # Define WITH_OWN_SUBPROCESS_PY if you want to use with python 2.3.
281 #
282 # Define NO_ACCURATE_DIFF if your diff program at least sometimes misses
283 # a missing newline at the end of the file.
284
285
286 ## Output files
287 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
288 AC_OUTPUT
289
290
291 ## Cleanup
292 rm -f "${config_append}"