fsmonitor: preserve utf8 filenames in fsmonitor-watchman log
[git/git.git] / t / t7519 / fsmonitor-watchman
1 #!/usr/bin/perl
2
3 use strict;
4 use warnings;
5 use IPC::Open2;
6
7 # An example hook script to integrate Watchman
8 # (https://facebook.github.io/watchman/) with git to speed up detecting
9 # new and modified files.
10 #
11 # The hook is passed a version (currently 1) and a time in nanoseconds
12 # formatted as a string and outputs to stdout all files that have been
13 # modified since the given time. Paths must be relative to the root of
14 # the working tree and separated by a single NUL.
15 #
16 # To enable this hook, rename this file to "query-watchman" and set
17 # 'git config core.fsmonitor .git/hooks/query-watchman'
18 #
19 my ($version, $time) = @ARGV;
20 #print STDERR "$0 $version $time\n";
21
22 # Check the hook interface version
23
24 if ($version == 1) {
25 # convert nanoseconds to seconds
26 $time = int $time / 1000000000;
27 } else {
28 die "Unsupported query-fsmonitor hook version '$version'.\n" .
29 "Falling back to scanning...\n";
30 }
31
32 # Convert unix style paths to escaped Windows style paths when running
33 # in Windows command prompt
34
35 my $system = `uname -s`;
36 $system =~ s/[\r\n]+//g;
37 my $git_work_tree;
38
39 if ($system =~ m/^MSYS_NT/ || $system =~ m/^MINGW/) {
40 $git_work_tree = `cygpath -aw "\$PWD"`;
41 $git_work_tree =~ s/[\r\n]+//g;
42 $git_work_tree =~ s,\\,/,g;
43 } else {
44 $git_work_tree = $ENV{'PWD'};
45 }
46
47 my $retry = 1;
48
49 launch_watchman();
50
51 sub launch_watchman {
52
53 my $pid = open2(\*CHLD_OUT, \*CHLD_IN, 'watchman -j')
54 or die "open2() failed: $!\n" .
55 "Falling back to scanning...\n";
56
57 # In the query expression below we're asking for names of files that
58 # changed since $time but were not transient (ie created after
59 # $time but no longer exist).
60 #
61 # To accomplish this, we're using the "since" generator to use the
62 # recency index to select candidate nodes and "fields" to limit the
63 # output to file names only. Then we're using the "expression" term to
64 # further constrain the results.
65 #
66 # The category of transient files that we want to ignore will have a
67 # creation clock (cclock) newer than $time_t value and will also not
68 # currently exist.
69
70 my $query = <<" END";
71 ["query", "$git_work_tree", {
72 "since": $time,
73 "fields": ["name"],
74 "expression": ["not", ["allof", ["since", $time, "cclock"], ["not", "exists"]]]
75 }]
76 END
77
78 open (my $fh, ">", ".git/watchman-query.json");
79 print $fh $query;
80 close $fh;
81
82 print CHLD_IN $query;
83 close CHLD_IN;
84 my $response = do {local $/; <CHLD_OUT>};
85
86 open ($fh, ">", ".git/watchman-response.json");
87 print $fh $response;
88 close $fh;
89
90 die "Watchman: command returned no output.\n" .
91 "Falling back to scanning...\n" if $response eq "";
92 die "Watchman: command returned invalid output: $response\n" .
93 "Falling back to scanning...\n" unless $response =~ /^\{/;
94
95 my $json_pkg;
96 eval {
97 require JSON::XS;
98 $json_pkg = "JSON::XS";
99 1;
100 } or do {
101 require JSON::PP;
102 $json_pkg = "JSON::PP";
103 };
104
105 my $o = $json_pkg->new->utf8->decode($response);
106
107 if ($retry > 0 and $o->{error} and $o->{error} =~ m/unable to resolve root .* directory (.*) is not watched/) {
108 print STDERR "Adding '$git_work_tree' to watchman's watch list.\n";
109 $retry--;
110 qx/watchman watch "$git_work_tree"/;
111 die "Failed to make watchman watch '$git_work_tree'.\n" .
112 "Falling back to scanning...\n" if $? != 0;
113
114 # Watchman will always return all files on the first query so
115 # return the fast "everything is dirty" flag to git and do the
116 # Watchman query just to get it over with now so we won't pay
117 # the cost in git to look up each individual file.
118
119 open ($fh, ">", ".git/watchman-output.out");
120 print "/\0";
121 close $fh;
122
123 print "/\0";
124 eval { launch_watchman() };
125 exit 0;
126 }
127
128 die "Watchman: $o->{error}.\n" .
129 "Falling back to scanning...\n" if $o->{error};
130
131 open ($fh, ">", ".git/watchman-output.out");
132 binmode $fh, ":utf8";
133 print $fh @{$o->{files}};
134 close $fh;
135
136 binmode STDOUT, ":utf8";
137 local $, = "\0";
138 print @{$o->{files}};
139 }