Merge branch 'db/remote-builtin' into jk/send-pack
[git/git.git] / gitweb / gitweb.perl
1 #!/usr/bin/perl
2
3 # gitweb - simple web interface to track changes in git repositories
4 #
5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
6 # (C) 2005, Christian Gierke
7 #
8 # This program is licensed under the GPLv2
9
10 use strict;
11 use warnings;
12 use CGI qw(:standard :escapeHTML -nosticky);
13 use CGI::Util qw(unescape);
14 use CGI::Carp qw(fatalsToBrowser);
15 use Encode;
16 use Fcntl ':mode';
17 use File::Find qw();
18 use File::Basename qw(basename);
19 binmode STDOUT, ':utf8';
20
21 BEGIN {
22 CGI->compile() if $ENV{'MOD_PERL'};
23 }
24
25 our $cgi = new CGI;
26 our $version = "++GIT_VERSION++";
27 our $my_url = $cgi->url();
28 our $my_uri = $cgi->url(-absolute => 1);
29
30 # core git executable to use
31 # this can just be "git" if your webserver has a sensible PATH
32 our $GIT = "++GIT_BINDIR++/git";
33
34 # absolute fs-path which will be prepended to the project path
35 #our $projectroot = "/pub/scm";
36 our $projectroot = "++GITWEB_PROJECTROOT++";
37
38 # fs traversing limit for getting project list
39 # the number is relative to the projectroot
40 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
41
42 # target of the home link on top of all pages
43 our $home_link = $my_uri || "/";
44
45 # string of the home link on top of all pages
46 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
47
48 # name of your site or organization to appear in page titles
49 # replace this with something more descriptive for clearer bookmarks
50 our $site_name = "++GITWEB_SITENAME++"
51 || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
52
53 # filename of html text to include at top of each page
54 our $site_header = "++GITWEB_SITE_HEADER++";
55 # html text to include at home page
56 our $home_text = "++GITWEB_HOMETEXT++";
57 # filename of html text to include at bottom of each page
58 our $site_footer = "++GITWEB_SITE_FOOTER++";
59
60 # URI of stylesheets
61 our @stylesheets = ("++GITWEB_CSS++");
62 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
63 our $stylesheet = undef;
64 # URI of GIT logo (72x27 size)
65 our $logo = "++GITWEB_LOGO++";
66 # URI of GIT favicon, assumed to be image/png type
67 our $favicon = "++GITWEB_FAVICON++";
68
69 # URI and label (title) of GIT logo link
70 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
71 #our $logo_label = "git documentation";
72 our $logo_url = "http://git.or.cz/";
73 our $logo_label = "git homepage";
74
75 # source of projects list
76 our $projects_list = "++GITWEB_LIST++";
77
78 # the width (in characters) of the projects list "Description" column
79 our $projects_list_description_width = 25;
80
81 # default order of projects list
82 # valid values are none, project, descr, owner, and age
83 our $default_projects_order = "project";
84
85 # show repository only if this file exists
86 # (only effective if this variable evaluates to true)
87 our $export_ok = "++GITWEB_EXPORT_OK++";
88
89 # only allow viewing of repositories also shown on the overview page
90 our $strict_export = "++GITWEB_STRICT_EXPORT++";
91
92 # list of git base URLs used for URL to where fetch project from,
93 # i.e. full URL is "$git_base_url/$project"
94 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
95
96 # default blob_plain mimetype and default charset for text/plain blob
97 our $default_blob_plain_mimetype = 'text/plain';
98 our $default_text_plain_charset = undef;
99
100 # file to use for guessing MIME types before trying /etc/mime.types
101 # (relative to the current git repository)
102 our $mimetypes_file = undef;
103
104 # assume this charset if line contains non-UTF-8 characters;
105 # it should be valid encoding (see Encoding::Supported(3pm) for list),
106 # for which encoding all byte sequences are valid, for example
107 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
108 # could be even 'utf-8' for the old behavior)
109 our $fallback_encoding = 'latin1';
110
111 # rename detection options for git-diff and git-diff-tree
112 # - default is '-M', with the cost proportional to
113 # (number of removed files) * (number of new files).
114 # - more costly is '-C' (which implies '-M'), with the cost proportional to
115 # (number of changed files + number of removed files) * (number of new files)
116 # - even more costly is '-C', '--find-copies-harder' with cost
117 # (number of files in the original tree) * (number of new files)
118 # - one might want to include '-B' option, e.g. '-B', '-M'
119 our @diff_opts = ('-M'); # taken from git_commit
120
121 # information about snapshot formats that gitweb is capable of serving
122 our %known_snapshot_formats = (
123 # name => {
124 # 'display' => display name,
125 # 'type' => mime type,
126 # 'suffix' => filename suffix,
127 # 'format' => --format for git-archive,
128 # 'compressor' => [compressor command and arguments]
129 # (array reference, optional)}
130 #
131 'tgz' => {
132 'display' => 'tar.gz',
133 'type' => 'application/x-gzip',
134 'suffix' => '.tar.gz',
135 'format' => 'tar',
136 'compressor' => ['gzip']},
137
138 'tbz2' => {
139 'display' => 'tar.bz2',
140 'type' => 'application/x-bzip2',
141 'suffix' => '.tar.bz2',
142 'format' => 'tar',
143 'compressor' => ['bzip2']},
144
145 'zip' => {
146 'display' => 'zip',
147 'type' => 'application/x-zip',
148 'suffix' => '.zip',
149 'format' => 'zip'},
150 );
151
152 # Aliases so we understand old gitweb.snapshot values in repository
153 # configuration.
154 our %known_snapshot_format_aliases = (
155 'gzip' => 'tgz',
156 'bzip2' => 'tbz2',
157
158 # backward compatibility: legacy gitweb config support
159 'x-gzip' => undef, 'gz' => undef,
160 'x-bzip2' => undef, 'bz2' => undef,
161 'x-zip' => undef, '' => undef,
162 );
163
164 # You define site-wide feature defaults here; override them with
165 # $GITWEB_CONFIG as necessary.
166 our %feature = (
167 # feature => {
168 # 'sub' => feature-sub (subroutine),
169 # 'override' => allow-override (boolean),
170 # 'default' => [ default options...] (array reference)}
171 #
172 # if feature is overridable (it means that allow-override has true value),
173 # then feature-sub will be called with default options as parameters;
174 # return value of feature-sub indicates if to enable specified feature
175 #
176 # if there is no 'sub' key (no feature-sub), then feature cannot be
177 # overriden
178 #
179 # use gitweb_check_feature(<feature>) to check if <feature> is enabled
180
181 # Enable the 'blame' blob view, showing the last commit that modified
182 # each line in the file. This can be very CPU-intensive.
183
184 # To enable system wide have in $GITWEB_CONFIG
185 # $feature{'blame'}{'default'} = [1];
186 # To have project specific config enable override in $GITWEB_CONFIG
187 # $feature{'blame'}{'override'} = 1;
188 # and in project config gitweb.blame = 0|1;
189 'blame' => {
190 'sub' => \&feature_blame,
191 'override' => 0,
192 'default' => [0]},
193
194 # Enable the 'snapshot' link, providing a compressed archive of any
195 # tree. This can potentially generate high traffic if you have large
196 # project.
197
198 # Value is a list of formats defined in %known_snapshot_formats that
199 # you wish to offer.
200 # To disable system wide have in $GITWEB_CONFIG
201 # $feature{'snapshot'}{'default'} = [];
202 # To have project specific config enable override in $GITWEB_CONFIG
203 # $feature{'snapshot'}{'override'} = 1;
204 # and in project config, a comma-separated list of formats or "none"
205 # to disable. Example: gitweb.snapshot = tbz2,zip;
206 'snapshot' => {
207 'sub' => \&feature_snapshot,
208 'override' => 0,
209 'default' => ['tgz']},
210
211 # Enable text search, which will list the commits which match author,
212 # committer or commit text to a given string. Enabled by default.
213 # Project specific override is not supported.
214 'search' => {
215 'override' => 0,
216 'default' => [1]},
217
218 # Enable grep search, which will list the files in currently selected
219 # tree containing the given string. Enabled by default. This can be
220 # potentially CPU-intensive, of course.
221
222 # To enable system wide have in $GITWEB_CONFIG
223 # $feature{'grep'}{'default'} = [1];
224 # To have project specific config enable override in $GITWEB_CONFIG
225 # $feature{'grep'}{'override'} = 1;
226 # and in project config gitweb.grep = 0|1;
227 'grep' => {
228 'override' => 0,
229 'default' => [1]},
230
231 # Enable the pickaxe search, which will list the commits that modified
232 # a given string in a file. This can be practical and quite faster
233 # alternative to 'blame', but still potentially CPU-intensive.
234
235 # To enable system wide have in $GITWEB_CONFIG
236 # $feature{'pickaxe'}{'default'} = [1];
237 # To have project specific config enable override in $GITWEB_CONFIG
238 # $feature{'pickaxe'}{'override'} = 1;
239 # and in project config gitweb.pickaxe = 0|1;
240 'pickaxe' => {
241 'sub' => \&feature_pickaxe,
242 'override' => 0,
243 'default' => [1]},
244
245 # Make gitweb use an alternative format of the URLs which can be
246 # more readable and natural-looking: project name is embedded
247 # directly in the path and the query string contains other
248 # auxiliary information. All gitweb installations recognize
249 # URL in either format; this configures in which formats gitweb
250 # generates links.
251
252 # To enable system wide have in $GITWEB_CONFIG
253 # $feature{'pathinfo'}{'default'} = [1];
254 # Project specific override is not supported.
255
256 # Note that you will need to change the default location of CSS,
257 # favicon, logo and possibly other files to an absolute URL. Also,
258 # if gitweb.cgi serves as your indexfile, you will need to force
259 # $my_uri to contain the script name in your $GITWEB_CONFIG.
260 'pathinfo' => {
261 'override' => 0,
262 'default' => [0]},
263
264 # Make gitweb consider projects in project root subdirectories
265 # to be forks of existing projects. Given project $projname.git,
266 # projects matching $projname/*.git will not be shown in the main
267 # projects list, instead a '+' mark will be added to $projname
268 # there and a 'forks' view will be enabled for the project, listing
269 # all the forks. If project list is taken from a file, forks have
270 # to be listed after the main project.
271
272 # To enable system wide have in $GITWEB_CONFIG
273 # $feature{'forks'}{'default'} = [1];
274 # Project specific override is not supported.
275 'forks' => {
276 'override' => 0,
277 'default' => [0]},
278 );
279
280 sub gitweb_check_feature {
281 my ($name) = @_;
282 return unless exists $feature{$name};
283 my ($sub, $override, @defaults) = (
284 $feature{$name}{'sub'},
285 $feature{$name}{'override'},
286 @{$feature{$name}{'default'}});
287 if (!$override) { return @defaults; }
288 if (!defined $sub) {
289 warn "feature $name is not overrideable";
290 return @defaults;
291 }
292 return $sub->(@defaults);
293 }
294
295 sub feature_blame {
296 my ($val) = git_get_project_config('blame', '--bool');
297
298 if ($val eq 'true') {
299 return 1;
300 } elsif ($val eq 'false') {
301 return 0;
302 }
303
304 return $_[0];
305 }
306
307 sub feature_snapshot {
308 my (@fmts) = @_;
309
310 my ($val) = git_get_project_config('snapshot');
311
312 if ($val) {
313 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
314 }
315
316 return @fmts;
317 }
318
319 sub feature_grep {
320 my ($val) = git_get_project_config('grep', '--bool');
321
322 if ($val eq 'true') {
323 return (1);
324 } elsif ($val eq 'false') {
325 return (0);
326 }
327
328 return ($_[0]);
329 }
330
331 sub feature_pickaxe {
332 my ($val) = git_get_project_config('pickaxe', '--bool');
333
334 if ($val eq 'true') {
335 return (1);
336 } elsif ($val eq 'false') {
337 return (0);
338 }
339
340 return ($_[0]);
341 }
342
343 # checking HEAD file with -e is fragile if the repository was
344 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
345 # and then pruned.
346 sub check_head_link {
347 my ($dir) = @_;
348 my $headfile = "$dir/HEAD";
349 return ((-e $headfile) ||
350 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
351 }
352
353 sub check_export_ok {
354 my ($dir) = @_;
355 return (check_head_link($dir) &&
356 (!$export_ok || -e "$dir/$export_ok"));
357 }
358
359 # process alternate names for backward compatibility
360 # filter out unsupported (unknown) snapshot formats
361 sub filter_snapshot_fmts {
362 my @fmts = @_;
363
364 @fmts = map {
365 exists $known_snapshot_format_aliases{$_} ?
366 $known_snapshot_format_aliases{$_} : $_} @fmts;
367 @fmts = grep(exists $known_snapshot_formats{$_}, @fmts);
368
369 }
370
371 our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
372 do $GITWEB_CONFIG if -e $GITWEB_CONFIG;
373
374 # version of the core git binary
375 our $git_version = qx($GIT --version) =~ m/git version (.*)$/ ? $1 : "unknown";
376
377 $projects_list ||= $projectroot;
378
379 # ======================================================================
380 # input validation and dispatch
381 our $action = $cgi->param('a');
382 if (defined $action) {
383 if ($action =~ m/[^0-9a-zA-Z\.\-_]/) {
384 die_error(undef, "Invalid action parameter");
385 }
386 }
387
388 # parameters which are pathnames
389 our $project = $cgi->param('p');
390 if (defined $project) {
391 if (!validate_pathname($project) ||
392 !(-d "$projectroot/$project") ||
393 !check_head_link("$projectroot/$project") ||
394 ($export_ok && !(-e "$projectroot/$project/$export_ok")) ||
395 ($strict_export && !project_in_list($project))) {
396 undef $project;
397 die_error(undef, "No such project");
398 }
399 }
400
401 our $file_name = $cgi->param('f');
402 if (defined $file_name) {
403 if (!validate_pathname($file_name)) {
404 die_error(undef, "Invalid file parameter");
405 }
406 }
407
408 our $file_parent = $cgi->param('fp');
409 if (defined $file_parent) {
410 if (!validate_pathname($file_parent)) {
411 die_error(undef, "Invalid file parent parameter");
412 }
413 }
414
415 # parameters which are refnames
416 our $hash = $cgi->param('h');
417 if (defined $hash) {
418 if (!validate_refname($hash)) {
419 die_error(undef, "Invalid hash parameter");
420 }
421 }
422
423 our $hash_parent = $cgi->param('hp');
424 if (defined $hash_parent) {
425 if (!validate_refname($hash_parent)) {
426 die_error(undef, "Invalid hash parent parameter");
427 }
428 }
429
430 our $hash_base = $cgi->param('hb');
431 if (defined $hash_base) {
432 if (!validate_refname($hash_base)) {
433 die_error(undef, "Invalid hash base parameter");
434 }
435 }
436
437 my %allowed_options = (
438 "--no-merges" => [ qw(rss atom log shortlog history) ],
439 );
440
441 our @extra_options = $cgi->param('opt');
442 if (defined @extra_options) {
443 foreach my $opt (@extra_options) {
444 if (not exists $allowed_options{$opt}) {
445 die_error(undef, "Invalid option parameter");
446 }
447 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
448 die_error(undef, "Invalid option parameter for this action");
449 }
450 }
451 }
452
453 our $hash_parent_base = $cgi->param('hpb');
454 if (defined $hash_parent_base) {
455 if (!validate_refname($hash_parent_base)) {
456 die_error(undef, "Invalid hash parent base parameter");
457 }
458 }
459
460 # other parameters
461 our $page = $cgi->param('pg');
462 if (defined $page) {
463 if ($page =~ m/[^0-9]/) {
464 die_error(undef, "Invalid page parameter");
465 }
466 }
467
468 our $searchtype = $cgi->param('st');
469 if (defined $searchtype) {
470 if ($searchtype =~ m/[^a-z]/) {
471 die_error(undef, "Invalid searchtype parameter");
472 }
473 }
474
475 our $searchtext = $cgi->param('s');
476 our $search_regexp;
477 if (defined $searchtext) {
478 if (length($searchtext) < 2) {
479 die_error(undef, "At least two characters are required for search parameter");
480 }
481 $search_regexp = quotemeta $searchtext;
482 }
483
484 # now read PATH_INFO and use it as alternative to parameters
485 sub evaluate_path_info {
486 return if defined $project;
487 my $path_info = $ENV{"PATH_INFO"};
488 return if !$path_info;
489 $path_info =~ s,^/+,,;
490 return if !$path_info;
491 # find which part of PATH_INFO is project
492 $project = $path_info;
493 $project =~ s,/+$,,;
494 while ($project && !check_head_link("$projectroot/$project")) {
495 $project =~ s,/*[^/]*$,,;
496 }
497 # validate project
498 $project = validate_pathname($project);
499 if (!$project ||
500 ($export_ok && !-e "$projectroot/$project/$export_ok") ||
501 ($strict_export && !project_in_list($project))) {
502 undef $project;
503 return;
504 }
505 # do not change any parameters if an action is given using the query string
506 return if $action;
507 $path_info =~ s,^$project/*,,;
508 my ($refname, $pathname) = split(/:/, $path_info, 2);
509 if (defined $pathname) {
510 # we got "project.git/branch:filename" or "project.git/branch:dir/"
511 # we could use git_get_type(branch:pathname), but it needs $git_dir
512 $pathname =~ s,^/+,,;
513 if (!$pathname || substr($pathname, -1) eq "/") {
514 $action ||= "tree";
515 $pathname =~ s,/$,,;
516 } else {
517 $action ||= "blob_plain";
518 }
519 $hash_base ||= validate_refname($refname);
520 $file_name ||= validate_pathname($pathname);
521 } elsif (defined $refname) {
522 # we got "project.git/branch"
523 $action ||= "shortlog";
524 $hash ||= validate_refname($refname);
525 }
526 }
527 evaluate_path_info();
528
529 # path to the current git repository
530 our $git_dir;
531 $git_dir = "$projectroot/$project" if $project;
532
533 # dispatch
534 my %actions = (
535 "blame" => \&git_blame2,
536 "blobdiff" => \&git_blobdiff,
537 "blobdiff_plain" => \&git_blobdiff_plain,
538 "blob" => \&git_blob,
539 "blob_plain" => \&git_blob_plain,
540 "commitdiff" => \&git_commitdiff,
541 "commitdiff_plain" => \&git_commitdiff_plain,
542 "commit" => \&git_commit,
543 "forks" => \&git_forks,
544 "heads" => \&git_heads,
545 "history" => \&git_history,
546 "log" => \&git_log,
547 "rss" => \&git_rss,
548 "atom" => \&git_atom,
549 "search" => \&git_search,
550 "search_help" => \&git_search_help,
551 "shortlog" => \&git_shortlog,
552 "summary" => \&git_summary,
553 "tag" => \&git_tag,
554 "tags" => \&git_tags,
555 "tree" => \&git_tree,
556 "snapshot" => \&git_snapshot,
557 "object" => \&git_object,
558 # those below don't need $project
559 "opml" => \&git_opml,
560 "project_list" => \&git_project_list,
561 "project_index" => \&git_project_index,
562 );
563
564 if (!defined $action) {
565 if (defined $hash) {
566 $action = git_get_type($hash);
567 } elsif (defined $hash_base && defined $file_name) {
568 $action = git_get_type("$hash_base:$file_name");
569 } elsif (defined $project) {
570 $action = 'summary';
571 } else {
572 $action = 'project_list';
573 }
574 }
575 if (!defined($actions{$action})) {
576 die_error(undef, "Unknown action");
577 }
578 if ($action !~ m/^(opml|project_list|project_index)$/ &&
579 !$project) {
580 die_error(undef, "Project needed");
581 }
582 $actions{$action}->();
583 exit;
584
585 ## ======================================================================
586 ## action links
587
588 sub href(%) {
589 my %params = @_;
590 # default is to use -absolute url() i.e. $my_uri
591 my $href = $params{-full} ? $my_url : $my_uri;
592
593 # XXX: Warning: If you touch this, check the search form for updating,
594 # too.
595
596 my @mapping = (
597 project => "p",
598 action => "a",
599 file_name => "f",
600 file_parent => "fp",
601 hash => "h",
602 hash_parent => "hp",
603 hash_base => "hb",
604 hash_parent_base => "hpb",
605 page => "pg",
606 order => "o",
607 searchtext => "s",
608 searchtype => "st",
609 snapshot_format => "sf",
610 extra_options => "opt",
611 );
612 my %mapping = @mapping;
613
614 if ($params{-replay}) {
615 while (my ($name, $symbol) = each %mapping) {
616 if (!exists $params{$name}) {
617 # to allow for multivalued params we use arrayref form
618 $params{$name} = [ $cgi->param($symbol) ];
619 }
620 }
621 }
622
623 $params{'project'} = $project unless exists $params{'project'};
624
625 my ($use_pathinfo) = gitweb_check_feature('pathinfo');
626 if ($use_pathinfo) {
627 # use PATH_INFO for project name
628 $href .= "/$params{'project'}" if defined $params{'project'};
629 delete $params{'project'};
630
631 # Summary just uses the project path URL
632 if (defined $params{'action'} && $params{'action'} eq 'summary') {
633 delete $params{'action'};
634 }
635 }
636
637 # now encode the parameters explicitly
638 my @result = ();
639 for (my $i = 0; $i < @mapping; $i += 2) {
640 my ($name, $symbol) = ($mapping[$i], $mapping[$i+1]);
641 if (defined $params{$name}) {
642 if (ref($params{$name}) eq "ARRAY") {
643 foreach my $par (@{$params{$name}}) {
644 push @result, $symbol . "=" . esc_param($par);
645 }
646 } else {
647 push @result, $symbol . "=" . esc_param($params{$name});
648 }
649 }
650 }
651 $href .= "?" . join(';', @result) if scalar @result;
652
653 return $href;
654 }
655
656
657 ## ======================================================================
658 ## validation, quoting/unquoting and escaping
659
660 sub validate_pathname {
661 my $input = shift || return undef;
662
663 # no '.' or '..' as elements of path, i.e. no '.' nor '..'
664 # at the beginning, at the end, and between slashes.
665 # also this catches doubled slashes
666 if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
667 return undef;
668 }
669 # no null characters
670 if ($input =~ m!\0!) {
671 return undef;
672 }
673 return $input;
674 }
675
676 sub validate_refname {
677 my $input = shift || return undef;
678
679 # textual hashes are O.K.
680 if ($input =~ m/^[0-9a-fA-F]{40}$/) {
681 return $input;
682 }
683 # it must be correct pathname
684 $input = validate_pathname($input)
685 or return undef;
686 # restrictions on ref name according to git-check-ref-format
687 if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
688 return undef;
689 }
690 return $input;
691 }
692
693 # decode sequences of octets in utf8 into Perl's internal form,
694 # which is utf-8 with utf8 flag set if needed. gitweb writes out
695 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
696 sub to_utf8 {
697 my $str = shift;
698 my $res;
699 eval { $res = decode_utf8($str, Encode::FB_CROAK); };
700 if (defined $res) {
701 return $res;
702 } else {
703 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
704 }
705 }
706
707 # quote unsafe chars, but keep the slash, even when it's not
708 # correct, but quoted slashes look too horrible in bookmarks
709 sub esc_param {
710 my $str = shift;
711 $str =~ s/([^A-Za-z0-9\-_.~()\/:@])/sprintf("%%%02X", ord($1))/eg;
712 $str =~ s/\+/%2B/g;
713 $str =~ s/ /\+/g;
714 return $str;
715 }
716
717 # quote unsafe chars in whole URL, so some charactrs cannot be quoted
718 sub esc_url {
719 my $str = shift;
720 $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&=])/sprintf("%%%02X", ord($1))/eg;
721 $str =~ s/\+/%2B/g;
722 $str =~ s/ /\+/g;
723 return $str;
724 }
725
726 # replace invalid utf8 character with SUBSTITUTION sequence
727 sub esc_html ($;%) {
728 my $str = shift;
729 my %opts = @_;
730
731 $str = to_utf8($str);
732 $str = $cgi->escapeHTML($str);
733 if ($opts{'-nbsp'}) {
734 $str =~ s/ /&nbsp;/g;
735 }
736 $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
737 return $str;
738 }
739
740 # quote control characters and escape filename to HTML
741 sub esc_path {
742 my $str = shift;
743 my %opts = @_;
744
745 $str = to_utf8($str);
746 $str = $cgi->escapeHTML($str);
747 if ($opts{'-nbsp'}) {
748 $str =~ s/ /&nbsp;/g;
749 }
750 $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
751 return $str;
752 }
753
754 # Make control characters "printable", using character escape codes (CEC)
755 sub quot_cec {
756 my $cntrl = shift;
757 my %es = ( # character escape codes, aka escape sequences
758 "\t" => '\t', # tab (HT)
759 "\n" => '\n', # line feed (LF)
760 "\r" => '\r', # carrige return (CR)
761 "\f" => '\f', # form feed (FF)
762 "\b" => '\b', # backspace (BS)
763 "\a" => '\a', # alarm (bell) (BEL)
764 "\e" => '\e', # escape (ESC)
765 "\013" => '\v', # vertical tab (VT)
766 "\000" => '\0', # nul character (NUL)
767 );
768 my $chr = ( (exists $es{$cntrl})
769 ? $es{$cntrl}
770 : sprintf('\%03o', ord($cntrl)) );
771 return "<span class=\"cntrl\">$chr</span>";
772 }
773
774 # Alternatively use unicode control pictures codepoints,
775 # Unicode "printable representation" (PR)
776 sub quot_upr {
777 my $cntrl = shift;
778 my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
779 return "<span class=\"cntrl\">$chr</span>";
780 }
781
782 # git may return quoted and escaped filenames
783 sub unquote {
784 my $str = shift;
785
786 sub unq {
787 my $seq = shift;
788 my %es = ( # character escape codes, aka escape sequences
789 't' => "\t", # tab (HT, TAB)
790 'n' => "\n", # newline (NL)
791 'r' => "\r", # return (CR)
792 'f' => "\f", # form feed (FF)
793 'b' => "\b", # backspace (BS)
794 'a' => "\a", # alarm (bell) (BEL)
795 'e' => "\e", # escape (ESC)
796 'v' => "\013", # vertical tab (VT)
797 );
798
799 if ($seq =~ m/^[0-7]{1,3}$/) {
800 # octal char sequence
801 return chr(oct($seq));
802 } elsif (exists $es{$seq}) {
803 # C escape sequence, aka character escape code
804 return $es{$seq}
805 }
806 # quoted ordinary character
807 return $seq;
808 }
809
810 if ($str =~ m/^"(.*)"$/) {
811 # needs unquoting
812 $str = $1;
813 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
814 }
815 return $str;
816 }
817
818 # escape tabs (convert tabs to spaces)
819 sub untabify {
820 my $line = shift;
821
822 while ((my $pos = index($line, "\t")) != -1) {
823 if (my $count = (8 - ($pos % 8))) {
824 my $spaces = ' ' x $count;
825 $line =~ s/\t/$spaces/;
826 }
827 }
828
829 return $line;
830 }
831
832 sub project_in_list {
833 my $project = shift;
834 my @list = git_get_projects_list();
835 return @list && scalar(grep { $_->{'path'} eq $project } @list);
836 }
837
838 ## ----------------------------------------------------------------------
839 ## HTML aware string manipulation
840
841 sub chop_str {
842 my $str = shift;
843 my $len = shift;
844 my $add_len = shift || 10;
845
846 # allow only $len chars, but don't cut a word if it would fit in $add_len
847 # if it doesn't fit, cut it if it's still longer than the dots we would add
848 $str =~ m/^(.{0,$len}[^ \/\-_:\.@]{0,$add_len})(.*)/;
849 my $body = $1;
850 my $tail = $2;
851 if (length($tail) > 4) {
852 $tail = " ...";
853 $body =~ s/&[^;]*$//; # remove chopped character entities
854 }
855 return "$body$tail";
856 }
857
858 # takes the same arguments as chop_str, but also wraps a <span> around the
859 # result with a title attribute if it does get chopped. Additionally, the
860 # string is HTML-escaped.
861 sub chop_and_escape_str {
862 my $str = shift;
863 my $len = shift;
864 my $add_len = shift || 10;
865
866 my $chopped = chop_str($str, $len, $add_len);
867 if ($chopped eq $str) {
868 return esc_html($chopped);
869 } else {
870 return qq{<span title="} . esc_html($str) . qq{">} .
871 esc_html($chopped) . qq{</span>};
872 }
873 }
874
875 ## ----------------------------------------------------------------------
876 ## functions returning short strings
877
878 # CSS class for given age value (in seconds)
879 sub age_class {
880 my $age = shift;
881
882 if (!defined $age) {
883 return "noage";
884 } elsif ($age < 60*60*2) {
885 return "age0";
886 } elsif ($age < 60*60*24*2) {
887 return "age1";
888 } else {
889 return "age2";
890 }
891 }
892
893 # convert age in seconds to "nn units ago" string
894 sub age_string {
895 my $age = shift;
896 my $age_str;
897
898 if ($age > 60*60*24*365*2) {
899 $age_str = (int $age/60/60/24/365);
900 $age_str .= " years ago";
901 } elsif ($age > 60*60*24*(365/12)*2) {
902 $age_str = int $age/60/60/24/(365/12);
903 $age_str .= " months ago";
904 } elsif ($age > 60*60*24*7*2) {
905 $age_str = int $age/60/60/24/7;
906 $age_str .= " weeks ago";
907 } elsif ($age > 60*60*24*2) {
908 $age_str = int $age/60/60/24;
909 $age_str .= " days ago";
910 } elsif ($age > 60*60*2) {
911 $age_str = int $age/60/60;
912 $age_str .= " hours ago";
913 } elsif ($age > 60*2) {
914 $age_str = int $age/60;
915 $age_str .= " min ago";
916 } elsif ($age > 2) {
917 $age_str = int $age;
918 $age_str .= " sec ago";
919 } else {
920 $age_str .= " right now";
921 }
922 return $age_str;
923 }
924
925 use constant {
926 S_IFINVALID => 0030000,
927 S_IFGITLINK => 0160000,
928 };
929
930 # submodule/subproject, a commit object reference
931 sub S_ISGITLINK($) {
932 my $mode = shift;
933
934 return (($mode & S_IFMT) == S_IFGITLINK)
935 }
936
937 # convert file mode in octal to symbolic file mode string
938 sub mode_str {
939 my $mode = oct shift;
940
941 if (S_ISGITLINK($mode)) {
942 return 'm---------';
943 } elsif (S_ISDIR($mode & S_IFMT)) {
944 return 'drwxr-xr-x';
945 } elsif (S_ISLNK($mode)) {
946 return 'lrwxrwxrwx';
947 } elsif (S_ISREG($mode)) {
948 # git cares only about the executable bit
949 if ($mode & S_IXUSR) {
950 return '-rwxr-xr-x';
951 } else {
952 return '-rw-r--r--';
953 };
954 } else {
955 return '----------';
956 }
957 }
958
959 # convert file mode in octal to file type string
960 sub file_type {
961 my $mode = shift;
962
963 if ($mode !~ m/^[0-7]+$/) {
964 return $mode;
965 } else {
966 $mode = oct $mode;
967 }
968
969 if (S_ISGITLINK($mode)) {
970 return "submodule";
971 } elsif (S_ISDIR($mode & S_IFMT)) {
972 return "directory";
973 } elsif (S_ISLNK($mode)) {
974 return "symlink";
975 } elsif (S_ISREG($mode)) {
976 return "file";
977 } else {
978 return "unknown";
979 }
980 }
981
982 # convert file mode in octal to file type description string
983 sub file_type_long {
984 my $mode = shift;
985
986 if ($mode !~ m/^[0-7]+$/) {
987 return $mode;
988 } else {
989 $mode = oct $mode;
990 }
991
992 if (S_ISGITLINK($mode)) {
993 return "submodule";
994 } elsif (S_ISDIR($mode & S_IFMT)) {
995 return "directory";
996 } elsif (S_ISLNK($mode)) {
997 return "symlink";
998 } elsif (S_ISREG($mode)) {
999 if ($mode & S_IXUSR) {
1000 return "executable";
1001 } else {
1002 return "file";
1003 };
1004 } else {
1005 return "unknown";
1006 }
1007 }
1008
1009
1010 ## ----------------------------------------------------------------------
1011 ## functions returning short HTML fragments, or transforming HTML fragments
1012 ## which don't belong to other sections
1013
1014 # format line of commit message.
1015 sub format_log_line_html {
1016 my $line = shift;
1017
1018 $line = esc_html($line, -nbsp=>1);
1019 if ($line =~ m/([0-9a-fA-F]{8,40})/) {
1020 my $hash_text = $1;
1021 my $link =
1022 $cgi->a({-href => href(action=>"object", hash=>$hash_text),
1023 -class => "text"}, $hash_text);
1024 $line =~ s/$hash_text/$link/;
1025 }
1026 return $line;
1027 }
1028
1029 # format marker of refs pointing to given object
1030 sub format_ref_marker {
1031 my ($refs, $id) = @_;
1032 my $markers = '';
1033
1034 if (defined $refs->{$id}) {
1035 foreach my $ref (@{$refs->{$id}}) {
1036 my ($type, $name) = qw();
1037 # e.g. tags/v2.6.11 or heads/next
1038 if ($ref =~ m!^(.*?)s?/(.*)$!) {
1039 $type = $1;
1040 $name = $2;
1041 } else {
1042 $type = "ref";
1043 $name = $ref;
1044 }
1045
1046 $markers .= " <span class=\"$type\" title=\"$ref\">" .
1047 esc_html($name) . "</span>";
1048 }
1049 }
1050
1051 if ($markers) {
1052 return ' <span class="refs">'. $markers . '</span>';
1053 } else {
1054 return "";
1055 }
1056 }
1057
1058 # format, perhaps shortened and with markers, title line
1059 sub format_subject_html {
1060 my ($long, $short, $href, $extra) = @_;
1061 $extra = '' unless defined($extra);
1062
1063 if (length($short) < length($long)) {
1064 return $cgi->a({-href => $href, -class => "list subject",
1065 -title => to_utf8($long)},
1066 esc_html($short) . $extra);
1067 } else {
1068 return $cgi->a({-href => $href, -class => "list subject"},
1069 esc_html($long) . $extra);
1070 }
1071 }
1072
1073 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
1074 sub format_git_diff_header_line {
1075 my $line = shift;
1076 my $diffinfo = shift;
1077 my ($from, $to) = @_;
1078
1079 if ($diffinfo->{'nparents'}) {
1080 # combined diff
1081 $line =~ s!^(diff (.*?) )"?.*$!$1!;
1082 if ($to->{'href'}) {
1083 $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1084 esc_path($to->{'file'}));
1085 } else { # file was deleted (no href)
1086 $line .= esc_path($to->{'file'});
1087 }
1088 } else {
1089 # "ordinary" diff
1090 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
1091 if ($from->{'href'}) {
1092 $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
1093 'a/' . esc_path($from->{'file'}));
1094 } else { # file was added (no href)
1095 $line .= 'a/' . esc_path($from->{'file'});
1096 }
1097 $line .= ' ';
1098 if ($to->{'href'}) {
1099 $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1100 'b/' . esc_path($to->{'file'}));
1101 } else { # file was deleted
1102 $line .= 'b/' . esc_path($to->{'file'});
1103 }
1104 }
1105
1106 return "<div class=\"diff header\">$line</div>\n";
1107 }
1108
1109 # format extended diff header line, before patch itself
1110 sub format_extended_diff_header_line {
1111 my $line = shift;
1112 my $diffinfo = shift;
1113 my ($from, $to) = @_;
1114
1115 # match <path>
1116 if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
1117 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
1118 esc_path($from->{'file'}));
1119 }
1120 if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
1121 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
1122 esc_path($to->{'file'}));
1123 }
1124 # match single <mode>
1125 if ($line =~ m/\s(\d{6})$/) {
1126 $line .= '<span class="info"> (' .
1127 file_type_long($1) .
1128 ')</span>';
1129 }
1130 # match <hash>
1131 if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
1132 # can match only for combined diff
1133 $line = 'index ';
1134 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
1135 if ($from->{'href'}[$i]) {
1136 $line .= $cgi->a({-href=>$from->{'href'}[$i],
1137 -class=>"hash"},
1138 substr($diffinfo->{'from_id'}[$i],0,7));
1139 } else {
1140 $line .= '0' x 7;
1141 }
1142 # separator
1143 $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
1144 }
1145 $line .= '..';
1146 if ($to->{'href'}) {
1147 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
1148 substr($diffinfo->{'to_id'},0,7));
1149 } else {
1150 $line .= '0' x 7;
1151 }
1152
1153 } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
1154 # can match only for ordinary diff
1155 my ($from_link, $to_link);
1156 if ($from->{'href'}) {
1157 $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
1158 substr($diffinfo->{'from_id'},0,7));
1159 } else {
1160 $from_link = '0' x 7;
1161 }
1162 if ($to->{'href'}) {
1163 $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
1164 substr($diffinfo->{'to_id'},0,7));
1165 } else {
1166 $to_link = '0' x 7;
1167 }
1168 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
1169 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
1170 }
1171
1172 return $line . "<br/>\n";
1173 }
1174
1175 # format from-file/to-file diff header
1176 sub format_diff_from_to_header {
1177 my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
1178 my $line;
1179 my $result = '';
1180
1181 $line = $from_line;
1182 #assert($line =~ m/^---/) if DEBUG;
1183 # no extra formatting for "^--- /dev/null"
1184 if (! $diffinfo->{'nparents'}) {
1185 # ordinary (single parent) diff
1186 if ($line =~ m!^--- "?a/!) {
1187 if ($from->{'href'}) {
1188 $line = '--- a/' .
1189 $cgi->a({-href=>$from->{'href'}, -class=>"path"},
1190 esc_path($from->{'file'}));
1191 } else {
1192 $line = '--- a/' .
1193 esc_path($from->{'file'});
1194 }
1195 }
1196 $result .= qq!<div class="diff from_file">$line</div>\n!;
1197
1198 } else {
1199 # combined diff (merge commit)
1200 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
1201 if ($from->{'href'}[$i]) {
1202 $line = '--- ' .
1203 $cgi->a({-href=>href(action=>"blobdiff",
1204 hash_parent=>$diffinfo->{'from_id'}[$i],
1205 hash_parent_base=>$parents[$i],
1206 file_parent=>$from->{'file'}[$i],
1207 hash=>$diffinfo->{'to_id'},
1208 hash_base=>$hash,
1209 file_name=>$to->{'file'}),
1210 -class=>"path",
1211 -title=>"diff" . ($i+1)},
1212 $i+1) .
1213 '/' .
1214 $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
1215 esc_path($from->{'file'}[$i]));
1216 } else {
1217 $line = '--- /dev/null';
1218 }
1219 $result .= qq!<div class="diff from_file">$line</div>\n!;
1220 }
1221 }
1222
1223 $line = $to_line;
1224 #assert($line =~ m/^\+\+\+/) if DEBUG;
1225 # no extra formatting for "^+++ /dev/null"
1226 if ($line =~ m!^\+\+\+ "?b/!) {
1227 if ($to->{'href'}) {
1228 $line = '+++ b/' .
1229 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
1230 esc_path($to->{'file'}));
1231 } else {
1232 $line = '+++ b/' .
1233 esc_path($to->{'file'});
1234 }
1235 }
1236 $result .= qq!<div class="diff to_file">$line</div>\n!;
1237
1238 return $result;
1239 }
1240
1241 # create note for patch simplified by combined diff
1242 sub format_diff_cc_simplified {
1243 my ($diffinfo, @parents) = @_;
1244 my $result = '';
1245
1246 $result .= "<div class=\"diff header\">" .
1247 "diff --cc ";
1248 if (!is_deleted($diffinfo)) {
1249 $result .= $cgi->a({-href => href(action=>"blob",
1250 hash_base=>$hash,
1251 hash=>$diffinfo->{'to_id'},
1252 file_name=>$diffinfo->{'to_file'}),
1253 -class => "path"},
1254 esc_path($diffinfo->{'to_file'}));
1255 } else {
1256 $result .= esc_path($diffinfo->{'to_file'});
1257 }
1258 $result .= "</div>\n" . # class="diff header"
1259 "<div class=\"diff nodifferences\">" .
1260 "Simple merge" .
1261 "</div>\n"; # class="diff nodifferences"
1262
1263 return $result;
1264 }
1265
1266 # format patch (diff) line (not to be used for diff headers)
1267 sub format_diff_line {
1268 my $line = shift;
1269 my ($from, $to) = @_;
1270 my $diff_class = "";
1271
1272 chomp $line;
1273
1274 if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
1275 # combined diff
1276 my $prefix = substr($line, 0, scalar @{$from->{'href'}});
1277 if ($line =~ m/^\@{3}/) {
1278 $diff_class = " chunk_header";
1279 } elsif ($line =~ m/^\\/) {
1280 $diff_class = " incomplete";
1281 } elsif ($prefix =~ tr/+/+/) {
1282 $diff_class = " add";
1283 } elsif ($prefix =~ tr/-/-/) {
1284 $diff_class = " rem";
1285 }
1286 } else {
1287 # assume ordinary diff
1288 my $char = substr($line, 0, 1);
1289 if ($char eq '+') {
1290 $diff_class = " add";
1291 } elsif ($char eq '-') {
1292 $diff_class = " rem";
1293 } elsif ($char eq '@') {
1294 $diff_class = " chunk_header";
1295 } elsif ($char eq "\\") {
1296 $diff_class = " incomplete";
1297 }
1298 }
1299 $line = untabify($line);
1300 if ($from && $to && $line =~ m/^\@{2} /) {
1301 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
1302 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
1303
1304 $from_lines = 0 unless defined $from_lines;
1305 $to_lines = 0 unless defined $to_lines;
1306
1307 if ($from->{'href'}) {
1308 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
1309 -class=>"list"}, $from_text);
1310 }
1311 if ($to->{'href'}) {
1312 $to_text = $cgi->a({-href=>"$to->{'href'}#l$to_start",
1313 -class=>"list"}, $to_text);
1314 }
1315 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
1316 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
1317 return "<div class=\"diff$diff_class\">$line</div>\n";
1318 } elsif ($from && $to && $line =~ m/^\@{3}/) {
1319 my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
1320 my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
1321
1322 @from_text = split(' ', $ranges);
1323 for (my $i = 0; $i < @from_text; ++$i) {
1324 ($from_start[$i], $from_nlines[$i]) =
1325 (split(',', substr($from_text[$i], 1)), 0);
1326 }
1327
1328 $to_text = pop @from_text;
1329 $to_start = pop @from_start;
1330 $to_nlines = pop @from_nlines;
1331
1332 $line = "<span class=\"chunk_info\">$prefix ";
1333 for (my $i = 0; $i < @from_text; ++$i) {
1334 if ($from->{'href'}[$i]) {
1335 $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
1336 -class=>"list"}, $from_text[$i]);
1337 } else {
1338 $line .= $from_text[$i];
1339 }
1340 $line .= " ";
1341 }
1342 if ($to->{'href'}) {
1343 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
1344 -class=>"list"}, $to_text);
1345 } else {
1346 $line .= $to_text;
1347 }
1348 $line .= " $prefix</span>" .
1349 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
1350 return "<div class=\"diff$diff_class\">$line</div>\n";
1351 }
1352 return "<div class=\"diff$diff_class\">" . esc_html($line, -nbsp=>1) . "</div>\n";
1353 }
1354
1355 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
1356 # linked. Pass the hash of the tree/commit to snapshot.
1357 sub format_snapshot_links {
1358 my ($hash) = @_;
1359 my @snapshot_fmts = gitweb_check_feature('snapshot');
1360 @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1361 my $num_fmts = @snapshot_fmts;
1362 if ($num_fmts > 1) {
1363 # A parenthesized list of links bearing format names.
1364 # e.g. "snapshot (_tar.gz_ _zip_)"
1365 return "snapshot (" . join(' ', map
1366 $cgi->a({
1367 -href => href(
1368 action=>"snapshot",
1369 hash=>$hash,
1370 snapshot_format=>$_
1371 )
1372 }, $known_snapshot_formats{$_}{'display'})
1373 , @snapshot_fmts) . ")";
1374 } elsif ($num_fmts == 1) {
1375 # A single "snapshot" link whose tooltip bears the format name.
1376 # i.e. "_snapshot_"
1377 my ($fmt) = @snapshot_fmts;
1378 return
1379 $cgi->a({
1380 -href => href(
1381 action=>"snapshot",
1382 hash=>$hash,
1383 snapshot_format=>$fmt
1384 ),
1385 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
1386 }, "snapshot");
1387 } else { # $num_fmts == 0
1388 return undef;
1389 }
1390 }
1391
1392 ## ----------------------------------------------------------------------
1393 ## git utility subroutines, invoking git commands
1394
1395 # returns path to the core git executable and the --git-dir parameter as list
1396 sub git_cmd {
1397 return $GIT, '--git-dir='.$git_dir;
1398 }
1399
1400 # returns path to the core git executable and the --git-dir parameter as string
1401 sub git_cmd_str {
1402 return join(' ', git_cmd());
1403 }
1404
1405 # get HEAD ref of given project as hash
1406 sub git_get_head_hash {
1407 my $project = shift;
1408 my $o_git_dir = $git_dir;
1409 my $retval = undef;
1410 $git_dir = "$projectroot/$project";
1411 if (open my $fd, "-|", git_cmd(), "rev-parse", "--verify", "HEAD") {
1412 my $head = <$fd>;
1413 close $fd;
1414 if (defined $head && $head =~ /^([0-9a-fA-F]{40})$/) {
1415 $retval = $1;
1416 }
1417 }
1418 if (defined $o_git_dir) {
1419 $git_dir = $o_git_dir;
1420 }
1421 return $retval;
1422 }
1423
1424 # get type of given object
1425 sub git_get_type {
1426 my $hash = shift;
1427
1428 open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
1429 my $type = <$fd>;
1430 close $fd or return;
1431 chomp $type;
1432 return $type;
1433 }
1434
1435 # repository configuration
1436 our $config_file = '';
1437 our %config;
1438
1439 # store multiple values for single key as anonymous array reference
1440 # single values stored directly in the hash, not as [ <value> ]
1441 sub hash_set_multi {
1442 my ($hash, $key, $value) = @_;
1443
1444 if (!exists $hash->{$key}) {
1445 $hash->{$key} = $value;
1446 } elsif (!ref $hash->{$key}) {
1447 $hash->{$key} = [ $hash->{$key}, $value ];
1448 } else {
1449 push @{$hash->{$key}}, $value;
1450 }
1451 }
1452
1453 # return hash of git project configuration
1454 # optionally limited to some section, e.g. 'gitweb'
1455 sub git_parse_project_config {
1456 my $section_regexp = shift;
1457 my %config;
1458
1459 local $/ = "\0";
1460
1461 open my $fh, "-|", git_cmd(), "config", '-z', '-l',
1462 or return;
1463
1464 while (my $keyval = <$fh>) {
1465 chomp $keyval;
1466 my ($key, $value) = split(/\n/, $keyval, 2);
1467
1468 hash_set_multi(\%config, $key, $value)
1469 if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
1470 }
1471 close $fh;
1472
1473 return %config;
1474 }
1475
1476 # convert config value to boolean, 'true' or 'false'
1477 # no value, number > 0, 'true' and 'yes' values are true
1478 # rest of values are treated as false (never as error)
1479 sub config_to_bool {
1480 my $val = shift;
1481
1482 # strip leading and trailing whitespace
1483 $val =~ s/^\s+//;
1484 $val =~ s/\s+$//;
1485
1486 return (!defined $val || # section.key
1487 ($val =~ /^\d+$/ && $val) || # section.key = 1
1488 ($val =~ /^(?:true|yes)$/i)); # section.key = true
1489 }
1490
1491 # convert config value to simple decimal number
1492 # an optional value suffix of 'k', 'm', or 'g' will cause the value
1493 # to be multiplied by 1024, 1048576, or 1073741824
1494 sub config_to_int {
1495 my $val = shift;
1496
1497 # strip leading and trailing whitespace
1498 $val =~ s/^\s+//;
1499 $val =~ s/\s+$//;
1500
1501 if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
1502 $unit = lc($unit);
1503 # unknown unit is treated as 1
1504 return $num * ($unit eq 'g' ? 1073741824 :
1505 $unit eq 'm' ? 1048576 :
1506 $unit eq 'k' ? 1024 : 1);
1507 }
1508 return $val;
1509 }
1510
1511 # convert config value to array reference, if needed
1512 sub config_to_multi {
1513 my $val = shift;
1514
1515 return ref($val) ? $val : [ $val ];
1516 }
1517
1518 sub git_get_project_config {
1519 my ($key, $type) = @_;
1520
1521 # key sanity check
1522 return unless ($key);
1523 $key =~ s/^gitweb\.//;
1524 return if ($key =~ m/\W/);
1525
1526 # type sanity check
1527 if (defined $type) {
1528 $type =~ s/^--//;
1529 $type = undef
1530 unless ($type eq 'bool' || $type eq 'int');
1531 }
1532
1533 # get config
1534 if (!defined $config_file ||
1535 $config_file ne "$git_dir/config") {
1536 %config = git_parse_project_config('gitweb');
1537 $config_file = "$git_dir/config";
1538 }
1539
1540 # ensure given type
1541 if (!defined $type) {
1542 return $config{"gitweb.$key"};
1543 } elsif ($type eq 'bool') {
1544 # backward compatibility: 'git config --bool' returns true/false
1545 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
1546 } elsif ($type eq 'int') {
1547 return config_to_int($config{"gitweb.$key"});
1548 }
1549 return $config{"gitweb.$key"};
1550 }
1551
1552 # get hash of given path at given ref
1553 sub git_get_hash_by_path {
1554 my $base = shift;
1555 my $path = shift || return undef;
1556 my $type = shift;
1557
1558 $path =~ s,/+$,,;
1559
1560 open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
1561 or die_error(undef, "Open git-ls-tree failed");
1562 my $line = <$fd>;
1563 close $fd or return undef;
1564
1565 if (!defined $line) {
1566 # there is no tree or hash given by $path at $base
1567 return undef;
1568 }
1569
1570 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa panic.c'
1571 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
1572 if (defined $type && $type ne $2) {
1573 # type doesn't match
1574 return undef;
1575 }
1576 return $3;
1577 }
1578
1579 # get path of entry with given hash at given tree-ish (ref)
1580 # used to get 'from' filename for combined diff (merge commit) for renames
1581 sub git_get_path_by_hash {
1582 my $base = shift || return;
1583 my $hash = shift || return;
1584
1585 local $/ = "\0";
1586
1587 open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
1588 or return undef;
1589 while (my $line = <$fd>) {
1590 chomp $line;
1591
1592 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423 gitweb'
1593 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f gitweb/README'
1594 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
1595 close $fd;
1596 return $1;
1597 }
1598 }
1599 close $fd;
1600 return undef;
1601 }
1602
1603 ## ......................................................................
1604 ## git utility functions, directly accessing git repository
1605
1606 sub git_get_project_description {
1607 my $path = shift;
1608
1609 $git_dir = "$projectroot/$path";
1610 open my $fd, "$projectroot/$path/description"
1611 or return git_get_project_config('description');
1612 my $descr = <$fd>;
1613 close $fd;
1614 if (defined $descr) {
1615 chomp $descr;
1616 }
1617 return $descr;
1618 }
1619
1620 sub git_get_project_url_list {
1621 my $path = shift;
1622
1623 $git_dir = "$projectroot/$path";
1624 open my $fd, "$projectroot/$path/cloneurl"
1625 or return wantarray ?
1626 @{ config_to_multi(git_get_project_config('url')) } :
1627 config_to_multi(git_get_project_config('url'));
1628 my @git_project_url_list = map { chomp; $_ } <$fd>;
1629 close $fd;
1630
1631 return wantarray ? @git_project_url_list : \@git_project_url_list;
1632 }
1633
1634 sub git_get_projects_list {
1635 my ($filter) = @_;
1636 my @list;
1637
1638 $filter ||= '';
1639 $filter =~ s/\.git$//;
1640
1641 my ($check_forks) = gitweb_check_feature('forks');
1642
1643 if (-d $projects_list) {
1644 # search in directory
1645 my $dir = $projects_list . ($filter ? "/$filter" : '');
1646 # remove the trailing "/"
1647 $dir =~ s!/+$!!;
1648 my $pfxlen = length("$dir");
1649 my $pfxdepth = ($dir =~ tr!/!!);
1650
1651 File::Find::find({
1652 follow_fast => 1, # follow symbolic links
1653 follow_skip => 2, # ignore duplicates
1654 dangling_symlinks => 0, # ignore dangling symlinks, silently
1655 wanted => sub {
1656 # skip project-list toplevel, if we get it.
1657 return if (m!^[/.]$!);
1658 # only directories can be git repositories
1659 return unless (-d $_);
1660 # don't traverse too deep (Find is super slow on os x)
1661 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
1662 $File::Find::prune = 1;
1663 return;
1664 }
1665
1666 my $subdir = substr($File::Find::name, $pfxlen + 1);
1667 # we check related file in $projectroot
1668 if ($check_forks and $subdir =~ m#/.#) {
1669 $File::Find::prune = 1;
1670 } elsif (check_export_ok("$projectroot/$filter/$subdir")) {
1671 push @list, { path => ($filter ? "$filter/" : '') . $subdir };
1672 $File::Find::prune = 1;
1673 }
1674 },
1675 }, "$dir");
1676
1677 } elsif (-f $projects_list) {
1678 # read from file(url-encoded):
1679 # 'git%2Fgit.git Linus+Torvalds'
1680 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
1681 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
1682 my %paths;
1683 open my ($fd), $projects_list or return;
1684 PROJECT:
1685 while (my $line = <$fd>) {
1686 chomp $line;
1687 my ($path, $owner) = split ' ', $line;
1688 $path = unescape($path);
1689 $owner = unescape($owner);
1690 if (!defined $path) {
1691 next;
1692 }
1693 if ($filter ne '') {
1694 # looking for forks;
1695 my $pfx = substr($path, 0, length($filter));
1696 if ($pfx ne $filter) {
1697 next PROJECT;
1698 }
1699 my $sfx = substr($path, length($filter));
1700 if ($sfx !~ /^\/.*\.git$/) {
1701 next PROJECT;
1702 }
1703 } elsif ($check_forks) {
1704 PATH:
1705 foreach my $filter (keys %paths) {
1706 # looking for forks;
1707 my $pfx = substr($path, 0, length($filter));
1708 if ($pfx ne $filter) {
1709 next PATH;
1710 }
1711 my $sfx = substr($path, length($filter));
1712 if ($sfx !~ /^\/.*\.git$/) {
1713 next PATH;
1714 }
1715 # is a fork, don't include it in
1716 # the list
1717 next PROJECT;
1718 }
1719 }
1720 if (check_export_ok("$projectroot/$path")) {
1721 my $pr = {
1722 path => $path,
1723 owner => to_utf8($owner),
1724 };
1725 push @list, $pr;
1726 (my $forks_path = $path) =~ s/\.git$//;
1727 $paths{$forks_path}++;
1728 }
1729 }
1730 close $fd;
1731 }
1732 return @list;
1733 }
1734
1735 our $gitweb_project_owner = undef;
1736 sub git_get_project_list_from_file {
1737
1738 return if (defined $gitweb_project_owner);
1739
1740 $gitweb_project_owner = {};
1741 # read from file (url-encoded):
1742 # 'git%2Fgit.git Linus+Torvalds'
1743 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
1744 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
1745 if (-f $projects_list) {
1746 open (my $fd , $projects_list);
1747 while (my $line = <$fd>) {
1748 chomp $line;
1749 my ($pr, $ow) = split ' ', $line;
1750 $pr = unescape($pr);
1751 $ow = unescape($ow);
1752 $gitweb_project_owner->{$pr} = to_utf8($ow);
1753 }
1754 close $fd;
1755 }
1756 }
1757
1758 sub git_get_project_owner {
1759 my $project = shift;
1760 my $owner;
1761
1762 return undef unless $project;
1763
1764 if (!defined $gitweb_project_owner) {
1765 git_get_project_list_from_file();
1766 }
1767
1768 if (exists $gitweb_project_owner->{$project}) {
1769 $owner = $gitweb_project_owner->{$project};
1770 }
1771 if (!defined $owner) {
1772 $owner = get_file_owner("$projectroot/$project");
1773 }
1774
1775 return $owner;
1776 }
1777
1778 sub git_get_last_activity {
1779 my ($path) = @_;
1780 my $fd;
1781
1782 $git_dir = "$projectroot/$path";
1783 open($fd, "-|", git_cmd(), 'for-each-ref',
1784 '--format=%(committer)',
1785 '--sort=-committerdate',
1786 '--count=1',
1787 'refs/heads') or return;
1788 my $most_recent = <$fd>;
1789 close $fd or return;
1790 if (defined $most_recent &&
1791 $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
1792 my $timestamp = $1;
1793 my $age = time - $timestamp;
1794 return ($age, age_string($age));
1795 }
1796 return (undef, undef);
1797 }
1798
1799 sub git_get_references {
1800 my $type = shift || "";
1801 my %refs;
1802 # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
1803 # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
1804 open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
1805 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
1806 or return;
1807
1808 while (my $line = <$fd>) {
1809 chomp $line;
1810 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type/?[^^]+)!) {
1811 if (defined $refs{$1}) {
1812 push @{$refs{$1}}, $2;
1813 } else {
1814 $refs{$1} = [ $2 ];
1815 }
1816 }
1817 }
1818 close $fd or return;
1819 return \%refs;
1820 }
1821
1822 sub git_get_rev_name_tags {
1823 my $hash = shift || return undef;
1824
1825 open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
1826 or return;
1827 my $name_rev = <$fd>;
1828 close $fd;
1829
1830 if ($name_rev =~ m|^$hash tags/(.*)$|) {
1831 return $1;
1832 } else {
1833 # catches also '$hash undefined' output
1834 return undef;
1835 }
1836 }
1837
1838 ## ----------------------------------------------------------------------
1839 ## parse to hash functions
1840
1841 sub parse_date {
1842 my $epoch = shift;
1843 my $tz = shift || "-0000";
1844
1845 my %date;
1846 my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
1847 my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
1848 my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
1849 $date{'hour'} = $hour;
1850 $date{'minute'} = $min;
1851 $date{'mday'} = $mday;
1852 $date{'day'} = $days[$wday];
1853 $date{'month'} = $months[$mon];
1854 $date{'rfc2822'} = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
1855 $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
1856 $date{'mday-time'} = sprintf "%d %s %02d:%02d",
1857 $mday, $months[$mon], $hour ,$min;
1858 $date{'iso-8601'} = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
1859 1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
1860
1861 $tz =~ m/^([+\-][0-9][0-9])([0-9][0-9])$/;
1862 my $local = $epoch + ((int $1 + ($2/60)) * 3600);
1863 ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
1864 $date{'hour_local'} = $hour;
1865 $date{'minute_local'} = $min;
1866 $date{'tz_local'} = $tz;
1867 $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
1868 1900+$year, $mon+1, $mday,
1869 $hour, $min, $sec, $tz);
1870 return %date;
1871 }
1872
1873 sub parse_tag {
1874 my $tag_id = shift;
1875 my %tag;
1876 my @comment;
1877
1878 open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
1879 $tag{'id'} = $tag_id;
1880 while (my $line = <$fd>) {
1881 chomp $line;
1882 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
1883 $tag{'object'} = $1;
1884 } elsif ($line =~ m/^type (.+)$/) {
1885 $tag{'type'} = $1;
1886 } elsif ($line =~ m/^tag (.+)$/) {
1887 $tag{'name'} = $1;
1888 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
1889 $tag{'author'} = $1;
1890 $tag{'epoch'} = $2;
1891 $tag{'tz'} = $3;
1892 } elsif ($line =~ m/--BEGIN/) {
1893 push @comment, $line;
1894 last;
1895 } elsif ($line eq "") {
1896 last;
1897 }
1898 }
1899 push @comment, <$fd>;
1900 $tag{'comment'} = \@comment;
1901 close $fd or return;
1902 if (!defined $tag{'name'}) {
1903 return
1904 };
1905 return %tag
1906 }
1907
1908 sub parse_commit_text {
1909 my ($commit_text, $withparents) = @_;
1910 my @commit_lines = split '\n', $commit_text;
1911 my %co;
1912
1913 pop @commit_lines; # Remove '\0'
1914
1915 if (! @commit_lines) {
1916 return;
1917 }
1918
1919 my $header = shift @commit_lines;
1920 if ($header !~ m/^[0-9a-fA-F]{40}/) {
1921 return;
1922 }
1923 ($co{'id'}, my @parents) = split ' ', $header;
1924 while (my $line = shift @commit_lines) {
1925 last if $line eq "\n";
1926 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
1927 $co{'tree'} = $1;
1928 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
1929 push @parents, $1;
1930 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
1931 $co{'author'} = $1;
1932 $co{'author_epoch'} = $2;
1933 $co{'author_tz'} = $3;
1934 if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
1935 $co{'author_name'} = $1;
1936 $co{'author_email'} = $2;
1937 } else {
1938 $co{'author_name'} = $co{'author'};
1939 }
1940 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
1941 $co{'committer'} = $1;
1942 $co{'committer_epoch'} = $2;
1943 $co{'committer_tz'} = $3;
1944 $co{'committer_name'} = $co{'committer'};
1945 if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
1946 $co{'committer_name'} = $1;
1947 $co{'committer_email'} = $2;
1948 } else {
1949 $co{'committer_name'} = $co{'committer'};
1950 }
1951 }
1952 }
1953 if (!defined $co{'tree'}) {
1954 return;
1955 };
1956 $co{'parents'} = \@parents;
1957 $co{'parent'} = $parents[0];
1958
1959 foreach my $title (@commit_lines) {
1960 $title =~ s/^ //;
1961 if ($title ne "") {
1962 $co{'title'} = chop_str($title, 80, 5);
1963 # remove leading stuff of merges to make the interesting part visible
1964 if (length($title) > 50) {
1965 $title =~ s/^Automatic //;
1966 $title =~ s/^merge (of|with) /Merge ... /i;
1967 if (length($title) > 50) {
1968 $title =~ s/(http|rsync):\/\///;
1969 }
1970 if (length($title) > 50) {
1971 $title =~ s/(master|www|rsync)\.//;
1972 }
1973 if (length($title) > 50) {
1974 $title =~ s/kernel.org:?//;
1975 }
1976 if (length($title) > 50) {
1977 $title =~ s/\/pub\/scm//;
1978 }
1979 }
1980 $co{'title_short'} = chop_str($title, 50, 5);
1981 last;
1982 }
1983 }
1984 if ($co{'title'} eq "") {
1985 $co{'title'} = $co{'title_short'} = '(no commit message)';
1986 }
1987 # remove added spaces
1988 foreach my $line (@commit_lines) {
1989 $line =~ s/^ //;
1990 }
1991 $co{'comment'} = \@commit_lines;
1992
1993 my $age = time - $co{'committer_epoch'};
1994 $co{'age'} = $age;
1995 $co{'age_string'} = age_string($age);
1996 my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
1997 if ($age > 60*60*24*7*2) {
1998 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
1999 $co{'age_string_age'} = $co{'age_string'};
2000 } else {
2001 $co{'age_string_date'} = $co{'age_string'};
2002 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
2003 }
2004 return %co;
2005 }
2006
2007 sub parse_commit {
2008 my ($commit_id) = @_;
2009 my %co;
2010
2011 local $/ = "\0";
2012
2013 open my $fd, "-|", git_cmd(), "rev-list",
2014 "--parents",
2015 "--header",
2016 "--max-count=1",
2017 $commit_id,
2018 "--",
2019 or die_error(undef, "Open git-rev-list failed");
2020 %co = parse_commit_text(<$fd>, 1);
2021 close $fd;
2022
2023 return %co;
2024 }
2025
2026 sub parse_commits {
2027 my ($commit_id, $maxcount, $skip, $arg, $filename) = @_;
2028 my @cos;
2029
2030 $maxcount ||= 1;
2031 $skip ||= 0;
2032
2033 local $/ = "\0";
2034
2035 open my $fd, "-|", git_cmd(), "rev-list",
2036 "--header",
2037 ($arg ? ($arg) : ()),
2038 ("--max-count=" . $maxcount),
2039 ("--skip=" . $skip),
2040 @extra_options,
2041 $commit_id,
2042 "--",
2043 ($filename ? ($filename) : ())
2044 or die_error(undef, "Open git-rev-list failed");
2045 while (my $line = <$fd>) {
2046 my %co = parse_commit_text($line);
2047 push @cos, \%co;
2048 }
2049 close $fd;
2050
2051 return wantarray ? @cos : \@cos;
2052 }
2053
2054 # parse ref from ref_file, given by ref_id, with given type
2055 sub parse_ref {
2056 my $ref_file = shift;
2057 my $ref_id = shift;
2058 my $type = shift || git_get_type($ref_id);
2059 my %ref_item;
2060
2061 $ref_item{'type'} = $type;
2062 $ref_item{'id'} = $ref_id;
2063 $ref_item{'epoch'} = 0;
2064 $ref_item{'age'} = "unknown";
2065 if ($type eq "tag") {
2066 my %tag = parse_tag($ref_id);
2067 $ref_item{'comment'} = $tag{'comment'};
2068 if ($tag{'type'} eq "commit") {
2069 my %co = parse_commit($tag{'object'});
2070 $ref_item{'epoch'} = $co{'committer_epoch'};
2071 $ref_item{'age'} = $co{'age_string'};
2072 } elsif (defined($tag{'epoch'})) {
2073 my $age = time - $tag{'epoch'};
2074 $ref_item{'epoch'} = $tag{'epoch'};
2075 $ref_item{'age'} = age_string($age);
2076 }
2077 $ref_item{'reftype'} = $tag{'type'};
2078 $ref_item{'name'} = $tag{'name'};
2079 $ref_item{'refid'} = $tag{'object'};
2080 } elsif ($type eq "commit"){
2081 my %co = parse_commit($ref_id);
2082 $ref_item{'reftype'} = "commit";
2083 $ref_item{'name'} = $ref_file;
2084 $ref_item{'title'} = $co{'title'};
2085 $ref_item{'refid'} = $ref_id;
2086 $ref_item{'epoch'} = $co{'committer_epoch'};
2087 $ref_item{'age'} = $co{'age_string'};
2088 } else {
2089 $ref_item{'reftype'} = $type;
2090 $ref_item{'name'} = $ref_file;
2091 $ref_item{'refid'} = $ref_id;
2092 }
2093
2094 return %ref_item;
2095 }
2096
2097 # parse line of git-diff-tree "raw" output
2098 sub parse_difftree_raw_line {
2099 my $line = shift;
2100 my %res;
2101
2102 # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M ls-files.c'
2103 # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M rev-tree.c'
2104 if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
2105 $res{'from_mode'} = $1;
2106 $res{'to_mode'} = $2;
2107 $res{'from_id'} = $3;
2108 $res{'to_id'} = $4;
2109 $res{'status'} = $res{'status_str'} = $5;
2110 $res{'similarity'} = $6;
2111 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
2112 ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
2113 } else {
2114 $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
2115 }
2116 }
2117 # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
2118 # combined diff (for merge commit)
2119 elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
2120 $res{'nparents'} = length($1);
2121 $res{'from_mode'} = [ split(' ', $2) ];
2122 $res{'to_mode'} = pop @{$res{'from_mode'}};
2123 $res{'from_id'} = [ split(' ', $3) ];
2124 $res{'to_id'} = pop @{$res{'from_id'}};
2125 $res{'status_str'} = $4;
2126 $res{'status'} = [ split('', $4) ];
2127 $res{'to_file'} = unquote($5);
2128 }
2129 # 'c512b523472485aef4fff9e57b229d9d243c967f'
2130 elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
2131 $res{'commit'} = $1;
2132 }
2133
2134 return wantarray ? %res : \%res;
2135 }
2136
2137 # wrapper: return parsed line of git-diff-tree "raw" output
2138 # (the argument might be raw line, or parsed info)
2139 sub parsed_difftree_line {
2140 my $line_or_ref = shift;
2141
2142 if (ref($line_or_ref) eq "HASH") {
2143 # pre-parsed (or generated by hand)
2144 return $line_or_ref;
2145 } else {
2146 return parse_difftree_raw_line($line_or_ref);
2147 }
2148 }
2149
2150 # parse line of git-ls-tree output
2151 sub parse_ls_tree_line ($;%) {
2152 my $line = shift;
2153 my %opts = @_;
2154 my %res;
2155
2156 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa panic.c'
2157 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
2158
2159 $res{'mode'} = $1;
2160 $res{'type'} = $2;
2161 $res{'hash'} = $3;
2162 if ($opts{'-z'}) {
2163 $res{'name'} = $4;
2164 } else {
2165 $res{'name'} = unquote($4);
2166 }
2167
2168 return wantarray ? %res : \%res;
2169 }
2170
2171 # generates _two_ hashes, references to which are passed as 2 and 3 argument
2172 sub parse_from_to_diffinfo {
2173 my ($diffinfo, $from, $to, @parents) = @_;
2174
2175 if ($diffinfo->{'nparents'}) {
2176 # combined diff
2177 $from->{'file'} = [];
2178 $from->{'href'} = [];
2179 fill_from_file_info($diffinfo, @parents)
2180 unless exists $diffinfo->{'from_file'};
2181 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2182 $from->{'file'}[$i] =
2183 defined $diffinfo->{'from_file'}[$i] ?
2184 $diffinfo->{'from_file'}[$i] :
2185 $diffinfo->{'to_file'};
2186 if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
2187 $from->{'href'}[$i] = href(action=>"blob",
2188 hash_base=>$parents[$i],
2189 hash=>$diffinfo->{'from_id'}[$i],
2190 file_name=>$from->{'file'}[$i]);
2191 } else {
2192 $from->{'href'}[$i] = undef;
2193 }
2194 }
2195 } else {
2196 # ordinary (not combined) diff
2197 $from->{'file'} = $diffinfo->{'from_file'};
2198 if ($diffinfo->{'status'} ne "A") { # not new (added) file
2199 $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
2200 hash=>$diffinfo->{'from_id'},
2201 file_name=>$from->{'file'});
2202 } else {
2203 delete $from->{'href'};
2204 }
2205 }
2206
2207 $to->{'file'} = $diffinfo->{'to_file'};
2208 if (!is_deleted($diffinfo)) { # file exists in result
2209 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
2210 hash=>$diffinfo->{'to_id'},
2211 file_name=>$to->{'file'});
2212 } else {
2213 delete $to->{'href'};
2214 }
2215 }
2216
2217 ## ......................................................................
2218 ## parse to array of hashes functions
2219
2220 sub git_get_heads_list {
2221 my $limit = shift;
2222 my @headslist;
2223
2224 open my $fd, '-|', git_cmd(), 'for-each-ref',
2225 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
2226 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
2227 'refs/heads'
2228 or return;
2229 while (my $line = <$fd>) {
2230 my %ref_item;
2231
2232 chomp $line;
2233 my ($refinfo, $committerinfo) = split(/\0/, $line);
2234 my ($hash, $name, $title) = split(' ', $refinfo, 3);
2235 my ($committer, $epoch, $tz) =
2236 ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
2237 $name =~ s!^refs/heads/!!;
2238
2239 $ref_item{'name'} = $name;
2240 $ref_item{'id'} = $hash;
2241 $ref_item{'title'} = $title || '(no commit message)';
2242 $ref_item{'epoch'} = $epoch;
2243 if ($epoch) {
2244 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
2245 } else {
2246 $ref_item{'age'} = "unknown";
2247 }
2248
2249 push @headslist, \%ref_item;
2250 }
2251 close $fd;
2252
2253 return wantarray ? @headslist : \@headslist;
2254 }
2255
2256 sub git_get_tags_list {
2257 my $limit = shift;
2258 my @tagslist;
2259
2260 open my $fd, '-|', git_cmd(), 'for-each-ref',
2261 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
2262 '--format=%(objectname) %(objecttype) %(refname) '.
2263 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
2264 'refs/tags'
2265 or return;
2266 while (my $line = <$fd>) {
2267 my %ref_item;
2268
2269 chomp $line;
2270 my ($refinfo, $creatorinfo) = split(/\0/, $line);
2271 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
2272 my ($creator, $epoch, $tz) =
2273 ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
2274 $name =~ s!^refs/tags/!!;
2275
2276 $ref_item{'type'} = $type;
2277 $ref_item{'id'} = $id;
2278 $ref_item{'name'} = $name;
2279 if ($type eq "tag") {
2280 $ref_item{'subject'} = $title;
2281 $ref_item{'reftype'} = $reftype;
2282 $ref_item{'refid'} = $refid;
2283 } else {
2284 $ref_item{'reftype'} = $type;
2285 $ref_item{'refid'} = $id;
2286 }
2287
2288 if ($type eq "tag" || $type eq "commit") {
2289 $ref_item{'epoch'} = $epoch;
2290 if ($epoch) {
2291 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
2292 } else {
2293 $ref_item{'age'} = "unknown";
2294 }
2295 }
2296
2297 push @tagslist, \%ref_item;
2298 }
2299 close $fd;
2300
2301 return wantarray ? @tagslist : \@tagslist;
2302 }
2303
2304 ## ----------------------------------------------------------------------
2305 ## filesystem-related functions
2306
2307 sub get_file_owner {
2308 my $path = shift;
2309
2310 my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
2311 my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
2312 if (!defined $gcos) {
2313 return undef;
2314 }
2315 my $owner = $gcos;
2316 $owner =~ s/[,;].*$//;
2317 return to_utf8($owner);
2318 }
2319
2320 ## ......................................................................
2321 ## mimetype related functions
2322
2323 sub mimetype_guess_file {
2324 my $filename = shift;
2325 my $mimemap = shift;
2326 -r $mimemap or return undef;
2327
2328 my %mimemap;
2329 open(MIME, $mimemap) or return undef;
2330 while (<MIME>) {
2331 next if m/^#/; # skip comments
2332 my ($mime, $exts) = split(/\t+/);
2333 if (defined $exts) {
2334 my @exts = split(/\s+/, $exts);
2335 foreach my $ext (@exts) {
2336 $mimemap{$ext} = $mime;
2337 }
2338 }
2339 }
2340 close(MIME);
2341
2342 $filename =~ /\.([^.]*)$/;
2343 return $mimemap{$1};
2344 }
2345
2346 sub mimetype_guess {
2347 my $filename = shift;
2348 my $mime;
2349 $filename =~ /\./ or return undef;
2350
2351 if ($mimetypes_file) {
2352 my $file = $mimetypes_file;
2353 if ($file !~ m!^/!) { # if it is relative path
2354 # it is relative to project
2355 $file = "$projectroot/$project/$file";
2356 }
2357 $mime = mimetype_guess_file($filename, $file);
2358 }
2359 $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
2360 return $mime;
2361 }
2362
2363 sub blob_mimetype {
2364 my $fd = shift;
2365 my $filename = shift;
2366
2367 if ($filename) {
2368 my $mime = mimetype_guess($filename);
2369 $mime and return $mime;
2370 }
2371
2372 # just in case
2373 return $default_blob_plain_mimetype unless $fd;
2374
2375 if (-T $fd) {
2376 return 'text/plain' .
2377 ($default_text_plain_charset ? '; charset='.$default_text_plain_charset : '');
2378 } elsif (! $filename) {
2379 return 'application/octet-stream';
2380 } elsif ($filename =~ m/\.png$/i) {
2381 return 'image/png';
2382 } elsif ($filename =~ m/\.gif$/i) {
2383 return 'image/gif';
2384 } elsif ($filename =~ m/\.jpe?g$/i) {
2385 return 'image/jpeg';
2386 } else {
2387 return 'application/octet-stream';
2388 }
2389 }
2390
2391 ## ======================================================================
2392 ## functions printing HTML: header, footer, error page
2393
2394 sub git_header_html {
2395 my $status = shift || "200 OK";
2396 my $expires = shift;
2397
2398 my $title = "$site_name";
2399 if (defined $project) {
2400 $title .= " - " . to_utf8($project);
2401 if (defined $action) {
2402 $title .= "/$action";
2403 if (defined $file_name) {
2404 $title .= " - " . esc_path($file_name);
2405 if ($action eq "tree" && $file_name !~ m|/$|) {
2406 $title .= "/";
2407 }
2408 }
2409 }
2410 }
2411 my $content_type;
2412 # require explicit support from the UA if we are to send the page as
2413 # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
2414 # we have to do this because MSIE sometimes globs '*/*', pretending to
2415 # support xhtml+xml but choking when it gets what it asked for.
2416 if (defined $cgi->http('HTTP_ACCEPT') &&
2417 $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
2418 $cgi->Accept('application/xhtml+xml') != 0) {
2419 $content_type = 'application/xhtml+xml';
2420 } else {
2421 $content_type = 'text/html';
2422 }
2423 print $cgi->header(-type=>$content_type, -charset => 'utf-8',
2424 -status=> $status, -expires => $expires);
2425 my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
2426 print <<EOF;
2427 <?xml version="1.0" encoding="utf-8"?>
2428 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
2429 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
2430 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
2431 <!-- git core binaries version $git_version -->
2432 <head>
2433 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
2434 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
2435 <meta name="robots" content="index, nofollow"/>
2436 <title>$title</title>
2437 EOF
2438 # print out each stylesheet that exist
2439 if (defined $stylesheet) {
2440 #provides backwards capability for those people who define style sheet in a config file
2441 print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
2442 } else {
2443 foreach my $stylesheet (@stylesheets) {
2444 next unless $stylesheet;
2445 print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
2446 }
2447 }
2448 if (defined $project) {
2449 printf('<link rel="alternate" title="%s log RSS feed" '.
2450 'href="%s" type="application/rss+xml" />'."\n",
2451 esc_param($project), href(action=>"rss"));
2452 printf('<link rel="alternate" title="%s log RSS feed (no merges)" '.
2453 'href="%s" type="application/rss+xml" />'."\n",
2454 esc_param($project), href(action=>"rss",
2455 extra_options=>"--no-merges"));
2456 printf('<link rel="alternate" title="%s log Atom feed" '.
2457 'href="%s" type="application/atom+xml" />'."\n",
2458 esc_param($project), href(action=>"atom"));
2459 printf('<link rel="alternate" title="%s log Atom feed (no merges)" '.
2460 'href="%s" type="application/atom+xml" />'."\n",
2461 esc_param($project), href(action=>"atom",
2462 extra_options=>"--no-merges"));
2463 } else {
2464 printf('<link rel="alternate" title="%s projects list" '.
2465 'href="%s" type="text/plain; charset=utf-8"/>'."\n",
2466 $site_name, href(project=>undef, action=>"project_index"));
2467 printf('<link rel="alternate" title="%s projects feeds" '.
2468 'href="%s" type="text/x-opml"/>'."\n",
2469 $site_name, href(project=>undef, action=>"opml"));
2470 }
2471 if (defined $favicon) {
2472 print qq(<link rel="shortcut icon" href="$favicon" type="image/png"/>\n);
2473 }
2474
2475 print "</head>\n" .
2476 "<body>\n";
2477
2478 if (-f $site_header) {
2479 open (my $fd, $site_header);
2480 print <$fd>;
2481 close $fd;
2482 }
2483
2484 print "<div class=\"page_header\">\n" .
2485 $cgi->a({-href => esc_url($logo_url),
2486 -title => $logo_label},
2487 qq(<img src="$logo" width="72" height="27" alt="git" class="logo"/>));
2488 print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
2489 if (defined $project) {
2490 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
2491 if (defined $action) {
2492 print " / $action";
2493 }
2494 print "\n";
2495 }
2496 print "</div>\n";
2497
2498 my ($have_search) = gitweb_check_feature('search');
2499 if ((defined $project) && ($have_search)) {
2500 if (!defined $searchtext) {
2501 $searchtext = "";
2502 }
2503 my $search_hash;
2504 if (defined $hash_base) {
2505 $search_hash = $hash_base;
2506 } elsif (defined $hash) {
2507 $search_hash = $hash;
2508 } else {
2509 $search_hash = "HEAD";
2510 }
2511 my $action = $my_uri;
2512 my ($use_pathinfo) = gitweb_check_feature('pathinfo');
2513 if ($use_pathinfo) {
2514 $action .= "/$project";
2515 } else {
2516 $cgi->param("p", $project);
2517 }
2518 $cgi->param("a", "search");
2519 $cgi->param("h", $search_hash);
2520 print $cgi->startform(-method => "get", -action => $action) .
2521 "<div class=\"search\">\n" .
2522 (!$use_pathinfo && $cgi->hidden(-name => "p") . "\n") .
2523 $cgi->hidden(-name => "a") . "\n" .
2524 $cgi->hidden(-name => "h") . "\n" .
2525 $cgi->popup_menu(-name => 'st', -default => 'commit',
2526 -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
2527 $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
2528 " search:\n",
2529 $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
2530 "</div>" .
2531 $cgi->end_form() . "\n";
2532 }
2533 }
2534
2535 sub git_footer_html {
2536 print "<div class=\"page_footer\">\n";
2537 if (defined $project) {
2538 my $descr = git_get_project_description($project);
2539 if (defined $descr) {
2540 print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
2541 }
2542 print $cgi->a({-href => href(action=>"rss"),
2543 -class => "rss_logo"}, "RSS") . " ";
2544 print $cgi->a({-href => href(action=>"atom"),
2545 -class => "rss_logo"}, "Atom") . "\n";
2546 } else {
2547 print $cgi->a({-href => href(project=>undef, action=>"opml"),
2548 -class => "rss_logo"}, "OPML") . " ";
2549 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
2550 -class => "rss_logo"}, "TXT") . "\n";
2551 }
2552 print "</div>\n" ;
2553
2554 if (-f $site_footer) {
2555 open (my $fd, $site_footer);
2556 print <$fd>;
2557 close $fd;
2558 }
2559
2560 print "</body>\n" .
2561 "</html>";
2562 }
2563
2564 sub die_error {
2565 my $status = shift || "403 Forbidden";
2566 my $error = shift || "Malformed query, file missing or permission denied";
2567
2568 git_header_html($status);
2569 print <<EOF;
2570 <div class="page_body">
2571 <br /><br />
2572 $status - $error
2573 <br />
2574 </div>
2575 EOF
2576 git_footer_html();
2577 exit;
2578 }
2579
2580 ## ----------------------------------------------------------------------
2581 ## functions printing or outputting HTML: navigation
2582
2583 sub git_print_page_nav {
2584 my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
2585 $extra = '' if !defined $extra; # pager or formats
2586
2587 my @navs = qw(summary shortlog log commit commitdiff tree);
2588 if ($suppress) {
2589 @navs = grep { $_ ne $suppress } @navs;
2590 }
2591
2592 my %arg = map { $_ => {action=>$_} } @navs;
2593 if (defined $head) {
2594 for (qw(commit commitdiff)) {
2595 $arg{$_}{'hash'} = $head;
2596 }
2597 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
2598 for (qw(shortlog log)) {
2599 $arg{$_}{'hash'} = $head;
2600 }
2601 }
2602 }
2603 $arg{'tree'}{'hash'} = $treehead if defined $treehead;
2604 $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
2605
2606 print "<div class=\"page_nav\">\n" .
2607 (join " | ",
2608 map { $_ eq $current ?
2609 $_ : $cgi->a({-href => href(%{$arg{$_}})}, "$_")
2610 } @navs);
2611 print "<br/>\n$extra<br/>\n" .
2612 "</div>\n";
2613 }
2614
2615 sub format_paging_nav {
2616 my ($action, $hash, $head, $page, $nrevs) = @_;
2617 my $paging_nav;
2618
2619
2620 if ($hash ne $head || $page) {
2621 $paging_nav .= $cgi->a({-href => href(action=>$action)}, "HEAD");
2622 } else {
2623 $paging_nav .= "HEAD";
2624 }
2625
2626 if ($page > 0) {
2627 $paging_nav .= " &sdot; " .
2628 $cgi->a({-href => href(-replay=>1, page=>$page-1),
2629 -accesskey => "p", -title => "Alt-p"}, "prev");
2630 } else {
2631 $paging_nav .= " &sdot; prev";
2632 }
2633
2634 if ($nrevs >= (100 * ($page+1)-1)) {
2635 $paging_nav .= " &sdot; " .
2636 $cgi->a({-href => href(-replay=>1, page=>$page+1),
2637 -accesskey => "n", -title => "Alt-n"}, "next");
2638 } else {
2639 $paging_nav .= " &sdot; next";
2640 }
2641
2642 return $paging_nav;
2643 }
2644
2645 ## ......................................................................
2646 ## functions printing or outputting HTML: div
2647
2648 sub git_print_header_div {
2649 my ($action, $title, $hash, $hash_base) = @_;
2650 my %args = ();
2651
2652 $args{'action'} = $action;
2653 $args{'hash'} = $hash if $hash;
2654 $args{'hash_base'} = $hash_base if $hash_base;
2655
2656 print "<div class=\"header\">\n" .
2657 $cgi->a({-href => href(%args), -class => "title"},
2658 $title ? $title : $action) .
2659 "\n</div>\n";
2660 }
2661
2662 #sub git_print_authorship (\%) {
2663 sub git_print_authorship {
2664 my $co = shift;
2665
2666 my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
2667 print "<div class=\"author_date\">" .
2668 esc_html($co->{'author_name'}) .
2669 " [$ad{'rfc2822'}";
2670 if ($ad{'hour_local'} < 6) {
2671 printf(" (<span class=\"atnight\">%02d:%02d</span> %s)",
2672 $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
2673 } else {
2674 printf(" (%02d:%02d %s)",
2675 $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
2676 }
2677 print "]</div>\n";
2678 }
2679
2680 sub git_print_page_path {
2681 my $name = shift;
2682 my $type = shift;
2683 my $hb = shift;
2684
2685
2686 print "<div class=\"page_path\">";
2687 print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
2688 -title => 'tree root'}, to_utf8("[$project]"));
2689 print " / ";
2690 if (defined $name) {
2691 my @dirname = split '/', $name;
2692 my $basename = pop @dirname;
2693 my $fullname = '';
2694
2695 foreach my $dir (@dirname) {
2696 $fullname .= ($fullname ? '/' : '') . $dir;
2697 print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
2698 hash_base=>$hb),
2699 -title => $fullname}, esc_path($dir));
2700 print " / ";
2701 }
2702 if (defined $type && $type eq 'blob') {
2703 print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
2704 hash_base=>$hb),
2705 -title => $name}, esc_path($basename));
2706 } elsif (defined $type && $type eq 'tree') {
2707 print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
2708 hash_base=>$hb),
2709 -title => $name}, esc_path($basename));
2710 print " / ";
2711 } else {
2712 print esc_path($basename);
2713 }
2714 }
2715 print "<br/></div>\n";
2716 }
2717
2718 # sub git_print_log (\@;%) {
2719 sub git_print_log ($;%) {
2720 my $log = shift;
2721 my %opts = @_;
2722
2723 if ($opts{'-remove_title'}) {
2724 # remove title, i.e. first line of log
2725 shift @$log;
2726 }
2727 # remove leading empty lines
2728 while (defined $log->[0] && $log->[0] eq "") {
2729 shift @$log;
2730 }
2731
2732 # print log
2733 my $signoff = 0;
2734 my $empty = 0;
2735 foreach my $line (@$log) {
2736 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
2737 $signoff = 1;
2738 $empty = 0;
2739 if (! $opts{'-remove_signoff'}) {
2740 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
2741 next;
2742 } else {
2743 # remove signoff lines
2744 next;
2745 }
2746 } else {
2747 $signoff = 0;
2748 }
2749
2750 # print only one empty line
2751 # do not print empty line after signoff
2752 if ($line eq "") {
2753 next if ($empty || $signoff);
2754 $empty = 1;
2755 } else {
2756 $empty = 0;
2757 }
2758
2759 print format_log_line_html($line) . "<br/>\n";
2760 }
2761
2762 if ($opts{'-final_empty_line'}) {
2763 # end with single empty line
2764 print "<br/>\n" unless $empty;
2765 }
2766 }
2767
2768 # return link target (what link points to)
2769 sub git_get_link_target {
2770 my $hash = shift;
2771 my $link_target;
2772
2773 # read link
2774 open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
2775 or return;
2776 {
2777 local $/;
2778 $link_target = <$fd>;
2779 }
2780 close $fd
2781 or return;
2782
2783 return $link_target;
2784 }
2785
2786 # given link target, and the directory (basedir) the link is in,
2787 # return target of link relative to top directory (top tree);
2788 # return undef if it is not possible (including absolute links).
2789 sub normalize_link_target {
2790 my ($link_target, $basedir, $hash_base) = @_;
2791
2792 # we can normalize symlink target only if $hash_base is provided
2793 return unless $hash_base;
2794
2795 # absolute symlinks (beginning with '/') cannot be normalized
2796 return if (substr($link_target, 0, 1) eq '/');
2797
2798 # normalize link target to path from top (root) tree (dir)
2799 my $path;
2800 if ($basedir) {
2801 $path = $basedir . '/' . $link_target;
2802 } else {
2803 # we are in top (root) tree (dir)
2804 $path = $link_target;
2805 }
2806
2807 # remove //, /./, and /../
2808 my @path_parts;
2809 foreach my $part (split('/', $path)) {
2810 # discard '.' and ''
2811 next if (!$part || $part eq '.');
2812 # handle '..'
2813 if ($part eq '..') {
2814 if (@path_parts) {
2815 pop @path_parts;
2816 } else {
2817 # link leads outside repository (outside top dir)
2818 return;
2819 }
2820 } else {
2821 push @path_parts, $part;
2822 }
2823 }
2824 $path = join('/', @path_parts);
2825
2826 return $path;
2827 }
2828
2829 # print tree entry (row of git_tree), but without encompassing <tr> element
2830 sub git_print_tree_entry {
2831 my ($t, $basedir, $hash_base, $have_blame) = @_;
2832
2833 my %base_key = ();
2834 $base_key{'hash_base'} = $hash_base if defined $hash_base;
2835
2836 # The format of a table row is: mode list link. Where mode is
2837 # the mode of the entry, list is the name of the entry, an href,
2838 # and link is the action links of the entry.
2839
2840 print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
2841 if ($t->{'type'} eq "blob") {
2842 print "<td class=\"list\">" .
2843 $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
2844 file_name=>"$basedir$t->{'name'}", %base_key),
2845 -class => "list"}, esc_path($t->{'name'}));
2846 if (S_ISLNK(oct $t->{'mode'})) {
2847 my $link_target = git_get_link_target($t->{'hash'});
2848 if ($link_target) {
2849 my $norm_target = normalize_link_target($link_target, $basedir, $hash_base);
2850 if (defined $norm_target) {
2851 print " -> " .
2852 $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
2853 file_name=>$norm_target),
2854 -title => $norm_target}, esc_path($link_target));
2855 } else {
2856 print " -> " . esc_path($link_target);
2857 }
2858 }
2859 }
2860 print "</td>\n";
2861 print "<td class=\"link\">";
2862 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
2863 file_name=>"$basedir$t->{'name'}", %base_key)},
2864 "blob");
2865 if ($have_blame) {
2866 print " | " .
2867 $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
2868 file_name=>"$basedir$t->{'name'}", %base_key)},
2869 "blame");
2870 }
2871 if (defined $hash_base) {
2872 print " | " .
2873 $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
2874 hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
2875 "history");
2876 }
2877 print " | " .
2878 $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
2879 file_name=>"$basedir$t->{'name'}")},
2880 "raw");
2881 print "</td>\n";
2882
2883 } elsif ($t->{'type'} eq "tree") {
2884 print "<td class=\"list\">";
2885 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
2886 file_name=>"$basedir$t->{'name'}", %base_key)},
2887 esc_path($t->{'name'}));
2888 print "</td>\n";
2889 print "<td class=\"link\">";
2890 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
2891 file_name=>"$basedir$t->{'name'}", %base_key)},
2892 "tree");
2893 if (defined $hash_base) {
2894 print " | " .
2895 $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
2896 file_name=>"$basedir$t->{'name'}")},
2897 "history");
2898 }
2899 print "</td>\n";
2900 } else {
2901 # unknown object: we can only present history for it
2902 # (this includes 'commit' object, i.e. submodule support)
2903 print "<td class=\"list\">" .
2904 esc_path($t->{'name'}) .
2905 "</td>\n";
2906 print "<td class=\"link\">";
2907 if (defined $hash_base) {
2908 print $cgi->a({-href => href(action=>"history",
2909 hash_base=>$hash_base,
2910 file_name=>"$basedir$t->{'name'}")},
2911 "history");
2912 }
2913 print "</td>\n";
2914 }
2915 }
2916
2917 ## ......................................................................
2918 ## functions printing large fragments of HTML
2919
2920 # get pre-image filenames for merge (combined) diff
2921 sub fill_from_file_info {
2922 my ($diff, @parents) = @_;
2923
2924 $diff->{'from_file'} = [ ];
2925 $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
2926 for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
2927 if ($diff->{'status'}[$i] eq 'R' ||
2928 $diff->{'status'}[$i] eq 'C') {
2929 $diff->{'from_file'}[$i] =
2930 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
2931 }
2932 }
2933
2934 return $diff;
2935 }
2936
2937 # is current raw difftree line of file deletion
2938 sub is_deleted {
2939 my $diffinfo = shift;
2940
2941 return $diffinfo->{'status_str'} =~ /D/;
2942 }
2943
2944 # does patch correspond to [previous] difftree raw line
2945 # $diffinfo - hashref of parsed raw diff format
2946 # $patchinfo - hashref of parsed patch diff format
2947 # (the same keys as in $diffinfo)
2948 sub is_patch_split {
2949 my ($diffinfo, $patchinfo) = @_;
2950
2951 return defined $diffinfo && defined $patchinfo
2952 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
2953 }
2954
2955
2956 sub git_difftree_body {
2957 my ($difftree, $hash, @parents) = @_;
2958 my ($parent) = $parents[0];
2959 my ($have_blame) = gitweb_check_feature('blame');
2960 print "<div class=\"list_head\">\n";
2961 if ($#{$difftree} > 10) {
2962 print(($#{$difftree} + 1) . " files changed:\n");
2963 }
2964 print "</div>\n";
2965
2966 print "<table class=\"" .
2967 (@parents > 1 ? "combined " : "") .
2968 "diff_tree\">\n";
2969
2970 # header only for combined diff in 'commitdiff' view
2971 my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
2972 if ($has_header) {
2973 # table header
2974 print "<thead><tr>\n" .
2975 "<th></th><th></th>\n"; # filename, patchN link
2976 for (my $i = 0; $i < @parents; $i++) {
2977 my $par = $parents[$i];
2978 print "<th>" .
2979 $cgi->a({-href => href(action=>"commitdiff",
2980 hash=>$hash, hash_parent=>$par),
2981 -title => 'commitdiff to parent number ' .
2982 ($i+1) . ': ' . substr($par,0,7)},
2983 $i+1) .
2984 "&nbsp;</th>\n";
2985 }
2986 print "</tr></thead>\n<tbody>\n";
2987 }
2988
2989 my $alternate = 1;
2990 my $patchno = 0;
2991 foreach my $line (@{$difftree}) {
2992 my $diff = parsed_difftree_line($line);
2993
2994 if ($alternate) {
2995 print "<tr class=\"dark\">\n";
2996 } else {
2997 print "<tr class=\"light\">\n";
2998 }
2999 $alternate ^= 1;
3000
3001 if (exists $diff->{'nparents'}) { # combined diff
3002
3003 fill_from_file_info($diff, @parents)
3004 unless exists $diff->{'from_file'};
3005
3006 if (!is_deleted($diff)) {
3007 # file exists in the result (child) commit
3008 print "<td>" .
3009 $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
3010 file_name=>$diff->{'to_file'},
3011 hash_base=>$hash),
3012 -class => "list"}, esc_path($diff->{'to_file'})) .
3013 "</td>\n";
3014 } else {
3015 print "<td>" .
3016 esc_path($diff->{'to_file'}) .
3017 "</td>\n";
3018 }
3019
3020 if ($action eq 'commitdiff') {
3021 # link to patch
3022 $patchno++;
3023 print "<td class=\"link\">" .
3024 $cgi->a({-href => "#patch$patchno"}, "patch") .
3025 " | " .
3026 "</td>\n";
3027 }
3028
3029 my $has_history = 0;
3030 my $not_deleted = 0;
3031 for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
3032 my $hash_parent = $parents[$i];
3033 my $from_hash = $diff->{'from_id'}[$i];
3034 my $from_path = $diff->{'from_file'}[$i];
3035 my $status = $diff->{'status'}[$i];
3036
3037 $has_history ||= ($status ne 'A');
3038 $not_deleted ||= ($status ne 'D');
3039
3040 if ($status eq 'A') {
3041 print "<td class=\"link\" align=\"right\"> | </td>\n";
3042 } elsif ($status eq 'D') {
3043 print "<td class=\"link\">" .
3044 $cgi->a({-href => href(action=>"blob",
3045 hash_base=>$hash,
3046 hash=>$from_hash,
3047 file_name=>$from_path)},
3048 "blob" . ($i+1)) .
3049 " | </td>\n";
3050 } else {
3051 if ($diff->{'to_id'} eq $from_hash) {
3052 print "<td class=\"link nochange\">";
3053 } else {
3054 print "<td class=\"link\">";
3055 }
3056 print $cgi->a({-href => href(action=>"blobdiff",
3057 hash=>$diff->{'to_id'},
3058 hash_parent=>$from_hash,
3059 hash_base=>$hash,
3060 hash_parent_base=>$hash_parent,
3061 file_name=>$diff->{'to_file'},
3062 file_parent=>$from_path)},
3063 "diff" . ($i+1)) .
3064 " | </td>\n";
3065 }
3066 }
3067
3068 print "<td class=\"link\">";
3069 if ($not_deleted) {
3070 print $cgi->a({-href => href(action=>"blob",
3071 hash=>$diff->{'to_id'},
3072 file_name=>$diff->{'to_file'},
3073 hash_base=>$hash)},
3074 "blob");
3075 print " | " if ($has_history);
3076 }
3077 if ($has_history) {
3078 print $cgi->a({-href => href(action=>"history",
3079 file_name=>$diff->{'to_file'},
3080 hash_base=>$hash)},
3081 "history");
3082 }
3083 print "</td>\n";
3084
3085 print "</tr>\n";
3086 next; # instead of 'else' clause, to avoid extra indent
3087 }
3088 # else ordinary diff
3089
3090 my ($to_mode_oct, $to_mode_str, $to_file_type);
3091 my ($from_mode_oct, $from_mode_str, $from_file_type);
3092 if ($diff->{'to_mode'} ne ('0' x 6)) {
3093 $to_mode_oct = oct $diff->{'to_mode'};
3094 if (S_ISREG($to_mode_oct)) { # only for regular file
3095 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
3096 }
3097 $to_file_type = file_type($diff->{'to_mode'});
3098 }
3099 if ($diff->{'from_mode'} ne ('0' x 6)) {
3100 $from_mode_oct = oct $diff->{'from_mode'};
3101 if (S_ISREG($to_mode_oct)) { # only for regular file
3102 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
3103 }
3104 $from_file_type = file_type($diff->{'from_mode'});
3105 }
3106
3107 if ($diff->{'status'} eq "A") { # created
3108 my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
3109 $mode_chng .= " with mode: $to_mode_str" if $to_mode_str;
3110 $mode_chng .= "]</span>";
3111 print "<td>";
3112 print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
3113 hash_base=>$hash, file_name=>$diff->{'file'}),
3114 -class => "list"}, esc_path($diff->{'file'}));
3115 print "</td>\n";
3116 print "<td>$mode_chng</td>\n";
3117 print "<td class=\"link\">";
3118 if ($action eq 'commitdiff') {
3119 # link to patch
3120 $patchno++;
3121 print $cgi->a({-href => "#patch$patchno"}, "patch");
3122 print " | ";
3123 }
3124 print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
3125 hash_base=>$hash, file_name=>$diff->{'file'})},
3126 "blob");
3127 print "</td>\n";
3128
3129 } elsif ($diff->{'status'} eq "D") { # deleted
3130 my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
3131 print "<td>";
3132 print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
3133 hash_base=>$parent, file_name=>$diff->{'file'}),
3134 -class => "list"}, esc_path($diff->{'file'}));
3135 print "</td>\n";
3136 print "<td>$mode_chng</td>\n";
3137 print "<td class=\"link\">";
3138 if ($action eq 'commitdiff') {
3139 # link to patch
3140 $patchno++;
3141 print $cgi->a({-href => "#patch$patchno"}, "patch");
3142 print " | ";
3143 }
3144 print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
3145 hash_base=>$parent, file_name=>$diff->{'file'})},
3146 "blob") . " | ";
3147 if ($have_blame) {
3148 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
3149 file_name=>$diff->{'file'})},
3150 "blame") . " | ";
3151 }
3152 print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
3153 file_name=>$diff->{'file'})},
3154 "history");
3155 print "</td>\n";
3156
3157 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
3158 my $mode_chnge = "";
3159 if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
3160 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
3161 if ($from_file_type ne $to_file_type) {
3162 $mode_chnge .= " from $from_file_type to $to_file_type";
3163 }
3164 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
3165 if ($from_mode_str && $to_mode_str) {
3166 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
3167 } elsif ($to_mode_str) {
3168 $mode_chnge .= " mode: $to_mode_str";
3169 }
3170 }
3171 $mode_chnge .= "]</span>\n";
3172 }
3173 print "<td>";
3174 print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
3175 hash_base=>$hash, file_name=>$diff->{'file'}),
3176 -class => "list"}, esc_path($diff->{'file'}));
3177 print "</td>\n";
3178 print "<td>$mode_chnge</td>\n";
3179 print "<td class=\"link\">";
3180 if ($action eq 'commitdiff') {
3181 # link to patch
3182 $patchno++;
3183 print $cgi->a({-href => "#patch$patchno"}, "patch") .
3184 " | ";
3185 } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
3186 # "commit" view and modified file (not onlu mode changed)
3187 print $cgi->a({-href => href(action=>"blobdiff",
3188 hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
3189 hash_base=>$hash, hash_parent_base=>$parent,
3190 file_name=>$diff->{'file'})},
3191 "diff") .
3192 " | ";
3193 }
3194 print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
3195 hash_base=>$hash, file_name=>$diff->{'file'})},
3196 "blob") . " | ";
3197 if ($have_blame) {
3198 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
3199 file_name=>$diff->{'file'})},
3200 "blame") . " | ";
3201 }
3202 print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
3203 file_name=>$diff->{'file'})},
3204 "history");
3205 print "</td>\n";
3206
3207 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
3208 my %status_name = ('R' => 'moved', 'C' => 'copied');
3209 my $nstatus = $status_name{$diff->{'status'}};
3210 my $mode_chng = "";
3211 if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
3212 # mode also for directories, so we cannot use $to_mode_str
3213 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
3214 }
3215 print "<td>" .
3216 $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
3217 hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
3218 -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
3219 "<td><span class=\"file_status $nstatus\">[$nstatus from " .
3220 $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
3221 hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
3222 -class => "list"}, esc_path($diff->{'from_file'})) .
3223 " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
3224 "<td class=\"link\">";
3225 if ($action eq 'commitdiff') {
3226 # link to patch
3227 $patchno++;
3228 print $cgi->a({-href => "#patch$patchno"}, "patch") .
3229 " | ";
3230 } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
3231 # "commit" view and modified file (not only pure rename or copy)
3232 print $cgi->a({-href => href(action=>"blobdiff",
3233 hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
3234 hash_base=>$hash, hash_parent_base=>$parent,
3235 file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
3236 "diff") .
3237 " | ";
3238 }
3239 print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
3240 hash_base=>$parent, file_name=>$diff->{'to_file'})},
3241 "blob") . " | ";
3242 if ($have_blame) {
3243 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
3244 file_name=>$diff->{'to_file'})},
3245 "blame") . " | ";
3246 }
3247 print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
3248 file_name=>$diff->{'to_file'})},
3249 "history");
3250 print "</td>\n";
3251
3252 } # we should not encounter Unmerged (U) or Unknown (X) status
3253 print "</tr>\n";
3254 }
3255 print "</tbody>" if $has_header;
3256 print "</table>\n";
3257 }
3258
3259 sub git_patchset_body {
3260 my ($fd, $difftree, $hash, @hash_parents) = @_;
3261 my ($hash_parent) = $hash_parents[0];
3262
3263 my $is_combined = (@hash_parents > 1);
3264 my $patch_idx = 0;
3265 my $patch_number = 0;
3266 my $patch_line;
3267 my $diffinfo;
3268 my $to_name;
3269 my (%from, %to);
3270
3271 print "<div class=\"patchset\">\n";
3272
3273 # skip to first patch
3274 while ($patch_line = <$fd>) {
3275 chomp $patch_line;
3276
3277 last if ($patch_line =~ m/^diff /);
3278 }
3279
3280 PATCH:
3281 while ($patch_line) {
3282
3283 # parse "git diff" header line
3284 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
3285 # $1 is from_name, which we do not use
3286 $to_name = unquote($2);
3287 $to_name =~ s!^b/!!;
3288 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
3289 # $1 is 'cc' or 'combined', which we do not use
3290 $to_name = unquote($2);
3291 } else {
3292 $to_name = undef;
3293 }
3294
3295 # check if current patch belong to current raw line
3296 # and parse raw git-diff line if needed
3297 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
3298 # this is continuation of a split patch
3299 print "<div class=\"patch cont\">\n";
3300 } else {
3301 # advance raw git-diff output if needed
3302 $patch_idx++ if defined $diffinfo;
3303
3304 # read and prepare patch information