84f2c1df2c22c88baa0ceb987ced6b9595a04a84
[git/git.git] / gitweb / gitweb.perl
1 #!/usr/bin/perl
2
3 # gitweb - simple web interface to track changes in git repositories
4 #
5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
6 # (C) 2005, Christian Gierke
7 #
8 # This program is licensed under the GPLv2
9
10 use 5.008;
11 use strict;
12 use warnings;
13 use CGI qw(:standard :escapeHTML -nosticky);
14 use CGI::Util qw(unescape);
15 use CGI::Carp qw(fatalsToBrowser set_message);
16 use Encode;
17 use Fcntl ':mode';
18 use File::Find qw();
19 use File::Basename qw(basename);
20 use Time::HiRes qw(gettimeofday tv_interval);
21 binmode STDOUT, ':utf8';
22
23 our $t0 = [ gettimeofday() ];
24 our $number_of_git_cmds = 0;
25
26 BEGIN {
27 CGI->compile() if $ENV{'MOD_PERL'};
28 }
29
30 our $version = "++GIT_VERSION++";
31
32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
33 sub evaluate_uri {
34 our $cgi;
35
36 our $my_url = $cgi->url();
37 our $my_uri = $cgi->url(-absolute => 1);
38
39 # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
40 # needed and used only for URLs with nonempty PATH_INFO
41 our $base_url = $my_url;
42
43 # When the script is used as DirectoryIndex, the URL does not contain the name
44 # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
45 # have to do it ourselves. We make $path_info global because it's also used
46 # later on.
47 #
48 # Another issue with the script being the DirectoryIndex is that the resulting
49 # $my_url data is not the full script URL: this is good, because we want
50 # generated links to keep implying the script name if it wasn't explicitly
51 # indicated in the URL we're handling, but it means that $my_url cannot be used
52 # as base URL.
53 # Therefore, if we needed to strip PATH_INFO, then we know that we have
54 # to build the base URL ourselves:
55 our $path_info = $ENV{"PATH_INFO"};
56 if ($path_info) {
57 if ($my_url =~ s,\Q$path_info\E$,, &&
58 $my_uri =~ s,\Q$path_info\E$,, &&
59 defined $ENV{'SCRIPT_NAME'}) {
60 $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
61 }
62 }
63
64 # target of the home link on top of all pages
65 our $home_link = $my_uri || "/";
66 }
67
68 # core git executable to use
69 # this can just be "git" if your webserver has a sensible PATH
70 our $GIT = "++GIT_BINDIR++/git";
71
72 # absolute fs-path which will be prepended to the project path
73 #our $projectroot = "/pub/scm";
74 our $projectroot = "++GITWEB_PROJECTROOT++";
75
76 # fs traversing limit for getting project list
77 # the number is relative to the projectroot
78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
79
80 # string of the home link on top of all pages
81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
82
83 # name of your site or organization to appear in page titles
84 # replace this with something more descriptive for clearer bookmarks
85 our $site_name = "++GITWEB_SITENAME++"
86 || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
87
88 # filename of html text to include at top of each page
89 our $site_header = "++GITWEB_SITE_HEADER++";
90 # html text to include at home page
91 our $home_text = "++GITWEB_HOMETEXT++";
92 # filename of html text to include at bottom of each page
93 our $site_footer = "++GITWEB_SITE_FOOTER++";
94
95 # URI of stylesheets
96 our @stylesheets = ("++GITWEB_CSS++");
97 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
98 our $stylesheet = undef;
99 # URI of GIT logo (72x27 size)
100 our $logo = "++GITWEB_LOGO++";
101 # URI of GIT favicon, assumed to be image/png type
102 our $favicon = "++GITWEB_FAVICON++";
103 # URI of gitweb.js (JavaScript code for gitweb)
104 our $javascript = "++GITWEB_JS++";
105
106 # URI and label (title) of GIT logo link
107 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
108 #our $logo_label = "git documentation";
109 our $logo_url = "http://git-scm.com/";
110 our $logo_label = "git homepage";
111
112 # source of projects list
113 our $projects_list = "++GITWEB_LIST++";
114
115 # the width (in characters) of the projects list "Description" column
116 our $projects_list_description_width = 25;
117
118 # default order of projects list
119 # valid values are none, project, descr, owner, and age
120 our $default_projects_order = "project";
121
122 # show repository only if this file exists
123 # (only effective if this variable evaluates to true)
124 our $export_ok = "++GITWEB_EXPORT_OK++";
125
126 # show repository only if this subroutine returns true
127 # when given the path to the project, for example:
128 # sub { return -e "$_[0]/git-daemon-export-ok"; }
129 our $export_auth_hook = undef;
130
131 # only allow viewing of repositories also shown on the overview page
132 our $strict_export = "++GITWEB_STRICT_EXPORT++";
133
134 # list of git base URLs used for URL to where fetch project from,
135 # i.e. full URL is "$git_base_url/$project"
136 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
137
138 # default blob_plain mimetype and default charset for text/plain blob
139 our $default_blob_plain_mimetype = 'text/plain';
140 our $default_text_plain_charset = undef;
141
142 # file to use for guessing MIME types before trying /etc/mime.types
143 # (relative to the current git repository)
144 our $mimetypes_file = undef;
145
146 # assume this charset if line contains non-UTF-8 characters;
147 # it should be valid encoding (see Encoding::Supported(3pm) for list),
148 # for which encoding all byte sequences are valid, for example
149 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
150 # could be even 'utf-8' for the old behavior)
151 our $fallback_encoding = 'latin1';
152
153 # rename detection options for git-diff and git-diff-tree
154 # - default is '-M', with the cost proportional to
155 # (number of removed files) * (number of new files).
156 # - more costly is '-C' (which implies '-M'), with the cost proportional to
157 # (number of changed files + number of removed files) * (number of new files)
158 # - even more costly is '-C', '--find-copies-harder' with cost
159 # (number of files in the original tree) * (number of new files)
160 # - one might want to include '-B' option, e.g. '-B', '-M'
161 our @diff_opts = ('-M'); # taken from git_commit
162
163 # Disables features that would allow repository owners to inject script into
164 # the gitweb domain.
165 our $prevent_xss = 0;
166
167 # Path to the highlight executable to use (must be the one from
168 # http://www.andre-simon.de due to assumptions about parameters and output).
169 # Useful if highlight is not installed on your webserver's PATH.
170 # [Default: highlight]
171 our $highlight_bin = "++HIGHLIGHT_BIN++";
172
173 # information about snapshot formats that gitweb is capable of serving
174 our %known_snapshot_formats = (
175 # name => {
176 # 'display' => display name,
177 # 'type' => mime type,
178 # 'suffix' => filename suffix,
179 # 'format' => --format for git-archive,
180 # 'compressor' => [compressor command and arguments]
181 # (array reference, optional)
182 # 'disabled' => boolean (optional)}
183 #
184 'tgz' => {
185 'display' => 'tar.gz',
186 'type' => 'application/x-gzip',
187 'suffix' => '.tar.gz',
188 'format' => 'tar',
189 'compressor' => ['gzip']},
190
191 'tbz2' => {
192 'display' => 'tar.bz2',
193 'type' => 'application/x-bzip2',
194 'suffix' => '.tar.bz2',
195 'format' => 'tar',
196 'compressor' => ['bzip2']},
197
198 'txz' => {
199 'display' => 'tar.xz',
200 'type' => 'application/x-xz',
201 'suffix' => '.tar.xz',
202 'format' => 'tar',
203 'compressor' => ['xz'],
204 'disabled' => 1},
205
206 'zip' => {
207 'display' => 'zip',
208 'type' => 'application/x-zip',
209 'suffix' => '.zip',
210 'format' => 'zip'},
211 );
212
213 # Aliases so we understand old gitweb.snapshot values in repository
214 # configuration.
215 our %known_snapshot_format_aliases = (
216 'gzip' => 'tgz',
217 'bzip2' => 'tbz2',
218 'xz' => 'txz',
219
220 # backward compatibility: legacy gitweb config support
221 'x-gzip' => undef, 'gz' => undef,
222 'x-bzip2' => undef, 'bz2' => undef,
223 'x-zip' => undef, '' => undef,
224 );
225
226 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
227 # are changed, it may be appropriate to change these values too via
228 # $GITWEB_CONFIG.
229 our %avatar_size = (
230 'default' => 16,
231 'double' => 32
232 );
233
234 # Used to set the maximum load that we will still respond to gitweb queries.
235 # If server load exceed this value then return "503 server busy" error.
236 # If gitweb cannot determined server load, it is taken to be 0.
237 # Leave it undefined (or set to 'undef') to turn off load checking.
238 our $maxload = 300;
239
240 # configuration for 'highlight' (http://www.andre-simon.de/)
241 # match by basename
242 our %highlight_basename = (
243 #'Program' => 'py',
244 #'Library' => 'py',
245 'SConstruct' => 'py', # SCons equivalent of Makefile
246 'Makefile' => 'make',
247 );
248 # match by extension
249 our %highlight_ext = (
250 # main extensions, defining name of syntax;
251 # see files in /usr/share/highlight/langDefs/ directory
252 map { $_ => $_ }
253 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
254 # alternate extensions, see /etc/highlight/filetypes.conf
255 'h' => 'c',
256 map { $_ => 'sh' } qw(bash zsh ksh),
257 map { $_ => 'cpp' } qw(cxx c++ cc),
258 map { $_ => 'php' } qw(php3 php4 php5 phps),
259 map { $_ => 'pl' } qw(perl pm), # perhaps also 'cgi'
260 map { $_ => 'make'} qw(mak mk),
261 map { $_ => 'xml' } qw(xhtml html htm),
262 );
263
264 # You define site-wide feature defaults here; override them with
265 # $GITWEB_CONFIG as necessary.
266 our %feature = (
267 # feature => {
268 # 'sub' => feature-sub (subroutine),
269 # 'override' => allow-override (boolean),
270 # 'default' => [ default options...] (array reference)}
271 #
272 # if feature is overridable (it means that allow-override has true value),
273 # then feature-sub will be called with default options as parameters;
274 # return value of feature-sub indicates if to enable specified feature
275 #
276 # if there is no 'sub' key (no feature-sub), then feature cannot be
277 # overridden
278 #
279 # use gitweb_get_feature(<feature>) to retrieve the <feature> value
280 # (an array) or gitweb_check_feature(<feature>) to check if <feature>
281 # is enabled
282
283 # Enable the 'blame' blob view, showing the last commit that modified
284 # each line in the file. This can be very CPU-intensive.
285
286 # To enable system wide have in $GITWEB_CONFIG
287 # $feature{'blame'}{'default'} = [1];
288 # To have project specific config enable override in $GITWEB_CONFIG
289 # $feature{'blame'}{'override'} = 1;
290 # and in project config gitweb.blame = 0|1;
291 'blame' => {
292 'sub' => sub { feature_bool('blame', @_) },
293 'override' => 0,
294 'default' => [0]},
295
296 # Enable the 'snapshot' link, providing a compressed archive of any
297 # tree. This can potentially generate high traffic if you have large
298 # project.
299
300 # Value is a list of formats defined in %known_snapshot_formats that
301 # you wish to offer.
302 # To disable system wide have in $GITWEB_CONFIG
303 # $feature{'snapshot'}{'default'} = [];
304 # To have project specific config enable override in $GITWEB_CONFIG
305 # $feature{'snapshot'}{'override'} = 1;
306 # and in project config, a comma-separated list of formats or "none"
307 # to disable. Example: gitweb.snapshot = tbz2,zip;
308 'snapshot' => {
309 'sub' => \&feature_snapshot,
310 'override' => 0,
311 'default' => ['tgz']},
312
313 # Enable text search, which will list the commits which match author,
314 # committer or commit text to a given string. Enabled by default.
315 # Project specific override is not supported.
316 'search' => {
317 'override' => 0,
318 'default' => [1]},
319
320 # Enable grep search, which will list the files in currently selected
321 # tree containing the given string. Enabled by default. This can be
322 # potentially CPU-intensive, of course.
323
324 # To enable system wide have in $GITWEB_CONFIG
325 # $feature{'grep'}{'default'} = [1];
326 # To have project specific config enable override in $GITWEB_CONFIG
327 # $feature{'grep'}{'override'} = 1;
328 # and in project config gitweb.grep = 0|1;
329 'grep' => {
330 'sub' => sub { feature_bool('grep', @_) },
331 'override' => 0,
332 'default' => [1]},
333
334 # Enable the pickaxe search, which will list the commits that modified
335 # a given string in a file. This can be practical and quite faster
336 # alternative to 'blame', but still potentially CPU-intensive.
337
338 # To enable system wide have in $GITWEB_CONFIG
339 # $feature{'pickaxe'}{'default'} = [1];
340 # To have project specific config enable override in $GITWEB_CONFIG
341 # $feature{'pickaxe'}{'override'} = 1;
342 # and in project config gitweb.pickaxe = 0|1;
343 'pickaxe' => {
344 'sub' => sub { feature_bool('pickaxe', @_) },
345 'override' => 0,
346 'default' => [1]},
347
348 # Enable showing size of blobs in a 'tree' view, in a separate
349 # column, similar to what 'ls -l' does. This cost a bit of IO.
350
351 # To disable system wide have in $GITWEB_CONFIG
352 # $feature{'show-sizes'}{'default'} = [0];
353 # To have project specific config enable override in $GITWEB_CONFIG
354 # $feature{'show-sizes'}{'override'} = 1;
355 # and in project config gitweb.showsizes = 0|1;
356 'show-sizes' => {
357 'sub' => sub { feature_bool('showsizes', @_) },
358 'override' => 0,
359 'default' => [1]},
360
361 # Make gitweb use an alternative format of the URLs which can be
362 # more readable and natural-looking: project name is embedded
363 # directly in the path and the query string contains other
364 # auxiliary information. All gitweb installations recognize
365 # URL in either format; this configures in which formats gitweb
366 # generates links.
367
368 # To enable system wide have in $GITWEB_CONFIG
369 # $feature{'pathinfo'}{'default'} = [1];
370 # Project specific override is not supported.
371
372 # Note that you will need to change the default location of CSS,
373 # favicon, logo and possibly other files to an absolute URL. Also,
374 # if gitweb.cgi serves as your indexfile, you will need to force
375 # $my_uri to contain the script name in your $GITWEB_CONFIG.
376 'pathinfo' => {
377 'override' => 0,
378 'default' => [0]},
379
380 # Make gitweb consider projects in project root subdirectories
381 # to be forks of existing projects. Given project $projname.git,
382 # projects matching $projname/*.git will not be shown in the main
383 # projects list, instead a '+' mark will be added to $projname
384 # there and a 'forks' view will be enabled for the project, listing
385 # all the forks. If project list is taken from a file, forks have
386 # to be listed after the main project.
387
388 # To enable system wide have in $GITWEB_CONFIG
389 # $feature{'forks'}{'default'} = [1];
390 # Project specific override is not supported.
391 'forks' => {
392 'override' => 0,
393 'default' => [0]},
394
395 # Insert custom links to the action bar of all project pages.
396 # This enables you mainly to link to third-party scripts integrating
397 # into gitweb; e.g. git-browser for graphical history representation
398 # or custom web-based repository administration interface.
399
400 # The 'default' value consists of a list of triplets in the form
401 # (label, link, position) where position is the label after which
402 # to insert the link and link is a format string where %n expands
403 # to the project name, %f to the project path within the filesystem,
404 # %h to the current hash (h gitweb parameter) and %b to the current
405 # hash base (hb gitweb parameter); %% expands to %.
406
407 # To enable system wide have in $GITWEB_CONFIG e.g.
408 # $feature{'actions'}{'default'} = [('graphiclog',
409 # '/git-browser/by-commit.html?r=%n', 'summary')];
410 # Project specific override is not supported.
411 'actions' => {
412 'override' => 0,
413 'default' => []},
414
415 # Allow gitweb scan project content tags described in ctags/
416 # of project repository, and display the popular Web 2.0-ish
417 # "tag cloud" near the project list. Note that this is something
418 # COMPLETELY different from the normal Git tags.
419
420 # gitweb by itself can show existing tags, but it does not handle
421 # tagging itself; you need an external application for that.
422 # For an example script, check Girocco's cgi/tagproj.cgi.
423 # You may want to install the HTML::TagCloud Perl module to get
424 # a pretty tag cloud instead of just a list of tags.
425
426 # To enable system wide have in $GITWEB_CONFIG
427 # $feature{'ctags'}{'default'} = ['path_to_tag_script'];
428 # Project specific override is not supported.
429 'ctags' => {
430 'override' => 0,
431 'default' => [0]},
432
433 # The maximum number of patches in a patchset generated in patch
434 # view. Set this to 0 or undef to disable patch view, or to a
435 # negative number to remove any limit.
436
437 # To disable system wide have in $GITWEB_CONFIG
438 # $feature{'patches'}{'default'} = [0];
439 # To have project specific config enable override in $GITWEB_CONFIG
440 # $feature{'patches'}{'override'} = 1;
441 # and in project config gitweb.patches = 0|n;
442 # where n is the maximum number of patches allowed in a patchset.
443 'patches' => {
444 'sub' => \&feature_patches,
445 'override' => 0,
446 'default' => [16]},
447
448 # Avatar support. When this feature is enabled, views such as
449 # shortlog or commit will display an avatar associated with
450 # the email of the committer(s) and/or author(s).
451
452 # Currently available providers are gravatar and picon.
453 # If an unknown provider is specified, the feature is disabled.
454
455 # Gravatar depends on Digest::MD5.
456 # Picon currently relies on the indiana.edu database.
457
458 # To enable system wide have in $GITWEB_CONFIG
459 # $feature{'avatar'}{'default'} = ['<provider>'];
460 # where <provider> is either gravatar or picon.
461 # To have project specific config enable override in $GITWEB_CONFIG
462 # $feature{'avatar'}{'override'} = 1;
463 # and in project config gitweb.avatar = <provider>;
464 'avatar' => {
465 'sub' => \&feature_avatar,
466 'override' => 0,
467 'default' => ['']},
468
469 # Enable displaying how much time and how many git commands
470 # it took to generate and display page. Disabled by default.
471 # Project specific override is not supported.
472 'timed' => {
473 'override' => 0,
474 'default' => [0]},
475
476 # Enable turning some links into links to actions which require
477 # JavaScript to run (like 'blame_incremental'). Not enabled by
478 # default. Project specific override is currently not supported.
479 'javascript-actions' => {
480 'override' => 0,
481 'default' => [0]},
482
483 # Syntax highlighting support. This is based on Daniel Svensson's
484 # and Sham Chukoury's work in gitweb-xmms2.git.
485 # It requires the 'highlight' program present in $PATH,
486 # and therefore is disabled by default.
487
488 # To enable system wide have in $GITWEB_CONFIG
489 # $feature{'highlight'}{'default'} = [1];
490
491 'highlight' => {
492 'sub' => sub { feature_bool('highlight', @_) },
493 'override' => 0,
494 'default' => [0]},
495
496 # Enable displaying of remote heads in the heads list
497
498 # To enable system wide have in $GITWEB_CONFIG
499 # $feature{'remote_heads'}{'default'} = [1];
500 # To have project specific config enable override in $GITWEB_CONFIG
501 # $feature{'remote_heads'}{'override'} = 1;
502 # and in project config gitweb.remote_heads = 0|1;
503 'remote_heads' => {
504 'sub' => sub { feature_bool('remote_heads', @_) },
505 'override' => 0,
506 'default' => [0]},
507 );
508
509 sub gitweb_get_feature {
510 my ($name) = @_;
511 return unless exists $feature{$name};
512 my ($sub, $override, @defaults) = (
513 $feature{$name}{'sub'},
514 $feature{$name}{'override'},
515 @{$feature{$name}{'default'}});
516 # project specific override is possible only if we have project
517 our $git_dir; # global variable, declared later
518 if (!$override || !defined $git_dir) {
519 return @defaults;
520 }
521 if (!defined $sub) {
522 warn "feature $name is not overridable";
523 return @defaults;
524 }
525 return $sub->(@defaults);
526 }
527
528 # A wrapper to check if a given feature is enabled.
529 # With this, you can say
530 #
531 # my $bool_feat = gitweb_check_feature('bool_feat');
532 # gitweb_check_feature('bool_feat') or somecode;
533 #
534 # instead of
535 #
536 # my ($bool_feat) = gitweb_get_feature('bool_feat');
537 # (gitweb_get_feature('bool_feat'))[0] or somecode;
538 #
539 sub gitweb_check_feature {
540 return (gitweb_get_feature(@_))[0];
541 }
542
543
544 sub feature_bool {
545 my $key = shift;
546 my ($val) = git_get_project_config($key, '--bool');
547
548 if (!defined $val) {
549 return ($_[0]);
550 } elsif ($val eq 'true') {
551 return (1);
552 } elsif ($val eq 'false') {
553 return (0);
554 }
555 }
556
557 sub feature_snapshot {
558 my (@fmts) = @_;
559
560 my ($val) = git_get_project_config('snapshot');
561
562 if ($val) {
563 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
564 }
565
566 return @fmts;
567 }
568
569 sub feature_patches {
570 my @val = (git_get_project_config('patches', '--int'));
571
572 if (@val) {
573 return @val;
574 }
575
576 return ($_[0]);
577 }
578
579 sub feature_avatar {
580 my @val = (git_get_project_config('avatar'));
581
582 return @val ? @val : @_;
583 }
584
585 # checking HEAD file with -e is fragile if the repository was
586 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
587 # and then pruned.
588 sub check_head_link {
589 my ($dir) = @_;
590 my $headfile = "$dir/HEAD";
591 return ((-e $headfile) ||
592 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
593 }
594
595 sub check_export_ok {
596 my ($dir) = @_;
597 return (check_head_link($dir) &&
598 (!$export_ok || -e "$dir/$export_ok") &&
599 (!$export_auth_hook || $export_auth_hook->($dir)));
600 }
601
602 # process alternate names for backward compatibility
603 # filter out unsupported (unknown) snapshot formats
604 sub filter_snapshot_fmts {
605 my @fmts = @_;
606
607 @fmts = map {
608 exists $known_snapshot_format_aliases{$_} ?
609 $known_snapshot_format_aliases{$_} : $_} @fmts;
610 @fmts = grep {
611 exists $known_snapshot_formats{$_} &&
612 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
613 }
614
615 # If it is set to code reference, it is code that it is to be run once per
616 # request, allowing updating configurations that change with each request,
617 # while running other code in config file only once.
618 #
619 # Otherwise, if it is false then gitweb would process config file only once;
620 # if it is true then gitweb config would be run for each request.
621 our $per_request_config = 1;
622
623 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM);
624 sub evaluate_gitweb_config {
625 our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
626 our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
627 # die if there are errors parsing config file
628 if (-e $GITWEB_CONFIG) {
629 do $GITWEB_CONFIG;
630 die $@ if $@;
631 } elsif (-e $GITWEB_CONFIG_SYSTEM) {
632 do $GITWEB_CONFIG_SYSTEM;
633 die $@ if $@;
634 }
635 }
636
637 # Get loadavg of system, to compare against $maxload.
638 # Currently it requires '/proc/loadavg' present to get loadavg;
639 # if it is not present it returns 0, which means no load checking.
640 sub get_loadavg {
641 if( -e '/proc/loadavg' ){
642 open my $fd, '<', '/proc/loadavg'
643 or return 0;
644 my @load = split(/\s+/, scalar <$fd>);
645 close $fd;
646
647 # The first three columns measure CPU and IO utilization of the last one,
648 # five, and 10 minute periods. The fourth column shows the number of
649 # currently running processes and the total number of processes in the m/n
650 # format. The last column displays the last process ID used.
651 return $load[0] || 0;
652 }
653 # additional checks for load average should go here for things that don't export
654 # /proc/loadavg
655
656 return 0;
657 }
658
659 # version of the core git binary
660 our $git_version;
661 sub evaluate_git_version {
662 our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
663 $number_of_git_cmds++;
664 }
665
666 sub check_loadavg {
667 if (defined $maxload && get_loadavg() > $maxload) {
668 die_error(503, "The load average on the server is too high");
669 }
670 }
671
672 # ======================================================================
673 # input validation and dispatch
674
675 # input parameters can be collected from a variety of sources (presently, CGI
676 # and PATH_INFO), so we define an %input_params hash that collects them all
677 # together during validation: this allows subsequent uses (e.g. href()) to be
678 # agnostic of the parameter origin
679
680 our %input_params = ();
681
682 # input parameters are stored with the long parameter name as key. This will
683 # also be used in the href subroutine to convert parameters to their CGI
684 # equivalent, and since the href() usage is the most frequent one, we store
685 # the name -> CGI key mapping here, instead of the reverse.
686 #
687 # XXX: Warning: If you touch this, check the search form for updating,
688 # too.
689
690 our @cgi_param_mapping = (
691 project => "p",
692 action => "a",
693 file_name => "f",
694 file_parent => "fp",
695 hash => "h",
696 hash_parent => "hp",
697 hash_base => "hb",
698 hash_parent_base => "hpb",
699 page => "pg",
700 order => "o",
701 searchtext => "s",
702 searchtype => "st",
703 snapshot_format => "sf",
704 extra_options => "opt",
705 search_use_regexp => "sr",
706 # this must be last entry (for manipulation from JavaScript)
707 javascript => "js"
708 );
709 our %cgi_param_mapping = @cgi_param_mapping;
710
711 # we will also need to know the possible actions, for validation
712 our %actions = (
713 "blame" => \&git_blame,
714 "blame_incremental" => \&git_blame_incremental,
715 "blame_data" => \&git_blame_data,
716 "blobdiff" => \&git_blobdiff,
717 "blobdiff_plain" => \&git_blobdiff_plain,
718 "blob" => \&git_blob,
719 "blob_plain" => \&git_blob_plain,
720 "commitdiff" => \&git_commitdiff,
721 "commitdiff_plain" => \&git_commitdiff_plain,
722 "commit" => \&git_commit,
723 "forks" => \&git_forks,
724 "heads" => \&git_heads,
725 "history" => \&git_history,
726 "log" => \&git_log,
727 "patch" => \&git_patch,
728 "patches" => \&git_patches,
729 "remotes" => \&git_remotes,
730 "rss" => \&git_rss,
731 "atom" => \&git_atom,
732 "search" => \&git_search,
733 "search_help" => \&git_search_help,
734 "shortlog" => \&git_shortlog,
735 "summary" => \&git_summary,
736 "tag" => \&git_tag,
737 "tags" => \&git_tags,
738 "tree" => \&git_tree,
739 "snapshot" => \&git_snapshot,
740 "object" => \&git_object,
741 # those below don't need $project
742 "opml" => \&git_opml,
743 "project_list" => \&git_project_list,
744 "project_index" => \&git_project_index,
745 );
746
747 # finally, we have the hash of allowed extra_options for the commands that
748 # allow them
749 our %allowed_options = (
750 "--no-merges" => [ qw(rss atom log shortlog history) ],
751 );
752
753 # fill %input_params with the CGI parameters. All values except for 'opt'
754 # should be single values, but opt can be an array. We should probably
755 # build an array of parameters that can be multi-valued, but since for the time
756 # being it's only this one, we just single it out
757 sub evaluate_query_params {
758 our $cgi;
759
760 while (my ($name, $symbol) = each %cgi_param_mapping) {
761 if ($symbol eq 'opt') {
762 $input_params{$name} = [ $cgi->param($symbol) ];
763 } else {
764 $input_params{$name} = $cgi->param($symbol);
765 }
766 }
767 }
768
769 # now read PATH_INFO and update the parameter list for missing parameters
770 sub evaluate_path_info {
771 return if defined $input_params{'project'};
772 return if !$path_info;
773 $path_info =~ s,^/+,,;
774 return if !$path_info;
775
776 # find which part of PATH_INFO is project
777 my $project = $path_info;
778 $project =~ s,/+$,,;
779 while ($project && !check_head_link("$projectroot/$project")) {
780 $project =~ s,/*[^/]*$,,;
781 }
782 return unless $project;
783 $input_params{'project'} = $project;
784
785 # do not change any parameters if an action is given using the query string
786 return if $input_params{'action'};
787 $path_info =~ s,^\Q$project\E/*,,;
788
789 # next, check if we have an action
790 my $action = $path_info;
791 $action =~ s,/.*$,,;
792 if (exists $actions{$action}) {
793 $path_info =~ s,^$action/*,,;
794 $input_params{'action'} = $action;
795 }
796
797 # list of actions that want hash_base instead of hash, but can have no
798 # pathname (f) parameter
799 my @wants_base = (
800 'tree',
801 'history',
802 );
803
804 # we want to catch, among others
805 # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
806 my ($parentrefname, $parentpathname, $refname, $pathname) =
807 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
808
809 # first, analyze the 'current' part
810 if (defined $pathname) {
811 # we got "branch:filename" or "branch:dir/"
812 # we could use git_get_type(branch:pathname), but:
813 # - it needs $git_dir
814 # - it does a git() call
815 # - the convention of terminating directories with a slash
816 # makes it superfluous
817 # - embedding the action in the PATH_INFO would make it even
818 # more superfluous
819 $pathname =~ s,^/+,,;
820 if (!$pathname || substr($pathname, -1) eq "/") {
821 $input_params{'action'} ||= "tree";
822 $pathname =~ s,/$,,;
823 } else {
824 # the default action depends on whether we had parent info
825 # or not
826 if ($parentrefname) {
827 $input_params{'action'} ||= "blobdiff_plain";
828 } else {
829 $input_params{'action'} ||= "blob_plain";
830 }
831 }
832 $input_params{'hash_base'} ||= $refname;
833 $input_params{'file_name'} ||= $pathname;
834 } elsif (defined $refname) {
835 # we got "branch". In this case we have to choose if we have to
836 # set hash or hash_base.
837 #
838 # Most of the actions without a pathname only want hash to be
839 # set, except for the ones specified in @wants_base that want
840 # hash_base instead. It should also be noted that hand-crafted
841 # links having 'history' as an action and no pathname or hash
842 # set will fail, but that happens regardless of PATH_INFO.
843 if (defined $parentrefname) {
844 # if there is parent let the default be 'shortlog' action
845 # (for http://git.example.com/repo.git/A..B links); if there
846 # is no parent, dispatch will detect type of object and set
847 # action appropriately if required (if action is not set)
848 $input_params{'action'} ||= "shortlog";
849 }
850 if ($input_params{'action'} &&
851 grep { $_ eq $input_params{'action'} } @wants_base) {
852 $input_params{'hash_base'} ||= $refname;
853 } else {
854 $input_params{'hash'} ||= $refname;
855 }
856 }
857
858 # next, handle the 'parent' part, if present
859 if (defined $parentrefname) {
860 # a missing pathspec defaults to the 'current' filename, allowing e.g.
861 # someproject/blobdiff/oldrev..newrev:/filename
862 if ($parentpathname) {
863 $parentpathname =~ s,^/+,,;
864 $parentpathname =~ s,/$,,;
865 $input_params{'file_parent'} ||= $parentpathname;
866 } else {
867 $input_params{'file_parent'} ||= $input_params{'file_name'};
868 }
869 # we assume that hash_parent_base is wanted if a path was specified,
870 # or if the action wants hash_base instead of hash
871 if (defined $input_params{'file_parent'} ||
872 grep { $_ eq $input_params{'action'} } @wants_base) {
873 $input_params{'hash_parent_base'} ||= $parentrefname;
874 } else {
875 $input_params{'hash_parent'} ||= $parentrefname;
876 }
877 }
878
879 # for the snapshot action, we allow URLs in the form
880 # $project/snapshot/$hash.ext
881 # where .ext determines the snapshot and gets removed from the
882 # passed $refname to provide the $hash.
883 #
884 # To be able to tell that $refname includes the format extension, we
885 # require the following two conditions to be satisfied:
886 # - the hash input parameter MUST have been set from the $refname part
887 # of the URL (i.e. they must be equal)
888 # - the snapshot format MUST NOT have been defined already (e.g. from
889 # CGI parameter sf)
890 # It's also useless to try any matching unless $refname has a dot,
891 # so we check for that too
892 if (defined $input_params{'action'} &&
893 $input_params{'action'} eq 'snapshot' &&
894 defined $refname && index($refname, '.') != -1 &&
895 $refname eq $input_params{'hash'} &&
896 !defined $input_params{'snapshot_format'}) {
897 # We loop over the known snapshot formats, checking for
898 # extensions. Allowed extensions are both the defined suffix
899 # (which includes the initial dot already) and the snapshot
900 # format key itself, with a prepended dot
901 while (my ($fmt, $opt) = each %known_snapshot_formats) {
902 my $hash = $refname;
903 unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
904 next;
905 }
906 my $sfx = $1;
907 # a valid suffix was found, so set the snapshot format
908 # and reset the hash parameter
909 $input_params{'snapshot_format'} = $fmt;
910 $input_params{'hash'} = $hash;
911 # we also set the format suffix to the one requested
912 # in the URL: this way a request for e.g. .tgz returns
913 # a .tgz instead of a .tar.gz
914 $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
915 last;
916 }
917 }
918 }
919
920 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
921 $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
922 $searchtext, $search_regexp);
923 sub evaluate_and_validate_params {
924 our $action = $input_params{'action'};
925 if (defined $action) {
926 if (!validate_action($action)) {
927 die_error(400, "Invalid action parameter");
928 }
929 }
930
931 # parameters which are pathnames
932 our $project = $input_params{'project'};
933 if (defined $project) {
934 if (!validate_project($project)) {
935 undef $project;
936 die_error(404, "No such project");
937 }
938 }
939
940 our $file_name = $input_params{'file_name'};
941 if (defined $file_name) {
942 if (!validate_pathname($file_name)) {
943 die_error(400, "Invalid file parameter");
944 }
945 }
946
947 our $file_parent = $input_params{'file_parent'};
948 if (defined $file_parent) {
949 if (!validate_pathname($file_parent)) {
950 die_error(400, "Invalid file parent parameter");
951 }
952 }
953
954 # parameters which are refnames
955 our $hash = $input_params{'hash'};
956 if (defined $hash) {
957 if (!validate_refname($hash)) {
958 die_error(400, "Invalid hash parameter");
959 }
960 }
961
962 our $hash_parent = $input_params{'hash_parent'};
963 if (defined $hash_parent) {
964 if (!validate_refname($hash_parent)) {
965 die_error(400, "Invalid hash parent parameter");
966 }
967 }
968
969 our $hash_base = $input_params{'hash_base'};
970 if (defined $hash_base) {
971 if (!validate_refname($hash_base)) {
972 die_error(400, "Invalid hash base parameter");
973 }
974 }
975
976 our @extra_options = @{$input_params{'extra_options'}};
977 # @extra_options is always defined, since it can only be (currently) set from
978 # CGI, and $cgi->param() returns the empty array in array context if the param
979 # is not set
980 foreach my $opt (@extra_options) {
981 if (not exists $allowed_options{$opt}) {
982 die_error(400, "Invalid option parameter");
983 }
984 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
985 die_error(400, "Invalid option parameter for this action");
986 }
987 }
988
989 our $hash_parent_base = $input_params{'hash_parent_base'};
990 if (defined $hash_parent_base) {
991 if (!validate_refname($hash_parent_base)) {
992 die_error(400, "Invalid hash parent base parameter");
993 }
994 }
995
996 # other parameters
997 our $page = $input_params{'page'};
998 if (defined $page) {
999 if ($page =~ m/[^0-9]/) {
1000 die_error(400, "Invalid page parameter");
1001 }
1002 }
1003
1004 our $searchtype = $input_params{'searchtype'};
1005 if (defined $searchtype) {
1006 if ($searchtype =~ m/[^a-z]/) {
1007 die_error(400, "Invalid searchtype parameter");
1008 }
1009 }
1010
1011 our $search_use_regexp = $input_params{'search_use_regexp'};
1012
1013 our $searchtext = $input_params{'searchtext'};
1014 our $search_regexp;
1015 if (defined $searchtext) {
1016 if (length($searchtext) < 2) {
1017 die_error(403, "At least two characters are required for search parameter");
1018 }
1019 $search_regexp = $search_use_regexp ? $searchtext : quotemeta $searchtext;
1020 }
1021 }
1022
1023 # path to the current git repository
1024 our $git_dir;
1025 sub evaluate_git_dir {
1026 our $git_dir = "$projectroot/$project" if $project;
1027 }
1028
1029 our (@snapshot_fmts, $git_avatar);
1030 sub configure_gitweb_features {
1031 # list of supported snapshot formats
1032 our @snapshot_fmts = gitweb_get_feature('snapshot');
1033 @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1034
1035 # check that the avatar feature is set to a known provider name,
1036 # and for each provider check if the dependencies are satisfied.
1037 # if the provider name is invalid or the dependencies are not met,
1038 # reset $git_avatar to the empty string.
1039 our ($git_avatar) = gitweb_get_feature('avatar');
1040 if ($git_avatar eq 'gravatar') {
1041 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1042 } elsif ($git_avatar eq 'picon') {
1043 # no dependencies
1044 } else {
1045 $git_avatar = '';
1046 }
1047 }
1048
1049 # custom error handler: 'die <message>' is Internal Server Error
1050 sub handle_errors_html {
1051 my $msg = shift; # it is already HTML escaped
1052
1053 # to avoid infinite loop where error occurs in die_error,
1054 # change handler to default handler, disabling handle_errors_html
1055 set_message("Error occured when inside die_error:\n$msg");
1056
1057 # you cannot jump out of die_error when called as error handler;
1058 # the subroutine set via CGI::Carp::set_message is called _after_
1059 # HTTP headers are already written, so it cannot write them itself
1060 die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1061 }
1062 set_message(\&handle_errors_html);
1063
1064 # dispatch
1065 sub dispatch {
1066 if (!defined $action) {
1067 if (defined $hash) {
1068 $action = git_get_type($hash);
1069 } elsif (defined $hash_base && defined $file_name) {
1070 $action = git_get_type("$hash_base:$file_name");
1071 } elsif (defined $project) {
1072 $action = 'summary';
1073 } else {
1074 $action = 'project_list';
1075 }
1076 }
1077 if (!defined($actions{$action})) {
1078 die_error(400, "Unknown action");
1079 }
1080 if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1081 !$project) {
1082 die_error(400, "Project needed");
1083 }
1084 $actions{$action}->();
1085 }
1086
1087 sub reset_timer {
1088 our $t0 = [ gettimeofday() ]
1089 if defined $t0;
1090 our $number_of_git_cmds = 0;
1091 }
1092
1093 our $first_request = 1;
1094 sub run_request {
1095 reset_timer();
1096
1097 evaluate_uri();
1098 if ($first_request) {
1099 evaluate_gitweb_config();
1100 evaluate_git_version();
1101 }
1102 if ($per_request_config) {
1103 if (ref($per_request_config) eq 'CODE') {
1104 $per_request_config->();
1105 } elsif (!$first_request) {
1106 evaluate_gitweb_config();
1107 }
1108 }
1109 check_loadavg();
1110
1111 # $projectroot and $projects_list might be set in gitweb config file
1112 $projects_list ||= $projectroot;
1113
1114 evaluate_query_params();
1115 evaluate_path_info();
1116 evaluate_and_validate_params();
1117 evaluate_git_dir();
1118
1119 configure_gitweb_features();
1120
1121 dispatch();
1122 }
1123
1124 our $is_last_request = sub { 1 };
1125 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1126 our $CGI = 'CGI';
1127 our $cgi;
1128 sub configure_as_fcgi {
1129 require CGI::Fast;
1130 our $CGI = 'CGI::Fast';
1131
1132 my $request_number = 0;
1133 # let each child service 100 requests
1134 our $is_last_request = sub { ++$request_number > 100 };
1135 }
1136 sub evaluate_argv {
1137 my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1138 configure_as_fcgi()
1139 if $script_name =~ /\.fcgi$/;
1140
1141 return unless (@ARGV);
1142
1143 require Getopt::Long;
1144 Getopt::Long::GetOptions(
1145 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1146 'nproc|n=i' => sub {
1147 my ($arg, $val) = @_;
1148 return unless eval { require FCGI::ProcManager; 1; };
1149 my $proc_manager = FCGI::ProcManager->new({
1150 n_processes => $val,
1151 });
1152 our $pre_listen_hook = sub { $proc_manager->pm_manage() };
1153 our $pre_dispatch_hook = sub { $proc_manager->pm_pre_dispatch() };
1154 our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1155 },
1156 );
1157 }
1158
1159 sub run {
1160 evaluate_argv();
1161
1162 $first_request = 1;
1163 $pre_listen_hook->()
1164 if $pre_listen_hook;
1165
1166 REQUEST:
1167 while ($cgi = $CGI->new()) {
1168 $pre_dispatch_hook->()
1169 if $pre_dispatch_hook;
1170
1171 run_request();
1172
1173 $post_dispatch_hook->()
1174 if $post_dispatch_hook;
1175 $first_request = 0;
1176
1177 last REQUEST if ($is_last_request->());
1178 }
1179
1180 DONE_GITWEB:
1181 1;
1182 }
1183
1184 run();
1185
1186 if (defined caller) {
1187 # wrapped in a subroutine processing requests,
1188 # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1189 return;
1190 } else {
1191 # pure CGI script, serving single request
1192 exit;
1193 }
1194
1195 ## ======================================================================
1196 ## action links
1197
1198 # possible values of extra options
1199 # -full => 0|1 - use absolute/full URL ($my_uri/$my_url as base)
1200 # -replay => 1 - start from a current view (replay with modifications)
1201 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1202 sub href {
1203 my %params = @_;
1204 # default is to use -absolute url() i.e. $my_uri
1205 my $href = $params{-full} ? $my_url : $my_uri;
1206
1207 $params{'project'} = $project unless exists $params{'project'};
1208
1209 if ($params{-replay}) {
1210 while (my ($name, $symbol) = each %cgi_param_mapping) {
1211 if (!exists $params{$name}) {
1212 $params{$name} = $input_params{$name};
1213 }
1214 }
1215 }
1216
1217 my $use_pathinfo = gitweb_check_feature('pathinfo');
1218 if (defined $params{'project'} &&
1219 (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1220 # try to put as many parameters as possible in PATH_INFO:
1221 # - project name
1222 # - action
1223 # - hash_parent or hash_parent_base:/file_parent
1224 # - hash or hash_base:/filename
1225 # - the snapshot_format as an appropriate suffix
1226
1227 # When the script is the root DirectoryIndex for the domain,
1228 # $href here would be something like http://gitweb.example.com/
1229 # Thus, we strip any trailing / from $href, to spare us double
1230 # slashes in the final URL
1231 $href =~ s,/$,,;
1232
1233 # Then add the project name, if present
1234 $href .= "/".esc_path_info($params{'project'});
1235 delete $params{'project'};
1236
1237 # since we destructively absorb parameters, we keep this
1238 # boolean that remembers if we're handling a snapshot
1239 my $is_snapshot = $params{'action'} eq 'snapshot';
1240
1241 # Summary just uses the project path URL, any other action is
1242 # added to the URL
1243 if (defined $params{'action'}) {
1244 $href .= "/".esc_path_info($params{'action'})
1245 unless $params{'action'} eq 'summary';
1246 delete $params{'action'};
1247 }
1248
1249 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1250 # stripping nonexistent or useless pieces
1251 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1252 || $params{'hash_parent'} || $params{'hash'});
1253 if (defined $params{'hash_base'}) {
1254 if (defined $params{'hash_parent_base'}) {
1255 $href .= esc_path_info($params{'hash_parent_base'});
1256 # skip the file_parent if it's the same as the file_name
1257 if (defined $params{'file_parent'}) {
1258 if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1259 delete $params{'file_parent'};
1260 } elsif ($params{'file_parent'} !~ /\.\./) {
1261 $href .= ":/".esc_path_info($params{'file_parent'});
1262 delete $params{'file_parent'};
1263 }
1264 }
1265 $href .= "..";
1266 delete $params{'hash_parent'};
1267 delete $params{'hash_parent_base'};
1268 } elsif (defined $params{'hash_parent'}) {
1269 $href .= esc_path_info($params{'hash_parent'}). "..";
1270 delete $params{'hash_parent'};
1271 }
1272
1273 $href .= esc_path_info($params{'hash_base'});
1274 if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1275 $href .= ":/".esc_path_info($params{'file_name'});
1276 delete $params{'file_name'};
1277 }
1278 delete $params{'hash'};
1279 delete $params{'hash_base'};
1280 } elsif (defined $params{'hash'}) {
1281 $href .= esc_path_info($params{'hash'});
1282 delete $params{'hash'};
1283 }
1284
1285 # If the action was a snapshot, we can absorb the
1286 # snapshot_format parameter too
1287 if ($is_snapshot) {
1288 my $fmt = $params{'snapshot_format'};
1289 # snapshot_format should always be defined when href()
1290 # is called, but just in case some code forgets, we
1291 # fall back to the default
1292 $fmt ||= $snapshot_fmts[0];
1293 $href .= $known_snapshot_formats{$fmt}{'suffix'};
1294 delete $params{'snapshot_format'};
1295 }
1296 }
1297
1298 # now encode the parameters explicitly
1299 my @result = ();
1300 for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1301 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1302 if (defined $params{$name}) {
1303 if (ref($params{$name}) eq "ARRAY") {
1304 foreach my $par (@{$params{$name}}) {
1305 push @result, $symbol . "=" . esc_param($par);
1306 }
1307 } else {
1308 push @result, $symbol . "=" . esc_param($params{$name});
1309 }
1310 }
1311 }
1312 $href .= "?" . join(';', @result) if scalar @result;
1313
1314 # final transformation: trailing spaces must be escaped (URI-encoded)
1315 $href =~ s/(\s+)$/CGI::escape($1)/e;
1316
1317 return $href;
1318 }
1319
1320
1321 ## ======================================================================
1322 ## validation, quoting/unquoting and escaping
1323
1324 sub validate_action {
1325 my $input = shift || return undef;
1326 return undef unless exists $actions{$input};
1327 return $input;
1328 }
1329
1330 sub validate_project {
1331 my $input = shift || return undef;
1332 if (!validate_pathname($input) ||
1333 !(-d "$projectroot/$input") ||
1334 !check_export_ok("$projectroot/$input") ||
1335 ($strict_export && !project_in_list($input))) {
1336 return undef;
1337 } else {
1338 return $input;
1339 }
1340 }
1341
1342 sub validate_pathname {
1343 my $input = shift || return undef;
1344
1345 # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1346 # at the beginning, at the end, and between slashes.
1347 # also this catches doubled slashes
1348 if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1349 return undef;
1350 }
1351 # no null characters
1352 if ($input =~ m!\0!) {
1353 return undef;
1354 }
1355 return $input;
1356 }
1357
1358 sub validate_refname {
1359 my $input = shift || return undef;
1360
1361 # textual hashes are O.K.
1362 if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1363 return $input;
1364 }
1365 # it must be correct pathname
1366 $input = validate_pathname($input)
1367 or return undef;
1368 # restrictions on ref name according to git-check-ref-format
1369 if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1370 return undef;
1371 }
1372 return $input;
1373 }
1374
1375 # decode sequences of octets in utf8 into Perl's internal form,
1376 # which is utf-8 with utf8 flag set if needed. gitweb writes out
1377 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1378 sub to_utf8 {
1379 my $str = shift;
1380 return undef unless defined $str;
1381 if (utf8::valid($str)) {
1382 utf8::decode($str);
1383 return $str;
1384 } else {
1385 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1386 }
1387 }
1388
1389 # quote unsafe chars, but keep the slash, even when it's not
1390 # correct, but quoted slashes look too horrible in bookmarks
1391 sub esc_param {
1392 my $str = shift;
1393 return undef unless defined $str;
1394 $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1395 $str =~ s/ /\+/g;
1396 return $str;
1397 }
1398
1399 # the quoting rules for path_info fragment are slightly different
1400 sub esc_path_info {
1401 my $str = shift;
1402 return undef unless defined $str;
1403
1404 # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1405 $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1406
1407 return $str;
1408 }
1409
1410 # quote unsafe chars in whole URL, so some characters cannot be quoted
1411 sub esc_url {
1412 my $str = shift;
1413 return undef unless defined $str;
1414 $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1415 $str =~ s/ /\+/g;
1416 return $str;
1417 }
1418
1419 # quote unsafe characters in HTML attributes
1420 sub esc_attr {
1421
1422 # for XHTML conformance escaping '"' to '&quot;' is not enough
1423 return esc_html(@_);
1424 }
1425
1426 # replace invalid utf8 character with SUBSTITUTION sequence
1427 sub esc_html {
1428 my $str = shift;
1429 my %opts = @_;
1430
1431 return undef unless defined $str;
1432
1433 $str = to_utf8($str);
1434 $str = $cgi->escapeHTML($str);
1435 if ($opts{'-nbsp'}) {
1436 $str =~ s/ /&nbsp;/g;
1437 }
1438 $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1439 return $str;
1440 }
1441
1442 # quote control characters and escape filename to HTML
1443 sub esc_path {
1444 my $str = shift;
1445 my %opts = @_;
1446
1447 return undef unless defined $str;
1448
1449 $str = to_utf8($str);
1450 $str = $cgi->escapeHTML($str);
1451 if ($opts{'-nbsp'}) {
1452 $str =~ s/ /&nbsp;/g;
1453 }
1454 $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1455 return $str;
1456 }
1457
1458 # Make control characters "printable", using character escape codes (CEC)
1459 sub quot_cec {
1460 my $cntrl = shift;
1461 my %opts = @_;
1462 my %es = ( # character escape codes, aka escape sequences
1463 "\t" => '\t', # tab (HT)
1464 "\n" => '\n', # line feed (LF)
1465 "\r" => '\r', # carrige return (CR)
1466 "\f" => '\f', # form feed (FF)
1467 "\b" => '\b', # backspace (BS)
1468 "\a" => '\a', # alarm (bell) (BEL)
1469 "\e" => '\e', # escape (ESC)
1470 "\013" => '\v', # vertical tab (VT)
1471 "\000" => '\0', # nul character (NUL)
1472 );
1473 my $chr = ( (exists $es{$cntrl})
1474 ? $es{$cntrl}
1475 : sprintf('\%2x', ord($cntrl)) );
1476 if ($opts{-nohtml}) {
1477 return $chr;
1478 } else {
1479 return "<span class=\"cntrl\">$chr</span>";
1480 }
1481 }
1482
1483 # Alternatively use unicode control pictures codepoints,
1484 # Unicode "printable representation" (PR)
1485 sub quot_upr {
1486 my $cntrl = shift;
1487 my %opts = @_;
1488
1489 my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1490 if ($opts{-nohtml}) {
1491 return $chr;
1492 } else {
1493 return "<span class=\"cntrl\">$chr</span>";
1494 }
1495 }
1496
1497 # git may return quoted and escaped filenames
1498 sub unquote {
1499 my $str = shift;
1500
1501 sub unq {
1502 my $seq = shift;
1503 my %es = ( # character escape codes, aka escape sequences
1504 't' => "\t", # tab (HT, TAB)
1505 'n' => "\n", # newline (NL)
1506 'r' => "\r", # return (CR)
1507 'f' => "\f", # form feed (FF)
1508 'b' => "\b", # backspace (BS)
1509 'a' => "\a", # alarm (bell) (BEL)
1510 'e' => "\e", # escape (ESC)
1511 'v' => "\013", # vertical tab (VT)
1512 );
1513
1514 if ($seq =~ m/^[0-7]{1,3}$/) {
1515 # octal char sequence
1516 return chr(oct($seq));
1517 } elsif (exists $es{$seq}) {
1518 # C escape sequence, aka character escape code
1519 return $es{$seq};
1520 }
1521 # quoted ordinary character
1522 return $seq;
1523 }
1524
1525 if ($str =~ m/^"(.*)"$/) {
1526 # needs unquoting
1527 $str = $1;
1528 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1529 }
1530 return $str;
1531 }
1532
1533 # escape tabs (convert tabs to spaces)
1534 sub untabify {
1535 my $line = shift;
1536
1537 while ((my $pos = index($line, "\t")) != -1) {
1538 if (my $count = (8 - ($pos % 8))) {
1539 my $spaces = ' ' x $count;
1540 $line =~ s/\t/$spaces/;
1541 }
1542 }
1543
1544 return $line;
1545 }
1546
1547 sub project_in_list {
1548 my $project = shift;
1549 my @list = git_get_projects_list();
1550 return @list && scalar(grep { $_->{'path'} eq $project } @list);
1551 }
1552
1553 ## ----------------------------------------------------------------------
1554 ## HTML aware string manipulation
1555
1556 # Try to chop given string on a word boundary between position
1557 # $len and $len+$add_len. If there is no word boundary there,
1558 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1559 # (marking chopped part) would be longer than given string.
1560 sub chop_str {
1561 my $str = shift;
1562 my $len = shift;
1563 my $add_len = shift || 10;
1564 my $where = shift || 'right'; # 'left' | 'center' | 'right'
1565
1566 # Make sure perl knows it is utf8 encoded so we don't
1567 # cut in the middle of a utf8 multibyte char.
1568 $str = to_utf8($str);
1569
1570 # allow only $len chars, but don't cut a word if it would fit in $add_len
1571 # if it doesn't fit, cut it if it's still longer than the dots we would add
1572 # remove chopped character entities entirely
1573
1574 # when chopping in the middle, distribute $len into left and right part
1575 # return early if chopping wouldn't make string shorter
1576 if ($where eq 'center') {
1577 return $str if ($len + 5 >= length($str)); # filler is length 5
1578 $len = int($len/2);
1579 } else {
1580 return $str if ($len + 4 >= length($str)); # filler is length 4
1581 }
1582
1583 # regexps: ending and beginning with word part up to $add_len
1584 my $endre = qr/.{$len}\w{0,$add_len}/;
1585 my $begre = qr/\w{0,$add_len}.{$len}/;
1586
1587 if ($where eq 'left') {
1588 $str =~ m/^(.*?)($begre)$/;
1589 my ($lead, $body) = ($1, $2);
1590 if (length($lead) > 4) {
1591 $lead = " ...";
1592 }
1593 return "$lead$body";
1594
1595 } elsif ($where eq 'center') {
1596 $str =~ m/^($endre)(.*)$/;
1597 my ($left, $str) = ($1, $2);
1598 $str =~ m/^(.*?)($begre)$/;
1599 my ($mid, $right) = ($1, $2);
1600 if (length($mid) > 5) {
1601 $mid = " ... ";
1602 }
1603 return "$left$mid$right";
1604
1605 } else {
1606 $str =~ m/^($endre)(.*)$/;
1607 my $body = $1;
1608 my $tail = $2;
1609 if (length($tail) > 4) {
1610 $tail = "... ";
1611 }
1612 return "$body$tail";
1613 }
1614 }
1615
1616 # takes the same arguments as chop_str, but also wraps a <span> around the
1617 # result with a title attribute if it does get chopped. Additionally, the
1618 # string is HTML-escaped.
1619 sub chop_and_escape_str {
1620 my ($str) = @_;
1621
1622 my $chopped = chop_str(@_);
1623 if ($chopped eq $str) {
1624 return esc_html($chopped);
1625 } else {
1626 $str =~ s/[[:cntrl:]]/?/g;
1627 return $cgi->span({-title=>$str}, esc_html($chopped));
1628 }
1629 }
1630
1631 ## ----------------------------------------------------------------------
1632 ## functions returning short strings
1633
1634 # CSS class for given age value (in seconds)
1635 sub age_class {
1636 my $age = shift;
1637
1638 if (!defined $age) {
1639 return "noage";
1640 } elsif ($age < 60*60*2) {
1641 return "age0";
1642 } elsif ($age < 60*60*24*2) {
1643 return "age1";
1644 } else {
1645 return "age2";
1646 }
1647 }
1648
1649 # convert age in seconds to "nn units ago" string
1650 sub age_string {
1651 my $age = shift;
1652 my $age_str;
1653
1654 if ($age > 60*60*24*365*2) {
1655 $age_str = (int $age/60/60/24/365);
1656 $age_str .= " years ago";
1657 } elsif ($age > 60*60*24*(365/12)*2) {
1658 $age_str = int $age/60/60/24/(365/12);
1659 $age_str .= " months ago";
1660 } elsif ($age > 60*60*24*7*2) {
1661 $age_str = int $age/60/60/24/7;
1662 $age_str .= " weeks ago";
1663 } elsif ($age > 60*60*24*2) {
1664 $age_str = int $age/60/60/24;
1665 $age_str .= " days ago";
1666 } elsif ($age > 60*60*2) {
1667 $age_str = int $age/60/60;
1668 $age_str .= " hours ago";
1669 } elsif ($age > 60*2) {
1670 $age_str = int $age/60;
1671 $age_str .= " min ago";
1672 } elsif ($age > 2) {
1673 $age_str = int $age;
1674 $age_str .= " sec ago";
1675 } else {
1676 $age_str .= " right now";
1677 }
1678 return $age_str;
1679 }
1680
1681 use constant {
1682 S_IFINVALID => 0030000,
1683 S_IFGITLINK => 0160000,
1684 };
1685
1686 # submodule/subproject, a commit object reference
1687 sub S_ISGITLINK {
1688 my $mode = shift;
1689
1690 return (($mode & S_IFMT) == S_IFGITLINK)
1691 }
1692
1693 # convert file mode in octal to symbolic file mode string
1694 sub mode_str {
1695 my $mode = oct shift;
1696
1697 if (S_ISGITLINK($mode)) {
1698 return 'm---------';
1699 } elsif (S_ISDIR($mode & S_IFMT)) {
1700 return 'drwxr-xr-x';
1701 } elsif (S_ISLNK($mode)) {
1702 return 'lrwxrwxrwx';
1703 } elsif (S_ISREG($mode)) {
1704 # git cares only about the executable bit
1705 if ($mode & S_IXUSR) {
1706 return '-rwxr-xr-x';
1707 } else {
1708 return '-rw-r--r--';
1709 };
1710 } else {
1711 return '----------';
1712 }
1713 }
1714
1715 # convert file mode in octal to file type string
1716 sub file_type {
1717 my $mode = shift;
1718
1719 if ($mode !~ m/^[0-7]+$/) {
1720 return $mode;
1721 } else {
1722 $mode = oct $mode;
1723 }
1724
1725 if (S_ISGITLINK($mode)) {
1726 return "submodule";
1727 } elsif (S_ISDIR($mode & S_IFMT)) {
1728 return "directory";
1729 } elsif (S_ISLNK($mode)) {
1730 return "symlink";
1731 } elsif (S_ISREG($mode)) {
1732 return "file";
1733 } else {
1734 return "unknown";
1735 }
1736 }
1737
1738 # convert file mode in octal to file type description string
1739 sub file_type_long {
1740 my $mode = shift;
1741
1742 if ($mode !~ m/^[0-7]+$/) {
1743 return $mode;
1744 } else {
1745 $mode = oct $mode;
1746 }
1747
1748 if (S_ISGITLINK($mode)) {
1749 return "submodule";
1750 } elsif (S_ISDIR($mode & S_IFMT)) {
1751 return "directory";
1752 } elsif (S_ISLNK($mode)) {
1753 return "symlink";
1754 } elsif (S_ISREG($mode)) {
1755 if ($mode & S_IXUSR) {
1756 return "executable";
1757 } else {
1758 return "file";
1759 };
1760 } else {
1761 return "unknown";
1762 }
1763 }
1764
1765
1766 ## ----------------------------------------------------------------------
1767 ## functions returning short HTML fragments, or transforming HTML fragments
1768 ## which don't belong to other sections
1769
1770 # format line of commit message.
1771 sub format_log_line_html {
1772 my $line = shift;
1773
1774 $line = esc_html($line, -nbsp=>1);
1775 $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1776 $cgi->a({-href => href(action=>"object", hash=>$1),
1777 -class => "text"}, $1);
1778 }eg;
1779
1780 return $line;
1781 }
1782
1783 # format marker of refs pointing to given object
1784
1785 # the destination action is chosen based on object type and current context:
1786 # - for annotated tags, we choose the tag view unless it's the current view
1787 # already, in which case we go to shortlog view
1788 # - for other refs, we keep the current view if we're in history, shortlog or
1789 # log view, and select shortlog otherwise
1790 sub format_ref_marker {
1791 my ($refs, $id) = @_;
1792 my $markers = '';
1793
1794 if (defined $refs->{$id}) {
1795 foreach my $ref (@{$refs->{$id}}) {
1796 # this code exploits the fact that non-lightweight tags are the
1797 # only indirect objects, and that they are the only objects for which
1798 # we want to use tag instead of shortlog as action
1799 my ($type, $name) = qw();
1800 my $indirect = ($ref =~ s/\^\{\}$//);
1801 # e.g. tags/v2.6.11 or heads/next
1802 if ($ref =~ m!^(.*?)s?/(.*)$!) {
1803 $type = $1;
1804 $name = $2;
1805 } else {
1806 $type = "ref";
1807 $name = $ref;
1808 }
1809
1810 my $class = $type;
1811 $class .= " indirect" if $indirect;
1812
1813 my $dest_action = "shortlog";
1814
1815 if ($indirect) {
1816 $dest_action = "tag" unless $action eq "tag";
1817 } elsif ($action =~ /^(history|(short)?log)$/) {
1818 $dest_action = $action;
1819 }
1820
1821 my $dest = "";
1822 $dest .= "refs/" unless $ref =~ m!^refs/!;
1823 $dest .= $ref;
1824
1825 my $link = $cgi->a({
1826 -href => href(
1827 action=>$dest_action,
1828 hash=>$dest
1829 )}, $name);
1830
1831 $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
1832 $link . "</span>";
1833 }
1834 }
1835
1836 if ($markers) {
1837 return ' <span class="refs">'. $markers . '</span>';
1838 } else {
1839 return "";
1840 }
1841 }
1842
1843 # format, perhaps shortened and with markers, title line
1844 sub format_subject_html {
1845 my ($long, $short, $href, $extra) = @_;
1846 $extra = '' unless defined($extra);
1847
1848 if (length($short) < length($long)) {
1849 $long =~ s/[[:cntrl:]]/?/g;
1850 return $cgi->a({-href => $href, -class => "list subject",
1851 -title => to_utf8($long)},
1852 esc_html($short)) . $extra;
1853 } else {
1854 return $cgi->a({-href => $href, -class => "list subject"},
1855 esc_html($long)) . $extra;
1856 }
1857 }
1858
1859 # Rather than recomputing the url for an email multiple times, we cache it
1860 # after the first hit. This gives a visible benefit in views where the avatar
1861 # for the same email is used repeatedly (e.g. shortlog).
1862 # The cache is shared by all avatar engines (currently gravatar only), which
1863 # are free to use it as preferred. Since only one avatar engine is used for any
1864 # given page, there's no risk for cache conflicts.
1865 our %avatar_cache = ();
1866
1867 # Compute the picon url for a given email, by using the picon search service over at
1868 # http://www.cs.indiana.edu/picons/search.html
1869 sub picon_url {
1870 my $email = lc shift;
1871 if (!$avatar_cache{$email}) {
1872 my ($user, $domain) = split('@', $email);
1873 $avatar_cache{$email} =
1874 "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
1875 "$domain/$user/" .
1876 "users+domains+unknown/up/single";
1877 }
1878 return $avatar_cache{$email};
1879 }
1880
1881 # Compute the gravatar url for a given email, if it's not in the cache already.
1882 # Gravatar stores only the part of the URL before the size, since that's the
1883 # one computationally more expensive. This also allows reuse of the cache for
1884 # different sizes (for this particular engine).
1885 sub gravatar_url {
1886 my $email = lc shift;
1887 my $size = shift;
1888 $avatar_cache{$email} ||=
1889 "http://www.gravatar.com/avatar/" .
1890 Digest::MD5::md5_hex($email) . "?s=";
1891 return $avatar_cache{$email} . $size;
1892 }
1893
1894 # Insert an avatar for the given $email at the given $size if the feature
1895 # is enabled.
1896 sub git_get_avatar {
1897 my ($email, %opts) = @_;
1898 my $pre_white = ($opts{-pad_before} ? "&nbsp;" : "");
1899 my $post_white = ($opts{-pad_after} ? "&nbsp;" : "");
1900 $opts{-size} ||= 'default';
1901 my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
1902 my $url = "";
1903 if ($git_avatar eq 'gravatar') {
1904 $url = gravatar_url($email, $size);
1905 } elsif ($git_avatar eq 'picon') {
1906 $url = picon_url($email);
1907 }
1908 # Other providers can be added by extending the if chain, defining $url
1909 # as needed. If no variant puts something in $url, we assume avatars
1910 # are completely disabled/unavailable.
1911 if ($url) {
1912 return $pre_white .
1913 "<img width=\"$size\" " .
1914 "class=\"avatar\" " .
1915 "src=\"".esc_url($url)."\" " .
1916 "alt=\"\" " .
1917 "/>" . $post_white;
1918 } else {
1919 return "";
1920 }
1921 }
1922
1923 sub format_search_author {
1924 my ($author, $searchtype, $displaytext) = @_;
1925 my $have_search = gitweb_check_feature('search');
1926
1927 if ($have_search) {
1928 my $performed = "";
1929 if ($searchtype eq 'author') {
1930 $performed = "authored";
1931 } elsif ($searchtype eq 'committer') {
1932 $performed = "committed";
1933 }
1934
1935 return $cgi->a({-href => href(action=>"search", hash=>$hash,
1936 searchtext=>$author,
1937 searchtype=>$searchtype), class=>"list",
1938 title=>"Search for commits $performed by $author"},
1939 $displaytext);
1940
1941 } else {
1942 return $displaytext;
1943 }
1944 }
1945
1946 # format the author name of the given commit with the given tag
1947 # the author name is chopped and escaped according to the other
1948 # optional parameters (see chop_str).
1949 sub format_author_html {
1950 my $tag = shift;
1951 my $co = shift;
1952 my $author = chop_and_escape_str($co->{'author_name'}, @_);
1953 return "<$tag class=\"author\">" .
1954 format_search_author($co->{'author_name'}, "author",
1955 git_get_avatar($co->{'author_email'}, -pad_after => 1) .
1956 $author) .
1957 "</$tag>";
1958 }
1959
1960 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
1961 sub format_git_diff_header_line {
1962 my $line = shift;
1963 my $diffinfo = shift;
1964 my ($from, $to) = @_;
1965
1966 if ($diffinfo->{'nparents'}) {
1967 # combined diff
1968 $line =~ s!^(diff (.*?) )"?.*$!$1!;
1969 if ($to->{'href'}) {
1970 $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1971 esc_path($to->{'file'}));
1972 } else { # file was deleted (no href)
1973 $line .= esc_path($to->{'file'});
1974 }
1975 } else {
1976 # "ordinary" diff
1977 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
1978 if ($from->{'href'}) {
1979 $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
1980 'a/' . esc_path($from->{'file'}));
1981 } else { # file was added (no href)
1982 $line .= 'a/' . esc_path($from->{'file'});
1983 }
1984 $line .= ' ';
1985 if ($to->{'href'}) {
1986 $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1987 'b/' . esc_path($to->{'file'}));
1988 } else { # file was deleted
1989 $line .= 'b/' . esc_path($to->{'file'});
1990 }
1991 }
1992
1993 return "<div class=\"diff header\">$line</div>\n";
1994 }
1995
1996 # format extended diff header line, before patch itself
1997 sub format_extended_diff_header_line {
1998 my $line = shift;
1999 my $diffinfo = shift;
2000 my ($from, $to) = @_;
2001
2002 # match <path>
2003 if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2004 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2005 esc_path($from->{'file'}));
2006 }
2007 if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2008 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2009 esc_path($to->{'file'}));
2010 }
2011 # match single <mode>
2012 if ($line =~ m/\s(\d{6})$/) {
2013 $line .= '<span class="info"> (' .
2014 file_type_long($1) .
2015 ')</span>';
2016 }
2017 # match <hash>
2018 if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2019 # can match only for combined diff
2020 $line = 'index ';
2021 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2022 if ($from->{'href'}[$i]) {
2023 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2024 -class=>"hash"},
2025 substr($diffinfo->{'from_id'}[$i],0,7));
2026 } else {
2027 $line .= '0' x 7;
2028 }
2029 # separator
2030 $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2031 }
2032 $line .= '..';
2033 if ($to->{'href'}) {
2034 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2035 substr($diffinfo->{'to_id'},0,7));
2036 } else {
2037 $line .= '0' x 7;
2038 }
2039
2040 } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2041 # can match only for ordinary diff
2042 my ($from_link, $to_link);
2043 if ($from->{'href'}) {
2044 $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2045 substr($diffinfo->{'from_id'},0,7));
2046 } else {
2047 $from_link = '0' x 7;
2048 }
2049 if ($to->{'href'}) {
2050 $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2051 substr($diffinfo->{'to_id'},0,7));
2052 } else {
2053 $to_link = '0' x 7;
2054 }
2055 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2056 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2057 }
2058
2059 return $line . "<br/>\n";
2060 }
2061
2062 # format from-file/to-file diff header
2063 sub format_diff_from_to_header {
2064 my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2065 my $line;
2066 my $result = '';
2067
2068 $line = $from_line;
2069 #assert($line =~ m/^---/) if DEBUG;
2070 # no extra formatting for "^--- /dev/null"
2071 if (! $diffinfo->{'nparents'}) {
2072 # ordinary (single parent) diff
2073 if ($line =~ m!^--- "?a/!) {
2074 if ($from->{'href'}) {
2075 $line = '--- a/' .
2076 $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2077 esc_path($from->{'file'}));
2078 } else {
2079 $line = '--- a/' .
2080 esc_path($from->{'file'});
2081 }
2082 }
2083 $result .= qq!<div class="diff from_file">$line</div>\n!;
2084
2085 } else {
2086 # combined diff (merge commit)
2087 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2088 if ($from->{'href'}[$i]) {
2089 $line = '--- ' .
2090 $cgi->a({-href=>href(action=>"blobdiff",
2091 hash_parent=>$diffinfo->{'from_id'}[$i],
2092 hash_parent_base=>$parents[$i],
2093 file_parent=>$from->{'file'}[$i],
2094 hash=>$diffinfo->{'to_id'},
2095 hash_base=>$hash,
2096 file_name=>$to->{'file'}),
2097 -class=>"path",
2098 -title=>"diff" . ($i+1)},
2099 $i+1) .
2100 '/' .
2101 $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2102 esc_path($from->{'file'}[$i]));
2103 } else {
2104 $line = '--- /dev/null';
2105 }
2106 $result .= qq!<div class="diff from_file">$line</div>\n!;
2107 }
2108 }
2109
2110 $line = $to_line;
2111 #assert($line =~ m/^\+\+\+/) if DEBUG;
2112 # no extra formatting for "^+++ /dev/null"
2113 if ($line =~ m!^\+\+\+ "?b/!) {
2114 if ($to->{'href'}) {
2115 $line = '+++ b/' .
2116 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2117 esc_path($to->{'file'}));
2118 } else {
2119 $line = '+++ b/' .
2120 esc_path($to->{'file'});
2121 }
2122 }
2123 $result .= qq!<div class="diff to_file">$line</div>\n!;
2124
2125 return $result;
2126 }
2127
2128 # create note for patch simplified by combined diff
2129 sub format_diff_cc_simplified {
2130 my ($diffinfo, @parents) = @_;
2131 my $result = '';
2132
2133 $result .= "<div class=\"diff header\">" .
2134 "diff --cc ";
2135 if (!is_deleted($diffinfo)) {
2136 $result .= $cgi->a({-href => href(action=>"blob",
2137 hash_base=>$hash,
2138 hash=>$diffinfo->{'to_id'},
2139 file_name=>$diffinfo->{'to_file'}),
2140 -class => "path"},
2141 esc_path($diffinfo->{'to_file'}));
2142 } else {
2143 $result .= esc_path($diffinfo->{'to_file'});
2144 }
2145 $result .= "</div>\n" . # class="diff header"
2146 "<div class=\"diff nodifferences\">" .
2147 "Simple merge" .
2148 "</div>\n"; # class="diff nodifferences"
2149
2150 return $result;
2151 }
2152
2153 # format patch (diff) line (not to be used for diff headers)
2154 sub format_diff_line {
2155 my $line = shift;
2156 my ($from, $to) = @_;
2157 my $diff_class = "";
2158
2159 chomp $line;
2160
2161 if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2162 # combined diff
2163 my $prefix = substr($line, 0, scalar @{$from->{'href'}});
2164 if ($line =~ m/^\@{3}/) {
2165 $diff_class = " chunk_header";
2166 } elsif ($line =~ m/^\\/) {
2167 $diff_class = " incomplete";
2168 } elsif ($prefix =~ tr/+/+/) {
2169 $diff_class = " add";
2170 } elsif ($prefix =~ tr/-/-/) {
2171 $diff_class = " rem";
2172 }
2173 } else {
2174 # assume ordinary diff
2175 my $char = substr($line, 0, 1);
2176 if ($char eq '+') {
2177 $diff_class = " add";
2178 } elsif ($char eq '-') {
2179 $diff_class = " rem";
2180 } elsif ($char eq '@') {
2181 $diff_class = " chunk_header";
2182 } elsif ($char eq "\\") {
2183 $diff_class = " incomplete";
2184 }
2185 }
2186 $line = untabify($line);
2187 if ($from && $to && $line =~ m/^\@{2} /) {
2188 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2189 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2190
2191 $from_lines = 0 unless defined $from_lines;
2192 $to_lines = 0 unless defined $to_lines;
2193
2194 if ($from->{'href'}) {
2195 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2196 -class=>"list"}, $from_text);
2197 }
2198 if ($to->{'href'}) {
2199 $to_text = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2200 -class=>"list"}, $to_text);
2201 }
2202 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2203 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2204 return "<div class=\"diff$diff_class\">$line</div>\n";
2205 } elsif ($from && $to && $line =~ m/^\@{3}/) {
2206 my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2207 my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2208
2209 @from_text = split(' ', $ranges);
2210 for (my $i = 0; $i < @from_text; ++$i) {
2211 ($from_start[$i], $from_nlines[$i]) =
2212 (split(',', substr($from_text[$i], 1)), 0);
2213 }
2214
2215 $to_text = pop @from_text;
2216 $to_start = pop @from_start;
2217 $to_nlines = pop @from_nlines;
2218
2219 $line = "<span class=\"chunk_info\">$prefix ";
2220 for (my $i = 0; $i < @from_text; ++$i) {
2221 if ($from->{'href'}[$i]) {
2222 $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2223 -class=>"list"}, $from_text[$i]);
2224 } else {
2225 $line .= $from_text[$i];
2226 }
2227 $line .= " ";
2228 }
2229 if ($to->{'href'}) {
2230 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2231 -class=>"list"}, $to_text);
2232 } else {
2233 $line .= $to_text;
2234 }
2235 $line .= " $prefix</span>" .
2236 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2237 return "<div class=\"diff$diff_class\">$line</div>\n";
2238 }
2239 return "<div class=\"diff$diff_class\">" . esc_html($line, -nbsp=>1) . "</div>\n";
2240 }
2241
2242 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2243 # linked. Pass the hash of the tree/commit to snapshot.
2244 sub format_snapshot_links {
2245 my ($hash) = @_;
2246 my $num_fmts = @snapshot_fmts;
2247 if ($num_fmts > 1) {
2248 # A parenthesized list of links bearing format names.
2249 # e.g. "snapshot (_tar.gz_ _zip_)"
2250 return "snapshot (" . join(' ', map
2251 $cgi->a({
2252 -href => href(
2253 action=>"snapshot",
2254 hash=>$hash,
2255 snapshot_format=>$_
2256 )
2257 }, $known_snapshot_formats{$_}{'display'})
2258 , @snapshot_fmts) . ")";
2259 } elsif ($num_fmts == 1) {
2260 # A single "snapshot" link whose tooltip bears the format name.
2261 # i.e. "_snapshot_"
2262 my ($fmt) = @snapshot_fmts;
2263 return
2264 $cgi->a({
2265 -href => href(
2266 action=>"snapshot",
2267 hash=>$hash,
2268 snapshot_format=>$fmt
2269 ),
2270 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2271 }, "snapshot");
2272 } else { # $num_fmts == 0
2273 return undef;
2274 }
2275 }
2276
2277 ## ......................................................................
2278 ## functions returning values to be passed, perhaps after some
2279 ## transformation, to other functions; e.g. returning arguments to href()
2280
2281 # returns hash to be passed to href to generate gitweb URL
2282 # in -title key it returns description of link
2283 sub get_feed_info {
2284 my $format = shift || 'Atom';
2285 my %res = (action => lc($format));
2286
2287 # feed links are possible only for project views
2288 return unless (defined $project);
2289 # some views should link to OPML, or to generic project feed,
2290 # or don't have specific feed yet (so they should use generic)
2291 return if ($action =~ /^(?:tags|heads|forks|tag|search)$/x);
2292
2293 my $branch;
2294 # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2295 # from tag links; this also makes possible to detect branch links
2296 if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2297 (defined $hash && $hash =~ m!^refs/heads/(.*)$!)) {
2298 $branch = $1;
2299 }
2300 # find log type for feed description (title)
2301 my $type = 'log';
2302 if (defined $file_name) {
2303 $type = "history of $file_name";
2304 $type .= "/" if ($action eq 'tree');
2305 $type .= " on '$branch'" if (defined $branch);
2306 } else {
2307 $type = "log of $branch" if (defined $branch);
2308 }
2309
2310 $res{-title} = $type;
2311 $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2312 $res{'file_name'} = $file_name;
2313
2314 return %res;
2315 }
2316
2317 ## ----------------------------------------------------------------------
2318 ## git utility subroutines, invoking git commands
2319
2320 # returns path to the core git executable and the --git-dir parameter as list
2321 sub git_cmd {
2322 $number_of_git_cmds++;
2323 return $GIT, '--git-dir='.$git_dir;
2324 }
2325
2326 # quote the given arguments for passing them to the shell
2327 # quote_command("command", "arg 1", "arg with ' and ! characters")
2328 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2329 # Try to avoid using this function wherever possible.
2330 sub quote_command {
2331 return join(' ',
2332 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2333 }
2334
2335 # get HEAD ref of given project as hash
2336 sub git_get_head_hash {
2337 return git_get_full_hash(shift, 'HEAD');
2338 }
2339
2340 sub git_get_full_hash {
2341 return git_get_hash(@_);
2342 }
2343
2344 sub git_get_short_hash {
2345 return git_get_hash(@_, '--short=7');
2346 }
2347
2348 sub git_get_hash {
2349 my ($project, $hash, @options) = @_;
2350 my $o_git_dir = $git_dir;
2351 my $retval = undef;
2352 $git_dir = "$projectroot/$project";
2353 if (open my $fd, '-|', git_cmd(), 'rev-parse',
2354 '--verify', '-q', @options, $hash) {
2355 $retval = <$fd>;
2356 chomp $retval if defined $retval;
2357 close $fd;
2358 }
2359 if (defined $o_git_dir) {
2360 $git_dir = $o_git_dir;
2361 }
2362 return $retval;
2363 }
2364
2365 # get type of given object
2366 sub git_get_type {
2367 my $hash = shift;
2368
2369 open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2370 my $type = <$fd>;
2371 close $fd or return;
2372 chomp $type;
2373 return $type;
2374 }
2375
2376 # repository configuration
2377 our $config_file = '';
2378 our %config;
2379
2380 # store multiple values for single key as anonymous array reference
2381 # single values stored directly in the hash, not as [ <value> ]
2382 sub hash_set_multi {
2383 my ($hash, $key, $value) = @_;
2384
2385 if (!exists $hash->{$key}) {
2386 $hash->{$key} = $value;
2387 } elsif (!ref $hash->{$key}) {
2388 $hash->{$key} = [ $hash->{$key}, $value ];
2389 } else {
2390 push @{$hash->{$key}}, $value;
2391 }
2392 }
2393
2394 # return hash of git project configuration
2395 # optionally limited to some section, e.g. 'gitweb'
2396 sub git_parse_project_config {
2397 my $section_regexp = shift;
2398 my %config;
2399
2400 local $/ = "\0";
2401
2402 open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2403 or return;
2404
2405 while (my $keyval = <$fh>) {
2406 chomp $keyval;
2407 my ($key, $value) = split(/\n/, $keyval, 2);
2408
2409 hash_set_multi(\%config, $key, $value)
2410 if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2411 }
2412 close $fh;
2413
2414 return %config;
2415 }
2416
2417 # convert config value to boolean: 'true' or 'false'
2418 # no value, number > 0, 'true' and 'yes' values are true
2419 # rest of values are treated as false (never as error)
2420 sub config_to_bool {
2421 my $val = shift;
2422
2423 return 1 if !defined $val; # section.key
2424
2425 # strip leading and trailing whitespace
2426 $val =~ s/^\s+//;
2427 $val =~ s/\s+$//;
2428
2429 return (($val =~ /^\d+$/ && $val) || # section.key = 1
2430 ($val =~ /^(?:true|yes)$/i)); # section.key = true
2431 }
2432
2433 # convert config value to simple decimal number
2434 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2435 # to be multiplied by 1024, 1048576, or 1073741824
2436 sub config_to_int {
2437 my $val = shift;
2438
2439 # strip leading and trailing whitespace
2440 $val =~ s/^\s+//;
2441 $val =~ s/\s+$//;
2442
2443 if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2444 $unit = lc($unit);
2445 # unknown unit is treated as 1
2446 return $num * ($unit eq 'g' ? 1073741824 :
2447 $unit eq 'm' ? 1048576 :
2448 $unit eq 'k' ? 1024 : 1);
2449 }
2450 return $val;
2451 }
2452
2453 # convert config value to array reference, if needed
2454 sub config_to_multi {
2455 my $val = shift;
2456
2457 return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2458 }
2459
2460 sub git_get_project_config {
2461 my ($key, $type) = @_;
2462
2463 return unless defined $git_dir;
2464
2465 # key sanity check
2466 return unless ($key);
2467 $key =~ s/^gitweb\.//;
2468 return if ($key =~ m/\W/);
2469
2470 # type sanity check
2471 if (defined $type) {
2472 $type =~ s/^--//;
2473 $type = undef
2474 unless ($type eq 'bool' || $type eq 'int');
2475 }
2476
2477 # get config
2478 if (!defined $config_file ||
2479 $config_file ne "$git_dir/config") {
2480 %config = git_parse_project_config('gitweb');
2481 $config_file = "$git_dir/config";
2482 }
2483
2484 # check if config variable (key) exists
2485 return unless exists $config{"gitweb.$key"};
2486
2487 # ensure given type
2488 if (!defined $type) {
2489 return $config{"gitweb.$key"};
2490 } elsif ($type eq 'bool') {
2491 # backward compatibility: 'git config --bool' returns true/false
2492 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2493 } elsif ($type eq 'int') {
2494 return config_to_int($config{"gitweb.$key"});
2495 }
2496 return $config{"gitweb.$key"};
2497 }
2498
2499 # get hash of given path at given ref
2500 sub git_get_hash_by_path {
2501 my $base = shift;
2502 my $path = shift || return undef;
2503 my $type = shift;
2504
2505 $path =~ s,/+$,,;
2506
2507 open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2508 or die_error(500, "Open git-ls-tree failed");
2509 my $line = <$fd>;
2510 close $fd or return undef;
2511
2512 if (!defined $line) {
2513 # there is no tree or hash given by $path at $base
2514 return undef;
2515 }
2516
2517 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa panic.c'
2518 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2519 if (defined $type && $type ne $2) {
2520 # type doesn't match
2521 return undef;
2522 }
2523 return $3;
2524 }
2525
2526 # get path of entry with given hash at given tree-ish (ref)
2527 # used to get 'from' filename for combined diff (merge commit) for renames
2528 sub git_get_path_by_hash {
2529 my $base = shift || return;
2530 my $hash = shift || return;
2531
2532 local $/ = "\0";
2533
2534 open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2535 or return undef;
2536 while (my $line = <$fd>) {
2537 chomp $line;
2538
2539 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423 gitweb'
2540 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f gitweb/README'
2541 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2542 close $fd;
2543 return $1;
2544 }
2545 }
2546 close $fd;
2547 return undef;
2548 }
2549
2550 ## ......................................................................
2551 ## git utility functions, directly accessing git repository
2552
2553 sub git_get_project_description {
2554 my $path = shift;
2555
2556 $git_dir = "$projectroot/$path";
2557 open my $fd, '<', "$git_dir/description"
2558 or return git_get_project_config('description');
2559 my $descr = <$fd>;
2560 close $fd;
2561 if (defined $descr) {
2562 chomp $descr;
2563 }
2564 return $descr;
2565 }
2566
2567 sub git_get_project_ctags {
2568 my $path = shift;
2569 my $ctags = {};
2570
2571 $git_dir = "$projectroot/$path";
2572 opendir my $dh, "$git_dir/ctags"
2573 or return $ctags;
2574 foreach (grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh)) {
2575 open my $ct, '<', $_ or next;
2576 my $val = <$ct>;
2577 chomp $val;
2578 close $ct;
2579 my $ctag = $_; $ctag =~ s#.*/##;
2580 $ctags->{$ctag} = $val;
2581 }
2582 closedir $dh;
2583 $ctags;
2584 }
2585
2586 sub git_populate_project_tagcloud {
2587 my $ctags = shift;
2588
2589 # First, merge different-cased tags; tags vote on casing
2590 my %ctags_lc;
2591 foreach (keys %$ctags) {
2592 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2593 if (not $ctags_lc{lc $_}->{topcount}
2594 or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2595 $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2596 $ctags_lc{lc $_}->{topname} = $_;
2597 }
2598 }
2599
2600 my $cloud;
2601 if (eval { require HTML::TagCloud; 1; }) {
2602 $cloud = HTML::TagCloud->new;
2603 foreach (sort keys %ctags_lc) {
2604 # Pad the title with spaces so that the cloud looks
2605 # less crammed.
2606 my $title = $ctags_lc{$_}->{topname};
2607 $title =~ s/ /&nbsp;/g;
2608 $title =~ s/^/&nbsp;/g;
2609 $title =~ s/$/&nbsp;/g;
2610 $cloud->add($title, $home_link."?by_tag=".$_, $ctags_lc{$_}->{count});
2611 }
2612 } else {
2613 $cloud = \%ctags_lc;
2614 }
2615 $cloud;
2616 }
2617
2618 sub git_show_project_tagcloud {
2619 my ($cloud, $count) = @_;
2620 print STDERR ref($cloud)."..\n";
2621 if (ref $cloud eq 'HTML::TagCloud') {
2622 return $cloud->html_and_css($count);
2623 } else {
2624 my @tags = sort { $cloud->{$a}->{count} <=> $cloud->{$b}->{count} } keys %$cloud;
2625 return '<p align="center">' . join (', ', map {
2626 $cgi->a({-href=>"$home_link?by_tag=$_"}, $cloud->{$_}->{topname})
2627 } splice(@tags, 0, $count)) . '</p>';
2628 }
2629 }
2630
2631 sub git_get_project_url_list {
2632 my $path = shift;
2633
2634 $git_dir = "$projectroot/$path";
2635 open my $fd, '<', "$git_dir/cloneurl"
2636 or return wantarray ?
2637 @{ config_to_multi(git_get_project_config('url')) } :
2638 config_to_multi(git_get_project_config('url'));
2639 my @git_project_url_list = map { chomp; $_ } <$fd>;
2640 close $fd;
2641
2642 return wantarray ? @git_project_url_list : \@git_project_url_list;
2643 }
2644
2645 sub git_get_projects_list {
2646 my ($filter) = @_;
2647 my @list;
2648
2649 $filter ||= '';
2650 $filter =~ s/\.git$//;
2651
2652 my $check_forks = gitweb_check_feature('forks');
2653
2654 if (-d $projects_list) {
2655 # search in directory
2656 my $dir = $projects_list . ($filter ? "/$filter" : '');
2657 # remove the trailing "/"
2658 $dir =~ s!/+$!!;
2659 my $pfxlen = length("$dir");
2660 my $pfxdepth = ($dir =~ tr!/!!);
2661
2662 File::Find::find({
2663 follow_fast => 1, # follow symbolic links
2664 follow_skip => 2, # ignore duplicates
2665 dangling_symlinks => 0, # ignore dangling symlinks, silently
2666 wanted => sub {
2667 # global variables
2668 our $project_maxdepth;
2669 our $projectroot;
2670 # skip project-list toplevel, if we get it.
2671 return if (m!^[/.]$!);
2672 # only directories can be git repositories
2673 return unless (-d $_);
2674 # don't traverse too deep (Find is super slow on os x)
2675 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2676 $File::Find::prune = 1;
2677 return;
2678 }
2679
2680 my $subdir = substr($File::Find::name, $pfxlen + 1);
2681 # we check related file in $projectroot
2682 my $path = ($filter ? "$filter/" : '') . $subdir;
2683 if (check_export_ok("$projectroot/$path")) {
2684 push @list, { path => $path };
2685 $File::Find::prune = 1;
2686 }
2687 },
2688 }, "$dir");
2689
2690 } elsif (-f $projects_list) {
2691 # read from file(url-encoded):
2692 # 'git%2Fgit.git Linus+Torvalds'
2693 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2694 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2695 my %paths;
2696 open my $fd, '<', $projects_list or return;
2697 PROJECT:
2698 while (my $line = <$fd>) {
2699 chomp $line;
2700 my ($path, $owner) = split ' ', $line;
2701 $path = unescape($path);
2702 $owner = unescape($owner);
2703 if (!defined $path) {
2704 next;
2705 }
2706 if ($filter ne '') {
2707 # looking for forks;
2708 my $pfx = substr($path, 0, length($filter));
2709 if ($pfx ne $filter) {
2710 next PROJECT;
2711 }
2712 my $sfx = substr($path, length($filter));
2713 if ($sfx !~ /^\/.*\.git$/) {
2714 next PROJECT;
2715 }
2716 } elsif ($check_forks) {
2717 PATH:
2718 foreach my $filter (keys %paths) {
2719 # looking for forks;
2720 my $pfx = substr($path, 0, length($filter));
2721 if ($pfx ne $filter) {
2722 next PATH;
2723 }
2724 my $sfx = substr($path, length($filter));
2725 if ($sfx !~ /^\/.*\.git$/) {
2726 next PATH;
2727 }
2728 # is a fork, don't include it in
2729 # the list
2730 next PROJECT;
2731 }
2732 }
2733 if (check_export_ok("$projectroot/$path")) {
2734 my $pr = {
2735 path => $path,
2736 owner => to_utf8($owner),
2737 };
2738 push @list, $pr;
2739 (my $forks_path = $path) =~ s/\.git$//;
2740 $paths{$forks_path}++;
2741 }
2742 }
2743 close $fd;
2744 }
2745 return @list;
2746 }
2747
2748 our $gitweb_project_owner = undef;
2749 sub git_get_project_list_from_file {
2750
2751 return if (defined $gitweb_project_owner);
2752
2753 $gitweb_project_owner = {};
2754 # read from file (url-encoded):
2755 # 'git%2Fgit.git Linus+Torvalds'
2756 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2757 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2758 if (-f $projects_list) {
2759 open(my $fd, '<', $projects_list);
2760 while (my $line = <$fd>) {
2761 chomp $line;
2762 my ($pr, $ow) = split ' ', $line;
2763 $pr = unescape($pr);
2764 $ow = unescape($ow);
2765 $gitweb_project_owner->{$pr} = to_utf8($ow);
2766 }
2767 close $fd;
2768 }
2769 }
2770
2771 sub git_get_project_owner {
2772 my $project = shift;
2773 my $owner;
2774
2775 return undef unless $project;
2776 $git_dir = "$projectroot/$project";
2777
2778 if (!defined $gitweb_project_owner) {
2779 git_get_project_list_from_file();
2780 }
2781
2782 if (exists $gitweb_project_owner->{$project}) {
2783 $owner = $gitweb_project_owner->{$project};
2784 }
2785 if (!defined $owner){
2786 $owner = git_get_project_config('owner');
2787 }
2788 if (!defined $owner) {
2789 $owner = get_file_owner("$git_dir");
2790 }
2791
2792 return $owner;
2793 }
2794
2795 sub git_get_last_activity {
2796 my ($path) = @_;
2797 my $fd;
2798
2799 $git_dir = "$projectroot/$path";
2800 open($fd, "-|", git_cmd(), 'for-each-ref',
2801 '--format=%(committer)',
2802 '--sort=-committerdate',
2803 '--count=1',
2804 'refs/heads') or return;
2805 my $most_recent = <$fd>;
2806 close $fd or return;
2807 if (defined $most_recent &&
2808 $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
2809 my $timestamp = $1;
2810 my $age = time - $timestamp;
2811 return ($age, age_string($age));
2812 }
2813 return (undef, undef);
2814 }
2815
2816 # Implementation note: when a single remote is wanted, we cannot use 'git
2817 # remote show -n' because that command always work (assuming it's a remote URL
2818 # if it's not defined), and we cannot use 'git remote show' because that would
2819 # try to make a network roundtrip. So the only way to find if that particular
2820 # remote is defined is to walk the list provided by 'git remote -v' and stop if
2821 # and when we find what we want.
2822 sub git_get_remotes_list {
2823 my $wanted = shift;
2824 my %remotes = ();
2825
2826 open my $fd, '-|' , git_cmd(), 'remote', '-v';
2827 return unless $fd;
2828 while (my $remote = <$fd>) {
2829 chomp $remote;
2830 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
2831 next if $wanted and not $remote eq $wanted;
2832 my ($url, $key) = ($1, $2);
2833
2834 $remotes{$remote} ||= { 'heads' => () };
2835 $remotes{$remote}{$key} = $url;
2836 }
2837 close $fd or return;
2838 return wantarray ? %remotes : \%remotes;
2839 }
2840
2841 # Takes a hash of remotes as first parameter and fills it by adding the
2842 # available remote heads for each of the indicated remotes.
2843 sub fill_remote_heads {
2844 my $remotes = shift;
2845 my @heads = map { "remotes/$_" } keys %$remotes;
2846 my @remoteheads = git_get_heads_list(undef, @heads);
2847 foreach my $remote (keys %$remotes) {
2848 $remotes->{$remote}{'heads'} = [ grep {
2849 $_->{'name'} =~ s!^$remote/!!
2850 } @remoteheads ];
2851 }
2852 }
2853
2854 sub git_get_references {
2855 my $type = shift || "";
2856 my %refs;
2857 # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
2858 # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
2859 open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
2860 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
2861 or return;
2862
2863 while (my $line = <$fd>) {
2864 chomp $line;
2865 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
2866 if (defined $refs{$1}) {
2867 push @{$refs{$1}}, $2;
2868 } else {
2869 $refs{$1} = [ $2 ];
2870 }
2871 }
2872 }
2873 close $fd or return;
2874 return \%refs;
2875 }
2876
2877 sub git_get_rev_name_tags {
2878 my $hash = shift || return undef;
2879
2880 open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
2881 or return;
2882 my $name_rev = <$fd>;
2883 close $fd;
2884
2885 if ($name_rev =~ m|^$hash tags/(.*)$|) {
2886 return $1;
2887 } else {
2888 # catches also '$hash undefined' output
2889 return undef;
2890 }
2891 }
2892
2893 ## ----------------------------------------------------------------------
2894 ## parse to hash functions
2895
2896 sub parse_date {
2897 my $epoch = shift;
2898 my $tz = shift || "-0000";
2899
2900 my %date;
2901 my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
2902 my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
2903 my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
2904 $date{'hour'} = $hour;
2905 $date{'minute'} = $min;
2906 $date{'mday'} = $mday;
2907 $date{'day'} = $days[$wday];
2908 $date{'month'} = $months[$mon];
2909 $date{'rfc2822'} = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
2910 $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
2911 $date{'mday-time'} = sprintf "%d %s %02d:%02d",
2912 $mday, $months[$mon], $hour ,$min;
2913 $date{'iso-8601'} = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
2914 1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
2915
2916 $tz =~ m/^([+\-][0-9][0-9])([0-9][0-9])$/;
2917 my $local = $epoch + ((int $1 + ($2/60)) * 3600);
2918 ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
2919 $date{'hour_local'} = $hour;
2920 $date{'minute_local'} = $min;
2921 $date{'tz_local'} = $tz;
2922 $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
2923 1900+$year, $mon+1, $mday,
2924 $hour, $min, $sec, $tz);
2925 return %date;
2926 }
2927
2928 sub parse_tag {
2929 my $tag_id = shift;
2930 my %tag;
2931 my @comment;
2932
2933 open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
2934 $tag{'id'} = $tag_id;
2935 while (my $line = <$fd>) {
2936 chomp $line;
2937 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
2938 $tag{'object'} = $1;
2939 } elsif ($line =~ m/^type (.+)$/) {
2940 $tag{'type'} = $1;
2941 } elsif ($line =~ m/^tag (.+)$/) {
2942 $tag{'name'} = $1;
2943 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
2944 $tag{'author'} = $1;
2945 $tag{'author_epoch'} = $2;
2946 $tag{'author_tz'} = $3;
2947 if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
2948 $tag{'author_name'} = $1;
2949 $tag{'author_email'} = $2;
2950 } else {
2951 $tag{'author_name'} = $tag{'author'};
2952 }
2953 } elsif ($line =~ m/--BEGIN/) {
2954 push @comment, $line;
2955 last;
2956 } elsif ($line eq "") {
2957 last;
2958 }
2959 }
2960 push @comment, <$fd>;
2961 $tag{'comment'} = \@comment;
2962 close $fd or return;
2963 if (!defined $tag{'name'}) {
2964 return
2965 };
2966 return %tag
2967 }
2968
2969 sub parse_commit_text {
2970 my ($commit_text, $withparents) = @_;
2971 my @commit_lines = split '\n', $commit_text;
2972 my %co;
2973
2974 pop @commit_lines; # Remove '\0'
2975
2976 if (! @commit_lines) {
2977 return;
2978 }
2979
2980 my $header = shift @commit_lines;
2981 if ($header !~ m/^[0-9a-fA-F]{40}/) {
2982 return;
2983 }
2984 ($co{'id'}, my @parents) = split ' ', $header;
2985 while (my $line = shift @commit_lines) {
2986 last if $line eq "\n";
2987 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
2988 $co{'tree'} = $1;
2989 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
2990 push @parents, $1;
2991 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
2992 $co{'author'} = to_utf8($1);
2993 $co{'author_epoch'} = $2;
2994 $co{'author_tz'} = $3;
2995 if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
2996 $co{'author_name'} = $1;
2997 $co{'author_email'} = $2;
2998 } else {
2999 $co{'author_name'} = $co{'author'};
3000 }
3001 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3002 $co{'committer'} = to_utf8($1);
3003 $co{'committer_epoch'} = $2;
3004 $co{'committer_tz'} = $3;
3005 if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3006 $co{'committer_name'} = $1;
3007 $co{'committer_email'} = $2;
3008 } else {
3009 $co{'committer_name'} = $co{'committer'};
3010 }
3011 }
3012 }
3013 if (!defined $co{'tree'}) {
3014 return;
3015 };
3016 $co{'parents'} = \@parents;
3017 $co{'parent'} = $parents[0];
3018
3019 foreach my $title (@commit_lines) {
3020 $title =~ s/^ //;
3021 if ($title ne "") {
3022 $co{'title'} = chop_str($title, 80, 5);
3023 # remove leading stuff of merges to make the interesting part visible
3024 if (length($title) > 50) {
3025 $title =~ s/^Automatic //;
3026 $title =~ s/^merge (of|with) /Merge ... /i;
3027 if (length($title) > 50) {
3028 $title =~ s/(http|rsync):\/\///;
3029 }
3030 if (length($title) > 50) {
3031 $title =~ s/(master|www|rsync)\.//;
3032 }
3033 if (length($title) > 50) {
3034 $title =~ s/kernel.org:?//;
3035 }
3036 if (length($title) > 50) {
3037 $title =~ s/\/pub\/scm//;
3038 }
3039 }
3040 $co{'title_short'} = chop_str($title, 50, 5);
3041 last;
3042 }
3043 }
3044 if (! defined $co{'title'} || $co{'title'} eq "") {
3045 $co{'title'} = $co{'title_short'} = '(no commit message)';
3046 }
3047 # remove added spaces
3048 foreach my $line (@commit_lines) {
3049 $line =~ s/^ //;
3050 }
3051 $co{'comment'} = \@commit_lines;
3052
3053 my $age = time - $co{'committer_epoch'};
3054 $co{'age'} = $age;
3055 $co{'age_string'} = age_string($age);
3056 my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3057 if ($age > 60*60*24*7*2) {
3058 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3059 $co{'age_string_age'} = $co{'age_string'};
3060 } else {
3061 $co{'age_string_date'} = $co{'age_string'};
3062 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3063 }
3064 return %co;
3065 }
3066
3067 sub parse_commit {
3068 my ($commit_id) = @_;
3069 my %co;
3070
3071 local $/ = "\0";
3072
3073 open my $fd, "-|", git_cmd(), "rev-list",
3074 "--parents",
3075 "--header",
3076 "--max-count=1",
3077 $commit_id,
3078 "--",
3079 or die_error(500, "Open git-rev-list failed");
3080 %co = parse_commit_text(<$fd>, 1);
3081 close $fd;
3082
3083 return %co;
3084 }
3085
3086 sub parse_commits {
3087 my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3088 my @cos;
3089
3090 $maxcount ||= 1;
3091 $skip ||= 0;
3092
3093 local $/ = "\0";
3094
3095 open my $fd, "-|", git_cmd(), "rev-list",
3096 "--header",
3097 @args,
3098 ("--max-count=" . $maxcount),
3099 ("--skip=" . $skip),
3100 @extra_options,
3101 $commit_id,
3102 "--",
3103 ($filename ? ($filename) : ())
3104 or die_error(500, "Open git-rev-list failed");
3105 while (my $line = <$fd>) {
3106 my %co = parse_commit_text($line);
3107 push @cos, \%co;
3108 }
3109 close $fd;
3110
3111 return wantarray ? @cos : \@cos;
3112 }
3113
3114 # parse line of git-diff-tree "raw" output
3115 sub parse_difftree_raw_line {
3116 my $line = shift;
3117 my %res;
3118
3119 # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M ls-files.c'
3120 # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M rev-tree.c'
3121 if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3122 $res{'from_mode'} = $1;
3123 $res{'to_mode'} = $2;
3124 $res{'from_id'} = $3;
3125 $res{'to_id'} = $4;
3126 $res{'status'} = $5;
3127 $res{'similarity'} = $6;
3128 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3129 ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3130 } else {
3131 $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3132 }
3133 }
3134 # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3135 # combined diff (for merge commit)
3136 elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3137 $res{'nparents'} = length($1);
3138 $res{'from_mode'} = [ split(' ', $2) ];
3139 $res{'to_mode'} = pop @{$res{'from_mode'}};
3140 $res{'from_id'} = [ split(' ', $3) ];
3141 $res{'to_id'} = pop @{$res{'from_id'}};
3142 $res{'status'} = [ split('', $4) ];
3143 $res{'to_file'} = unquote($5);
3144 }
3145 # 'c512b523472485aef4fff9e57b229d9d243c967f'
3146 elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3147 $res{'commit'} = $1;
3148 }
3149
3150 return wantarray ? %res : \%res;
3151 }
3152
3153 # wrapper: return parsed line of git-diff-tree "raw" output
3154 # (the argument might be raw line, or parsed info)
3155 sub parsed_difftree_line {
3156 my $line_or_ref = shift;
3157
3158 if (ref($line_or_ref) eq "HASH") {
3159 # pre-parsed (or generated by hand)
3160 return $line_or_ref;
3161 } else {
3162 return parse_difftree_raw_line($line_or_ref);
3163 }
3164 }
3165
3166 # parse line of git-ls-tree output
3167 sub parse_ls_tree_line {
3168 my $line = shift;
3169 my %opts = @_;
3170 my %res;
3171
3172 if ($opts{'-l'}) {
3173 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa 16717 panic.c'
3174 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3175
3176 $res{'mode'} = $1;
3177 $res{'type'} = $2;
3178 $res{'hash'} = $3;
3179 $res{'size'} = $4;
3180 if ($opts{'-z'}) {
3181 $res{'name'} = $5;
3182 } else {
3183 $res{'name'} = unquote($5);
3184 }
3185 } else {
3186 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa panic.c'
3187 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3188
3189 $res{'mode'} = $1;
3190 $res{'type'} = $2;
3191 $res{'hash'} = $3;
3192 if ($opts{'-z'}) {
3193 $res{'name'} = $4;
3194 } else {
3195 $res{'name'} = unquote($4);
3196 }
3197 }
3198
3199 return wantarray ? %res : \%res;
3200 }
3201
3202 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3203 sub parse_from_to_diffinfo {
3204 my ($diffinfo, $from, $to, @parents) = @_;
3205
3206 if ($diffinfo->{'nparents'}) {
3207 # combined diff
3208 $from->{'file'} = [];
3209 $from->{'href'} = [];
3210 fill_from_file_info($diffinfo, @parents)
3211 unless exists $diffinfo->{'from_file'};
3212 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3213 $from->{'file'}[$i] =
3214 defined $diffinfo->{'from_file'}[$i] ?
3215 $diffinfo->{'from_file'}[$i] :
3216 $diffinfo->{'to_file'};
3217 if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3218 $from->{'href'}[$i] = href(action=>"blob",
3219 hash_base=>$parents[$i],
3220 hash=>$diffinfo->{'from_id'}[$i],
3221 file_name=>$from->{'file'}[$i]);
3222 } else {
3223 $from->{'href'}[$i] = undef;
3224 }
3225 }
3226 } else {
3227 # ordinary (not combined) diff
3228 $from->{'file'} = $diffinfo->{'from_file'};
3229 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3230 $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3231 hash=>$diffinfo->{'from_id'},
3232 file_name=>$from->{'file'});
3233 } else {
3234 delete $from->{'href'};
3235 }
3236 }
3237
3238 $to->{'file'} = $diffinfo->{'to_file'};
3239 if (!is_deleted($diffinfo)) { # file exists in result
3240 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3241 hash=>$diffinfo->{'to_id'},
3242 file_name=>$to->{'file'});
3243 } else {
3244 delete $to->{'href'};
3245 }
3246 }
3247
3248 ## ......................................................................
3249 ## parse to array of hashes functions
3250
3251 sub git_get_heads_list {
3252 my ($limit, @classes) = @_;
3253 @classes = ('heads') unless @classes;
3254 my @patterns = map { "refs/$_" } @classes;
3255 my @headslist;
3256
3257 open my $fd, '-|', git_cmd(), 'for-each-ref',
3258 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3259 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3260 @patterns
3261 or return;
3262 while (my $line = <$fd>) {
3263 my %ref_item;
3264
3265 chomp $line;
3266 my ($refinfo, $committerinfo) = split(/\0/, $line);
3267 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3268 my ($committer, $epoch, $tz) =
3269 ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3270 $ref_item{'fullname'} = $name;
3271 $name =~ s!^refs/(?:head|remote)s/!!;
3272
3273 $ref_item{'name'} = $name;
3274 $ref_item{'id'} = $hash;
3275 $ref_item{'title'} = $title || '(no commit message)';
3276 $ref_item{'epoch'} = $epoch;
3277 if ($epoch) {
3278 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3279 } else {
3280 $ref_item{'age'} = "unknown";
3281 }
3282
3283 push @headslist, \%ref_item;
3284 }
3285 close $fd;
3286
3287 return wantarray ? @headslist : \@headslist;
3288 }
3289
3290 sub git_get_tags_list {
3291 my $limit = shift;
3292 my @tagslist;
3293
3294 open my $fd, '-|', git_cmd(), 'for-each-ref',
3295 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3296 '--format=%(objectname) %(objecttype) %(refname) '.
3297 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3298 'refs/tags'
3299 or return;
3300 while (my $line = <$fd>) {
3301 my %ref_item;
3302
3303 chomp $line;
3304 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3305 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3306 my ($creator, $epoch, $tz) =
3307 ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3308 $ref_item{'fullname'} = $name;
3309 $name =~ s!^refs/tags/!!;
3310
3311 $ref_item{'type'} = $type;
3312 $ref_item{'id'} = $id;
3313 $ref_item{'name'} = $name;
3314 if ($type eq "tag") {
3315 $ref_item{'subject'} = $title;
3316 $ref_item{'reftype'} = $reftype;
3317 $ref_item{'refid'} = $refid;
3318 } else {
3319 $ref_item{'reftype'} = $type;
3320 $ref_item{'refid'} = $id;
3321 }
3322
3323 if ($type eq "tag" || $type eq "commit") {
3324 $ref_item{'epoch'} = $epoch;
3325 if ($epoch) {
3326 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3327 } else {
3328 $ref_item{'age'} = "unknown";
3329 }
3330 }
3331
3332 push @tagslist, \%ref_item;
3333 }
3334 close $fd;
3335
3336 return wantarray ? @tagslist : \@tagslist;
3337 }
3338
3339 ## ----------------------------------------------------------------------
3340 ## filesystem-related functions
3341
3342 sub get_file_owner {
3343 my $path = shift;
3344
3345 my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3346 my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3347 if (!defined $gcos) {
3348 return undef;
3349 }
3350 my $owner = $gcos;
3351 $owner =~ s/[,;].*$//;
3352 return to_utf8($owner);
3353 }
3354
3355 # assume that file exists
3356 sub insert_file {
3357 my $filename = shift;
3358
3359 open my $fd, '<', $filename;
3360 print map { to_utf8($_) } <$fd>;
3361 close $fd;
3362 }
3363
3364 ## ......................................................................
3365 ## mimetype related functions
3366
3367 sub mimetype_guess_file {
3368 my $filename = shift;
3369 my $mimemap = shift;
3370 -r $mimemap or return undef;
3371
3372 my %mimemap;
3373 open(my $mh, '<', $mimemap) or return undef;
3374 while (<$mh>) {
3375 next if m/^#/; # skip comments
3376 my ($mimetype, $exts) = split(/\t+/);
3377 if (defined $exts) {
3378 my @exts = split(/\s+/, $exts);
3379 foreach my $ext (@exts) {
3380 $mimemap{$ext} = $mimetype;
3381 }
3382 }
3383 }
3384 close($mh);
3385
3386 $filename =~ /\.([^.]*)$/;
3387 return $mimemap{$1};
3388 }
3389
3390 sub mimetype_guess {
3391 my $filename = shift;
3392 my $mime;
3393 $filename =~ /\./ or return undef;
3394
3395 if ($mimetypes_file) {
3396 my $file = $mimetypes_file;
3397 if ($file !~ m!^/!) { # if it is relative path
3398 # it is relative to project
3399 $file = "$projectroot/$project/$file";
3400 }
3401 $mime = mimetype_guess_file($filename, $file);
3402 }
3403 $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3404 return $mime;
3405 }
3406
3407 sub blob_mimetype {
3408 my $fd = shift;
3409 my $filename = shift;
3410
3411 if ($filename) {
3412 my $mime = mimetype_guess($filename);
3413 $mime and return $mime;
3414 }
3415
3416 # just in case
3417 return $default_blob_plain_mimetype unless $fd;
3418
3419 if (-T $fd) {
3420 return 'text/plain';
3421 } elsif (! $filename) {
3422 return 'application/octet-stream';
3423 } elsif ($filename =~ m/\.png$/i) {
3424 return 'image/png';
3425 } elsif ($filename =~ m/\.gif$/i) {
3426 return 'image/gif';
3427 } elsif ($filename =~ m/\.jpe?g$/i) {
3428 return 'image/jpeg';
3429 } else {
3430 return 'application/octet-stream';
3431 }
3432 }
3433
3434 sub blob_contenttype {
3435 my ($fd, $file_name, $type) = @_;
3436
3437 $type ||= blob_mimetype($fd, $file_name);
3438 if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3439 $type .= "; charset=$default_text_plain_charset";
3440 }
3441
3442 return $type;
3443 }
3444
3445 # guess file syntax for syntax highlighting; return undef if no highlighting
3446 # the name of syntax can (in the future) depend on syntax highlighter used
3447 sub guess_file_syntax {
3448 my ($highlight, $mimetype, $file_name) = @_;
3449 return undef unless ($highlight && defined $file_name);
3450 my $basename = basename($file_name, '.in');
3451 return $highlight_basename{$basename}
3452 if exists $highlight_basename{$basename};
3453
3454 $basename =~ /\.([^.]*)$/;
3455 my $ext = $1 or return undef;
3456 return $highlight_ext{$ext}
3457 if exists $highlight_ext{$ext};
3458
3459 return undef;
3460 }
3461
3462 # run highlighter and return FD of its output,
3463 # or return original FD if no highlighting
3464 sub run_highlighter {
3465 my ($fd, $highlight, $syntax) = @_;
3466 return $fd unless ($highlight && defined $syntax);
3467
3468 close $fd
3469 or die_error(404, "Reading blob failed");
3470 open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3471 quote_command($highlight_bin).
3472 " --xhtml --fragment --syntax $syntax |"
3473 or die_error(500, "Couldn't open file or run syntax highlighter");
3474 return $fd;
3475 }
3476
3477 ## ======================================================================
3478 ## functions printing HTML: header, footer, error page
3479
3480 sub get_page_title {
3481 my $title = to_utf8($site_name);
3482
3483 return $title unless (defined $project);
3484 $title .= " - " . to_utf8($project);
3485
3486 return $title unless (defined $action);
3487 $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3488
3489 return $title unless (defined $file_name);
3490 $title .= " - " . esc_path($file_name);
3491 if ($action eq "tree" && $file_name !~ m|/$|) {
3492 $title .= "/";
3493 }
3494
3495 return $title;
3496 }
3497
3498 sub print_feed_meta {
3499 if (defined $project) {
3500 my %href_params = get_feed_info();
3501 if (!exists $href_params{'-title'}) {
3502 $href_params{'-title'} = 'log';
3503 }
3504
3505 foreach my $format qw(RSS Atom) {
3506 my $type = lc($format);
3507 my %link_attr = (
3508 '-rel' => 'alternate',
3509 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3510 '-type' => "application/$type+xml"
3511 );
3512
3513 $href_params{'action'} = $type;
3514 $link_attr{'-href'} = href(%href_params);
3515 print "<link ".
3516 "rel=\"$link_attr{'-rel'}\" ".
3517 "title=\"$link_attr{'-title'}\" ".
3518 "href=\"$link_attr{'-href'}\" ".
3519 "type=\"$link_attr{'-type'}\" ".
3520 "/>\n";
3521
3522 $href_params{'extra_options'} = '--no-merges';
3523 $link_attr{'-href'} = href(%href_params);
3524 $link_attr{'-title'} .= ' (no merges)';
3525