Merge branch 'ak/maint-for-each-ref-no-lookup' into maint
[git/git.git] / configure.ac
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
3
4 AC_PREREQ(2.59)
5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
6
7 AC_CONFIG_SRCDIR([git.c])
8
9 config_file=config.mak.autogen
10 config_append=config.mak.append
11 config_in=config.mak.in
12
13 echo "# ${config_append}. Generated by configure." > "${config_append}"
14
15
16 ## Definitions of macros
17 # GIT_CONF_APPEND_LINE(LINE)
18 # --------------------------
19 # Append LINE to file ${config_append}
20 AC_DEFUN([GIT_CONF_APPEND_LINE],
21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
22 #
23 # GIT_ARG_SET_PATH(PROGRAM)
24 # -------------------------
25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
26 AC_DEFUN([GIT_ARG_SET_PATH],
27 [AC_ARG_WITH([$1],
28 [AS_HELP_STRING([--with-$1=PATH],
29 [provide PATH to $1])],
30 [GIT_CONF_APPEND_PATH($1)],[])
31 ])# GIT_ARG_SET_PATH
32 #
33 # GIT_CONF_APPEND_PATH(PROGRAM)
34 # ------------------------------
35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
36 # Used by GIT_ARG_SET_PATH(PROGRAM)
37 AC_DEFUN([GIT_CONF_APPEND_PATH],
38 [PROGRAM=m4_toupper($1); \
39 if test "$withval" = "no"; then \
40 AC_MSG_ERROR([You cannot use git without $1]); \
41 else \
42 if test "$withval" = "yes"; then \
43 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
44 else \
45 m4_toupper($1)_PATH=$withval; \
46 AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
47 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
48 fi; \
49 fi; \
50 ]) # GIT_CONF_APPEND_PATH
51 #
52 # GIT_PARSE_WITH(PACKAGE)
53 # -----------------------
54 # For use in AC_ARG_WITH action-if-found, for packages default ON.
55 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
56 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
57 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
58 AC_DEFUN([GIT_PARSE_WITH],
59 [PACKAGE=m4_toupper($1); \
60 if test "$withval" = "no"; then \
61 m4_toupper(NO_$1)=YesPlease; \
62 elif test "$withval" = "yes"; then \
63 m4_toupper(NO_$1)=; \
64 else \
65 m4_toupper(NO_$1)=; \
66 m4_toupper($1)DIR=$withval; \
67 AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
68 GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
69 fi \
70 ])# GIT_PARSE_WITH
71
72 dnl
73 dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
74 dnl -----------------------------------------
75 dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
76 dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
77 dnl -Wall), it does not work. By looking for function definition in
78 dnl libraries, this problem can be worked around.
79 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
80 AC_SEARCH_LIBS([$1],,
81 [$2],[$3])
82 ],[$3])])
83
84 dnl
85 dnl GIT_STASH_FLAGS(BASEPATH_VAR)
86 dnl -----------------------------
87 dnl Allow for easy stashing of LDFLAGS and CPPFLAGS before running
88 dnl tests that may want to take user settings into account.
89 AC_DEFUN([GIT_STASH_FLAGS],[
90 if test -n "$1"; then
91 old_CPPFLAGS="$CPPFLAGS"
92 old_LDFLAGS="$LDFLAGS"
93 CPPFLAGS="-I$1/include $CPPFLAGS"
94 LDFLAGS="-L$1/$lib $LDFLAGS"
95 fi
96 ])
97
98 dnl
99 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
100 dnl -----------------------------
101 dnl Restore the stashed *FLAGS values.
102 AC_DEFUN([GIT_UNSTASH_FLAGS],[
103 if test -n "$1"; then
104 CPPFLAGS="$old_CPPFLAGS"
105 LDFLAGS="$old_LDFLAGS"
106 fi
107 ])
108
109 ## Site configuration related to programs (before tests)
110 ## --with-PACKAGE[=ARG] and --without-PACKAGE
111 #
112 # Set lib to alternative name of lib directory (e.g. lib64)
113 AC_ARG_WITH([lib],
114 [AS_HELP_STRING([--with-lib=ARG],
115 [ARG specifies alternative name for lib directory])],
116 [if test "$withval" = "no" || test "$withval" = "yes"; then \
117 AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
118 else \
119 lib=$withval; \
120 AC_MSG_NOTICE([Setting lib to '$lib']); \
121 GIT_CONF_APPEND_LINE(lib=$withval); \
122 fi; \
123 ],[])
124
125 if test -z "$lib"; then
126 AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
127 lib=lib
128 fi
129
130 AC_ARG_ENABLE([pthreads],
131 [AS_HELP_STRING([--enable-pthreads=FLAGS],
132 [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
133 [The default if FLAGS is not specified is to try first -pthread]
134 [and then -lpthread.]
135 [--without-pthreads will disable threading.])],
136 [
137 if test "x$enableval" = "xyes"; then
138 AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
139 elif test "x$enableval" != "xno"; then
140 PTHREAD_CFLAGS=$enableval
141 AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
142 else
143 AC_MSG_NOTICE([POSIX Threads will be disabled.])
144 NO_PTHREADS=YesPlease
145 USER_NOPTHREAD=1
146 fi],
147 [
148 AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
149 ])
150
151 ## Site configuration (override autodetection)
152 ## --with-PACKAGE[=ARG] and --without-PACKAGE
153 AC_MSG_NOTICE([CHECKS for site configuration])
154 #
155 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
156 # tests. These tests take up a significant amount of the total test time
157 # but are not needed unless you plan to talk to SVN repos.
158 #
159 # Define MOZILLA_SHA1 environment variable when running make to make use of
160 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
161 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
162 # choice) has very fast version optimized for i586.
163 #
164 # Define PPC_SHA1 environment variable when running make to make use of
165 # a bundled SHA1 routine optimized for PowerPC.
166 #
167 # Define ARM_SHA1 environment variable when running make to make use of
168 # a bundled SHA1 routine optimized for ARM.
169 #
170 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
171 # This also implies MOZILLA_SHA1.
172 #
173 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
174 # /foo/bar/include and /foo/bar/lib directories.
175 AC_ARG_WITH(openssl,
176 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
177 AS_HELP_STRING([], [ARG can be prefix for openssl library and headers]),\
178 GIT_PARSE_WITH(openssl))
179 #
180 # Define NO_CURL if you do not have curl installed. git-http-pull and
181 # git-http-push are not built, and you cannot use http:// and https://
182 # transports.
183 #
184 # Define CURLDIR=/foo/bar if your curl header and library files are in
185 # /foo/bar/include and /foo/bar/lib directories.
186 AC_ARG_WITH(curl,
187 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
188 AS_HELP_STRING([], [ARG can be also prefix for curl library and headers]),
189 GIT_PARSE_WITH(curl))
190 #
191 # Define NO_EXPAT if you do not have expat installed. git-http-push is
192 # not built, and you cannot push using http:// and https:// transports.
193 #
194 # Define EXPATDIR=/foo/bar if your expat header and library files are in
195 # /foo/bar/include and /foo/bar/lib directories.
196 AC_ARG_WITH(expat,
197 AS_HELP_STRING([--with-expat],
198 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
199 AS_HELP_STRING([], [ARG can be also prefix for expat library and headers]),
200 GIT_PARSE_WITH(expat))
201 #
202 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
203 # installed in /sw, but don't want GIT to link against any libraries
204 # installed there. If defined you may specify your own (or Fink's)
205 # include directories and library directories by defining CFLAGS
206 # and LDFLAGS appropriately.
207 #
208 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
209 # have DarwinPorts installed in /opt/local, but don't want GIT to
210 # link against any libraries installed there. If defined you may
211 # specify your own (or DarwinPort's) include directories and
212 # library directories by defining CFLAGS and LDFLAGS appropriately.
213 #
214 # Define NO_MMAP if you want to avoid mmap.
215 #
216 # Define NO_ICONV if your libc does not properly support iconv.
217 AC_ARG_WITH(iconv,
218 AS_HELP_STRING([--without-iconv],
219 [if your architecture doesn't properly support iconv])
220 AS_HELP_STRING([--with-iconv=PATH],
221 [PATH is prefix for libiconv library and headers])
222 AS_HELP_STRING([],
223 [used only if you need linking with libiconv]),
224 GIT_PARSE_WITH(iconv))
225
226 ## --enable-FEATURE[=ARG] and --disable-FEATURE
227 #
228 # Define USE_NSEC below if you want git to care about sub-second file mtimes
229 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
230 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
231 # randomly break unless your underlying filesystem supports those sub-second
232 # times (my ext3 doesn't).
233 #
234 # Define USE_STDEV below if you want git to care about the underlying device
235 # change being considered an inode change from the update-index perspective.
236
237 #
238 # Define SHELL_PATH to provide path to shell.
239 GIT_ARG_SET_PATH(shell)
240 #
241 # Define PERL_PATH to provide path to Perl.
242 GIT_ARG_SET_PATH(perl)
243 #
244 # Define ZLIB_PATH to provide path to zlib.
245 GIT_ARG_SET_PATH(zlib)
246 #
247 # Declare the with-tcltk/without-tcltk options.
248 AC_ARG_WITH(tcltk,
249 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
250 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
251 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
252 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
253 GIT_PARSE_WITH(tcltk))
254 #
255
256
257 ## Checks for programs.
258 AC_MSG_NOTICE([CHECKS for programs])
259 #
260 AC_PROG_CC([cc gcc])
261 # which switch to pass runtime path to dynamic libraries to the linker
262 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
263 SAVE_LDFLAGS="${LDFLAGS}"
264 LDFLAGS="${SAVE_LDFLAGS} -R /"
265 AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
266 LDFLAGS="${SAVE_LDFLAGS}"
267 ])
268 if test "$git_cv_ld_dashr" = "yes"; then
269 AC_SUBST(CC_LD_DYNPATH, [-R])
270 else
271 AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
272 SAVE_LDFLAGS="${LDFLAGS}"
273 LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
274 AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
275 LDFLAGS="${SAVE_LDFLAGS}"
276 ])
277 if test "$git_cv_ld_wl_rpath" = "yes"; then
278 AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
279 else
280 AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
281 SAVE_LDFLAGS="${LDFLAGS}"
282 LDFLAGS="${SAVE_LDFLAGS} -rpath /"
283 AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
284 LDFLAGS="${SAVE_LDFLAGS}"
285 ])
286 if test "$git_cv_ld_rpath" = "yes"; then
287 AC_SUBST(CC_LD_DYNPATH, [-rpath])
288 else
289 AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
290 fi
291 fi
292 fi
293 #AC_PROG_INSTALL # needs install-sh or install.sh in sources
294 AC_CHECK_TOOLS(AR, [gar ar], :)
295 AC_CHECK_PROGS(TAR, [gtar tar])
296 # TCLTK_PATH will be set to some value if we want Tcl/Tk
297 # or will be empty otherwise.
298 if test -z "$NO_TCLTK"; then
299 if test "$with_tcltk" = ""; then
300 # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
301 TCLTK_PATH=wish
302 AC_SUBST(TCLTK_PATH)
303 elif test "$with_tcltk" = "yes"; then
304 # Tcl/Tk check requested.
305 AC_CHECK_PROGS(TCLTK_PATH, [wish], )
306 else
307 AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
308 TCLTK_PATH="$with_tcltk"
309 AC_SUBST(TCLTK_PATH)
310 fi
311 fi
312 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
313 if test -n "$ASCIIDOC"; then
314 AC_MSG_CHECKING([for asciidoc version])
315 asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
316 case "${asciidoc_version}" in
317 asciidoc' '8*)
318 ASCIIDOC8=YesPlease
319 AC_MSG_RESULT([${asciidoc_version} > 7])
320 ;;
321 asciidoc' '7*)
322 ASCIIDOC8=
323 AC_MSG_RESULT([${asciidoc_version}])
324 ;;
325 *)
326 ASCIIDOC8=
327 AC_MSG_RESULT([${asciidoc_version} (unknown)])
328 ;;
329 esac
330 fi
331 AC_SUBST(ASCIIDOC8)
332
333
334 ## Checks for libraries.
335 AC_MSG_NOTICE([CHECKS for libraries])
336 #
337 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
338 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
339
340 GIT_STASH_FLAGS($OPENSSLDIR)
341
342 AC_CHECK_LIB([crypto], [SHA1_Init],
343 [NEEDS_SSL_WITH_CRYPTO=],
344 [AC_CHECK_LIB([ssl], [SHA1_Init],
345 [NEEDS_SSL_WITH_CRYPTO=YesPlease
346 NEEDS_SSL_WITH_CRYPTO=],
347 [NO_OPENSSL=YesPlease])])
348
349 GIT_UNSTASH_FLAGS($OPENSSLDIR)
350
351 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
352 AC_SUBST(NO_OPENSSL)
353
354 #
355 # Define NO_CURL if you do not have libcurl installed. git-http-pull and
356 # git-http-push are not built, and you cannot use http:// and https://
357 # transports.
358
359 GIT_STASH_FLAGS($CURLDIR)
360
361 AC_CHECK_LIB([curl], [curl_global_init],
362 [NO_CURL=],
363 [NO_CURL=YesPlease])
364
365 GIT_UNSTASH_FLAGS($CURLDIR)
366
367 AC_SUBST(NO_CURL)
368
369 #
370 # Define NO_EXPAT if you do not have expat installed. git-http-push is
371 # not built, and you cannot push using http:// and https:// transports.
372
373 GIT_STASH_FLAGS($EXPATDIR)
374
375 AC_CHECK_LIB([expat], [XML_ParserCreate],
376 [NO_EXPAT=],
377 [NO_EXPAT=YesPlease])
378
379 GIT_UNSTASH_FLAGS($EXPATDIR)
380
381 AC_SUBST(NO_EXPAT)
382
383 #
384 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
385 # some Solaris installations).
386 # Define NO_ICONV if neither libc nor libiconv support iconv.
387
388 if test -z "$NO_ICONV"; then
389
390 GIT_STASH_FLAGS($ICONVDIR)
391
392 AC_DEFUN([ICONVTEST_SRC], [
393 #include <iconv.h>
394
395 int main(void)
396 {
397 iconv_open("", "");
398 return 0;
399 }
400 ])
401
402 if test -n "$ICONVDIR"; then
403 lib_order="-liconv -lc"
404 else
405 lib_order="-lc -liconv"
406 fi
407
408 NO_ICONV=YesPlease
409
410 for l in $lib_order; do
411 if test "$l" = "-liconv"; then
412 NEEDS_LIBICONV=YesPlease
413 else
414 NEEDS_LIBICONV=
415 fi
416
417 old_LIBS="$LIBS"
418 LIBS="$LIBS $l"
419 AC_MSG_CHECKING([for iconv in $l])
420 AC_LINK_IFELSE(ICONVTEST_SRC,
421 [AC_MSG_RESULT([yes])
422 NO_ICONV=
423 break],
424 [AC_MSG_RESULT([no])])
425 LIBS="$old_LIBS"
426 done
427
428 #in case of break
429 LIBS="$old_LIBS"
430
431 GIT_UNSTASH_FLAGS($ICONVDIR)
432
433 AC_SUBST(NEEDS_LIBICONV)
434 AC_SUBST(NO_ICONV)
435
436 if test -n "$NO_ICONV"; then
437 NEEDS_LIBICONV=
438 fi
439
440 fi
441
442 #
443 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
444
445 GIT_STASH_FLAGS($ZLIB_PATH)
446
447 AC_DEFUN([ZLIBTEST_SRC], [
448 #include <zlib.h>
449
450 int main(void)
451 {
452 deflateBound(0, 0);
453 return 0;
454 }
455 ])
456 AC_MSG_CHECKING([for deflateBound in -lz])
457 old_LIBS="$LIBS"
458 LIBS="$LIBS -lz"
459 AC_LINK_IFELSE(ZLIBTEST_SRC,
460 [AC_MSG_RESULT([yes])],
461 [AC_MSG_RESULT([no])
462 NO_DEFLATE_BOUND=yes])
463 LIBS="$old_LIBS"
464
465 GIT_UNSTASH_FLAGS($ZLIB_PATH)
466
467 AC_SUBST(NO_DEFLATE_BOUND)
468
469 #
470 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
471 # Patrick Mauritz).
472 AC_CHECK_LIB([c], [socket],
473 [NEEDS_SOCKET=],
474 [NEEDS_SOCKET=YesPlease])
475 AC_SUBST(NEEDS_SOCKET)
476 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
477
478
479 ## Checks for header files.
480 AC_MSG_NOTICE([CHECKS for header files])
481 #
482 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
483 AC_CHECK_HEADER([sys/select.h],
484 [NO_SYS_SELECT_H=],
485 [NO_SYS_SELECT_H=UnfortunatelyYes])
486 AC_SUBST(NO_SYS_SELECT_H)
487 #
488 # Define OLD_ICONV if your library has an old iconv(), where the second
489 # (input buffer pointer) parameter is declared with type (const char **).
490 AC_DEFUN([OLDICONVTEST_SRC], [[
491 #include <iconv.h>
492
493 extern size_t iconv(iconv_t cd,
494 char **inbuf, size_t *inbytesleft,
495 char **outbuf, size_t *outbytesleft);
496
497 int main(void)
498 {
499 return 0;
500 }
501 ]])
502
503 GIT_STASH_FLAGS($ICONVDIR)
504
505 AC_MSG_CHECKING([for old iconv()])
506 AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
507 [AC_MSG_RESULT([no])],
508 [AC_MSG_RESULT([yes])
509 OLD_ICONV=UnfortunatelyYes])
510
511 GIT_UNSTASH_FLAGS($ICONVDIR)
512
513 AC_SUBST(OLD_ICONV)
514
515 ## Checks for typedefs, structures, and compiler characteristics.
516 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
517 #
518 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
519 AC_CHECK_MEMBER(struct dirent.d_ino,
520 [NO_D_INO_IN_DIRENT=],
521 [NO_D_INO_IN_DIRENT=YesPlease],
522 [#include <dirent.h>])
523 AC_SUBST(NO_D_INO_IN_DIRENT)
524 #
525 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
526 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
527 AC_CHECK_MEMBER(struct dirent.d_type,
528 [NO_D_TYPE_IN_DIRENT=],
529 [NO_D_TYPE_IN_DIRENT=YesPlease],
530 [#include <dirent.h>])
531 AC_SUBST(NO_D_TYPE_IN_DIRENT)
532 #
533 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
534 # sockaddr_storage.
535 AC_CHECK_TYPE(struct sockaddr_storage,
536 [NO_SOCKADDR_STORAGE=],
537 [NO_SOCKADDR_STORAGE=YesPlease],[
538 #include <sys/types.h>
539 #include <sys/socket.h>
540 ])
541 AC_SUBST(NO_SOCKADDR_STORAGE)
542 #
543 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
544 AC_CHECK_TYPE([struct addrinfo],[
545 GIT_CHECK_FUNC([getaddrinfo],
546 [NO_IPV6=],
547 [NO_IPV6=YesPlease])
548 ],[NO_IPV6=YesPlease],[
549 #include <sys/types.h>
550 #include <sys/socket.h>
551 #include <netdb.h>
552 ])
553 AC_SUBST(NO_IPV6)
554 #
555 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
556 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
557 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
558 # some C compilers supported these specifiers prior to C99 as an extension.
559 AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
560 [ac_cv_c_c99_format],
561 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
562 AC_RUN_IFELSE(
563 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
564 [[char buf[64];
565 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
566 return 1;
567 else if (strcmp(buf, "12345"))
568 return 2;]])],
569 [ac_cv_c_c99_format=yes],
570 [ac_cv_c_c99_format=no])
571 ])
572 if test $ac_cv_c_c99_format = no; then
573 NO_C99_FORMAT=YesPlease
574 else
575 NO_C99_FORMAT=
576 fi
577 AC_SUBST(NO_C99_FORMAT)
578 #
579 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
580 # when attempting to read from an fopen'ed directory.
581 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
582 [ac_cv_fread_reads_directories],
583 [
584 AC_RUN_IFELSE(
585 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
586 [[char c;
587 FILE *f = fopen(".", "r");
588 return f && fread(&c, 1, 1, f)]])],
589 [ac_cv_fread_reads_directories=no],
590 [ac_cv_fread_reads_directories=yes])
591 ])
592 if test $ac_cv_fread_reads_directories = yes; then
593 FREAD_READS_DIRECTORIES=UnfortunatelyYes
594 else
595 FREAD_READS_DIRECTORIES=
596 fi
597 AC_SUBST(FREAD_READS_DIRECTORIES)
598 #
599 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
600 # or vsnprintf() return -1 instead of number of characters which would
601 # have been written to the final string if enough space had been available.
602 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
603 [ac_cv_snprintf_returns_bogus],
604 [
605 AC_RUN_IFELSE(
606 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
607 #include "stdarg.h"
608
609 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
610 {
611 int ret;
612 va_list ap;
613 va_start(ap, format);
614 ret = vsnprintf(str, maxsize, format, ap);
615 va_end(ap);
616 return ret;
617 }],
618 [[char buf[6];
619 if (test_vsnprintf(buf, 3, "%s", "12345") != 5
620 || strcmp(buf, "12")) return 1;
621 if (snprintf(buf, 3, "%s", "12345") != 5
622 || strcmp(buf, "12")) return 1]])],
623 [ac_cv_snprintf_returns_bogus=no],
624 [ac_cv_snprintf_returns_bogus=yes])
625 ])
626 if test $ac_cv_snprintf_returns_bogus = yes; then
627 SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
628 else
629 SNPRINTF_RETURNS_BOGUS=
630 fi
631 AC_SUBST(SNPRINTF_RETURNS_BOGUS)
632
633
634 ## Checks for library functions.
635 ## (in default C library and libraries checked by AC_CHECK_LIB)
636 AC_MSG_NOTICE([CHECKS for library functions])
637 #
638 # Define NO_STRCASESTR if you don't have strcasestr.
639 GIT_CHECK_FUNC(strcasestr,
640 [NO_STRCASESTR=],
641 [NO_STRCASESTR=YesPlease])
642 AC_SUBST(NO_STRCASESTR)
643 #
644 # Define NO_MEMMEM if you don't have memmem.
645 GIT_CHECK_FUNC(memmem,
646 [NO_MEMMEM=],
647 [NO_MEMMEM=YesPlease])
648 AC_SUBST(NO_MEMMEM)
649 #
650 # Define NO_STRLCPY if you don't have strlcpy.
651 GIT_CHECK_FUNC(strlcpy,
652 [NO_STRLCPY=],
653 [NO_STRLCPY=YesPlease])
654 AC_SUBST(NO_STRLCPY)
655 #
656 # Define NO_UINTMAX_T if your platform does not have uintmax_t
657 AC_CHECK_TYPE(uintmax_t,
658 [NO_UINTMAX_T=],
659 [NO_UINTMAX_T=YesPlease],[
660 #include <inttypes.h>
661 ])
662 AC_SUBST(NO_UINTMAX_T)
663 #
664 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
665 GIT_CHECK_FUNC(strtoumax,
666 [NO_STRTOUMAX=],
667 [NO_STRTOUMAX=YesPlease])
668 AC_SUBST(NO_STRTOUMAX)
669 #
670 # Define NO_SETENV if you don't have setenv in the C library.
671 GIT_CHECK_FUNC(setenv,
672 [NO_SETENV=],
673 [NO_SETENV=YesPlease])
674 AC_SUBST(NO_SETENV)
675 #
676 # Define NO_UNSETENV if you don't have unsetenv in the C library.
677 GIT_CHECK_FUNC(unsetenv,
678 [NO_UNSETENV=],
679 [NO_UNSETENV=YesPlease])
680 AC_SUBST(NO_UNSETENV)
681 #
682 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
683 GIT_CHECK_FUNC(mkdtemp,
684 [NO_MKDTEMP=],
685 [NO_MKDTEMP=YesPlease])
686 AC_SUBST(NO_MKDTEMP)
687 #
688 # Define NO_MMAP if you want to avoid mmap.
689 #
690 # Define NO_ICONV if your libc does not properly support iconv.
691
692
693 ## Other checks.
694 # Define USE_PIC if you need the main git objects to be built with -fPIC
695 # in order to build and link perl/Git.so. x86-64 seems to need this.
696 #
697 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
698 # Enable it on Windows. By default, symrefs are still used.
699 #
700 # Define NO_PTHREADS if we do not have pthreads
701 #
702 # Define PTHREAD_LIBS to the linker flag used for Pthread support and define
703 # THREADED_DELTA_SEARCH if Pthreads are available.
704 AC_DEFUN([PTHREADTEST_SRC], [
705 #include <pthread.h>
706
707 int main(void)
708 {
709 pthread_mutex_t test_mutex;
710 return (0);
711 }
712 ])
713
714 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
715 dnl [[#include <pthread.h>]],
716 dnl [[pthread_mutex_t test_mutex;]]
717 dnl )])
718
719 NO_PTHREADS=UnfortunatelyYes
720 THREADED_DELTA_SEARCH=
721 PTHREAD_LIBS=
722
723 if test -n "$USER_NOPTHREAD"; then
724 AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
725 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
726 # -D_REENTRANT' or some such.
727 elif test -z "$PTHREAD_CFLAGS"; then
728 for opt in -pthread -lpthread; do
729 old_CFLAGS="$CFLAGS"
730 CFLAGS="$opt $CFLAGS"
731 AC_MSG_CHECKING([Checking for POSIX Threads with '$opt'])
732 AC_LINK_IFELSE(PTHREADTEST_SRC,
733 [AC_MSG_RESULT([yes])
734 NO_PTHREADS=
735 PTHREAD_LIBS="$opt"
736 THREADED_DELTA_SEARCH=YesPlease
737 break
738 ],
739 [AC_MSG_RESULT([no])])
740 CFLAGS="$old_CFLAGS"
741 done
742 else
743 old_CFLAGS="$CFLAGS"
744 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
745 AC_MSG_CHECKING([Checking for POSIX Threads with '$PTHREAD_CFLAGS'])
746 AC_LINK_IFELSE(PTHREADTEST_SRC,
747 [AC_MSG_RESULT([yes])
748 NO_PTHREADS=
749 PTHREAD_LIBS="$PTHREAD_CFLAGS"
750 THREADED_DELTA_SEARCH=YesPlease
751 ],
752 [AC_MSG_RESULT([no])])
753
754 CFLAGS="$old_CFLAGS"
755 fi
756
757 CFLAGS="$old_CFLAGS"
758
759 AC_SUBST(PTHREAD_LIBS)
760 AC_SUBST(NO_PTHREADS)
761 AC_SUBST(THREADED_DELTA_SEARCH)
762
763 ## Output files
764 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
765 AC_OUTPUT
766
767
768 ## Cleanup
769 rm -f "${config_append}"