Merge branch 'master' of git://repo.or.cz/git-gui
[git/git.git] / git-gui / lib / merge.tcl
1 # git-gui branch merge support
2 # Copyright (C) 2006, 2007 Shawn Pearce
3
4 namespace eval merge {
5
6 proc _can_merge {} {
7 global HEAD commit_type file_states
8
9 if {[string match amend* $commit_type]} {
10 info_popup {Cannot merge while amending.
11
12 You must finish amending this commit before starting any type of merge.
13 }
14 return 0
15 }
16
17 if {[committer_ident] eq {}} {return 0}
18 if {![lock_index merge]} {return 0}
19
20 # -- Our in memory state should match the repository.
21 #
22 repository_state curType curHEAD curMERGE_HEAD
23 if {$commit_type ne $curType || $HEAD ne $curHEAD} {
24 info_popup {Last scanned state does not match repository state.
25
26 Another Git program has modified this repository since the last scan. A rescan must be performed before a merge can be performed.
27
28 The rescan will be automatically started now.
29 }
30 unlock_index
31 rescan {set ui_status_value {Ready.}}
32 return 0
33 }
34
35 foreach path [array names file_states] {
36 switch -glob -- [lindex $file_states($path) 0] {
37 _O {
38 continue; # and pray it works!
39 }
40 U? {
41 error_popup "You are in the middle of a conflicted merge.
42
43 File [short_path $path] has merge conflicts.
44
45 You must resolve them, add the file, and commit to complete the current merge. Only then can you begin another merge.
46 "
47 unlock_index
48 return 0
49 }
50 ?? {
51 error_popup "You are in the middle of a change.
52
53 File [short_path $path] is modified.
54
55 You should complete the current commit before starting a merge. Doing so will help you abort a failed merge, should the need arise.
56 "
57 unlock_index
58 return 0
59 }
60 }
61 }
62
63 return 1
64 }
65
66 proc _refs {w list} {
67 set r {}
68 foreach i [$w.source.l curselection] {
69 lappend r [lindex [lindex $list $i] 0]
70 }
71 return $r
72 }
73
74 proc _visualize {w list} {
75 set revs [_refs $w $list]
76 if {$revs eq {}} return
77 lappend revs --not HEAD
78 do_gitk $revs
79 }
80
81 proc _start {w list} {
82 global HEAD ui_status_value current_branch
83
84 set cmd [list git merge]
85 set names [_refs $w $list]
86 set revcnt [llength $names]
87 append cmd { } $names
88
89 if {$revcnt == 0} {
90 return
91 } elseif {$revcnt == 1} {
92 set unit branch
93 } elseif {$revcnt <= 15} {
94 set unit branches
95
96 if {[tk_dialog \
97 $w.confirm_octopus \
98 [wm title $w] \
99 "Use octopus merge strategy?
100
101 You are merging $revcnt branches at once. This requires using the octopus merge driver, which may not succeed if there are file-level conflicts.
102 " \
103 question \
104 0 \
105 {Cancel} \
106 {Use octopus} \
107 ] != 1} return
108 } else {
109 tk_messageBox \
110 -icon error \
111 -type ok \
112 -title [wm title $w] \
113 -parent $w \
114 -message "Too many branches selected.
115
116 You have requested to merge $revcnt branches in an octopus merge. This exceeds Git's internal limit of 15 branches per merge.
117
118 Please select fewer branches. To merge more than 15 branches, merge the branches in batches.
119 "
120 return
121 }
122
123 set msg "Merging $current_branch, [join $names {, }]"
124 set ui_status_value "$msg..."
125 set cons [console::new "Merge" $msg]
126 console::exec $cons $cmd [namespace code [list _finish $revcnt]]
127 bind $w <Destroy> {}
128 destroy $w
129 }
130
131 proc _finish {revcnt w ok} {
132 console::done $w $ok
133 if {$ok} {
134 set msg {Merge completed successfully.}
135 } else {
136 if {$revcnt != 1} {
137 info_popup "Octopus merge failed.
138
139 Your merge of $revcnt branches has failed.
140
141 There are file-level conflicts between the branches which must be resolved manually.
142
143 The working directory will now be reset.
144
145 You can attempt this merge again by merging only one branch at a time." $w
146
147 set fd [open "| git read-tree --reset -u HEAD" r]
148 fconfigure $fd -blocking 0 -translation binary
149 fileevent $fd readable \
150 [namespace code [list _reset_wait $fd]]
151 set ui_status_value {Aborting... please wait...}
152 return
153 }
154
155 set msg {Merge failed. Conflict resolution is required.}
156 }
157 unlock_index
158 rescan [list set ui_status_value $msg]
159 }
160
161 proc dialog {} {
162 global current_branch
163 global M1B
164
165 if {![_can_merge]} return
166
167 set fmt {list %(objectname) %(*objectname) %(refname) %(subject)}
168 set cmd [list git for-each-ref --tcl --format=$fmt]
169 lappend cmd refs/heads
170 lappend cmd refs/remotes
171 lappend cmd refs/tags
172 set fr_fd [open "| $cmd" r]
173 fconfigure $fr_fd -translation binary
174 while {[gets $fr_fd line] > 0} {
175 set line [eval $line]
176 set ref [lindex $line 2]
177 regsub ^refs/(heads|remotes|tags)/ $ref {} ref
178 set subj($ref) [lindex $line 3]
179 lappend sha1([lindex $line 0]) $ref
180 if {[lindex $line 1] ne {}} {
181 lappend sha1([lindex $line 1]) $ref
182 }
183 }
184 close $fr_fd
185
186 set to_show {}
187 set fr_fd [open "| git rev-list --all --not HEAD"]
188 while {[gets $fr_fd line] > 0} {
189 if {[catch {set ref $sha1($line)}]} continue
190 foreach n $ref {
191 lappend to_show [list $n $line]
192 }
193 }
194 close $fr_fd
195 set to_show [lsort -unique $to_show]
196
197 set w .merge_setup
198 toplevel $w
199 wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
200
201 set _visualize [namespace code [list _visualize $w $to_show]]
202 set _start [namespace code [list _start $w $to_show]]
203
204 label $w.header \
205 -text "Merge Into $current_branch" \
206 -font font_uibold
207 pack $w.header -side top -fill x
208
209 frame $w.buttons
210 button $w.buttons.visualize -text Visualize -command $_visualize
211 pack $w.buttons.visualize -side left
212 button $w.buttons.create -text Merge -command $_start
213 pack $w.buttons.create -side right
214 button $w.buttons.cancel -text {Cancel} -command [list destroy $w]
215 pack $w.buttons.cancel -side right -padx 5
216 pack $w.buttons -side bottom -fill x -pady 10 -padx 10
217
218 labelframe $w.source -text {Source Branches}
219 listbox $w.source.l \
220 -height 10 \
221 -width 70 \
222 -font font_diff \
223 -selectmode extended \
224 -yscrollcommand [list $w.source.sby set]
225 scrollbar $w.source.sby -command [list $w.source.l yview]
226 pack $w.source.sby -side right -fill y
227 pack $w.source.l -side left -fill both -expand 1
228 pack $w.source -fill both -expand 1 -pady 5 -padx 5
229
230 foreach ref $to_show {
231 set n [lindex $ref 0]
232 if {[string length $n] > 20} {
233 set n "[string range $n 0 16]..."
234 }
235 $w.source.l insert end [format {%s %-20s %s} \
236 [string range [lindex $ref 1] 0 5] \
237 $n \
238 $subj([lindex $ref 0])]
239 }
240
241 bind $w.source.l <Key-k> [list event generate %W <Key-Up>]
242 bind $w.source.l <Key-j> [list event generate %W <Key-Down>]
243 bind $w.source.l <Key-h> [list event generate %W <Key-Left>]
244 bind $w.source.l <Key-l> [list event generate %W <Key-Right>]
245 bind $w.source.l <Key-v> $_visualize
246
247 bind $w <$M1B-Key-Return> $_start
248 bind $w <Visibility> "grab $w; focus $w.source.l"
249 bind $w <Key-Escape> "unlock_index;destroy $w"
250 bind $w <Destroy> unlock_index
251 wm title $w "[appname] ([reponame]): Merge"
252 tkwait window $w
253 }
254
255 proc reset_hard {} {
256 global HEAD commit_type file_states
257
258 if {[string match amend* $commit_type]} {
259 info_popup {Cannot abort while amending.
260
261 You must finish amending this commit.
262 }
263 return
264 }
265
266 if {![lock_index abort]} return
267
268 if {[string match *merge* $commit_type]} {
269 set op merge
270 } else {
271 set op commit
272 }
273
274 if {[ask_popup "Abort $op?
275
276 Aborting the current $op will cause *ALL* uncommitted changes to be lost.
277
278 Continue with aborting the current $op?"] eq {yes}} {
279 set fd [open "| git read-tree --reset -u HEAD" r]
280 fconfigure $fd -blocking 0 -translation binary
281 fileevent $fd readable [namespace code [list _reset_wait $fd]]
282 set ui_status_value {Aborting... please wait...}
283 } else {
284 unlock_index
285 }
286 }
287
288 proc _reset_wait {fd} {
289 global ui_comm
290
291 read $fd
292 if {[eof $fd]} {
293 close $fd
294 unlock_index
295
296 $ui_comm delete 0.0 end
297 $ui_comm edit modified false
298
299 catch {file delete [gitdir MERGE_HEAD]}
300 catch {file delete [gitdir rr-cache MERGE_RR]}
301 catch {file delete [gitdir SQUASH_MSG]}
302 catch {file delete [gitdir MERGE_MSG]}
303 catch {file delete [gitdir GITGUI_MSG]}
304
305 rescan {set ui_status_value {Abort completed. Ready.}}
306 }
307 }
308
309 }