git-gui: Support starting gitk from Gui Blame
[git/git.git] / lib / blame.tcl
1 # git-gui blame viewer
2 # Copyright (C) 2006, 2007 Shawn Pearce
3
4 class blame {
5
6 image create photo ::blame::img_back_arrow -data {R0lGODlhGAAYAIUAAPwCBEzKXFTSZIz+nGzmhGzqfGTidIT+nEzGXHTqhGzmfGzifFzadETCVES+VARWDFzWbHzyjAReDGTadFTOZDSyRDyyTCymPARaFGTedFzSbDy2TCyqRCyqPARaDAyCHES6VDy6VCyiPAR6HCSeNByWLARyFARiDARqFGTifARiFAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAYABgAAAajQIBwSCwaj8ikcsk0BppJwRPqHEypQwHBis0WDAdEFyBIKBaMAKLBdjQeSkFBYTBAIvgEoS6JmhUTEwIUDQ4VFhcMGEhyCgoZExoUaxsWHB0THkgfAXUGAhoBDSAVFR0XBnCbDRmgog0hpSIiDJpJIyEQhBUcJCIlwA22SSYVogknEg8eD82qSigdDSknY0IqJQXPYxIl1dZCGNvWw+Dm510GQQAh/mhDcmVhdGVkIGJ5IEJNUFRvR0lGIFBybyB2ZXJzaW9uIDIuNQ0KqSBEZXZlbENvciAxOTk3LDE5OTguIEFsbCByaWdodHMgcmVzZXJ2ZWQuDQpodHRwOi8vd3d3LmRldmVsY29yLmNvbQA7}
7
8 # Persistant data (survives loads)
9 #
10 field history {}; # viewer history: {commit path}
11 field header ; # array commit,key -> header field
12
13 # Tk UI control paths
14 #
15 field w ; # top window in this viewer
16 field w_back ; # our back button
17 field w_path ; # label showing the current file path
18 field w_columns ; # list of all column widgets in the viewer
19 field w_line ; # text column: all line numbers
20 field w_amov ; # text column: annotations + move tracking
21 field w_asim ; # text column: annotations (simple computation)
22 field w_file ; # text column: actual file data
23 field w_cviewer ; # pane showing commit message
24 field status ; # status mega-widget instance
25 field old_height ; # last known height of $w.file_pane
26
27 # Tk UI colors
28 #
29 variable active_color #c0edc5
30 variable group_colors {
31 #d6d6d6
32 #e1e1e1
33 #ececec
34 }
35
36 # Current blame data; cleared/reset on each load
37 #
38 field commit ; # input commit to blame
39 field path ; # input filename to view in $commit
40
41 field current_fd {} ; # background process running
42 field highlight_line -1 ; # current line selected
43 field highlight_column {} ; # current commit column selected
44 field highlight_commit {} ; # sha1 of commit selected
45
46 field total_lines 0 ; # total length of file
47 field blame_lines 0 ; # number of lines computed
48 field amov_data ; # list of {commit origfile origline}
49 field asim_data ; # list of {commit origfile origline}
50
51 field r_commit ; # commit currently being parsed
52 field r_orig_line ; # original line number
53 field r_final_line ; # final line number
54 field r_line_count ; # lines in this region
55
56 field tooltip_wm {} ; # Current tooltip toplevel, if open
57 field tooltip_t {} ; # Text widget in $tooltip_wm
58 field tooltip_timer {} ; # Current timer event for our tooltip
59 field tooltip_commit {} ; # Commit(s) in tooltip
60
61 constructor new {i_commit i_path} {
62 global cursor_ptr
63 variable active_color
64 variable group_colors
65
66 set commit $i_commit
67 set path $i_path
68
69 make_toplevel top w
70 wm title $top [append "[appname] ([reponame]): " [mc "File Viewer"]]
71
72 frame $w.header -background gold
73 label $w.header.commit_l \
74 -text [mc "Commit:"] \
75 -background gold \
76 -foreground black \
77 -anchor w \
78 -justify left
79 set w_back $w.header.commit_b
80 label $w_back \
81 -image ::blame::img_back_arrow \
82 -borderwidth 0 \
83 -relief flat \
84 -state disabled \
85 -background gold \
86 -foreground black \
87 -activebackground gold
88 bind $w_back <Button-1> "
89 if {\[$w_back cget -state\] eq {normal}} {
90 [cb _history_menu]
91 }
92 "
93 label $w.header.commit \
94 -textvariable @commit \
95 -background gold \
96 -foreground black \
97 -anchor w \
98 -justify left
99 label $w.header.path_l \
100 -text [mc "File:"] \
101 -background gold \
102 -foreground black \
103 -anchor w \
104 -justify left
105 set w_path $w.header.path
106 label $w_path \
107 -background gold \
108 -foreground black \
109 -anchor w \
110 -justify left
111 pack $w.header.commit_l -side left
112 pack $w_back -side left
113 pack $w.header.commit -side left
114 pack $w_path -fill x -side right
115 pack $w.header.path_l -side right
116
117 panedwindow $w.file_pane -orient vertical
118 frame $w.file_pane.out
119 frame $w.file_pane.cm
120 $w.file_pane add $w.file_pane.out \
121 -sticky nsew \
122 -minsize 100 \
123 -height 100 \
124 -width 100
125 $w.file_pane add $w.file_pane.cm \
126 -sticky nsew \
127 -minsize 25 \
128 -height 25 \
129 -width 100
130
131 set w_line $w.file_pane.out.linenumber_t
132 text $w_line \
133 -takefocus 0 \
134 -highlightthickness 0 \
135 -padx 0 -pady 0 \
136 -background white \
137 -foreground black \
138 -borderwidth 0 \
139 -state disabled \
140 -wrap none \
141 -height 40 \
142 -width 6 \
143 -font font_diff
144 $w_line tag conf linenumber -justify right -rmargin 5
145
146 set w_amov $w.file_pane.out.amove_t
147 text $w_amov \
148 -takefocus 0 \
149 -highlightthickness 0 \
150 -padx 0 -pady 0 \
151 -background white \
152 -foreground black \
153 -borderwidth 0 \
154 -state disabled \
155 -wrap none \
156 -height 40 \
157 -width 5 \
158 -font font_diff
159 $w_amov tag conf author_abbr -justify right -rmargin 5
160 $w_amov tag conf curr_commit
161 $w_amov tag conf prior_commit -foreground blue -underline 1
162 $w_amov tag bind prior_commit \
163 <Button-1> \
164 "[cb _load_commit $w_amov @amov_data @%x,%y];break"
165
166 set w_asim $w.file_pane.out.asimple_t
167 text $w_asim \
168 -takefocus 0 \
169 -highlightthickness 0 \
170 -padx 0 -pady 0 \
171 -background white \
172 -foreground black \
173 -borderwidth 0 \
174 -state disabled \
175 -wrap none \
176 -height 40 \
177 -width 4 \
178 -font font_diff
179 $w_asim tag conf author_abbr -justify right
180 $w_asim tag conf curr_commit
181 $w_asim tag conf prior_commit -foreground blue -underline 1
182 $w_asim tag bind prior_commit \
183 <Button-1> \
184 "[cb _load_commit $w_asim @asim_data @%x,%y];break"
185
186 set w_file $w.file_pane.out.file_t
187 text $w_file \
188 -takefocus 0 \
189 -highlightthickness 0 \
190 -padx 0 -pady 0 \
191 -background white \
192 -foreground black \
193 -borderwidth 0 \
194 -state disabled \
195 -wrap none \
196 -height 40 \
197 -width 80 \
198 -xscrollcommand [list $w.file_pane.out.sbx set] \
199 -font font_diff
200
201 set w_columns [list $w_amov $w_asim $w_line $w_file]
202
203 scrollbar $w.file_pane.out.sbx \
204 -orient h \
205 -command [list $w_file xview]
206 scrollbar $w.file_pane.out.sby \
207 -orient v \
208 -command [list scrollbar2many $w_columns yview]
209 eval grid $w_columns $w.file_pane.out.sby -sticky nsew
210 grid conf \
211 $w.file_pane.out.sbx \
212 -column [expr {[llength $w_columns] - 1}] \
213 -sticky we
214 grid columnconfigure \
215 $w.file_pane.out \
216 [expr {[llength $w_columns] - 1}] \
217 -weight 1
218 grid rowconfigure $w.file_pane.out 0 -weight 1
219
220 set w_cviewer $w.file_pane.cm.t
221 text $w_cviewer \
222 -background white \
223 -foreground black \
224 -borderwidth 0 \
225 -state disabled \
226 -wrap none \
227 -height 10 \
228 -width 80 \
229 -xscrollcommand [list $w.file_pane.cm.sbx set] \
230 -yscrollcommand [list $w.file_pane.cm.sby set] \
231 -font font_diff
232 $w_cviewer tag conf still_loading \
233 -font font_uiitalic \
234 -justify center
235 $w_cviewer tag conf header_key \
236 -tabs {3c} \
237 -background $active_color \
238 -font font_uibold
239 $w_cviewer tag conf header_val \
240 -background $active_color \
241 -font font_ui
242 $w_cviewer tag raise sel
243 scrollbar $w.file_pane.cm.sbx \
244 -orient h \
245 -command [list $w_cviewer xview]
246 scrollbar $w.file_pane.cm.sby \
247 -orient v \
248 -command [list $w_cviewer yview]
249 pack $w.file_pane.cm.sby -side right -fill y
250 pack $w.file_pane.cm.sbx -side bottom -fill x
251 pack $w_cviewer -expand 1 -fill both
252
253 set status [::status_bar::new $w.status]
254
255 menu $w.ctxm -tearoff 0
256 $w.ctxm add command \
257 -label [mc "Copy Commit"] \
258 -command [cb _copycommit]
259 $w.ctxm add command \
260 -label [mc "Do Full Copy Detection"] \
261 -command [cb _fullcopyblame]
262 $w.ctxm add command \
263 -label [mc "Show History Context"] \
264 -command [cb _gitkcommit]
265
266 foreach i $w_columns {
267 for {set g 0} {$g < [llength $group_colors]} {incr g} {
268 $i tag conf color$g -background [lindex $group_colors $g]
269 }
270
271 $i conf -cursor $cursor_ptr
272 $i conf -yscrollcommand [list many2scrollbar \
273 $w_columns yview $w.file_pane.out.sby]
274 bind $i <Button-1> "
275 [cb _hide_tooltip]
276 [cb _click $i @%x,%y]
277 focus $i
278 "
279 bind $i <Any-Motion> [cb _show_tooltip $i @%x,%y]
280 bind $i <Any-Enter> [cb _hide_tooltip]
281 bind $i <Any-Leave> [cb _hide_tooltip]
282 bind_button3 $i "
283 [cb _hide_tooltip]
284 set cursorX %x
285 set cursorY %y
286 set cursorW %W
287 tk_popup $w.ctxm %X %Y
288 "
289 bind $i <Shift-Tab> "[list focus $w_cviewer];break"
290 bind $i <Tab> "[list focus $w_cviewer];break"
291 }
292
293 foreach i [concat $w_columns $w_cviewer] {
294 bind $i <Key-Up> {catch {%W yview scroll -1 units};break}
295 bind $i <Key-Down> {catch {%W yview scroll 1 units};break}
296 bind $i <Key-Left> {catch {%W xview scroll -1 units};break}
297 bind $i <Key-Right> {catch {%W xview scroll 1 units};break}
298 bind $i <Key-k> {catch {%W yview scroll -1 units};break}
299 bind $i <Key-j> {catch {%W yview scroll 1 units};break}
300 bind $i <Key-h> {catch {%W xview scroll -1 units};break}
301 bind $i <Key-l> {catch {%W xview scroll 1 units};break}
302 bind $i <Control-Key-b> {catch {%W yview scroll -1 pages};break}
303 bind $i <Control-Key-f> {catch {%W yview scroll 1 pages};break}
304 }
305
306 bind $w_cviewer <Shift-Tab> "[list focus $w_file];break"
307 bind $w_cviewer <Tab> "[list focus $w_file];break"
308 bind $w_cviewer <Button-1> [list focus $w_cviewer]
309 bind $w_file <Visibility> [list focus $w_file]
310
311 grid configure $w.header -sticky ew
312 grid configure $w.file_pane -sticky nsew
313 grid configure $w.status -sticky ew
314 grid columnconfigure $top 0 -weight 1
315 grid rowconfigure $top 0 -weight 0
316 grid rowconfigure $top 1 -weight 1
317 grid rowconfigure $top 2 -weight 0
318
319 set req_w [winfo reqwidth $top]
320 set req_h [winfo reqheight $top]
321 set scr_h [expr {[winfo screenheight $top] - 100}]
322 if {$req_w < 600} {set req_w 600}
323 if {$req_h < $scr_h} {set req_h $scr_h}
324 set g "${req_w}x${req_h}"
325 wm geometry $top $g
326 update
327
328 set old_height [winfo height $w.file_pane]
329 $w.file_pane sash place 0 \
330 [lindex [$w.file_pane sash coord 0] 0] \
331 [expr {int($old_height * 0.70)}]
332 bind $w.file_pane <Configure> \
333 "if {{$w.file_pane} eq {%W}} {[cb _resize %h]}"
334
335 wm protocol $top WM_DELETE_WINDOW "destroy $top"
336 bind $top <Destroy> [cb _kill]
337
338 _load $this {}
339 }
340
341 method _kill {} {
342 if {$current_fd ne {}} {
343 kill_file_process $current_fd
344 catch {close $current_fd}
345 set current_fd {}
346 }
347 }
348
349 method _load {jump} {
350 variable group_colors
351
352 _hide_tooltip $this
353
354 if {$total_lines != 0 || $current_fd ne {}} {
355 _kill $this
356
357 foreach i $w_columns {
358 $i conf -state normal
359 $i delete 0.0 end
360 foreach g [$i tag names] {
361 if {[regexp {^g[0-9a-f]{40}$} $g]} {
362 $i tag delete $g
363 }
364 }
365 $i conf -state disabled
366 }
367
368 $w_cviewer conf -state normal
369 $w_cviewer delete 0.0 end
370 $w_cviewer conf -state disabled
371
372 set highlight_line -1
373 set highlight_column {}
374 set highlight_commit {}
375 set total_lines 0
376 }
377
378 if {$history eq {}} {
379 $w_back conf -state disabled
380 } else {
381 $w_back conf -state normal
382 }
383
384 # Index 0 is always empty. There is never line 0 as
385 # we use only 1 based lines, as that matches both with
386 # git-blame output and with Tk's text widget.
387 #
388 set amov_data [list [list]]
389 set asim_data [list [list]]
390
391 $status show [mc "Reading %s..." "$commit:[escape_path $path]"]
392 $w_path conf -text [escape_path $path]
393 if {$commit eq {}} {
394 set fd [open $path r]
395 fconfigure $fd -eofchar {}
396 } else {
397 set fd [git_read cat-file blob "$commit:$path"]
398 }
399 fconfigure $fd -blocking 0 -translation lf -encoding binary
400 fileevent $fd readable [cb _read_file $fd $jump]
401 set current_fd $fd
402 }
403
404 method _history_menu {} {
405 set m $w.backmenu
406 if {[winfo exists $m]} {
407 $m delete 0 end
408 } else {
409 menu $m -tearoff 0
410 }
411
412 for {set i [expr {[llength $history] - 1}]
413 } {$i >= 0} {incr i -1} {
414 set e [lindex $history $i]
415 set c [lindex $e 0]
416 set f [lindex $e 1]
417
418 if {[regexp {^[0-9a-f]{40}$} $c]} {
419 set t [string range $c 0 8]...
420 } elseif {$c eq {}} {
421 set t {Working Directory}
422 } else {
423 set t $c
424 }
425 if {![catch {set summary $header($c,summary)}]} {
426 append t " $summary"
427 if {[string length $t] > 70} {
428 set t [string range $t 0 66]...
429 }
430 }
431
432 $m add command -label $t -command [cb _goback $i]
433 }
434 set X [winfo rootx $w_back]
435 set Y [expr {[winfo rooty $w_back] + [winfo height $w_back]}]
436 tk_popup $m $X $Y
437 }
438
439 method _goback {i} {
440 set dat [lindex $history $i]
441 set history [lrange $history 0 [expr {$i - 1}]]
442 set commit [lindex $dat 0]
443 set path [lindex $dat 1]
444 _load $this [lrange $dat 2 5]
445 }
446
447 method _read_file {fd jump} {
448 if {$fd ne $current_fd} {
449 catch {close $fd}
450 return
451 }
452
453 foreach i $w_columns {$i conf -state normal}
454 while {[gets $fd line] >= 0} {
455 regsub "\r\$" $line {} line
456 incr total_lines
457 lappend amov_data {}
458 lappend asim_data {}
459
460 if {$total_lines > 1} {
461 foreach i $w_columns {$i insert end "\n"}
462 }
463
464 $w_line insert end "$total_lines" linenumber
465 $w_file insert end "$line"
466 }
467
468 set ln_wc [expr {[string length $total_lines] + 2}]
469 if {[$w_line cget -width] < $ln_wc} {
470 $w_line conf -width $ln_wc
471 }
472
473 foreach i $w_columns {$i conf -state disabled}
474
475 if {[eof $fd]} {
476 close $fd
477
478 # If we don't force Tk to update the widgets *right now*
479 # none of our jump commands will cause a change in the UI.
480 #
481 update
482
483 if {[llength $jump] == 1} {
484 set highlight_line [lindex $jump 0]
485 $w_file see "$highlight_line.0"
486 } elseif {[llength $jump] == 4} {
487 set highlight_column [lindex $jump 0]
488 set highlight_line [lindex $jump 1]
489 $w_file xview moveto [lindex $jump 2]
490 $w_file yview moveto [lindex $jump 3]
491 }
492
493 _exec_blame $this $w_asim @asim_data \
494 [list] \
495 [mc "Loading copy/move tracking annotations..."]
496 }
497 } ifdeleted { catch {close $fd} }
498
499 method _exec_blame {cur_w cur_d options cur_s} {
500 lappend options --incremental
501 if {$commit eq {}} {
502 lappend options --contents $path
503 } else {
504 lappend options $commit
505 }
506 lappend options -- $path
507 set fd [eval git_read --nice blame $options]
508 fconfigure $fd -blocking 0 -translation lf -encoding binary
509 fileevent $fd readable [cb _read_blame $fd $cur_w $cur_d]
510 set current_fd $fd
511 set blame_lines 0
512
513 $status start \
514 $cur_s \
515 [mc "lines annotated"]
516 }
517
518 method _read_blame {fd cur_w cur_d} {
519 upvar #0 $cur_d line_data
520 variable group_colors
521
522 if {$fd ne $current_fd} {
523 catch {close $fd}
524 return
525 }
526
527 $cur_w conf -state normal
528 while {[gets $fd line] >= 0} {
529 if {[regexp {^([a-z0-9]{40}) (\d+) (\d+) (\d+)$} $line line \
530 cmit original_line final_line line_count]} {
531 set r_commit $cmit
532 set r_orig_line $original_line
533 set r_final_line $final_line
534 set r_line_count $line_count
535 } elseif {[string match {filename *} $line]} {
536 set file [string range $line 9 end]
537 set n $r_line_count
538 set lno $r_final_line
539 set oln $r_orig_line
540 set cmit $r_commit
541
542 if {[regexp {^0{40}$} $cmit]} {
543 set commit_abbr work
544 set commit_type curr_commit
545 } elseif {$cmit eq $commit} {
546 set commit_abbr this
547 set commit_type curr_commit
548 } else {
549 set commit_type prior_commit
550 set commit_abbr [string range $cmit 0 3]
551 }
552
553 set author_abbr {}
554 set a_name {}
555 catch {set a_name $header($cmit,author)}
556 while {$a_name ne {}} {
557 if {$author_abbr ne {}
558 && [string index $a_name 0] eq {'}} {
559 regsub {^'[^']+'\s+} $a_name {} a_name
560 }
561 if {![regexp {^([[:upper:]])} $a_name _a]} break
562 append author_abbr $_a
563 unset _a
564 if {![regsub \
565 {^[[:upper:]][^\s]*\s+} \
566 $a_name {} a_name ]} break
567 }
568 if {$author_abbr eq {}} {
569 set author_abbr { |}
570 } else {
571 set author_abbr [string range $author_abbr 0 3]
572 }
573 unset a_name
574
575 set first_lno $lno
576 while {
577 $first_lno > 1
578 && $cmit eq [lindex $line_data [expr {$first_lno - 1}] 0]
579 && $file eq [lindex $line_data [expr {$first_lno - 1}] 1]
580 } {
581 incr first_lno -1
582 }
583
584 set color {}
585 if {$first_lno < $lno} {
586 foreach g [$w_file tag names $first_lno.0] {
587 if {[regexp {^color[0-9]+$} $g]} {
588 set color $g
589 break
590 }
591 }
592 } else {
593 set i [lsort [concat \
594 [$w_file tag names "[expr {$first_lno - 1}].0"] \
595 [$w_file tag names "[expr {$lno + $n}].0"] \
596 ]]
597 for {set g 0} {$g < [llength $group_colors]} {incr g} {
598 if {[lsearch -sorted -exact $i color$g] == -1} {
599 set color color$g
600 break
601 }
602 }
603 }
604 if {$color eq {}} {
605 set color color0
606 }
607
608 while {$n > 0} {
609 set lno_e "$lno.0 lineend + 1c"
610 if {[lindex $line_data $lno] ne {}} {
611 set g [lindex $line_data $lno 0]
612 foreach i $w_columns {
613 $i tag remove g$g $lno.0 $lno_e
614 }
615 }
616 lset line_data $lno [list $cmit $file $oln]
617
618 $cur_w delete $lno.0 "$lno.0 lineend"
619 if {$lno == $first_lno} {
620 $cur_w insert $lno.0 $commit_abbr $commit_type
621 } elseif {$lno == [expr {$first_lno + 1}]} {
622 $cur_w insert $lno.0 $author_abbr author_abbr
623 } else {
624 $cur_w insert $lno.0 { |}
625 }
626
627 foreach i $w_columns {
628 if {$cur_w eq $w_amov} {
629 for {set g 0} \
630 {$g < [llength $group_colors]} \
631 {incr g} {
632 $i tag remove color$g $lno.0 $lno_e
633 }
634 $i tag add $color $lno.0 $lno_e
635 }
636 $i tag add g$cmit $lno.0 $lno_e
637 }
638
639 if {$highlight_column eq $cur_w} {
640 if {$highlight_line == -1
641 && [lindex [$w_file yview] 0] == 0} {
642 $w_file see $lno.0
643 set highlight_line $lno
644 }
645 if {$highlight_line == $lno} {
646 _showcommit $this $cur_w $lno
647 }
648 }
649
650 incr n -1
651 incr lno
652 incr oln
653 incr blame_lines
654 }
655
656 while {
657 $cmit eq [lindex $line_data $lno 0]
658 && $file eq [lindex $line_data $lno 1]
659 } {
660 $cur_w delete $lno.0 "$lno.0 lineend"
661
662 if {$lno == $first_lno} {
663 $cur_w insert $lno.0 $commit_abbr $commit_type
664 } elseif {$lno == [expr {$first_lno + 1}]} {
665 $cur_w insert $lno.0 $author_abbr author_abbr
666 } else {
667 $cur_w insert $lno.0 { |}
668 }
669
670 if {$cur_w eq $w_amov} {
671 foreach i $w_columns {
672 for {set g 0} \
673 {$g < [llength $group_colors]} \
674 {incr g} {
675 $i tag remove color$g $lno.0 $lno_e
676 }
677 $i tag add $color $lno.0 $lno_e
678 }
679 }
680
681 incr lno
682 }
683
684 } elseif {[regexp {^([a-z-]+) (.*)$} $line line key data]} {
685 set header($r_commit,$key) $data
686 }
687 }
688 $cur_w conf -state disabled
689
690 if {[eof $fd]} {
691 close $fd
692 if {$cur_w eq $w_asim} {
693 # Switches for original location detection
694 set threshold [get_config gui.copyblamethreshold]
695 set original_options [list "-C$threshold"]
696
697 if {![is_config_true gui.fastcopyblame]} {
698 # thorough copy search; insert before the threshold
699 set original_options [linsert $original_options 0 -C]
700 }
701 if {[git-version >= 1.5.3]} {
702 lappend original_options -w ; # ignore indentation changes
703 }
704
705 _exec_blame $this $w_amov @amov_data \
706 $original_options \
707 [mc "Loading original location annotations..."]
708 } else {
709 set current_fd {}
710 $status stop [mc "Annotation complete."]
711 }
712 } else {
713 $status update $blame_lines $total_lines
714 }
715 } ifdeleted { catch {close $fd} }
716
717 method _find_commit_bound {data_list start_idx delta} {
718 upvar #0 $data_list line_data
719 set pos $start_idx
720 set limit [expr {[llength $line_data] - 1}]
721 set base_commit [lindex $line_data $pos 0]
722
723 while {$pos > 0 && $pos < $limit} {
724 set new_pos [expr {$pos + $delta}]
725 if {[lindex $line_data $new_pos 0] ne $base_commit} {
726 return $pos
727 }
728
729 set pos $new_pos
730 }
731
732 return $pos
733 }
734
735 method _fullcopyblame {} {
736 if {$current_fd ne {}} {
737 tk_messageBox \
738 -icon error \
739 -type ok \
740 -title [mc "Busy"] \
741 -message [mc "Annotation process is already running."]
742
743 return
744 }
745
746 # Switches for original location detection
747 set threshold [get_config gui.copyblamethreshold]
748 set original_options [list -C -C "-C$threshold"]
749
750 if {[git-version >= 1.5.3]} {
751 lappend original_options -w ; # ignore indentation changes
752 }
753
754 # Find the line range
755 set pos @$::cursorX,$::cursorY
756 set lno [lindex [split [$::cursorW index $pos] .] 0]
757 set min_amov_lno [_find_commit_bound $this @amov_data $lno -1]
758 set max_amov_lno [_find_commit_bound $this @amov_data $lno 1]
759 set min_asim_lno [_find_commit_bound $this @asim_data $lno -1]
760 set max_asim_lno [_find_commit_bound $this @asim_data $lno 1]
761
762 if {$min_asim_lno < $min_amov_lno} {
763 set min_amov_lno $min_asim_lno
764 }
765
766 if {$max_asim_lno > $max_amov_lno} {
767 set max_amov_lno $max_asim_lno
768 }
769
770 lappend original_options -L "$min_amov_lno,$max_amov_lno"
771
772 # Clear lines
773 for {set i $min_amov_lno} {$i <= $max_amov_lno} {incr i} {
774 lset amov_data $i [list ]
775 }
776
777 # Start the back-end process
778 _exec_blame $this $w_amov @amov_data \
779 $original_options \
780 [mc "Running thorough copy detection..."]
781 }
782
783 method _click {cur_w pos} {
784 set lno [lindex [split [$cur_w index $pos] .] 0]
785 _showcommit $this $cur_w $lno
786 }
787
788 method _load_commit {cur_w cur_d pos} {
789 upvar #0 $cur_d line_data
790 set lno [lindex [split [$cur_w index $pos] .] 0]
791 set dat [lindex $line_data $lno]
792 if {$dat ne {}} {
793 lappend history [list \
794 $commit $path \
795 $highlight_column \
796 $highlight_line \
797 [lindex [$w_file xview] 0] \
798 [lindex [$w_file yview] 0] \
799 ]
800 set commit [lindex $dat 0]
801 set path [lindex $dat 1]
802 _load $this [list [lindex $dat 2]]
803 }
804 }
805
806 method _showcommit {cur_w lno} {
807 global repo_config
808 variable active_color
809
810 if {$highlight_commit ne {}} {
811 foreach i $w_columns {
812 $i tag conf g$highlight_commit -background {}
813 $i tag lower g$highlight_commit
814 }
815 }
816
817 if {$cur_w eq $w_asim} {
818 set dat [lindex $asim_data $lno]
819 set highlight_column $w_asim
820 } else {
821 set dat [lindex $amov_data $lno]
822 set highlight_column $w_amov
823 }
824
825 $w_cviewer conf -state normal
826 $w_cviewer delete 0.0 end
827
828 if {$dat eq {}} {
829 set cmit {}
830 $w_cviewer insert end [mc "Loading annotation..."] still_loading
831 } else {
832 set cmit [lindex $dat 0]
833 set file [lindex $dat 1]
834
835 foreach i $w_columns {
836 $i tag conf g$cmit -background $active_color
837 $i tag raise g$cmit
838 }
839
840 set author_name {}
841 set author_email {}
842 set author_time {}
843 catch {set author_name $header($cmit,author)}
844 catch {set author_email $header($cmit,author-mail)}
845 catch {set author_time [format_date $header($cmit,author-time)]}
846
847 set committer_name {}
848 set committer_email {}
849 set committer_time {}
850 catch {set committer_name $header($cmit,committer)}
851 catch {set committer_email $header($cmit,committer-mail)}
852 catch {set committer_time [format_date $header($cmit,committer-time)]}
853
854 if {[catch {set msg $header($cmit,message)}]} {
855 set msg {}
856 catch {
857 set fd [git_read cat-file commit $cmit]
858 fconfigure $fd -encoding binary -translation lf
859 if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
860 set enc utf-8
861 }
862 while {[gets $fd line] > 0} {
863 if {[string match {encoding *} $line]} {
864 set enc [string tolower [string range $line 9 end]]
865 }
866 }
867 set msg [read $fd]
868 close $fd
869
870 set enc [tcl_encoding $enc]
871 if {$enc ne {}} {
872 set msg [encoding convertfrom $enc $msg]
873 set author_name [encoding convertfrom $enc $author_name]
874 set committer_name [encoding convertfrom $enc $committer_name]
875 set header($cmit,author) $author_name
876 set header($cmit,committer) $committer_name
877 set header($cmit,summary) \
878 [encoding convertfrom $enc $header($cmit,summary)]
879 }
880 set msg [string trim $msg]
881 }
882 set header($cmit,message) $msg
883 }
884
885 $w_cviewer insert end "commit $cmit\n" header_key
886 $w_cviewer insert end [strcat [mc "Author:"] "\t"] header_key
887 $w_cviewer insert end "$author_name $author_email" header_val
888 $w_cviewer insert end " $author_time\n" header_val
889
890 $w_cviewer insert end [strcat [mc "Committer:"] "\t"] header_key
891 $w_cviewer insert end "$committer_name $committer_email" header_val
892 $w_cviewer insert end " $committer_time\n" header_val
893
894 if {$file ne $path} {
895 $w_cviewer insert end [strcat [mc "Original File:"] "\t"] header_key
896 $w_cviewer insert end "[escape_path $file]\n" header_val
897 }
898
899 $w_cviewer insert end "\n$msg"
900 }
901 $w_cviewer conf -state disabled
902
903 set highlight_line $lno
904 set highlight_commit $cmit
905
906 if {[lsearch -exact $tooltip_commit $highlight_commit] != -1} {
907 _hide_tooltip $this
908 }
909 }
910
911 method _get_click_amov_info {} {
912 set pos @$::cursorX,$::cursorY
913 set lno [lindex [split [$::cursorW index $pos] .] 0]
914 return [lindex $amov_data $lno]
915 }
916
917 method _copycommit {} {
918 set dat [_get_click_amov_info $this]
919 if {$dat ne {}} {
920 clipboard clear
921 clipboard append \
922 -format STRING \
923 -type STRING \
924 -- [lindex $dat 0]
925 }
926 }
927
928 method _format_offset_date {base offset} {
929 set exval [expr {$base + $offset*24*60*60}]
930 return [clock format $exval -format {%Y-%m-%d}]
931 }
932
933 method _gitkcommit {} {
934 set dat [_get_click_amov_info $this]
935 if {$dat ne {}} {
936 set cmit [lindex $dat 0]
937 set radius [get_config gui.blamehistoryctx]
938 set cmdline [list --select-commit=$cmit]
939
940 if {$radius > 0} {
941 set author_time {}
942 set committer_time {}
943
944 catch {set author_time $header($cmit,author-time)}
945 catch {set committer_time $header($cmit,committer-time)}
946
947 if {$committer_time eq {}} {
948 set committer_time $author_time
949 }
950
951 set after_time [_format_offset_date $this $committer_time [expr {-$radius}]]
952 set before_time [_format_offset_date $this $committer_time $radius]
953
954 lappend cmdline --after=$after_time --before=$before_time
955 }
956
957 lappend cmdline $cmit
958
959 set base_rev "HEAD"
960 if {$commit ne {}} {
961 set base_rev $commit
962 }
963
964 if {$base_rev ne $cmit} {
965 lappend cmdline $base_rev
966 }
967
968 do_gitk $cmdline
969 }
970 }
971
972 method _show_tooltip {cur_w pos} {
973 if {$tooltip_wm ne {}} {
974 _open_tooltip $this $cur_w
975 } elseif {$tooltip_timer eq {}} {
976 set tooltip_timer [after 1000 [cb _open_tooltip $cur_w]]
977 }
978 }
979
980 method _open_tooltip {cur_w} {
981 set tooltip_timer {}
982 set pos_x [winfo pointerx $cur_w]
983 set pos_y [winfo pointery $cur_w]
984 if {[winfo containing $pos_x $pos_y] ne $cur_w} {
985 _hide_tooltip $this
986 return
987 }
988
989 if {$tooltip_wm ne "$cur_w.tooltip"} {
990 _hide_tooltip $this
991
992 set tooltip_wm [toplevel $cur_w.tooltip -borderwidth 1]
993 wm overrideredirect $tooltip_wm 1
994 wm transient $tooltip_wm [winfo toplevel $cur_w]
995 set tooltip_t $tooltip_wm.label
996 text $tooltip_t \
997 -takefocus 0 \
998 -highlightthickness 0 \
999 -relief flat \
1000 -borderwidth 0 \
1001 -wrap none \
1002 -background lightyellow \
1003 -foreground black
1004 $tooltip_t tag conf section_header -font font_uibold
1005 pack $tooltip_t
1006 } else {
1007 $tooltip_t conf -state normal
1008 $tooltip_t delete 0.0 end
1009 }
1010
1011 set pos @[join [list \
1012 [expr {$pos_x - [winfo rootx $cur_w]}] \
1013 [expr {$pos_y - [winfo rooty $cur_w]}]] ,]
1014 set lno [lindex [split [$cur_w index $pos] .] 0]
1015 if {$cur_w eq $w_amov} {
1016 set dat [lindex $amov_data $lno]
1017 set org {}
1018 } else {
1019 set dat [lindex $asim_data $lno]
1020 set org [lindex $amov_data $lno]
1021 }
1022
1023 if {$dat eq {}} {
1024 _hide_tooltip $this
1025 return
1026 }
1027
1028 set cmit [lindex $dat 0]
1029 set tooltip_commit [list $cmit]
1030
1031 set author_name {}
1032 set summary {}
1033 set author_time {}
1034 catch {set author_name $header($cmit,author)}
1035 catch {set summary $header($cmit,summary)}
1036 catch {set author_time [format_date $header($cmit,author-time)]}
1037
1038 $tooltip_t insert end "commit $cmit\n"
1039 $tooltip_t insert end "$author_name $author_time\n"
1040 $tooltip_t insert end "$summary"
1041
1042 if {$org ne {} && [lindex $org 0] ne $cmit} {
1043 set save [$tooltip_t get 0.0 end]
1044 $tooltip_t delete 0.0 end
1045
1046 set cmit [lindex $org 0]
1047 set file [lindex $org 1]
1048 lappend tooltip_commit $cmit
1049
1050 set author_name {}
1051 set summary {}
1052 set author_time {}
1053 catch {set author_name $header($cmit,author)}
1054 catch {set summary $header($cmit,summary)}
1055 catch {set author_time [format_date $header($cmit,author-time)]}
1056
1057 $tooltip_t insert end [strcat [mc "Originally By:"] "\n"] section_header
1058 $tooltip_t insert end "commit $cmit\n"
1059 $tooltip_t insert end "$author_name $author_time\n"
1060 $tooltip_t insert end "$summary\n"
1061
1062 if {$file ne $path} {
1063 $tooltip_t insert end [strcat [mc "In File:"] " "] section_header
1064 $tooltip_t insert end "$file\n"
1065 }
1066
1067 $tooltip_t insert end "\n"
1068 $tooltip_t insert end [strcat [mc "Copied Or Moved Here By:"] "\n"] section_header
1069 $tooltip_t insert end $save
1070 }
1071
1072 $tooltip_t conf -state disabled
1073 _position_tooltip $this
1074 }
1075
1076 method _position_tooltip {} {
1077 set max_h [lindex [split [$tooltip_t index end] .] 0]
1078 set max_w 0
1079 for {set i 1} {$i <= $max_h} {incr i} {
1080 set c [lindex [split [$tooltip_t index "$i.0 lineend"] .] 1]
1081 if {$c > $max_w} {set max_w $c}
1082 }
1083 $tooltip_t conf -width $max_w -height $max_h
1084
1085 set req_w [winfo reqwidth $tooltip_t]
1086 set req_h [winfo reqheight $tooltip_t]
1087 set pos_x [expr {[winfo pointerx .] + 5}]
1088 set pos_y [expr {[winfo pointery .] + 10}]
1089
1090 set g "${req_w}x${req_h}"
1091 if {$pos_x >= 0} {append g +}
1092 append g $pos_x
1093 if {$pos_y >= 0} {append g +}
1094 append g $pos_y
1095
1096 wm geometry $tooltip_wm $g
1097 raise $tooltip_wm
1098 }
1099
1100 method _hide_tooltip {} {
1101 if {$tooltip_wm ne {}} {
1102 destroy $tooltip_wm
1103 set tooltip_wm {}
1104 set tooltip_commit {}
1105 }
1106 if {$tooltip_timer ne {}} {
1107 after cancel $tooltip_timer
1108 set tooltip_timer {}
1109 }
1110 }
1111
1112 method _resize {new_height} {
1113 set diff [expr {$new_height - $old_height}]
1114 if {$diff == 0} return
1115
1116 set my [expr {[winfo height $w.file_pane] - 25}]
1117 set o [$w.file_pane sash coord 0]
1118 set ox [lindex $o 0]
1119 set oy [expr {[lindex $o 1] + $diff}]
1120 if {$oy < 0} {set oy 0}
1121 if {$oy > $my} {set oy $my}
1122 $w.file_pane sash place 0 $ox $oy
1123
1124 set old_height $new_height
1125 }
1126
1127 }