Merge branch 'maint'
[git/git.git] / git-svn.perl
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision $_repository
8 $_q $_authors %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
11
12 # From which subdir have we been invoked?
13 my $cmd_dir_prefix = eval {
14 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
15 } || '';
16
17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
18 $ENV{GIT_DIR} ||= '.git';
19 $Git::SVN::default_repo_id = 'svn';
20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
21 $Git::SVN::Ra::_log_window_size = 100;
22
23 $Git::SVN::Log::TZ = $ENV{TZ};
24 $ENV{TZ} = 'UTC';
25 $| = 1; # unbuffer STDOUT
26
27 sub fatal (@) { print STDERR "@_\n"; exit 1 }
28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
29 require SVN::Ra;
30 require SVN::Delta;
31 if ($SVN::Core::VERSION lt '1.1.0') {
32 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
33 }
34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
37 use Carp qw/croak/;
38 use Digest::MD5;
39 use IO::File qw//;
40 use File::Basename qw/dirname basename/;
41 use File::Path qw/mkpath/;
42 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
43 use IPC::Open3;
44 use Git;
45
46 BEGIN {
47 # import functions from Git into our packages, en masse
48 no strict 'refs';
49 foreach (qw/command command_oneline command_noisy command_output_pipe
50 command_input_pipe command_close_pipe/) {
51 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
52 Git::SVN::Migration Git::SVN::Log Git::SVN),
53 __PACKAGE__) {
54 *{"${package}::$_"} = \&{"Git::$_"};
55 }
56 }
57 }
58
59 my ($SVN);
60
61 $sha1 = qr/[a-f\d]{40}/;
62 $sha1_short = qr/[a-f\d]{4,40}/;
63 my ($_stdin, $_help, $_edit,
64 $_message, $_file,
65 $_template, $_shared,
66 $_version, $_fetch_all, $_no_rebase,
67 $_merge, $_strategy, $_dry_run, $_local,
68 $_prefix, $_no_checkout, $_url, $_verbose,
69 $_git_format, $_commit_url);
70 $Git::SVN::_follow_parent = 1;
71 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
72 'config-dir=s' => \$Git::SVN::Ra::config_dir,
73 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
74 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
75 'authors-file|A=s' => \$_authors,
76 'repack:i' => \$Git::SVN::_repack,
77 'noMetadata' => \$Git::SVN::_no_metadata,
78 'useSvmProps' => \$Git::SVN::_use_svm_props,
79 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
80 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
81 'no-checkout' => \$_no_checkout,
82 'quiet|q' => \$_q,
83 'repack-flags|repack-args|repack-opts=s' =>
84 \$Git::SVN::_repack_flags,
85 'use-log-author' => \$Git::SVN::_use_log_author,
86 'add-author-from' => \$Git::SVN::_add_author_from,
87 %remote_opts );
88
89 my ($_trunk, $_tags, $_branches, $_stdlayout);
90 my %icv;
91 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
92 'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
93 'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
94 'stdlayout|s' => \$_stdlayout,
95 'minimize-url|m' => \$Git::SVN::_minimize_url,
96 'no-metadata' => sub { $icv{noMetadata} = 1 },
97 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
98 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
99 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
100 %remote_opts );
101 my %cmt_opts = ( 'edit|e' => \$_edit,
102 'rmdir' => \$SVN::Git::Editor::_rmdir,
103 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
104 'l=i' => \$SVN::Git::Editor::_rename_limit,
105 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
106 );
107
108 my %cmd = (
109 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
110 { 'revision|r=s' => \$_revision,
111 'fetch-all|all' => \$_fetch_all,
112 %fc_opts } ],
113 clone => [ \&cmd_clone, "Initialize and fetch revisions",
114 { 'revision|r=s' => \$_revision,
115 %fc_opts, %init_opts } ],
116 init => [ \&cmd_init, "Initialize a repo for tracking" .
117 " (requires URL argument)",
118 \%init_opts ],
119 'multi-init' => [ \&cmd_multi_init,
120 "Deprecated alias for ".
121 "'$0 init -T<trunk> -b<branches> -t<tags>'",
122 \%init_opts ],
123 dcommit => [ \&cmd_dcommit,
124 'Commit several diffs to merge with upstream',
125 { 'merge|m|M' => \$_merge,
126 'strategy|s=s' => \$_strategy,
127 'verbose|v' => \$_verbose,
128 'dry-run|n' => \$_dry_run,
129 'fetch-all|all' => \$_fetch_all,
130 'commit-url=s' => \$_commit_url,
131 'revision|r=i' => \$_revision,
132 'no-rebase' => \$_no_rebase,
133 %cmt_opts, %fc_opts } ],
134 'set-tree' => [ \&cmd_set_tree,
135 "Set an SVN repository to a git tree-ish",
136 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
137 'create-ignore' => [ \&cmd_create_ignore,
138 'Create a .gitignore per svn:ignore',
139 { 'revision|r=i' => \$_revision
140 } ],
141 'propget' => [ \&cmd_propget,
142 'Print the value of a property on a file or directory',
143 { 'revision|r=i' => \$_revision } ],
144 'proplist' => [ \&cmd_proplist,
145 'List all properties of a file or directory',
146 { 'revision|r=i' => \$_revision } ],
147 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
148 { 'revision|r=i' => \$_revision
149 } ],
150 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
151 { 'revision|r=i' => \$_revision
152 } ],
153 'multi-fetch' => [ \&cmd_multi_fetch,
154 "Deprecated alias for $0 fetch --all",
155 { 'revision|r=s' => \$_revision, %fc_opts } ],
156 'migrate' => [ sub { },
157 # no-op, we automatically run this anyways,
158 'Migrate configuration/metadata/layout from
159 previous versions of git-svn',
160 { 'minimize' => \$Git::SVN::Migration::_minimize,
161 %remote_opts } ],
162 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
163 { 'limit=i' => \$Git::SVN::Log::limit,
164 'revision|r=s' => \$_revision,
165 'verbose|v' => \$Git::SVN::Log::verbose,
166 'incremental' => \$Git::SVN::Log::incremental,
167 'oneline' => \$Git::SVN::Log::oneline,
168 'show-commit' => \$Git::SVN::Log::show_commit,
169 'non-recursive' => \$Git::SVN::Log::non_recursive,
170 'authors-file|A=s' => \$_authors,
171 'color' => \$Git::SVN::Log::color,
172 'pager=s' => \$Git::SVN::Log::pager
173 } ],
174 'find-rev' => [ \&cmd_find_rev,
175 "Translate between SVN revision numbers and tree-ish",
176 {} ],
177 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
178 { 'merge|m|M' => \$_merge,
179 'verbose|v' => \$_verbose,
180 'strategy|s=s' => \$_strategy,
181 'local|l' => \$_local,
182 'fetch-all|all' => \$_fetch_all,
183 'dry-run|n' => \$_dry_run,
184 %fc_opts } ],
185 'commit-diff' => [ \&cmd_commit_diff,
186 'Commit a diff between two trees',
187 { 'message|m=s' => \$_message,
188 'file|F=s' => \$_file,
189 'revision|r=s' => \$_revision,
190 %cmt_opts } ],
191 'info' => [ \&cmd_info,
192 "Show info about the latest SVN revision
193 on the current branch",
194 { 'url' => \$_url, } ],
195 'blame' => [ \&Git::SVN::Log::cmd_blame,
196 "Show what revision and author last modified each line of a file",
197 { 'git-format' => \$_git_format } ],
198 );
199
200 my $cmd;
201 for (my $i = 0; $i < @ARGV; $i++) {
202 if (defined $cmd{$ARGV[$i]}) {
203 $cmd = $ARGV[$i];
204 splice @ARGV, $i, 1;
205 last;
206 }
207 };
208
209 # make sure we're always running at the top-level working directory
210 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
211 unless (-d $ENV{GIT_DIR}) {
212 if ($git_dir_user_set) {
213 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
214 "but it is not a directory\n";
215 }
216 my $git_dir = delete $ENV{GIT_DIR};
217 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
218 unless (length $cdup) {
219 die "Already at toplevel, but $git_dir ",
220 "not found '$cdup'\n";
221 }
222 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
223 unless (-d $git_dir) {
224 die "$git_dir still not found after going to ",
225 "'$cdup'\n";
226 }
227 $ENV{GIT_DIR} = $git_dir;
228 }
229 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
230 }
231
232 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
233
234 read_repo_config(\%opts);
235 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
236 Getopt::Long::Configure('pass_through');
237 }
238 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
239 'minimize-connections' => \$Git::SVN::Migration::_minimize,
240 'id|i=s' => \$Git::SVN::default_ref_id,
241 'svn-remote|remote|R=s' => sub {
242 $Git::SVN::no_reuse_existing = 1;
243 $Git::SVN::default_repo_id = $_[1] });
244 exit 1 if (!$rv && $cmd && $cmd ne 'log');
245
246 usage(0) if $_help;
247 version() if $_version;
248 usage(1) unless defined $cmd;
249 load_authors() if $_authors;
250
251 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
252 Git::SVN::Migration::migration_check();
253 }
254 Git::SVN::init_vars();
255 eval {
256 Git::SVN::verify_remotes_sanity();
257 $cmd{$cmd}->[0]->(@ARGV);
258 };
259 fatal $@ if $@;
260 post_fetch_checkout();
261 exit 0;
262
263 ####################### primary functions ######################
264 sub usage {
265 my $exit = shift || 0;
266 my $fd = $exit ? \*STDERR : \*STDOUT;
267 print $fd <<"";
268 git-svn - bidirectional operations between a single Subversion tree and git
269 Usage: git svn <command> [options] [arguments]\n
270
271 print $fd "Available commands:\n" unless $cmd;
272
273 foreach (sort keys %cmd) {
274 next if $cmd && $cmd ne $_;
275 next if /^multi-/; # don't show deprecated commands
276 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
277 foreach (sort keys %{$cmd{$_}->[2]}) {
278 # mixed-case options are for .git/config only
279 next if /[A-Z]/ && /^[a-z]+$/i;
280 # prints out arguments as they should be passed:
281 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
282 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
283 "--$_" : "-$_" }
284 split /\|/,$_)," $x\n";
285 }
286 }
287 print $fd <<"";
288 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
289 arbitrary identifier if you're tracking multiple SVN branches/repositories in
290 one git repository and want to keep them separate. See git-svn(1) for more
291 information.
292
293 exit $exit;
294 }
295
296 sub version {
297 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
298 exit 0;
299 }
300
301 sub do_git_init_db {
302 unless (-d $ENV{GIT_DIR}) {
303 my @init_db = ('init');
304 push @init_db, "--template=$_template" if defined $_template;
305 if (defined $_shared) {
306 if ($_shared =~ /[a-z]/) {
307 push @init_db, "--shared=$_shared";
308 } else {
309 push @init_db, "--shared";
310 }
311 }
312 command_noisy(@init_db);
313 $_repository = Git->repository(Repository => ".git");
314 }
315 my $set;
316 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
317 foreach my $i (keys %icv) {
318 die "'$set' and '$i' cannot both be set\n" if $set;
319 next unless defined $icv{$i};
320 command_noisy('config', "$pfx.$i", $icv{$i});
321 $set = $i;
322 }
323 }
324
325 sub init_subdir {
326 my $repo_path = shift or return;
327 mkpath([$repo_path]) unless -d $repo_path;
328 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
329 $ENV{GIT_DIR} = '.git';
330 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
331 }
332
333 sub cmd_clone {
334 my ($url, $path) = @_;
335 if (!defined $path &&
336 (defined $_trunk || defined $_branches || defined $_tags ||
337 defined $_stdlayout) &&
338 $url !~ m#^[a-z\+]+://#) {
339 $path = $url;
340 }
341 $path = basename($url) if !defined $path || !length $path;
342 cmd_init($url, $path);
343 Git::SVN::fetch_all($Git::SVN::default_repo_id);
344 }
345
346 sub cmd_init {
347 if (defined $_stdlayout) {
348 $_trunk = 'trunk' if (!defined $_trunk);
349 $_tags = 'tags' if (!defined $_tags);
350 $_branches = 'branches' if (!defined $_branches);
351 }
352 if (defined $_trunk || defined $_branches || defined $_tags) {
353 return cmd_multi_init(@_);
354 }
355 my $url = shift or die "SVN repository location required ",
356 "as a command-line argument\n";
357 init_subdir(@_);
358 do_git_init_db();
359
360 Git::SVN->init($url);
361 }
362
363 sub cmd_fetch {
364 if (grep /^\d+=./, @_) {
365 die "'<rev>=<commit>' fetch arguments are ",
366 "no longer supported.\n";
367 }
368 my ($remote) = @_;
369 if (@_ > 1) {
370 die "Usage: $0 fetch [--all] [svn-remote]\n";
371 }
372 $remote ||= $Git::SVN::default_repo_id;
373 if ($_fetch_all) {
374 cmd_multi_fetch();
375 } else {
376 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
377 }
378 }
379
380 sub cmd_set_tree {
381 my (@commits) = @_;
382 if ($_stdin || !@commits) {
383 print "Reading from stdin...\n";
384 @commits = ();
385 while (<STDIN>) {
386 if (/\b($sha1_short)\b/o) {
387 unshift @commits, $1;
388 }
389 }
390 }
391 my @revs;
392 foreach my $c (@commits) {
393 my @tmp = command('rev-parse',$c);
394 if (scalar @tmp == 1) {
395 push @revs, $tmp[0];
396 } elsif (scalar @tmp > 1) {
397 push @revs, reverse(command('rev-list',@tmp));
398 } else {
399 fatal "Failed to rev-parse $c";
400 }
401 }
402 my $gs = Git::SVN->new;
403 my ($r_last, $cmt_last) = $gs->last_rev_commit;
404 $gs->fetch;
405 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
406 fatal "There are new revisions that were fetched ",
407 "and need to be merged (or acknowledged) ",
408 "before committing.\nlast rev: $r_last\n",
409 " current: $gs->{last_rev}";
410 }
411 $gs->set_tree($_) foreach @revs;
412 print "Done committing ",scalar @revs," revisions to SVN\n";
413 unlink $gs->{index};
414 }
415
416 sub cmd_dcommit {
417 my $head = shift;
418 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
419 'Cannot dcommit with a dirty index. Commit your changes first, '
420 . "or stash them with `git stash'.\n";
421 $head ||= 'HEAD';
422 my @refs;
423 my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
424 unless ($gs) {
425 die "Unable to determine upstream SVN information from ",
426 "$head history.\nPerhaps the repository is empty.";
427 }
428 $url = defined $_commit_url ? $_commit_url : $gs->full_url;
429 my $last_rev = $_revision if defined $_revision;
430 if ($url) {
431 print "Committing to $url ...\n";
432 }
433 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
434 if ($_no_rebase && scalar(@$linear_refs) > 1) {
435 warn "Attempting to commit more than one change while ",
436 "--no-rebase is enabled.\n",
437 "If these changes depend on each other, re-running ",
438 "without --no-rebase may be required."
439 }
440 my $expect_url = $url;
441 Git::SVN::remove_username($expect_url);
442 while (1) {
443 my $d = shift @$linear_refs or last;
444 unless (defined $last_rev) {
445 (undef, $last_rev, undef) = cmt_metadata("$d~1");
446 unless (defined $last_rev) {
447 fatal "Unable to extract revision information ",
448 "from commit $d~1";
449 }
450 }
451 if ($_dry_run) {
452 print "diff-tree $d~1 $d\n";
453 } else {
454 my $cmt_rev;
455 my %ed_opts = ( r => $last_rev,
456 log => get_commit_entry($d)->{log},
457 ra => Git::SVN::Ra->new($url),
458 config => SVN::Core::config_get_config(
459 $Git::SVN::Ra::config_dir
460 ),
461 tree_a => "$d~1",
462 tree_b => $d,
463 editor_cb => sub {
464 print "Committed r$_[0]\n";
465 $cmt_rev = $_[0];
466 },
467 svn_path => '');
468 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
469 print "No changes\n$d~1 == $d\n";
470 } elsif ($parents->{$d} && @{$parents->{$d}}) {
471 $gs->{inject_parents_dcommit}->{$cmt_rev} =
472 $parents->{$d};
473 }
474 $_fetch_all ? $gs->fetch_all : $gs->fetch;
475 $last_rev = $cmt_rev;
476 next if $_no_rebase;
477
478 # we always want to rebase against the current HEAD,
479 # not any head that was passed to us
480 my @diff = command('diff-tree', $d,
481 $gs->refname, '--');
482 my @finish;
483 if (@diff) {
484 @finish = rebase_cmd();
485 print STDERR "W: $d and ", $gs->refname,
486 " differ, using @finish:\n",
487 join("\n", @diff), "\n";
488 } else {
489 print "No changes between current HEAD and ",
490 $gs->refname,
491 "\nResetting to the latest ",
492 $gs->refname, "\n";
493 @finish = qw/reset --mixed/;
494 }
495 command_noisy(@finish, $gs->refname);
496 if (@diff) {
497 @refs = ();
498 my ($url_, $rev_, $uuid_, $gs_) =
499 working_head_info($head, \@refs);
500 my ($linear_refs_, $parents_) =
501 linearize_history($gs_, \@refs);
502 if (scalar(@$linear_refs) !=
503 scalar(@$linear_refs_)) {
504 fatal "# of revisions changed ",
505 "\nbefore:\n",
506 join("\n", @$linear_refs),
507 "\n\nafter:\n",
508 join("\n", @$linear_refs_), "\n",
509 'If you are attempting to commit ',
510 "merges, try running:\n\t",
511 'git rebase --interactive',
512 '--preserve-merges ',
513 $gs->refname,
514 "\nBefore dcommitting";
515 }
516 if ($url_ ne $expect_url) {
517 fatal "URL mismatch after rebase: ",
518 "$url_ != $expect_url";
519 }
520 if ($uuid_ ne $uuid) {
521 fatal "uuid mismatch after rebase: ",
522 "$uuid_ != $uuid";
523 }
524 # remap parents
525 my (%p, @l, $i);
526 for ($i = 0; $i < scalar @$linear_refs; $i++) {
527 my $new = $linear_refs_->[$i] or next;
528 $p{$new} =
529 $parents->{$linear_refs->[$i]};
530 push @l, $new;
531 }
532 $parents = \%p;
533 $linear_refs = \@l;
534 }
535 }
536 }
537 unlink $gs->{index};
538 }
539
540 sub cmd_find_rev {
541 my $revision_or_hash = shift or die "SVN or git revision required ",
542 "as a command-line argument\n";
543 my $result;
544 if ($revision_or_hash =~ /^r\d+$/) {
545 my $head = shift;
546 $head ||= 'HEAD';
547 my @refs;
548 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
549 unless ($gs) {
550 die "Unable to determine upstream SVN information from ",
551 "$head history\n";
552 }
553 my $desired_revision = substr($revision_or_hash, 1);
554 $result = $gs->rev_map_get($desired_revision, $uuid);
555 } else {
556 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
557 $result = $rev;
558 }
559 print "$result\n" if $result;
560 }
561
562 sub cmd_rebase {
563 command_noisy(qw/update-index --refresh/);
564 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
565 unless ($gs) {
566 die "Unable to determine upstream SVN information from ",
567 "working tree history\n";
568 }
569 if ($_dry_run) {
570 print "Remote Branch: " . $gs->refname . "\n";
571 print "SVN URL: " . $url . "\n";
572 return;
573 }
574 if (command(qw/diff-index HEAD --/)) {
575 print STDERR "Cannot rebase with uncommited changes:\n";
576 command_noisy('status');
577 exit 1;
578 }
579 unless ($_local) {
580 # rebase will checkout for us, so no need to do it explicitly
581 $_no_checkout = 'true';
582 $_fetch_all ? $gs->fetch_all : $gs->fetch;
583 }
584 command_noisy(rebase_cmd(), $gs->refname);
585 }
586
587 sub cmd_show_ignore {
588 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
589 $gs ||= Git::SVN->new;
590 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
591 $gs->prop_walk($gs->{path}, $r, sub {
592 my ($gs, $path, $props) = @_;
593 print STDOUT "\n# $path\n";
594 my $s = $props->{'svn:ignore'} or return;
595 $s =~ s/[\r\n]+/\n/g;
596 chomp $s;
597 $s =~ s#^#$path#gm;
598 print STDOUT "$s\n";
599 });
600 }
601
602 sub cmd_show_externals {
603 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
604 $gs ||= Git::SVN->new;
605 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
606 $gs->prop_walk($gs->{path}, $r, sub {
607 my ($gs, $path, $props) = @_;
608 print STDOUT "\n# $path\n";
609 my $s = $props->{'svn:externals'} or return;
610 $s =~ s/[\r\n]+/\n/g;
611 chomp $s;
612 $s =~ s#^#$path#gm;
613 print STDOUT "$s\n";
614 });
615 }
616
617 sub cmd_create_ignore {
618 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
619 $gs ||= Git::SVN->new;
620 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
621 $gs->prop_walk($gs->{path}, $r, sub {
622 my ($gs, $path, $props) = @_;
623 # $path is of the form /path/to/dir/
624 my $ignore = '.' . $path . '.gitignore';
625 my $s = $props->{'svn:ignore'} or return;
626 open(GITIGNORE, '>', $ignore)
627 or fatal("Failed to open `$ignore' for writing: $!");
628 $s =~ s/[\r\n]+/\n/g;
629 chomp $s;
630 # Prefix all patterns so that the ignore doesn't apply
631 # to sub-directories.
632 $s =~ s#^#/#gm;
633 print GITIGNORE "$s\n";
634 close(GITIGNORE)
635 or fatal("Failed to close `$ignore': $!");
636 command_noisy('add', '-f', $ignore);
637 });
638 }
639
640 sub canonicalize_path {
641 my ($path) = @_;
642 my $dot_slash_added = 0;
643 if (substr($path, 0, 1) ne "/") {
644 $path = "./" . $path;
645 $dot_slash_added = 1;
646 }
647 # File::Spec->canonpath doesn't collapse x/../y into y (for a
648 # good reason), so let's do this manually.
649 $path =~ s#/+#/#g;
650 $path =~ s#/\.(?:/|$)#/#g;
651 $path =~ s#/[^/]+/\.\.##g;
652 $path =~ s#/$##g;
653 $path =~ s#^\./## if $dot_slash_added;
654 $path =~ s#^/##;
655 $path =~ s#^\.$##;
656 return $path;
657 }
658
659 # get_svnprops(PATH)
660 # ------------------
661 # Helper for cmd_propget and cmd_proplist below.
662 sub get_svnprops {
663 my $path = shift;
664 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
665 $gs ||= Git::SVN->new;
666
667 # prefix THE PATH by the sub-directory from which the user
668 # invoked us.
669 $path = $cmd_dir_prefix . $path;
670 fatal("No such file or directory: $path") unless -e $path;
671 my $is_dir = -d $path ? 1 : 0;
672 $path = $gs->{path} . '/' . $path;
673
674 # canonicalize the path (otherwise libsvn will abort or fail to
675 # find the file)
676 $path = canonicalize_path($path);
677
678 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
679 my $props;
680 if ($is_dir) {
681 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
682 }
683 else {
684 (undef, $props) = $gs->ra->get_file($path, $r, undef);
685 }
686 return $props;
687 }
688
689 # cmd_propget (PROP, PATH)
690 # ------------------------
691 # Print the SVN property PROP for PATH.
692 sub cmd_propget {
693 my ($prop, $path) = @_;
694 $path = '.' if not defined $path;
695 usage(1) if not defined $prop;
696 my $props = get_svnprops($path);
697 if (not defined $props->{$prop}) {
698 fatal("`$path' does not have a `$prop' SVN property.");
699 }
700 print $props->{$prop} . "\n";
701 }
702
703 # cmd_proplist (PATH)
704 # -------------------
705 # Print the list of SVN properties for PATH.
706 sub cmd_proplist {
707 my $path = shift;
708 $path = '.' if not defined $path;
709 my $props = get_svnprops($path);
710 print "Properties on '$path':\n";
711 foreach (sort keys %{$props}) {
712 print " $_\n";
713 }
714 }
715
716 sub cmd_multi_init {
717 my $url = shift;
718 unless (defined $_trunk || defined $_branches || defined $_tags) {
719 usage(1);
720 }
721
722 # there are currently some bugs that prevent multi-init/multi-fetch
723 # setups from working well without this.
724 $Git::SVN::_minimize_url = 1;
725
726 $_prefix = '' unless defined $_prefix;
727 if (defined $url) {
728 $url =~ s#/+$##;
729 init_subdir(@_);
730 }
731 do_git_init_db();
732 if (defined $_trunk) {
733 my $trunk_ref = $_prefix . 'trunk';
734 # try both old-style and new-style lookups:
735 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
736 unless ($gs_trunk) {
737 my ($trunk_url, $trunk_path) =
738 complete_svn_url($url, $_trunk);
739 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
740 undef, $trunk_ref);
741 }
742 }
743 return unless defined $_branches || defined $_tags;
744 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
745 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
746 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
747 }
748
749 sub cmd_multi_fetch {
750 my $remotes = Git::SVN::read_all_remotes();
751 foreach my $repo_id (sort keys %$remotes) {
752 if ($remotes->{$repo_id}->{url}) {
753 Git::SVN::fetch_all($repo_id, $remotes);
754 }
755 }
756 }
757
758 # this command is special because it requires no metadata
759 sub cmd_commit_diff {
760 my ($ta, $tb, $url) = @_;
761 my $usage = "Usage: $0 commit-diff -r<revision> ".
762 "<tree-ish> <tree-ish> [<URL>]";
763 fatal($usage) if (!defined $ta || !defined $tb);
764 my $svn_path = '';
765 if (!defined $url) {
766 my $gs = eval { Git::SVN->new };
767 if (!$gs) {
768 fatal("Needed URL or usable git-svn --id in ",
769 "the command-line\n", $usage);
770 }
771 $url = $gs->{url};
772 $svn_path = $gs->{path};
773 }
774 unless (defined $_revision) {
775 fatal("-r|--revision is a required argument\n", $usage);
776 }
777 if (defined $_message && defined $_file) {
778 fatal("Both --message/-m and --file/-F specified ",
779 "for the commit message.\n",
780 "I have no idea what you mean");
781 }
782 if (defined $_file) {
783 $_message = file_to_s($_file);
784 } else {
785 $_message ||= get_commit_entry($tb)->{log};
786 }
787 my $ra ||= Git::SVN::Ra->new($url);
788 my $r = $_revision;
789 if ($r eq 'HEAD') {
790 $r = $ra->get_latest_revnum;
791 } elsif ($r !~ /^\d+$/) {
792 die "revision argument: $r not understood by git-svn\n";
793 }
794 my %ed_opts = ( r => $r,
795 log => $_message,
796 ra => $ra,
797 tree_a => $ta,
798 tree_b => $tb,
799 editor_cb => sub { print "Committed r$_[0]\n" },
800 svn_path => $svn_path );
801 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
802 print "No changes\n$ta == $tb\n";
803 }
804 }
805
806 sub escape_uri_only {
807 my ($uri) = @_;
808 my @tmp;
809 foreach (split m{/}, $uri) {
810 s/([^\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
811 push @tmp, $_;
812 }
813 join('/', @tmp);
814 }
815
816 sub escape_url {
817 my ($url) = @_;
818 if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
819 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
820 $url = "$scheme://$domain$uri";
821 }
822 $url;
823 }
824
825 sub cmd_info {
826 my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
827 my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
828 if (exists $_[1]) {
829 die "Too many arguments specified\n";
830 }
831
832 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
833
834 if (!$file_type && !$diff_status) {
835 print STDERR "svn: '$path' is not under version control\n";
836 exit 1;
837 }
838
839 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
840 unless ($gs) {
841 die "Unable to determine upstream SVN information from ",
842 "working tree history\n";
843 }
844
845 # canonicalize_path() will return "" to make libsvn 1.5.x happy,
846 $path = "." if $path eq "";
847
848 my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
849
850 if ($_url) {
851 print escape_url($full_url), "\n";
852 return;
853 }
854
855 my $result = "Path: $path\n";
856 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
857 $result .= "URL: " . escape_url($full_url) . "\n";
858
859 eval {
860 my $repos_root = $gs->repos_root;
861 Git::SVN::remove_username($repos_root);
862 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
863 };
864 if ($@) {
865 $result .= "Repository Root: (offline)\n";
866 }
867 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A";
868 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
869
870 $result .= "Node Kind: " .
871 ($file_type eq "dir" ? "directory" : "file") . "\n";
872
873 my $schedule = $diff_status eq "A"
874 ? "add"
875 : ($diff_status eq "D" ? "delete" : "normal");
876 $result .= "Schedule: $schedule\n";
877
878 if ($diff_status eq "A") {
879 print $result, "\n";
880 return;
881 }
882
883 my ($lc_author, $lc_rev, $lc_date_utc);
884 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
885 my $log = command_output_pipe(@args);
886 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
887 while (<$log>) {
888 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
889 $lc_author = $1;
890 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
891 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
892 (undef, $lc_rev, undef) = ::extract_metadata($1);
893 }
894 }
895 close $log;
896
897 Git::SVN::Log::set_local_timezone();
898
899 $result .= "Last Changed Author: $lc_author\n";
900 $result .= "Last Changed Rev: $lc_rev\n";
901 $result .= "Last Changed Date: " .
902 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
903
904 if ($file_type ne "dir") {
905 my $text_last_updated_date =
906 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
907 $result .=
908 "Text Last Updated: " .
909 Git::SVN::Log::format_svn_date($text_last_updated_date) .
910 "\n";
911 my $checksum;
912 if ($diff_status eq "D") {
913 my ($fh, $ctx) =
914 command_output_pipe(qw(cat-file blob), "HEAD:$path");
915 if ($file_type eq "link") {
916 my $file_name = <$fh>;
917 $checksum = md5sum("link $file_name");
918 } else {
919 $checksum = md5sum($fh);
920 }
921 command_close_pipe($fh, $ctx);
922 } elsif ($file_type eq "link") {
923 my $file_name =
924 command(qw(cat-file blob), "HEAD:$path");
925 $checksum =
926 md5sum("link " . $file_name);
927 } else {
928 open FILE, "<", $path or die $!;
929 $checksum = md5sum(\*FILE);
930 close FILE or die $!;
931 }
932 $result .= "Checksum: " . $checksum . "\n";
933 }
934
935 print $result, "\n";
936 }
937
938 ########################### utility functions #########################
939
940 sub rebase_cmd {
941 my @cmd = qw/rebase/;
942 push @cmd, '-v' if $_verbose;
943 push @cmd, qw/--merge/ if $_merge;
944 push @cmd, "--strategy=$_strategy" if $_strategy;
945 @cmd;
946 }
947
948 sub post_fetch_checkout {
949 return if $_no_checkout;
950 my $gs = $Git::SVN::_head or return;
951 return if verify_ref('refs/heads/master^0');
952
953 my $valid_head = verify_ref('HEAD^0');
954 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
955 return if ($valid_head || !verify_ref('HEAD^0'));
956
957 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
958 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
959 return if -f $index;
960
961 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
962 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
963 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
964 print STDERR "Checked out HEAD:\n ",
965 $gs->full_url, " r", $gs->last_rev, "\n";
966 }
967
968 sub complete_svn_url {
969 my ($url, $path) = @_;
970 $path =~ s#/+$##;
971 if ($path !~ m#^[a-z\+]+://#) {
972 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
973 fatal("E: '$path' is not a complete URL ",
974 "and a separate URL is not specified");
975 }
976 return ($url, $path);
977 }
978 return ($path, '');
979 }
980
981 sub complete_url_ls_init {
982 my ($ra, $repo_path, $switch, $pfx) = @_;
983 unless ($repo_path) {
984 print STDERR "W: $switch not specified\n";
985 return;
986 }
987 $repo_path =~ s#/+$##;
988 if ($repo_path =~ m#^[a-z\+]+://#) {
989 $ra = Git::SVN::Ra->new($repo_path);
990 $repo_path = '';
991 } else {
992 $repo_path =~ s#^/+##;
993 unless ($ra) {
994 fatal("E: '$repo_path' is not a complete URL ",
995 "and a separate URL is not specified");
996 }
997 }
998 my $url = $ra->{url};
999 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1000 my $k = "svn-remote.$gs->{repo_id}.url";
1001 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1002 if ($orig_url && ($orig_url ne $gs->{url})) {
1003 die "$k already set: $orig_url\n",
1004 "wanted to set to: $gs->{url}\n";
1005 }
1006 command_oneline('config', $k, $gs->{url}) unless $orig_url;
1007 my $remote_path = "$ra->{svn_path}/$repo_path";
1008 $remote_path =~ s#/+#/#g;
1009 $remote_path =~ s#^/##g;
1010 $remote_path .= "/*" if $remote_path !~ /\*/;
1011 my ($n) = ($switch =~ /^--(\w+)/);
1012 if (length $pfx && $pfx !~ m#/$#) {
1013 die "--prefix='$pfx' must have a trailing slash '/'\n";
1014 }
1015 command_noisy('config',
1016 "svn-remote.$gs->{repo_id}.$n",
1017 "$remote_path:refs/remotes/$pfx*" .
1018 ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1019 }
1020
1021 sub verify_ref {
1022 my ($ref) = @_;
1023 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1024 { STDERR => 0 }); };
1025 }
1026
1027 sub get_tree_from_treeish {
1028 my ($treeish) = @_;
1029 # $treeish can be a symbolic ref, too:
1030 my $type = command_oneline(qw/cat-file -t/, $treeish);
1031 my $expected;
1032 while ($type eq 'tag') {
1033 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1034 }
1035 if ($type eq 'commit') {
1036 $expected = (grep /^tree /, command(qw/cat-file commit/,
1037 $treeish))[0];
1038 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1039 die "Unable to get tree from $treeish\n" unless $expected;
1040 } elsif ($type eq 'tree') {
1041 $expected = $treeish;
1042 } else {
1043 die "$treeish is a $type, expected tree, tag or commit\n";
1044 }
1045 return $expected;
1046 }
1047
1048 sub get_commit_entry {
1049 my ($treeish) = shift;
1050 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1051 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1052 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1053 open my $log_fh, '>', $commit_editmsg or croak $!;
1054
1055 my $type = command_oneline(qw/cat-file -t/, $treeish);
1056 if ($type eq 'commit' || $type eq 'tag') {
1057 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1058 $type, $treeish);
1059 my $in_msg = 0;
1060 my $author;
1061 my $saw_from = 0;
1062 my $msgbuf = "";
1063 while (<$msg_fh>) {
1064 if (!$in_msg) {
1065 $in_msg = 1 if (/^\s*$/);
1066 $author = $1 if (/^author (.*>)/);
1067 } elsif (/^git-svn-id: /) {
1068 # skip this for now, we regenerate the
1069 # correct one on re-fetch anyways
1070 # TODO: set *:merge properties or like...
1071 } else {
1072 if (/^From:/ || /^Signed-off-by:/) {
1073 $saw_from = 1;
1074 }
1075 $msgbuf .= $_;
1076 }
1077 }
1078 $msgbuf =~ s/\s+$//s;
1079 if ($Git::SVN::_add_author_from && defined($author)
1080 && !$saw_from) {
1081 $msgbuf .= "\n\nFrom: $author";
1082 }
1083 print $log_fh $msgbuf or croak $!;
1084 command_close_pipe($msg_fh, $ctx);
1085 }
1086 close $log_fh or croak $!;
1087
1088 if ($_edit || ($type eq 'tree')) {
1089 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1090 # TODO: strip out spaces, comments, like git-commit.sh
1091 system($editor, $commit_editmsg);
1092 }
1093 rename $commit_editmsg, $commit_msg or croak $!;
1094 open $log_fh, '<', $commit_msg or croak $!;
1095 { local $/; chomp($log_entry{log} = <$log_fh>); }
1096 close $log_fh or croak $!;
1097 unlink $commit_msg;
1098 \%log_entry;
1099 }
1100
1101 sub s_to_file {
1102 my ($str, $file, $mode) = @_;
1103 open my $fd,'>',$file or croak $!;
1104 print $fd $str,"\n" or croak $!;
1105 close $fd or croak $!;
1106 chmod ($mode &~ umask, $file) if (defined $mode);
1107 }
1108
1109 sub file_to_s {
1110 my $file = shift;
1111 open my $fd,'<',$file or croak "$!: file: $file\n";
1112 local $/;
1113 my $ret = <$fd>;
1114 close $fd or croak $!;
1115 $ret =~ s/\s*$//s;
1116 return $ret;
1117 }
1118
1119 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1120 sub load_authors {
1121 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1122 my $log = $cmd eq 'log';
1123 while (<$authors>) {
1124 chomp;
1125 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1126 my ($user, $name, $email) = ($1, $2, $3);
1127 if ($log) {
1128 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1129 } else {
1130 $users{$user} = [$name, $email];
1131 }
1132 }
1133 close $authors or croak $!;
1134 }
1135
1136 # convert GetOpt::Long specs for use by git-config
1137 sub read_repo_config {
1138 return unless -d $ENV{GIT_DIR};
1139 my $opts = shift;
1140 my @config_only;
1141 foreach my $o (keys %$opts) {
1142 # if we have mixedCase and a long option-only, then
1143 # it's a config-only variable that we don't need for
1144 # the command-line.
1145 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1146 my $v = $opts->{$o};
1147 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1148 $key =~ s/-//g;
1149 my $arg = 'git-config';
1150 $arg .= ' --int' if ($o =~ /[:=]i$/);
1151 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1152 if (ref $v eq 'ARRAY') {
1153 chomp(my @tmp = `$arg --get-all svn.$key`);
1154 @$v = @tmp if @tmp;
1155 } else {
1156 chomp(my $tmp = `$arg --get svn.$key`);
1157 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1158 $$v = $tmp;
1159 }
1160 }
1161 }
1162 delete @$opts{@config_only} if @config_only;
1163 }
1164
1165 sub extract_metadata {
1166 my $id = shift or return (undef, undef, undef);
1167 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1168 \s([a-f\d\-]+)$/x);
1169 if (!defined $rev || !$uuid || !$url) {
1170 # some of the original repositories I made had
1171 # identifiers like this:
1172 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1173 }
1174 return ($url, $rev, $uuid);
1175 }
1176
1177 sub cmt_metadata {
1178 return extract_metadata((grep(/^git-svn-id: /,
1179 command(qw/cat-file commit/, shift)))[-1]);
1180 }
1181
1182 sub working_head_info {
1183 my ($head, $refs) = @_;
1184 my @args = ('log', '--no-color', '--first-parent', '--pretty=medium');
1185 my ($fh, $ctx) = command_output_pipe(@args, $head);
1186 my $hash;
1187 my %max;
1188 while (<$fh>) {
1189 if ( m{^commit ($::sha1)$} ) {
1190 unshift @$refs, $hash if $hash and $refs;
1191 $hash = $1;
1192 next;
1193 }
1194 next unless s{^\s*(git-svn-id:)}{$1};
1195 my ($url, $rev, $uuid) = extract_metadata($_);
1196 if (defined $url && defined $rev) {
1197 next if $max{$url} and $max{$url} < $rev;
1198 if (my $gs = Git::SVN->find_by_url($url)) {
1199 my $c = $gs->rev_map_get($rev, $uuid);
1200 if ($c && $c eq $hash) {
1201 close $fh; # break the pipe
1202 return ($url, $rev, $uuid, $gs);
1203 } else {
1204 $max{$url} ||= $gs->rev_map_max;
1205 }
1206 }
1207 }
1208 }
1209 command_close_pipe($fh, $ctx);
1210 (undef, undef, undef, undef);
1211 }
1212
1213 sub read_commit_parents {
1214 my ($parents, $c) = @_;
1215 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1216 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1217 @{$parents->{$c}} = split(/ /, $p);
1218 }
1219
1220 sub linearize_history {
1221 my ($gs, $refs) = @_;
1222 my %parents;
1223 foreach my $c (@$refs) {
1224 read_commit_parents(\%parents, $c);
1225 }
1226
1227 my @linear_refs;
1228 my %skip = ();
1229 my $last_svn_commit = $gs->last_commit;
1230 foreach my $c (reverse @$refs) {
1231 next if $c eq $last_svn_commit;
1232 last if $skip{$c};
1233
1234 unshift @linear_refs, $c;
1235 $skip{$c} = 1;
1236
1237 # we only want the first parent to diff against for linear
1238 # history, we save the rest to inject when we finalize the
1239 # svn commit
1240 my $fp_a = verify_ref("$c~1");
1241 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1242 if (!$fp_a || !$fp_b) {
1243 die "Commit $c\n",
1244 "has no parent commit, and therefore ",
1245 "nothing to diff against.\n",
1246 "You should be working from a repository ",
1247 "originally created by git-svn\n";
1248 }
1249 if ($fp_a ne $fp_b) {
1250 die "$c~1 = $fp_a, however parsing commit $c ",
1251 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1252 }
1253
1254 foreach my $p (@{$parents{$c}}) {
1255 $skip{$p} = 1;
1256 }
1257 }
1258 (\@linear_refs, \%parents);
1259 }
1260
1261 sub find_file_type_and_diff_status {
1262 my ($path) = @_;
1263 return ('dir', '') if $path eq '';
1264
1265 my $diff_output =
1266 command_oneline(qw(diff --cached --name-status --), $path) || "";
1267 my $diff_status = (split(' ', $diff_output))[0] || "";
1268
1269 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1270
1271 return (undef, undef) if !$diff_status && !$ls_tree;
1272
1273 if ($diff_status eq "A") {
1274 return ("link", $diff_status) if -l $path;
1275 return ("dir", $diff_status) if -d $path;
1276 return ("file", $diff_status);
1277 }
1278
1279 my $mode = (split(' ', $ls_tree))[0] || "";
1280
1281 return ("link", $diff_status) if $mode eq "120000";
1282 return ("dir", $diff_status) if $mode eq "040000";
1283 return ("file", $diff_status);
1284 }
1285
1286 sub md5sum {
1287 my $arg = shift;
1288 my $ref = ref $arg;
1289 my $md5 = Digest::MD5->new();
1290 if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1291 $md5->addfile($arg) or croak $!;
1292 } elsif ($ref eq 'SCALAR') {
1293 $md5->add($$arg) or croak $!;
1294 } elsif (!$ref) {
1295 $md5->add($arg) or croak $!;
1296 } else {
1297 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1298 }
1299 return $md5->hexdigest();
1300 }
1301
1302 package Git::SVN;
1303 use strict;
1304 use warnings;
1305 use Fcntl qw/:DEFAULT :seek/;
1306 use constant rev_map_fmt => 'NH40';
1307 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1308 $_repack $_repack_flags $_use_svm_props $_head
1309 $_use_svnsync_props $no_reuse_existing $_minimize_url
1310 $_use_log_author $_add_author_from/;
1311 use Carp qw/croak/;
1312 use File::Path qw/mkpath/;
1313 use File::Copy qw/copy/;
1314 use IPC::Open3;
1315
1316 my ($_gc_nr, $_gc_period);
1317
1318 # properties that we do not log:
1319 my %SKIP_PROP;
1320 BEGIN {
1321 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1322 svn:special svn:executable
1323 svn:entry:committed-rev
1324 svn:entry:last-author
1325 svn:entry:uuid
1326 svn:entry:committed-date/;
1327
1328 # some options are read globally, but can be overridden locally
1329 # per [svn-remote "..."] section. Command-line options will *NOT*
1330 # override options set in an [svn-remote "..."] section
1331 no strict 'refs';
1332 for my $option (qw/follow_parent no_metadata use_svm_props
1333 use_svnsync_props/) {
1334 my $key = $option;
1335 $key =~ tr/_//d;
1336 my $prop = "-$option";
1337 *$option = sub {
1338 my ($self) = @_;
1339 return $self->{$prop} if exists $self->{$prop};
1340 my $k = "svn-remote.$self->{repo_id}.$key";
1341 eval { command_oneline(qw/config --get/, $k) };
1342 if ($@) {
1343 $self->{$prop} = ${"Git::SVN::_$option"};
1344 } else {
1345 my $v = command_oneline(qw/config --bool/,$k);
1346 $self->{$prop} = $v eq 'false' ? 0 : 1;
1347 }
1348 return $self->{$prop};
1349 }
1350 }
1351 }
1352
1353
1354 my (%LOCKFILES, %INDEX_FILES);
1355 END {
1356 unlink keys %LOCKFILES if %LOCKFILES;
1357 unlink keys %INDEX_FILES if %INDEX_FILES;
1358 }
1359
1360 sub resolve_local_globs {
1361 my ($url, $fetch, $glob_spec) = @_;
1362 return unless defined $glob_spec;
1363 my $ref = $glob_spec->{ref};
1364 my $path = $glob_spec->{path};
1365 foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1366 next unless m#^refs/remotes/$ref->{regex}$#;
1367 my $p = $1;
1368 my $pathname = desanitize_refname($path->full_path($p));
1369 my $refname = desanitize_refname($ref->full_path($p));
1370 if (my $existing = $fetch->{$pathname}) {
1371 if ($existing ne $refname) {
1372 die "Refspec conflict:\n",
1373 "existing: refs/remotes/$existing\n",
1374 " globbed: refs/remotes/$refname\n";
1375 }
1376 my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1377 $u =~ s!^\Q$url\E(/|$)!! or die
1378 "refs/remotes/$refname: '$url' not found in '$u'\n";
1379 if ($pathname ne $u) {
1380 warn "W: Refspec glob conflict ",
1381 "(ref: refs/remotes/$refname):\n",
1382 "expected path: $pathname\n",
1383 " real path: $u\n",
1384 "Continuing ahead with $u\n";
1385 next;
1386 }
1387 } else {
1388 $fetch->{$pathname} = $refname;
1389 }
1390 }
1391 }
1392
1393 sub parse_revision_argument {
1394 my ($base, $head) = @_;
1395 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1396 return ($base, $head);
1397 }
1398 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1399 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1400 return ($head, $head) if ($::_revision eq 'HEAD');
1401 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1402 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1403 die "revision argument: $::_revision not understood by git-svn\n";
1404 }
1405
1406 sub fetch_all {
1407 my ($repo_id, $remotes) = @_;
1408 if (ref $repo_id) {
1409 my $gs = $repo_id;
1410 $repo_id = undef;
1411 $repo_id = $gs->{repo_id};
1412 }
1413 $remotes ||= read_all_remotes();
1414 my $remote = $remotes->{$repo_id} or
1415 die "[svn-remote \"$repo_id\"] unknown\n";
1416 my $fetch = $remote->{fetch};
1417 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1418 my (@gs, @globs);
1419 my $ra = Git::SVN::Ra->new($url);
1420 my $uuid = $ra->get_uuid;
1421 my $head = $ra->get_latest_revnum;
1422 my $base = defined $fetch ? $head : 0;
1423
1424 # read the max revs for wildcard expansion (branches/*, tags/*)
1425 foreach my $t (qw/branches tags/) {
1426 defined $remote->{$t} or next;
1427 push @globs, $remote->{$t};
1428 my $max_rev = eval { tmp_config(qw/--int --get/,
1429 "svn-remote.$repo_id.${t}-maxRev") };
1430 if (defined $max_rev && ($max_rev < $base)) {
1431 $base = $max_rev;
1432 } elsif (!defined $max_rev) {
1433 $base = 0;
1434 }
1435 }
1436
1437 if ($fetch) {
1438 foreach my $p (sort keys %$fetch) {
1439 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1440 my $lr = $gs->rev_map_max;
1441 if (defined $lr) {
1442 $base = $lr if ($lr < $base);
1443 }
1444 push @gs, $gs;
1445 }
1446 }
1447
1448 ($base, $head) = parse_revision_argument($base, $head);
1449 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1450 }
1451
1452 sub read_all_remotes {
1453 my $r = {};
1454 my $use_svm_props = eval { command_oneline(qw/config --bool
1455 svn.useSvmProps/) };
1456 $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1457 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1458 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*(.+)\s*$!) {
1459 my ($remote, $local_ref, $_remote_ref) = ($1, $2, $3);
1460 die("svn-remote.$remote: remote ref '$_remote_ref' "
1461 . "must start with 'refs/remotes/'\n")
1462 unless $_remote_ref =~ m{^refs/remotes/(.+)};
1463 my $remote_ref = $1;
1464 $local_ref =~ s{^/}{};
1465 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1466 $r->{$remote}->{svm} = {} if $use_svm_props;
1467 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1468 $r->{$1}->{svm} = {};
1469 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1470 $r->{$1}->{url} = $2;
1471 } elsif (m!^(.+)\.(branches|tags)=
1472 (.*):refs/remotes/(.+)\s*$/!x) {
1473 my ($p, $g) = ($3, $4);
1474 my $rs = $r->{$1}->{$2} = {
1475 t => $2,
1476 remote => $1,
1477 path => Git::SVN::GlobSpec->new($p),
1478 ref => Git::SVN::GlobSpec->new($g) };
1479 if (length($rs->{ref}->{right}) != 0) {
1480 die "The '*' glob character must be the last ",
1481 "character of '$g'\n";
1482 }
1483 }
1484 }
1485
1486 map {
1487 if (defined $r->{$_}->{svm}) {
1488 my $svm;
1489 eval {
1490 my $section = "svn-remote.$_";
1491 $svm = {
1492 source => tmp_config('--get',
1493 "$section.svm-source"),
1494 replace => tmp_config('--get',
1495 "$section.svm-replace"),
1496 }
1497 };
1498 $r->{$_}->{svm} = $svm;
1499 }
1500 } keys %$r;
1501
1502 $r;
1503 }
1504
1505 sub init_vars {
1506 $_gc_nr = $_gc_period = 1000;
1507 if (defined $_repack || defined $_repack_flags) {
1508 warn "Repack options are obsolete; they have no effect.\n";
1509 }
1510 }
1511
1512 sub verify_remotes_sanity {
1513 return unless -d $ENV{GIT_DIR};
1514 my %seen;
1515 foreach (command(qw/config -l/)) {
1516 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1517 if ($seen{$1}) {
1518 die "Remote ref refs/remote/$1 is tracked by",
1519 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1520 "Please resolve this ambiguity in ",
1521 "your git configuration file before ",
1522 "continuing\n";
1523 }
1524 $seen{$1} = $_;
1525 }
1526 }
1527 }
1528
1529 sub find_existing_remote {
1530 my ($url, $remotes) = @_;
1531 return undef if $no_reuse_existing;
1532 my $existing;
1533 foreach my $repo_id (keys %$remotes) {
1534 my $u = $remotes->{$repo_id}->{url} or next;
1535 next if $u ne $url;
1536 $existing = $repo_id;
1537 last;
1538 }
1539 $existing;
1540 }
1541
1542 sub init_remote_config {
1543 my ($self, $url, $no_write) = @_;
1544 $url =~ s!/+$!!; # strip trailing slash
1545 my $r = read_all_remotes();
1546 my $existing = find_existing_remote($url, $r);
1547 if ($existing) {
1548 unless ($no_write) {
1549 print STDERR "Using existing ",
1550 "[svn-remote \"$existing\"]\n";
1551 }
1552 $self->{repo_id} = $existing;
1553 } elsif ($_minimize_url) {
1554 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1555 $existing = find_existing_remote($min_url, $r);
1556 if ($existing) {
1557 unless ($no_write) {
1558 print STDERR "Using existing ",
1559 "[svn-remote \"$existing\"]\n";
1560 }
1561 $self->{repo_id} = $existing;
1562 }
1563 if ($min_url ne $url) {
1564 unless ($no_write) {
1565 print STDERR "Using higher level of URL: ",
1566 "$url => $min_url\n";
1567 }
1568 my $old_path = $self->{path};
1569 $self->{path} = $url;
1570 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1571 if (length $old_path) {
1572 $self->{path} .= "/$old_path";
1573 }
1574 $url = $min_url;
1575 }
1576 }
1577 my $orig_url;
1578 if (!$existing) {
1579 # verify that we aren't overwriting anything:
1580 $orig_url = eval {
1581 command_oneline('config', '--get',
1582 "svn-remote.$self->{repo_id}.url")
1583 };
1584 if ($orig_url && ($orig_url ne $url)) {
1585 die "svn-remote.$self->{repo_id}.url already set: ",
1586 "$orig_url\nwanted to set to: $url\n";
1587 }
1588 }
1589 my ($xrepo_id, $xpath) = find_ref($self->refname);
1590 if (defined $xpath) {
1591 die "svn-remote.$xrepo_id.fetch already set to track ",
1592 "$xpath:refs/remotes/", $self->refname, "\n";
1593 }
1594 unless ($no_write) {
1595 command_noisy('config',
1596 "svn-remote.$self->{repo_id}.url", $url);
1597 $self->{path} =~ s{^/}{};
1598 command_noisy('config', '--add',
1599 "svn-remote.$self->{repo_id}.fetch",
1600 "$self->{path}:".$self->refname);
1601 }
1602 $self->{url} = $url;
1603 }
1604
1605 sub find_by_url { # repos_root and, path are optional
1606 my ($class, $full_url, $repos_root, $path) = @_;
1607
1608 return undef unless defined $full_url;
1609 remove_username($full_url);
1610 remove_username($repos_root) if defined $repos_root;
1611 my $remotes = read_all_remotes();
1612 if (defined $full_url && defined $repos_root && !defined $path) {
1613 $path = $full_url;
1614 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1615 }
1616 foreach my $repo_id (keys %$remotes) {
1617 my $u = $remotes->{$repo_id}->{url} or next;
1618 remove_username($u);
1619 next if defined $repos_root && $repos_root ne $u;
1620
1621 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1622 foreach (qw/branches tags/) {
1623 resolve_local_globs($u, $fetch,
1624 $remotes->{$repo_id}->{$_});
1625 }
1626 my $p = $path;
1627 my $rwr = rewrite_root({repo_id => $repo_id});
1628 my $svm = $remotes->{$repo_id}->{svm}
1629 if defined $remotes->{$repo_id}->{svm};
1630 unless (defined $p) {
1631 $p = $full_url;
1632 my $z = $u;
1633 my $prefix = '';
1634 if ($rwr) {
1635 $z = $rwr;
1636 } elsif (defined $svm) {
1637 $z = $svm->{source};
1638 $prefix = $svm->{replace};
1639 $prefix =~ s#^\Q$u\E(?:/|$)##;
1640 $prefix =~ s#/$##;
1641 }
1642 $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
1643 }
1644 foreach my $f (keys %$fetch) {
1645 next if $f ne $p;
1646 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1647 }
1648 }
1649 undef;
1650 }
1651
1652 sub init {
1653 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1654 my $self = _new($class, $repo_id, $ref_id, $path);
1655 if (defined $url) {
1656 $self->init_remote_config($url, $no_write);
1657 }
1658 $self;
1659 }
1660
1661 sub find_ref {
1662 my ($ref_id) = @_;
1663 foreach (command(qw/config -l/)) {
1664 next unless m!^svn-remote\.(.+)\.fetch=
1665 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1666 my ($repo_id, $path, $ref) = ($1, $2, $3);
1667 if ($ref eq $ref_id) {
1668 $path = '' if ($path =~ m#^\./?#);
1669 return ($repo_id, $path);
1670 }
1671 }
1672 (undef, undef, undef);
1673 }
1674
1675 sub new {
1676 my ($class, $ref_id, $repo_id, $path) = @_;
1677 if (defined $ref_id && !defined $repo_id && !defined $path) {
1678 ($repo_id, $path) = find_ref($ref_id);
1679 if (!defined $repo_id) {
1680 die "Could not find a \"svn-remote.*.fetch\" key ",
1681 "in the repository configuration matching: ",
1682 "refs/remotes/$ref_id\n";
1683 }
1684 }
1685 my $self = _new($class, $repo_id, $ref_id, $path);
1686 if (!defined $self->{path} || !length $self->{path}) {
1687 my $fetch = command_oneline('config', '--get',
1688 "svn-remote.$repo_id.fetch",
1689 ":refs/remotes/$ref_id\$") or
1690 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1691 "\":refs/remotes/$ref_id\$\" in config\n";
1692 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1693 }
1694 $self->{url} = command_oneline('config', '--get',
1695 "svn-remote.$repo_id.url") or
1696 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1697 $self->rebuild;
1698 $self;
1699 }
1700
1701 sub refname {
1702 my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1703
1704 # It cannot end with a slash /, we'll throw up on this because
1705 # SVN can't have directories with a slash in their name, either:
1706 if ($refname =~ m{/$}) {
1707 die "ref: '$refname' ends with a trailing slash, this is ",
1708 "not permitted by git nor Subversion\n";
1709 }
1710
1711 # It cannot have ASCII control character space, tilde ~, caret ^,
1712 # colon :, question-mark ?, asterisk *, space, or open bracket [
1713 # anywhere.
1714 #
1715 # Additionally, % must be escaped because it is used for escaping
1716 # and we want our escaped refname to be reversible
1717 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1718
1719 # no slash-separated component can begin with a dot .
1720 # /.* becomes /%2E*
1721 $refname =~ s{/\.}{/%2E}g;
1722
1723 # It cannot have two consecutive dots .. anywhere
1724 # .. becomes %2E%2E
1725 $refname =~ s{\.\.}{%2E%2E}g;
1726
1727 return $refname;
1728 }
1729
1730 sub desanitize_refname {
1731 my ($refname) = @_;
1732 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1733 return $refname;
1734 }
1735
1736 sub svm_uuid {
1737 my ($self) = @_;
1738 return $self->{svm}->{uuid} if $self->svm;
1739 $self->ra;
1740 unless ($self->{svm}) {
1741 die "SVM UUID not cached, and reading remotely failed\n";
1742 }
1743 $self->{svm}->{uuid};
1744 }
1745
1746 sub svm {
1747 my ($self) = @_;
1748 return $self->{svm} if $self->{svm};
1749 my $svm;
1750 # see if we have it in our config, first:
1751 eval {
1752 my $section = "svn-remote.$self->{repo_id}";
1753 $svm = {
1754 source => tmp_config('--get', "$section.svm-source"),
1755 uuid => tmp_config('--get', "$section.svm-uuid"),
1756 replace => tmp_config('--get', "$section.svm-replace"),
1757 }
1758 };
1759 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1760 $self->{svm} = $svm;
1761 }
1762 $self->{svm};
1763 }
1764
1765 sub _set_svm_vars {
1766 my ($self, $ra) = @_;
1767 return $ra if $self->svm;
1768
1769 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1770 "(svm:source, svm:uuid) ",
1771 "from the following URLs:\n" );
1772 sub read_svm_props {
1773 my ($self, $ra, $path, $r) = @_;
1774 my $props = ($ra->get_dir($path, $r))[2];
1775 my $src = $props->{'svm:source'};
1776 my $uuid = $props->{'svm:uuid'};
1777 return undef if (!$src || !$uuid);
1778
1779 chomp($src, $uuid);
1780
1781 $uuid =~ m{^[0-9a-f\-]{30,}$}
1782 or die "doesn't look right - svm:uuid is '$uuid'\n";
1783
1784 # the '!' is used to mark the repos_root!/relative/path
1785 $src =~ s{/?!/?}{/};
1786 $src =~ s{/+$}{}; # no trailing slashes please
1787 # username is of no interest
1788 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1789
1790 my $replace = $ra->{url};
1791 $replace .= "/$path" if length $path;
1792
1793 my $section = "svn-remote.$self->{repo_id}";
1794 tmp_config("$section.svm-source", $src);
1795 tmp_config("$section.svm-replace", $replace);
1796 tmp_config("$section.svm-uuid", $uuid);
1797 $self->{svm} = {
1798 source => $src,
1799 uuid => $uuid,
1800 replace => $replace
1801 };
1802 }
1803
1804 my $r = $ra->get_latest_revnum;
1805 my $path = $self->{path};
1806 my %tried;
1807 while (length $path) {
1808 unless ($tried{"$self->{url}/$path"}) {
1809 return $ra if $self->read_svm_props($ra, $path, $r);
1810 $tried{"$self->{url}/$path"} = 1;
1811 }
1812 $path =~ s#/?[^/]+$##;
1813 }
1814 die "Path: '$path' should be ''\n" if $path ne '';
1815 return $ra if $self->read_svm_props($ra, $path, $r);
1816 $tried{"$self->{url}/$path"} = 1;
1817
1818 if ($ra->{repos_root} eq $self->{url}) {
1819 die @err, (map { " $_\n" } keys %tried), "\n";
1820 }
1821
1822 # nope, make sure we're connected to the repository root:
1823 my $ok;
1824 my @tried_b;
1825 $path = $ra->{svn_path};
1826 $ra = Git::SVN::Ra->new($ra->{repos_root});
1827 while (length $path) {
1828 unless ($tried{"$ra->{url}/$path"}) {
1829 $ok = $self->read_svm_props($ra, $path, $r);
1830 last if $ok;
1831 $tried{"$ra->{url}/$path"} = 1;
1832 }
1833 $path =~ s#/?[^/]+$##;
1834 }
1835 die "Path: '$path' should be ''\n" if $path ne '';
1836 $ok ||= $self->read_svm_props($ra, $path, $r);
1837 $tried{"$ra->{url}/$path"} = 1;
1838 if (!$ok) {
1839 die @err, (map { " $_\n" } keys %tried), "\n";
1840 }
1841 Git::SVN::Ra->new($self->{url});
1842 }
1843
1844 sub svnsync {
1845 my ($self) = @_;
1846 return $self->{svnsync} if $self->{svnsync};
1847
1848 if ($self->no_metadata) {
1849 die "Can't have both 'noMetadata' and ",
1850 "'useSvnsyncProps' options set!\n";
1851 }
1852 if ($self->rewrite_root) {
1853 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1854 "options set!\n";
1855 }
1856
1857 my $svnsync;
1858 # see if we have it in our config, first:
1859 eval {
1860 my $section = "svn-remote.$self->{repo_id}";
1861
1862 my $url = tmp_config('--get', "$section.svnsync-url");
1863 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1864 die "doesn't look right - svn:sync-from-url is '$url'\n";
1865
1866 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
1867 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1868 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1869
1870 $svnsync = { url => $url, uuid => $uuid }
1871 };
1872 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1873 return $self->{svnsync} = $svnsync;
1874 }
1875
1876 my $err = "useSvnsyncProps set, but failed to read " .
1877 "svnsync property: svn:sync-from-";
1878 my $rp = $self->ra->rev_proplist(0);
1879
1880 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1881 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1882 die "doesn't look right - svn:sync-from-url is '$url'\n";
1883
1884 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1885 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1886 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1887
1888 my $section = "svn-remote.$self->{repo_id}";
1889 tmp_config('--add', "$section.svnsync-uuid", $uuid);
1890 tmp_config('--add', "$section.svnsync-url", $url);
1891 return $self->{svnsync} = { url => $url, uuid => $uuid };
1892 }
1893
1894 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1895 # remote lookup (useful for 'git svn log').
1896 sub ra_uuid {
1897 my ($self) = @_;
1898 unless ($self->{ra_uuid}) {
1899 my $key = "svn-remote.$self->{repo_id}.uuid";
1900 my $uuid = eval { tmp_config('--get', $key) };
1901 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1902 $self->{ra_uuid} = $uuid;
1903 } else {
1904 die "ra_uuid called without URL\n" unless $self->{url};
1905 $self->{ra_uuid} = $self->ra->get_uuid;
1906 tmp_config('--add', $key, $self->{ra_uuid});
1907 }
1908 }
1909 $self->{ra_uuid};
1910 }
1911
1912 sub _set_repos_root {
1913 my ($self, $repos_root) = @_;
1914 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1915 $repos_root ||= $self->ra->{repos_root};
1916 tmp_config($k, $repos_root);
1917 $repos_root;
1918 }
1919
1920 sub repos_root {
1921 my ($self) = @_;
1922 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1923 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1924 }
1925
1926 sub ra {
1927 my ($self) = shift;
1928 my $ra = Git::SVN::Ra->new($self->{url});
1929 $self->_set_repos_root($ra->{repos_root});
1930 if ($self->use_svm_props && !$self->{svm}) {
1931 if ($self->no_metadata) {
1932 die "Can't have both 'noMetadata' and ",
1933 "'useSvmProps' options set!\n";
1934 } elsif ($self->use_svnsync_props) {
1935 die "Can't have both 'useSvnsyncProps' and ",
1936 "'useSvmProps' options set!\n";
1937 }
1938 $ra = $self->_set_svm_vars($ra);
1939 $self->{-want_revprops} = 1;
1940 }
1941 $ra;
1942 }
1943
1944 sub rel_path {
1945 my ($self) = @_;
1946 my $repos_root = $self->ra->{repos_root};
1947 return $self->{path} if ($self->{url} eq $repos_root);
1948 my $url = $self->{url} .
1949 (length $self->{path} ? "/$self->{path}" : $self->{path});
1950 $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1951 $url;
1952 }
1953
1954 # prop_walk(PATH, REV, SUB)
1955 # -------------------------
1956 # Recursively traverse PATH at revision REV and invoke SUB for each
1957 # directory that contains a SVN property. SUB will be invoked as
1958 # follows: &SUB(gs, path, props); where `gs' is this instance of
1959 # Git::SVN, `path' the path to the directory where the properties
1960 # `props' were found. The `path' will be relative to point of checkout,
1961 # that is, if url://repo/trunk is the current Git branch, and that
1962 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
1963 # as `path' (note the trailing `/').
1964 sub prop_walk {
1965 my ($self, $path, $rev, $sub) = @_;
1966
1967 $path =~ s#^/##;
1968 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
1969 $path =~ s#^/*#/#g;
1970 my $p = $path;
1971 # Strip the irrelevant part of the path.
1972 $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
1973 # Ensure the path is terminated by a `/'.
1974 $p =~ s#/*$#/#;
1975
1976 # The properties contain all the internal SVN stuff nobody
1977 # (usually) cares about.
1978 my $interesting_props = 0;
1979 foreach (keys %{$props}) {
1980 # If it doesn't start with `svn:', it must be a
1981 # user-defined property.
1982 ++$interesting_props and next if $_ !~ /^svn:/;
1983 # FIXME: Fragile, if SVN adds new public properties,
1984 # this needs to be updated.
1985 ++$interesting_props if /^svn:(?:ignore|keywords|executable
1986 |eol-style|mime-type
1987 |externals|needs-lock)$/x;
1988 }
1989 &$sub($self, $p, $props) if $interesting_props;
1990
1991 foreach (sort keys %$dirent) {
1992 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1993 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
1994 }
1995 }
1996
1997 sub last_rev { ($_[0]->last_rev_commit)[0] }
1998 sub last_commit { ($_[0]->last_rev_commit)[1] }
1999
2000 # returns the newest SVN revision number and newest commit SHA1
2001 sub last_rev_commit {
2002 my ($self) = @_;
2003 if (defined $self->{last_rev} && defined $self->{last_commit}) {
2004 return ($self->{last_rev}, $self->{last_commit});
2005 }
2006 my $c = ::verify_ref($self->refname.'^0');
2007 if ($c && !$self->use_svm_props && !$self->no_metadata) {
2008 my $rev = (::cmt_metadata($c))[1];
2009 if (defined $rev) {
2010 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2011 return ($rev, $c);
2012 }
2013 }
2014 my $map_path = $self->map_path;
2015 unless (-e $map_path) {
2016 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2017 return (undef, undef);
2018 }
2019 my ($rev, $commit) = $self->rev_map_max(1);
2020 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2021 return ($rev, $commit);
2022 }
2023
2024 sub get_fetch_range {
2025 my ($self, $min, $max) = @_;
2026 $max ||= $self->ra->get_latest_revnum;
2027 $min ||= $self->rev_map_max;
2028 (++$min, $max);
2029 }
2030
2031 sub tmp_config {
2032 my (@args) = @_;
2033 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2034 my $config = "$ENV{GIT_DIR}/svn/.metadata";
2035 if (! -f $config && -f $old_def_config) {
2036 rename $old_def_config, $config or
2037 die "Failed rename $old_def_config => $config: $!\n";
2038 }
2039 my $old_config = $ENV{GIT_CONFIG};
2040 $ENV{GIT_CONFIG} = $config;
2041 $@ = undef;
2042 my @ret = eval {
2043 unless (-f $config) {
2044 mkfile($config);
2045 open my $fh, '>', $config or
2046 die "Can't open $config: $!\n";
2047 print $fh "; This file is used internally by ",
2048 "git-svn\n" or die
2049 "Couldn't write to $config: $!\n";
2050 print $fh "; You should not have to edit it\n" or
2051 die "Couldn't write to $config: $!\n";
2052 close $fh or die "Couldn't close $config: $!\n";
2053 }
2054 command('config', @args);
2055 };
2056 my $err = $@;
2057 if (defined $old_config) {
2058 $ENV{GIT_CONFIG} = $old_config;
2059 } else {
2060 delete $ENV{GIT_CONFIG};
2061 }
2062 die $err if $err;
2063 wantarray ? @ret : $ret[0];
2064 }
2065
2066 sub tmp_index_do {
2067 my ($self, $sub) = @_;
2068 my $old_index = $ENV{GIT_INDEX_FILE};
2069 $ENV{GIT_INDEX_FILE} = $self->{index};
2070 $@ = undef;
2071 my @ret = eval {
2072 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2073 mkpath([$dir]) unless -d $dir;
2074 &$sub;
2075 };
2076 my $err = $@;
2077 if (defined $old_index) {
2078 $ENV{GIT_INDEX_FILE} = $old_index;
2079 } else {
2080 delete $ENV{GIT_INDEX_FILE};
2081 }
2082 die $err if $err;
2083 wantarray ? @ret : $ret[0];
2084 }
2085
2086 sub assert_index_clean {
2087 my ($self, $treeish) = @_;
2088
2089 $self->tmp_index_do(sub {
2090 command_noisy('read-tree', $treeish) unless -e $self->{index};
2091 my $x = command_oneline('write-tree');
2092 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2093 /^tree ($::sha1)/mo);
2094 return if $y eq $x;
2095
2096 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2097 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2098 command_noisy('read-tree', $treeish);
2099 $x = command_oneline('write-tree');
2100 if ($y ne $x) {
2101 ::fatal "trees ($treeish) $y != $x\n",
2102 "Something is seriously wrong...";
2103 }
2104 });
2105 }
2106
2107 sub get_commit_parents {
2108 my ($self, $log_entry) = @_;
2109 my (%seen, @ret, @tmp);
2110 # legacy support for 'set-tree'; this is only used by set_tree_cb:
2111 if (my $ip = $self->{inject_parents}) {
2112 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2113 push @tmp, $commit;
2114 }
2115 }
2116 if (my $cur = ::verify_ref($self->refname.'^0')) {
2117 push @tmp, $cur;
2118 }
2119 if (my $ipd = $self->{inject_parents_dcommit}) {
2120 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2121 push @tmp, @$commit;
2122 }
2123 }
2124 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2125 while (my $p = shift @tmp) {
2126 next if $seen{$p};
2127 $seen{$p} = 1;
2128 push @ret, $p;
2129 # MAXPARENT is defined to 16 in commit-tree.c:
2130 last if @ret >= 16;
2131 }
2132 if (@tmp) {
2133 die "r$log_entry->{revision}: No room for parents:\n\t",
2134 join("\n\t", @tmp), "\n";
2135 }
2136 @ret;
2137 }
2138
2139 sub rewrite_root {
2140 my ($self) = @_;
2141 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2142 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2143 my $rwr = eval { command_oneline(qw/config --get/, $k) };
2144 if ($rwr) {
2145 $rwr =~ s#/+$##;
2146 if ($rwr !~ m#^[a-z\+]+://#) {
2147 die "$rwr is not a valid URL (key: $k)\n";
2148 }
2149 }
2150 $self->{-rewrite_root} = $rwr;
2151 }
2152
2153 sub metadata_url {
2154 my ($self) = @_;
2155 ($self->rewrite_root || $self->{url}) .
2156 (length $self->{path} ? '/' . $self->{path} : '');
2157 }
2158
2159 sub full_url {
2160 my ($self) = @_;
2161 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2162 }
2163
2164
2165 sub set_commit_header_env {
2166 my ($log_entry) = @_;
2167 my %env;
2168 foreach my $ned (qw/NAME EMAIL DATE/) {
2169 foreach my $ac (qw/AUTHOR COMMITTER/) {
2170 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2171 }
2172 }
2173
2174 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2175 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2176 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2177
2178 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2179 ? $log_entry->{commit_name}
2180 : $log_entry->{name};
2181 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2182 ? $log_entry->{commit_email}
2183 : $log_entry->{email};
2184 \%env;
2185 }
2186
2187 sub restore_commit_header_env {
2188 my ($env) = @_;
2189 foreach my $ned (qw/NAME EMAIL DATE/) {
2190 foreach my $ac (qw/AUTHOR COMMITTER/) {
2191 my $k = "GIT_${ac}_${ned}";
2192 if (defined $env->{$k}) {
2193 $ENV{$k} = $env->{$k};
2194 } else {
2195 delete $ENV{$k};
2196 }
2197 }
2198 }
2199 }
2200
2201 sub gc {
2202 command_noisy('gc', '--auto');
2203 };
2204
2205 sub do_git_commit {
2206 my ($self, $log_entry) = @_;
2207 my $lr = $self->last_rev;
2208 if (defined $lr && $lr >= $log_entry->{revision}) {
2209 die "Last fetched revision of ", $self->refname,
2210 " was r$lr, but we are about to fetch: ",
2211 "r$log_entry->{revision}!\n";
2212 }
2213 if (my $c = $self->rev_map_get($log_entry->{revision})) {
2214 croak "$log_entry->{revision} = $c already exists! ",
2215 "Why are we refetching it?\n";
2216 }
2217 my $old_env = set_commit_header_env($log_entry);
2218 my $tree = $log_entry->{tree};
2219 if (!defined $tree) {
2220 $tree = $self->tmp_index_do(sub {
2221 command_oneline('write-tree') });
2222 }
2223 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2224
2225 my @exec = ('git-commit-tree', $tree);
2226 foreach ($self->get_commit_parents($log_entry)) {
2227 push @exec, '-p', $_;
2228 }
2229 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2230 or croak $!;
2231 print $msg_fh $log_entry->{log} or croak $!;
2232 restore_commit_header_env($old_env);
2233 unless ($self->no_metadata) {
2234 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2235 or croak $!;
2236 }
2237 $msg_fh->flush == 0 or croak $!;
2238 close $msg_fh or croak $!;
2239 chomp(my $commit = do { local $/; <$out_fh> });
2240 close $out_fh or croak $!;
2241 waitpid $pid, 0;
2242 croak $? if $?;
2243 if ($commit !~ /^$::sha1$/o) {
2244 die "Failed to commit, invalid sha1: $commit\n";
2245 }
2246
2247 $self->rev_map_set($log_entry->{revision}, $commit, 1);
2248
2249 $self->{last_rev} = $log_entry->{revision};
2250 $self->{last_commit} = $commit;
2251 print "r$log_entry->{revision}";
2252 if (defined $log_entry->{svm_revision}) {
2253 print " (\@$log_entry->{svm_revision})";
2254 $self->rev_map_set($log_entry->{svm_revision}, $commit,
2255 0, $self->svm_uuid);
2256 }
2257 print " = $commit ($self->{ref_id})\n";
2258 if (--$_gc_nr == 0) {
2259 $_gc_nr = $_gc_period;
2260 gc();
2261 }
2262 return $commit;
2263 }
2264
2265 sub match_paths {
2266 my ($self, $paths, $r) = @_;
2267 return 1 if $self->{path} eq '';
2268 if (my $path = $paths->{"/$self->{path}"}) {
2269 return ($path->{action} eq 'D') ? 0 : 1;
2270 }
2271 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2272 if (grep /$self->{path_regex}/, keys %$paths) {
2273 return 1;
2274 }
2275 my $c = '';
2276 foreach (split m#/#, $self->{path}) {
2277 $c .= "/$_";
2278 next unless ($paths->{$c} &&
2279 ($paths->{$c}->{action} =~ /^[AR]$/));
2280 if ($self->ra->check_path($self->{path}, $r) ==
2281 $SVN::Node::dir) {
2282 return 1;
2283 }
2284 }
2285 return 0;
2286 }
2287
2288 sub find_parent_branch {
2289 my ($self, $paths, $rev) = @_;
2290 return undef unless $self->follow_parent;
2291 unless (defined $paths) {
2292 my $err_handler = $SVN::Error::handler;
2293 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2294 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2295 $paths =
2296 Git::SVN::Ra::dup_changed_paths($_[0]) });
2297 $SVN::Error::handler = $err_handler;
2298 }
2299 return undef unless defined $paths;
2300
2301 # look for a parent from another branch:
2302 my @b_path_components = split m#/#, $self->rel_path;
2303 my @a_path_components;
2304 my $i;
2305 while (@b_path_components) {
2306 $i = $paths->{'/'.join('/', @b_path_components)};
2307 last if $i && defined $i->{copyfrom_path};
2308 unshift(@a_path_components, pop(@b_path_components));
2309 }
2310 return undef unless defined $i && defined $i->{copyfrom_path};
2311 my $branch_from = $i->{copyfrom_path};
2312 if (@a_path_components) {
2313 print STDERR "branch_from: $branch_from => ";
2314 $branch_from .= '/'.join('/', @a_path_components);
2315 print STDERR $branch_from, "\n";
2316 }
2317 my $r = $i->{copyfrom_rev};
2318 my $repos_root = $self->ra->{repos_root};
2319 my $url = $self->ra->{url};
2320 my $new_url = $repos_root . $branch_from;
2321 print STDERR "Found possible branch point: ",
2322 "$new_url => ", $self->full_url, ", $r\n";
2323 $branch_from =~ s#^/##;
2324 my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2325 unless ($gs) {
2326 my $ref_id = $self->{ref_id};
2327 $ref_id =~ s/\@\d+$//;
2328 $ref_id .= "\@$r";
2329 # just grow a tail if we're not unique enough :x
2330 $ref_id .= '-' while find_ref($ref_id);
2331 print STDERR "Initializing parent: $ref_id\n";
2332 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2333 if ($u =~ s#^\Q$url\E(/|$)##) {
2334 $p = $u;
2335 $u = $url;
2336 $repo_id = $self->{repo_id};
2337 }
2338 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2339 }
2340 my ($r0, $parent) = $gs->find_rev_before($r, 1);
2341 if (!defined $r0 || !defined $parent) {
2342 my ($base, $head) = parse_revision_argument(0, $r);
2343 if ($base <= $r) {
2344 $gs->fetch($base, $r);
2345 }
2346 ($r0, $parent) = $gs->last_rev_commit;
2347 }
2348 if (defined $r0 && defined $parent) {
2349 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2350 my $ed;
2351 if ($self->ra->can_do_switch) {
2352 $self->assert_index_clean($parent);
2353 print STDERR "Following parent with do_switch\n";
2354 # do_switch works with svn/trunk >= r22312, but that
2355 # is not included with SVN 1.4.3 (the latest version
2356 # at the moment), so we can't rely on it
2357 $self->{last_commit} = $parent;
2358 $ed = SVN::Git::Fetcher->new($self);
2359 $gs->ra->gs_do_switch($r0, $rev, $gs,
2360 $self->full_url, $ed)
2361 or die "SVN connection failed somewhere...\n";
2362 } elsif ($self->ra->trees_match($new_url, $r0,
2363 $self->full_url, $rev)) {
2364 print STDERR "Trees match:\n",
2365 " $new_url\@$r0\n",
2366 " ${\$self->full_url}\@$rev\n",
2367 "Following parent with no changes\n";
2368 $self->tmp_index_do(sub {
2369 command_noisy('read-tree', $parent);
2370 });
2371 $self->{last_commit} = $parent;
2372 } else {
2373 print STDERR "Following parent with do_update\n";
2374 $ed = SVN::Git::Fetcher->new($self);
2375 $self->ra->gs_do_update($rev, $rev, $self, $ed)
2376 or die "SVN connection failed somewhere...\n";
2377 }
2378 print STDERR "Successfully followed parent\n";
2379 return $self->make_log_entry($rev, [$parent], $ed);
2380 }
2381 return undef;
2382 }
2383
2384 sub do_fetch {
2385 my ($self, $paths, $rev) = @_;
2386 my $ed;
2387 my ($last_rev, @parents);
2388 if (my $lc = $self->last_commit) {
2389 # we can have a branch that was deleted, then re-added
2390 # under the same name but copied from another path, in
2391 # which case we'll have multiple parents (we don't
2392 # want to break the original ref, nor lose copypath info):
2393 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2394 push @{$log_entry->{parents}}, $lc;
2395 return $log_entry;
2396 }
2397 $ed = SVN::Git::Fetcher->new($self);
2398 $last_rev = $self->{last_rev};
2399 $ed->{c} = $lc;
2400 @parents = ($lc);
2401 } else {
2402 $last_rev = $rev;
2403 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2404 return $log_entry;
2405 }
2406 $ed = SVN::Git::Fetcher->new($self);
2407 }
2408 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2409 die "SVN connection failed somewhere...\n";
2410 }
2411 $self->make_log_entry($rev, \@parents, $ed);
2412 }
2413
2414 sub get_untracked {
2415 my ($self, $ed) = @_;
2416 my @out;
2417 my $h = $ed->{empty};
2418 foreach (sort keys %$h) {
2419 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2420 push @out, " $act: " . uri_encode($_);
2421 warn "W: $act: $_\n";
2422 }
2423 foreach my $t (qw/dir_prop file_prop/) {
2424 $h = $ed->{$t} or next;
2425 foreach my $path (sort keys %$h) {
2426 my $ppath = $path eq '' ? '.' : $path;
2427 foreach my $prop (sort keys %{$h->{$path}}) {
2428 next if $SKIP_PROP{$prop};
2429 my $v = $h->{$path}->{$prop};
2430 my $t_ppath_prop = "$t: " .
2431 uri_encode($ppath) . ' ' .
2432 uri_encode($prop);
2433 if (defined $v) {
2434 push @out, " +$t_ppath_prop " .
2435 uri_encode($v);
2436 } else {
2437 push @out, " -$t_ppath_prop";
2438 }
2439 }
2440 }
2441 }
2442 foreach my $t (qw/absent_file absent_directory/) {
2443 $h = $ed->{$t} or next;
2444 foreach my $parent (sort keys %$h) {
2445 foreach my $path (sort @{$h->{$parent}}) {
2446 push @out, " $t: " .
2447 uri_encode("$parent/$path");
2448 warn "W: $t: $parent/$path ",
2449 "Insufficient permissions?\n";
2450 }
2451 }
2452 }
2453 \@out;
2454 }
2455
2456 sub parse_svn_date {
2457 my $date = shift || return '+0000 1970-01-01 00:00:00';
2458 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2459 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
2460 croak "Unable to parse date: $date\n";
2461 "+0000 $Y-$m-$d $H:$M:$S";
2462 }
2463
2464 sub check_author {
2465 my ($author) = @_;
2466 if (!defined $author || length $author == 0) {
2467 $author = '(no author)';
2468 } elsif (defined $::_authors && ! defined $::users{$author}) {
2469 die "Author: $author not defined in $::_authors file\n";
2470 }
2471 $author;
2472 }
2473
2474 sub make_log_entry {
2475 my ($self, $rev, $parents, $ed) = @_;
2476 my $untracked = $self->get_untracked($ed);
2477
2478 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2479 print $un "r$rev\n" or croak $!;
2480 print $un $_, "\n" foreach @$untracked;
2481 my %log_entry = ( parents => $parents || [], revision => $rev,
2482 log => '');
2483
2484 my $headrev;
2485 my $logged = delete $self->{logged_rev_props};
2486 if (!$logged || $self->{-want_revprops}) {
2487 my $rp = $self->ra->rev_proplist($rev);
2488 foreach (sort keys %$rp) {
2489 my $v = $rp->{$_};
2490 if (/^svn:(author|date|log)$/) {
2491 $log_entry{$1} = $v;
2492 } elsif ($_ eq 'svm:headrev') {
2493 $headrev = $v;
2494 } else {
2495 print $un " rev_prop: ", uri_encode($_), ' ',
2496 uri_encode($v), "\n";
2497 }
2498 }
2499 } else {
2500 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2501 }
2502 close $un or croak $!;
2503
2504 $log_entry{date} = parse_svn_date($log_entry{date});
2505 $log_entry{log} .= "\n";
2506 my $author = $log_entry{author} = check_author($log_entry{author});
2507 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2508 : ($author, undef);
2509
2510 my ($commit_name, $commit_email) = ($name, $email);
2511 if ($_use_log_author) {
2512 my $name_field;
2513 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2514 $name_field = $1;
2515 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2516 $name_field = $1;
2517 }
2518 if (!defined $name_field) {
2519 if (!defined $email) {
2520 $email = $name;
2521 }
2522 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2523 ($name, $email) = ($1, $2);
2524 } elsif ($name_field =~ /(.*)@/) {
2525 ($name, $email) = ($1, $name_field);
2526 } else {
2527 ($name, $email) = ($name_field, $name_field);
2528 }
2529 }
2530 if (defined $headrev && $self->use_svm_props) {
2531 if ($self->rewrite_root) {
2532 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2533 "options set!\n";
2534 }
2535 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2536 # we don't want "SVM: initializing mirror for junk" ...
2537 return undef if $r == 0;
2538 my $svm = $self->svm;
2539 if ($uuid ne $svm->{uuid}) {
2540 die "UUID mismatch on SVM path:\n",
2541 "expected: $svm->{uuid}\n",
2542 " got: $uuid\n";
2543 }
2544 my $full_url = $self->full_url;
2545 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2546 die "Failed to replace '$svm->{replace}' with ",
2547 "'$svm->{source}' in $full_url\n";
2548 # throw away username for storing in records
2549 remove_username($full_url);
2550 $log_entry{metadata} = "$full_url\@$r $uuid";
2551 $log_entry{svm_revision} = $r;
2552 $email ||= "$author\@$uuid";
2553 $commit_email ||= "$author\@$uuid";
2554 } elsif ($self->use_svnsync_props) {
2555 my $full_url = $self->svnsync->{url};
2556 $full_url .= "/$self->{path}" if length $self->{path};
2557 remove_username($full_url);
2558 my $uuid = $self->svnsync->{uuid};
2559 $log_entry{metadata} = "$full_url\@$rev $uuid";
2560 $email ||= "$author\@$uuid";
2561 $commit_email ||= "$author\@$uuid";
2562 } else {
2563 my $url = $self->metadata_url;
2564 remove_username($url);
2565 $log_entry{metadata} = "$url\@$rev " .
2566 $self->ra->get_uuid;
2567 $email ||= "$author\@" . $self->ra->get_uuid;
2568 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2569 }
2570 $log_entry{name} = $name;
2571 $log_entry{email} = $email;
2572 $log_entry{commit_name} = $commit_name;
2573 $log_entry{commit_email} = $commit_email;
2574 \%log_entry;
2575 }
2576
2577 sub fetch {
2578 my ($self, $min_rev, $max_rev, @parents) = @_;
2579 my ($last_rev, $last_commit) = $self->last_rev_commit;
2580 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2581 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2582 }
2583
2584 sub set_tree_cb {
2585 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2586 $self->{inject_parents} = { $rev => $tree };
2587 $self->fetch(undef, undef);
2588 }
2589
2590 sub set_tree {
2591 my ($self, $tree) = (shift, shift);
2592 my $log_entry = ::get_commit_entry($tree);
2593 unless ($self->{last_rev}) {
2594 ::fatal("Must have an existing revision to commit");
2595 }
2596 my %ed_opts = ( r => $self->{last_rev},
2597 log => $log_entry->{log},
2598 ra => $self->ra,
2599 tree_a => $self->{last_commit},
2600 tree_b => $tree,
2601 editor_cb => sub {
2602 $self->set_tree_cb($log_entry, $tree, @_) },
2603 svn_path => $self->{path} );
2604 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2605 print "No changes\nr$self->{last_rev} = $tree\n";
2606 }
2607 }
2608
2609 sub rebuild_from_rev_db {
2610 my ($self, $path) = @_;
2611 my $r = -1;
2612 open my $fh, '<', $path or croak "open: $!";
2613 binmode $fh or croak "binmode: $!";
2614 while (<$fh>) {
2615 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2616 chomp($_);
2617 ++$r;
2618 next if $_ eq ('0' x 40);
2619 $self->rev_map_set($r, $_);
2620 print "r$r = $_\n";
2621 }
2622 close $fh or croak "close: $!";
2623 unlink $path or croak "unlink: $!";
2624 }
2625
2626 sub rebuild {
2627 my ($self) = @_;
2628 my $map_path = $self->map_path;
2629 my $partial = (-e $map_path && ! -z $map_path);
2630 return unless ::verify_ref($self->refname.'^0');
2631 if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
2632 my $rev_db = $self->rev_db_path;
2633 $self->rebuild_from_rev_db($rev_db);
2634 if ($self->use_svm_props) {
2635 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2636 $self->rebuild_from_rev_db($svm_rev_db);
2637 }
2638 $self->unlink_rev_db_symlink;
2639 return;
2640 }
2641 print "Rebuilding $map_path ...\n" if (!$partial);
2642 my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
2643 (undef, undef));
2644 my ($log, $ctx) =
2645 command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2646 ($head ? "$head.." : "") . $self->refname,
2647 '--');
2648 my $metadata_url = $self->metadata_url;
2649 remove_username($metadata_url);
2650 my $svn_uuid = $self->ra_uuid;
2651 my $c;
2652 while (<$log>) {
2653 if ( m{^commit ($::sha1)$} ) {
2654 $c = $1;
2655 next;
2656 }
2657 next unless s{^\s*(git-svn-id:)}{$1};
2658 my ($url, $rev, $uuid) = ::extract_metadata($_);
2659 remove_username($url);
2660
2661 # ignore merges (from set-tree)
2662 next if (!defined $rev || !$uuid);
2663
2664 # if we merged or otherwise started elsewhere, this is
2665 # how we break out of it
2666 if (($uuid ne $svn_uuid) ||
2667 ($metadata_url && $url && ($url ne $metadata_url))) {
2668 next;
2669 }
2670 if ($partial && $head) {
2671 print "Partial-rebuilding $map_path ...\n";
2672 print "Currently at $base_rev = $head\n";
2673 $head = undef;
2674 }
2675
2676 $self->rev_map_set($rev, $c);
2677 print "r$rev = $c\n";
2678 }
2679 command_close_pipe($log, $ctx);
2680 print "Done rebuilding $map_path\n" if (!$partial || !$head);
2681 my $rev_db_path = $self->rev_db_path;
2682 if (-f $self->rev_db_path) {
2683 unlink $self->rev_db_path or croak "unlink: $!";
2684 }
2685 $self->unlink_rev_db_symlink;
2686 }
2687
2688 # rev_map:
2689 # Tie::File seems to be prone to offset errors if revisions get sparse,
2690 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
2691 # one of my favorite modules is out :< Next up would be one of the DBM
2692 # modules, but I'm not sure which is most portable...
2693 #
2694 # This is the replacement for the rev_db format, which was too big
2695 # and inefficient for large repositories with a lot of sparse history
2696 # (mainly tags)
2697 #
2698 # The format is this:
2699 # - 24 bytes for every record,
2700 # * 4 bytes for the integer representing an SVN revision number
2701 # * 20 bytes representing the sha1 of a git commit
2702 # - No empty padding records like the old format
2703 # (except the last record, which can be overwritten)
2704 # - new records are written append-only since SVN revision numbers
2705 # increase monotonically
2706 # - lookups on SVN revision number are done via a binary search
2707 # - Piping the file to xxd -c24 is a good way of dumping it for
2708 # viewing or editing (piped back through xxd -r), should the need
2709 # ever arise.
2710 # - The last record can be padding revision with an all-zero sha1
2711 # This is used to optimize fetch performance when using multiple
2712 # "fetch" directives in .git/config
2713 #
2714 # These files are disposable unless noMetadata or useSvmProps is set
2715
2716 sub _rev_map_set {
2717 my ($fh, $rev, $commit) = @_;
2718
2719 binmode $fh or croak "binmode: $!";
2720 my $size = (stat($fh))[7];
2721 ($size % 24) == 0 or croak "inconsistent size: $size";
2722
2723 my $wr_offset = 0;
2724 if ($size > 0) {
2725 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2726 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2727 $read == 24 or croak "read only $read bytes (!= 24)";
2728 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2729 if ($last_commit eq ('0' x40)) {
2730 if ($size >= 48) {
2731 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2732 $read = sysread($fh, $buf, 24) or
2733 croak "read: $!";
2734 $read == 24 or
2735 croak "read only $read bytes (!= 24)";
2736 ($last_rev, $last_commit) =
2737 unpack(rev_map_fmt, $buf);
2738 if ($last_commit eq ('0' x40)) {
2739 croak "inconsistent .rev_map\n";
2740 }
2741 }
2742 if ($last_rev >= $rev) {
2743 croak "last_rev is higher!: $last_rev >= $rev";
2744 }
2745 $wr_offset = -24;
2746 }
2747 }
2748 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2749 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2750 croak "write: $!";
2751 }
2752
2753 sub mkfile {
2754 my ($path) = @_;
2755 unless (-e $path) {
2756 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2757 mkpath([$dir]) unless -d $dir;
2758 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2759 close $fh or die "Couldn't close (create) $path: $!\n";
2760 }
2761 }
2762
2763 sub rev_map_set {
2764 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2765 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2766 my $db = $self->map_path($uuid);
2767 my $db_lock = "$db.lock";
2768 my $sig;
2769 if ($update_ref) {
2770 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2771 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2772 }
2773 mkfile($db);
2774
2775 $LOCKFILES{$db_lock} = 1;
2776 my $sync;
2777 # both of these options make our .rev_db file very, very important
2778 # and we can't afford to lose it because rebuild() won't work
2779 if ($self->use_svm_props || $self->no_metadata) {
2780 $sync = 1;
2781 copy($db, $db_lock) or die "rev_map_set(@_): ",
2782 "Failed to copy: ",
2783 "$db => $db_lock ($!)\n";
2784 } else {
2785 rename $db, $db_lock or die "rev_map_set(@_): ",
2786 "Failed to rename: ",
2787 "$db => $db_lock ($!)\n";
2788 }
2789
2790 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2791 or croak "Couldn't open $db_lock: $!\n";
2792 _rev_map_set($fh, $rev, $commit);
2793 if ($sync) {
2794 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2795 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2796 }
2797 close $fh or croak $!;
2798 if ($update_ref) {
2799 $_head = $self;
2800 command_noisy('update-ref', '-m', "r$rev",
2801 $self->refname, $commit);
2802 }
2803 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2804 "$db_lock => $db ($!)\n";
2805 delete $LOCKFILES{$db_lock};
2806 if ($update_ref) {
2807 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2808 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2809 kill $sig, $$ if defined $sig;
2810 }
2811 }
2812
2813 # If want_commit, this will return an array of (rev, commit) where
2814 # commit _must_ be a valid commit in the archive.
2815 # Otherwise, it'll return the max revision (whether or not the
2816 # commit is valid or just a 0x40 placeholder).
2817 sub rev_map_max {
2818 my ($self, $want_commit) = @_;
2819 $self->rebuild;
2820 my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
2821 $want_commit ? ($r, $c) : $r;
2822 }
2823
2824 sub rev_map_max_norebuild {
2825 my ($self, $want_commit) = @_;
2826 my $map_path = $self->map_path;
2827 stat $map_path or return $want_commit ? (0, undef) : 0;
2828 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2829 binmode $fh or croak "binmode: $!";
2830 my $size = (stat($fh))[7];
2831 ($size % 24) == 0 or croak "inconsistent size: $size";
2832
2833 if ($size == 0) {
2834 close $fh or croak "close: $!";
2835 return $want_commit ? (0, undef) : 0;
2836 }
2837
2838 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2839 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2840 my ($r, $c) = unpack(rev_map_fmt, $buf);
2841 if ($want_commit && $c eq ('0' x40)) {
2842 if ($size < 48) {
2843 return $want_commit ? (0, undef) : 0;
2844 }
2845 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2846 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2847 ($r, $c) = unpack(rev_map_fmt, $buf);
2848 if ($c eq ('0'x40)) {
2849 croak "Penultimate record is all-zeroes in $map_path";
2850 }
2851 }
2852 close $fh or croak "close: $!";
2853 $want_commit ? ($r, $c) : $r;
2854 }
2855
2856 sub rev_map_get {
2857 my ($self, $rev, $uuid) = @_;
2858 my $map_path = $self->map_path($uuid);
2859 return undef unless -e $map_path;
2860
2861 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2862 binmode $fh or croak "binmode: $!";
2863 my $size = (stat($fh))[7];
2864 ($size % 24) == 0 or croak "inconsistent size: $size";
2865
2866 if ($size == 0) {
2867 close $fh or croak "close: $fh";
2868 return undef;
2869 }
2870
2871 my ($l, $u) = (0, $size - 24);
2872 my ($r, $c, $buf);
2873
2874 while ($l <= $u) {
2875 my $i = int(($l/24 + $u/24) / 2) * 24;
2876 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2877 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2878 my ($r, $c) = unpack('NH40', $buf);
2879
2880 if ($r < $rev) {
2881 $l = $i + 24;
2882 } elsif ($r > $rev) {
2883 $u = $i - 24;
2884 } else { # $r == $rev
2885 close($fh) or croak "close: $!";
2886 return $c eq ('0' x 40) ? undef : $c;
2887 }
2888 }
2889 close($fh) or croak "close: $!";
2890 undef;
2891 }
2892
2893 # Finds the first svn revision that exists on (if $eq_ok is true) or
2894 # before $rev for the current branch. It will not search any lower
2895 # than $min_rev. Returns the git commit hash and svn revision number
2896 # if found, else (undef, undef).
2897 sub find_rev_before {
2898 my ($self, $rev, $eq_ok, $min_rev) = @_;
2899 --$rev unless $eq_ok;
2900 $min_rev ||= 1;
2901 while ($rev >= $min_rev) {
2902 if (my $c = $self->rev_map_get($rev)) {
2903 return ($rev, $c);
2904 }
2905 --$rev;
2906 }
2907 return (undef, undef);
2908 }
2909
2910 # Finds the first svn revision that exists on (if $eq_ok is true) or
2911 # after $rev for the current branch. It will not search any higher
2912 # than $max_rev. Returns the git commit hash and svn revision number
2913 # if found, else (undef, undef).
2914 sub find_rev_after {
2915 my ($self, $rev, $eq_ok, $max_rev) = @_;
2916 ++$rev unless $eq_ok;
2917 $max_rev ||= $self->rev_map_max;
2918 while ($rev <= $max_rev) {
2919 if (my $c = $self->rev_map_get($rev)) {
2920 return ($rev, $c);
2921 }
2922 ++$rev;
2923 }
2924 return (undef, undef);
2925 }
2926
2927 sub _new {
2928 my ($class, $repo_id, $ref_id, $path) = @_;
2929 unless (defined $repo_id && length $repo_id) {
2930 $repo_id = $Git::SVN::default_repo_id;
2931 }
2932 unless (defined $ref_id && length $ref_id) {
2933 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2934 }
2935 $_[1] = $repo_id;
2936 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2937 $_[3] = $path = '' unless (defined $path);
2938 mkpath(["$ENV{GIT_DIR}/svn"]);
2939 bless {
2940 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2941 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2942 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2943 }
2944
2945 # for read-only access of old .rev_db formats
2946 sub unlink_rev_db_symlink {
2947 my ($self) = @_;
2948 my $link = $self->rev_db_path;
2949 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2950 if (-l $link) {
2951 unlink $link or croak "unlink: $link failed!";
2952 }
2953 }
2954
2955 sub rev_db_path {
2956 my ($self, $uuid) = @_;
2957 my $db_path = $self->map_path($uuid);
2958 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2959 or croak "map_path: $db_path does not contain '/.rev_map.' !";
2960 $db_path;
2961 }
2962
2963 # the new replacement for .rev_db
2964 sub map_path {
2965 my ($self, $uuid) = @_;
2966 $uuid ||= $self->ra_uuid;
2967 "$self->{map_root}.$uuid";
2968 }
2969
2970 sub uri_encode {
2971 my ($f) = @_;
2972 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2973 $f
2974 }
2975
2976 sub remove_username {
2977 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2978 }
2979
2980 package Git::SVN::Prompt;
2981 use strict;
2982 use warnings;
2983 require SVN::Core;
2984 use vars qw/$_no_auth_cache $_username/;
2985
2986 sub simple {
2987 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2988 $may_save = undef if $_no_auth_cache;
2989 $default_username = $_username if defined $_username;
2990 if (defined $default_username && length $default_username) {
2991 if (defined $realm && length $realm) {
2992 print STDERR "Authentication realm: $realm\n";
2993 STDERR->flush;
2994 }
2995 $cred->username($default_username);
2996 } else {
2997 username($cred, $realm, $may_save, $pool);
2998 }
2999 $cred->password(_read_password("Password for '" .
3000 $cred->username . "': ", $realm));
3001 $cred->may_save($may_save);
3002 $SVN::_Core::SVN_NO_ERROR;
3003 }
3004
3005 sub ssl_server_trust {
3006 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3007 $may_save = undef if $_no_auth_cache;
3008 print STDERR "Error validating server certificate for '$realm':\n";
3009 {
3010 no warnings 'once';
3011 # All variables SVN::Auth::SSL::* are used only once,
3012 # so we're shutting up Perl warnings about this.
3013 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3014 print STDERR " - The certificate is not issued ",
3015 "by a trusted authority. Use the\n",
3016 " fingerprint to validate ",
3017 "the certificate manually!\n";
3018 }
3019 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3020 print STDERR " - The certificate hostname ",
3021 "does not match.\n";
3022 }
3023 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3024 print STDERR " - The certificate is not yet valid.\n";
3025 }
3026 if ($failures & $SVN::Auth::SSL::EXPIRED) {
3027 print STDERR " - The certificate has expired.\n";
3028 }
3029 if ($failures & $SVN::Auth::SSL::OTHER) {
3030 print STDERR " - The certificate has ",
3031 "an unknown error.\n";
3032 }
3033 } # no warnings 'once'
3034 printf STDERR
3035 "Certificate information:\n".
3036 " - Hostname: %s\n".
3037 " - Valid: from %s until %s\n".
3038 " - Issuer: %s\n".
3039 " - Fingerprint: %s\n",
3040 map $cert_info->$_, qw(hostname valid_from valid_until
3041 issuer_dname fingerprint);
3042 my $choice;
3043 prompt:
3044 print STDERR $may_save ?
3045 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
3046 "(R)eject or accept (t)emporarily? ";
3047 STDERR->flush;
3048 $choice = lc(substr(<STDIN> || 'R', 0, 1));
3049 if ($choice =~ /^t$/i) {
3050 $cred->may_save(undef);
3051 } elsif ($choice =~ /^r$/i) {
3052 return -1;
3053 } elsif ($may_save && $choice =~ /^p$/i) {
3054 $cred->may_save($may_save);
3055 } else {
3056 goto prompt;
3057 }
3058 $cred->accepted_failures($failures);
3059 $SVN::_Core::SVN_NO_ERROR;
3060 }
3061
3062 sub ssl_client_cert {
3063 my ($cred, $realm, $may_save, $pool) = @_;
3064 $may_save = undef if $_no_auth_cache;
3065 print STDERR "Client certificate filename: ";
3066 STDERR->flush;
3067 chomp(my $filename = <STDIN>);
3068 $cred->cert_file($filename);
3069 $cred->may_save($may_save);
3070 $SVN::_Core::SVN_NO_ERROR;
3071 }
3072
3073 sub ssl_client_cert_pw {
3074 my ($cred, $realm, $may_save, $pool) = @_;
3075 $may_save = undef if $_no_auth_cache;
3076 $cred->password(_read_password("Password: ", $realm));
3077 $cred->may_save($may_save);
3078 $SVN::_Core::SVN_NO_ERROR;
3079 }
3080
3081 sub username {
3082 my ($cred, $realm, $may_save, $pool) = @_;
3083 $may_save = undef if $_no_auth_cache;
3084 if (defined $realm && length $realm) {
3085 print STDERR "Authentication realm: $realm\n";
3086 }
3087 my $username;
3088 if (defined $_username) {
3089 $username = $_username;
3090 } else {
3091 print STDERR "Username: ";
3092 STDERR->flush;
3093 chomp($username = <STDIN>);
3094 }
3095 $cred->username($username);
3096 $cred->may_save($may_save);
3097 $SVN::_Core::SVN_NO_ERROR;
3098 }
3099
3100 sub _read_password {
3101 my ($prompt, $realm) = @_;
3102 print STDERR $prompt;
3103 STDERR->flush;
3104 require Term::ReadKey;
3105 Term::ReadKey::ReadMode('noecho');
3106 my $password = '';
3107 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
3108 last if $key =~ /[\012\015]/; # \n\r
3109 $password .= $key;
3110 }
3111 Term::ReadKey::ReadMode('restore');
3112 print STDERR "\n";
3113 STDERR->flush;
3114 $password;
3115 }
3116
3117 package SVN::Git::Fetcher;
3118 use vars qw/@ISA/;
3119 use strict;
3120 use warnings;
3121 use Carp qw/croak/;
3122 use File::Temp qw/tempfile/;
3123 use IO::File qw//;
3124
3125 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
3126 sub new {
3127 my ($class, $git_svn) = @_;
3128 my $self = SVN::Delta::Editor->new;
3129 bless $self, $class;
3130 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
3131 $self->{empty} = {};
3132 $self->{dir_prop} = {};
3133 $self->{file_prop} = {};
3134 $self->{absent_dir} = {};
3135 $self->{absent_file} = {};
3136 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3137 $self;
3138 }
3139
3140 sub set_path_strip {
3141 my ($self, $path) = @_;
3142 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3143 }
3144
3145 sub open_root {
3146 { path => '' };
3147 }
3148
3149 sub open_directory {
3150 my ($self, $path, $pb, $rev) = @_;
3151 { path => $path };
3152 }
3153
3154 sub git_path {
3155 my ($self, $path) = @_;
3156 if ($self->{path_strip}) {
3157 $path =~ s!$self->{path_strip}!! or
3158 die "Failed to strip path '$path' ($self->{path_strip})\n";
3159 }
3160 $path;
3161 }
3162
3163 sub delete_entry {
3164 my ($self, $path, $rev, $pb) = @_;
3165
3166 my $gpath = $self->git_path($path);
3167 return undef if ($gpath eq '');
3168
3169 # remove entire directories.
3170 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
3171 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3172 -r --name-only -z/,
3173 $self->{c}, '--', $gpath);
3174 local $/ = "\0";
3175 while (<$ls>) {
3176 chomp;
3177 $self->{gii}->remove($_);
3178 print "\tD\t$_\n" unless $::_q;
3179 }
3180 print "\tD\t$gpath/\n" unless $::_q;
3181 command_close_pipe($ls, $ctx);
3182 $self->{empty}->{$path} = 0
3183 } else {
3184 $self->{gii}->remove($gpath);
3185 print "\tD\t$gpath\n" unless $::_q;
3186 }
3187 undef;
3188 }
3189
3190 sub open_file {
3191 my ($self, $path, $pb, $rev) = @_;
3192 my $gpath = $self->git_path($path);
3193 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3194 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3195 unless (defined $mode && defined $blob) {
3196 die "$path was not found in commit $self->{c} (r$rev)\n";
3197 }
3198 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3199 pool => SVN::Pool->new, action => 'M' };
3200 }
3201
3202 sub add_file {
3203 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3204 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3205 delete $self->{empty}->{$dir};
3206 { path => $path, mode_a => 100644, mode_b => 100644,
3207 pool => SVN::Pool->new, action => 'A' };
3208 }
3209
3210 sub add_directory {
3211 my ($self, $path, $cp_path, $cp_rev) = @_;
3212 my $gpath = $self->git_path($path);
3213 if ($gpath eq '') {
3214 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3215 -r --name-only -z/,
3216 $self->{c});
3217 local $/ = "\0";
3218 while (<$ls>) {
3219 chomp;
3220 $self->{gii}->remove($_);
3221 print "\tD\t$_\n" unless $::_q;
3222 }
3223 command_close_pipe($ls, $ctx);
3224 $self->{empty}->{$path} = 0;
3225 }
3226 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3227 delete $self->{empty}->{$dir};
3228 $self->{empty}->{$path} = 1;
3229 { path => $path };
3230 }
3231
3232 sub change_dir_prop {
3233 my ($self, $db, $prop, $value) = @_;
3234 $self->{dir_prop}->{$db->{path}} ||= {};
3235 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3236 undef;
3237 }
3238
3239 sub absent_directory {
3240 my ($self, $path, $pb) = @_;
3241 $self->{absent_dir}->{$pb->{path}} ||= [];
3242 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3243 undef;
3244 }
3245
3246 sub absent_file {
3247 my ($self, $path, $pb) = @_;
3248 $self->{absent_file}->{$pb->{path}} ||= [];
3249 push @{$self->{absent_file}->{$pb->{path}}}, $path;
3250 undef;
3251 }
3252
3253 sub change_file_prop {
3254 my ($self, $fb, $prop, $value) = @_;
3255 if ($prop eq 'svn:executable') {
3256 if ($fb->{mode_b} != 120000) {
3257 $fb->{mode_b} = defined $value ? 100755 : 100644;
3258 }
3259 } elsif ($prop eq 'svn:special') {
3260 $fb->{mode_b} = defined $value ? 120000 : 100644;
3261 } else {
3262 $self->{file_prop}->{$fb->{path}} ||= {};
3263 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3264 }
3265 undef;
3266 }
3267
3268 sub apply_textdelta {
3269 my ($self, $fb, $exp) = @_;
3270 my $fh = Git::temp_acquire('svn_delta');
3271 # $fh gets auto-closed() by SVN::TxDelta::apply(),
3272 # (but $base does not,) so dup() it for reading in close_file
3273 open my $dup, '<&', $fh or croak $!;
3274 my $base = Git::temp_acquire('git_blob');
3275 if ($fb->{blob}) {
3276 print $base 'link ' if ($fb->{mode_a} == 120000);
3277 my $size = $::_repository->cat_blob($fb->{blob}, $base);
3278 die "Failed to read object $fb->{blob}" if ($size < 0);
3279
3280 if (defined $exp) {
3281 seek $base, 0, 0 or croak $!;
3282 my $got = ::md5sum($base);
3283 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
3284 "expected: $exp\n",
3285 " got: $got\n" if ($got ne $exp);
3286 }
3287 }
3288 seek $base, 0, 0 or croak $!;
3289 $fb->{fh} = $fh;
3290 $fb->{base} = $base;
3291 [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];