5bc21b878d413e27de8e3d54e66a138ff41c7daa
[git/git.git] / git-gui.sh
1 #!/bin/sh
2 # Tcl ignores the next line -*- tcl -*- \
3 if test "z$*" = zversion \
4 || test "z$*" = z--version; \
5 then \
6 echo 'git-gui version @@GITGUI_VERSION@@'; \
7 exit; \
8 fi; \
9 argv0=$0; \
10 exec wish "$argv0" -- "$@"
11
12 set appvers {@@GITGUI_VERSION@@}
13 set copyright [string map [list (c) \u00a9] {
14 Copyright (c) 2006-2010 Shawn Pearce, et. al.
15
16 This program is free software; you can redistribute it and/or modify
17 it under the terms of the GNU General Public License as published by
18 the Free Software Foundation; either version 2 of the License, or
19 (at your option) any later version.
20
21 This program is distributed in the hope that it will be useful,
22 but WITHOUT ANY WARRANTY; without even the implied warranty of
23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
24 GNU General Public License for more details.
25
26 You should have received a copy of the GNU General Public License
27 along with this program; if not, write to the Free Software
28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA}]
29
30 ######################################################################
31 ##
32 ## Tcl/Tk sanity check
33
34 if {[catch {package require Tcl 8.4} err]
35 || [catch {package require Tk 8.4} err]
36 } {
37 catch {wm withdraw .}
38 tk_messageBox \
39 -icon error \
40 -type ok \
41 -title "git-gui: fatal error" \
42 -message $err
43 exit 1
44 }
45
46 catch {rename send {}} ; # What an evil concept...
47
48 ######################################################################
49 ##
50 ## locate our library
51
52 if { [info exists ::env(GIT_GUI_LIB_DIR) ] } {
53 set oguilib $::env(GIT_GUI_LIB_DIR)
54 } else {
55 set oguilib {@@GITGUI_LIBDIR@@}
56 }
57 set oguirel {@@GITGUI_RELATIVE@@}
58 if {$oguirel eq {1}} {
59 set oguilib [file dirname [file normalize $argv0]]
60 if {[file tail $oguilib] eq {git-core}} {
61 set oguilib [file dirname $oguilib]
62 }
63 set oguilib [file dirname $oguilib]
64 set oguilib [file join $oguilib share git-gui lib]
65 set oguimsg [file join $oguilib msgs]
66 } elseif {[string match @@* $oguirel]} {
67 set oguilib [file join [file dirname [file normalize $argv0]] lib]
68 set oguimsg [file join [file dirname [file normalize $argv0]] po]
69 } else {
70 set oguimsg [file join $oguilib msgs]
71 }
72 unset oguirel
73
74 ######################################################################
75 ##
76 ## enable verbose loading?
77
78 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
79 unset _verbose
80 rename auto_load real__auto_load
81 proc auto_load {name args} {
82 puts stderr "auto_load $name"
83 return [uplevel 1 real__auto_load $name $args]
84 }
85 rename source real__source
86 proc source {args} {
87 puts stderr "source $args"
88 uplevel 1 [linsert $args 0 real__source]
89 }
90 if {[tk windowingsystem] eq "win32"} { console show }
91 }
92
93 ######################################################################
94 ##
95 ## Internationalization (i18n) through msgcat and gettext. See
96 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
97
98 package require msgcat
99
100 # Check for Windows 7 MUI language pack (missed by msgcat < 1.4.4)
101 if {[tk windowingsystem] eq "win32"
102 && [package vcompare [package provide msgcat] 1.4.4] < 0
103 } then {
104 proc _mc_update_locale {} {
105 set key {HKEY_CURRENT_USER\Control Panel\Desktop}
106 if {![catch {
107 package require registry
108 set uilocale [registry get $key "PreferredUILanguages"]
109 msgcat::ConvertLocale [string map {- _} [lindex $uilocale 0]]
110 } uilocale]} {
111 if {[string length $uilocale] > 0} {
112 msgcat::mclocale $uilocale
113 }
114 }
115 }
116 _mc_update_locale
117 }
118
119 proc _mc_trim {fmt} {
120 set cmk [string first @@ $fmt]
121 if {$cmk > 0} {
122 return [string range $fmt 0 [expr {$cmk - 1}]]
123 }
124 return $fmt
125 }
126
127 proc mc {en_fmt args} {
128 set fmt [_mc_trim [::msgcat::mc $en_fmt]]
129 if {[catch {set msg [eval [list format $fmt] $args]} err]} {
130 set msg [eval [list format [_mc_trim $en_fmt]] $args]
131 }
132 return $msg
133 }
134
135 proc strcat {args} {
136 return [join $args {}]
137 }
138
139 ::msgcat::mcload $oguimsg
140 unset oguimsg
141
142 ######################################################################
143 ##
144 ## On Mac, bring the current Wish process window to front
145
146 if {[tk windowingsystem] eq "aqua"} {
147 catch {
148 exec osascript -e [format {
149 tell application "System Events"
150 set frontmost of processes whose unix id is %d to true
151 end tell
152 } [pid]]
153 }
154 }
155
156 ######################################################################
157 ##
158 ## read only globals
159
160 set _appname {Git Gui}
161 set _gitdir {}
162 set _gitworktree {}
163 set _isbare {}
164 set _gitexec {}
165 set _githtmldir {}
166 set _reponame {}
167 set _iscygwin {}
168 set _search_path {}
169 set _shellpath {@@SHELL_PATH@@}
170
171 set _trace [lsearch -exact $argv --trace]
172 if {$_trace >= 0} {
173 set argv [lreplace $argv $_trace $_trace]
174 set _trace 1
175 if {[tk windowingsystem] eq "win32"} { console show }
176 } else {
177 set _trace 0
178 }
179
180 # variable for the last merged branch (useful for a default when deleting
181 # branches).
182 set _last_merged_branch {}
183
184 proc shellpath {} {
185 global _shellpath env
186 if {[string match @@* $_shellpath]} {
187 if {[info exists env(SHELL)]} {
188 return $env(SHELL)
189 } else {
190 return /bin/sh
191 }
192 }
193 return $_shellpath
194 }
195
196 proc appname {} {
197 global _appname
198 return $_appname
199 }
200
201 proc gitdir {args} {
202 global _gitdir
203 if {$args eq {}} {
204 return $_gitdir
205 }
206 return [eval [list file join $_gitdir] $args]
207 }
208
209 proc gitexec {args} {
210 global _gitexec
211 if {$_gitexec eq {}} {
212 if {[catch {set _gitexec [git --exec-path]} err]} {
213 error "Git not installed?\n\n$err"
214 }
215 if {[is_Cygwin]} {
216 set _gitexec [exec cygpath \
217 --windows \
218 --absolute \
219 $_gitexec]
220 } else {
221 set _gitexec [file normalize $_gitexec]
222 }
223 }
224 if {$args eq {}} {
225 return $_gitexec
226 }
227 return [eval [list file join $_gitexec] $args]
228 }
229
230 proc githtmldir {args} {
231 global _githtmldir
232 if {$_githtmldir eq {}} {
233 if {[catch {set _githtmldir [git --html-path]}]} {
234 # Git not installed or option not yet supported
235 return {}
236 }
237 if {[is_Cygwin]} {
238 set _githtmldir [exec cygpath \
239 --windows \
240 --absolute \
241 $_githtmldir]
242 } else {
243 set _githtmldir [file normalize $_githtmldir]
244 }
245 }
246 if {$args eq {}} {
247 return $_githtmldir
248 }
249 return [eval [list file join $_githtmldir] $args]
250 }
251
252 proc reponame {} {
253 return $::_reponame
254 }
255
256 proc is_MacOSX {} {
257 if {[tk windowingsystem] eq {aqua}} {
258 return 1
259 }
260 return 0
261 }
262
263 proc is_Windows {} {
264 if {$::tcl_platform(platform) eq {windows}} {
265 return 1
266 }
267 return 0
268 }
269
270 proc is_Cygwin {} {
271 global _iscygwin
272 if {$_iscygwin eq {}} {
273 if {$::tcl_platform(platform) eq {windows}} {
274 if {[catch {set p [exec cygpath --windir]} err]} {
275 set _iscygwin 0
276 } else {
277 set _iscygwin 1
278 # Handle MSys2 which is only cygwin when MSYSTEM is MSYS.
279 if {[info exists ::env(MSYSTEM)] && $::env(MSYSTEM) ne "MSYS"} {
280 set _iscygwin 0
281 }
282 }
283 } else {
284 set _iscygwin 0
285 }
286 }
287 return $_iscygwin
288 }
289
290 proc is_enabled {option} {
291 global enabled_options
292 if {[catch {set on $enabled_options($option)}]} {return 0}
293 return $on
294 }
295
296 proc enable_option {option} {
297 global enabled_options
298 set enabled_options($option) 1
299 }
300
301 proc disable_option {option} {
302 global enabled_options
303 set enabled_options($option) 0
304 }
305
306 ######################################################################
307 ##
308 ## config
309
310 proc is_many_config {name} {
311 switch -glob -- $name {
312 gui.recentrepo -
313 remote.*.fetch -
314 remote.*.push
315 {return 1}
316 *
317 {return 0}
318 }
319 }
320
321 proc is_config_true {name} {
322 global repo_config
323 if {[catch {set v $repo_config($name)}]} {
324 return 0
325 }
326 set v [string tolower $v]
327 if {$v eq {} || $v eq {true} || $v eq {1} || $v eq {yes} || $v eq {on}} {
328 return 1
329 } else {
330 return 0
331 }
332 }
333
334 proc is_config_false {name} {
335 global repo_config
336 if {[catch {set v $repo_config($name)}]} {
337 return 0
338 }
339 set v [string tolower $v]
340 if {$v eq {false} || $v eq {0} || $v eq {no} || $v eq {off}} {
341 return 1
342 } else {
343 return 0
344 }
345 }
346
347 proc get_config {name} {
348 global repo_config
349 if {[catch {set v $repo_config($name)}]} {
350 return {}
351 } else {
352 return $v
353 }
354 }
355
356 proc is_bare {} {
357 global _isbare
358 global _gitdir
359 global _gitworktree
360
361 if {$_isbare eq {}} {
362 if {[catch {
363 set _bare [git rev-parse --is-bare-repository]
364 switch -- $_bare {
365 true { set _isbare 1 }
366 false { set _isbare 0}
367 default { throw }
368 }
369 }]} {
370 if {[is_config_true core.bare]
371 || ($_gitworktree eq {}
372 && [lindex [file split $_gitdir] end] ne {.git})} {
373 set _isbare 1
374 } else {
375 set _isbare 0
376 }
377 }
378 }
379 return $_isbare
380 }
381
382 ######################################################################
383 ##
384 ## handy utils
385
386 proc _trace_exec {cmd} {
387 if {!$::_trace} return
388 set d {}
389 foreach v $cmd {
390 if {$d ne {}} {
391 append d { }
392 }
393 if {[regexp {[ \t\r\n'"$?*]} $v]} {
394 set v [sq $v]
395 }
396 append d $v
397 }
398 puts stderr $d
399 }
400
401 #'" fix poor old emacs font-lock mode
402
403 proc _git_cmd {name} {
404 global _git_cmd_path
405
406 if {[catch {set v $_git_cmd_path($name)}]} {
407 switch -- $name {
408 version -
409 --version -
410 --exec-path { return [list $::_git $name] }
411 }
412
413 set p [gitexec git-$name$::_search_exe]
414 if {[file exists $p]} {
415 set v [list $p]
416 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
417 # Try to determine what sort of magic will make
418 # git-$name go and do its thing, because native
419 # Tcl on Windows doesn't know it.
420 #
421 set p [gitexec git-$name]
422 set f [open $p r]
423 set s [gets $f]
424 close $f
425
426 switch -glob -- [lindex $s 0] {
427 #!*sh { set i sh }
428 #!*perl { set i perl }
429 #!*python { set i python }
430 default { error "git-$name is not supported: $s" }
431 }
432
433 upvar #0 _$i interp
434 if {![info exists interp]} {
435 set interp [_which $i]
436 }
437 if {$interp eq {}} {
438 error "git-$name requires $i (not in PATH)"
439 }
440 set v [concat [list $interp] [lrange $s 1 end] [list $p]]
441 } else {
442 # Assume it is builtin to git somehow and we
443 # aren't actually able to see a file for it.
444 #
445 set v [list $::_git $name]
446 }
447 set _git_cmd_path($name) $v
448 }
449 return $v
450 }
451
452 proc _which {what args} {
453 global env _search_exe _search_path
454
455 if {$_search_path eq {}} {
456 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
457 set _search_path [split [exec cygpath \
458 --windows \
459 --path \
460 --absolute \
461 $env(PATH)] {;}]
462 set _search_exe .exe
463 } elseif {[is_Windows]} {
464 set gitguidir [file dirname [info script]]
465 regsub -all ";" $gitguidir "\\;" gitguidir
466 set env(PATH) "$gitguidir;$env(PATH)"
467 set _search_path [split $env(PATH) {;}]
468 set _search_exe .exe
469 } else {
470 set _search_path [split $env(PATH) :]
471 set _search_exe {}
472 }
473 }
474
475 if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
476 set suffix {}
477 } else {
478 set suffix $_search_exe
479 }
480
481 foreach p $_search_path {
482 set p [file join $p $what$suffix]
483 if {[file exists $p]} {
484 return [file normalize $p]
485 }
486 }
487 return {}
488 }
489
490 # Test a file for a hashbang to identify executable scripts on Windows.
491 proc is_shellscript {filename} {
492 if {![file exists $filename]} {return 0}
493 set f [open $filename r]
494 fconfigure $f -encoding binary
495 set magic [read $f 2]
496 close $f
497 return [expr {$magic eq "#!"}]
498 }
499
500 # Run a command connected via pipes on stdout.
501 # This is for use with textconv filters and uses sh -c "..." to allow it to
502 # contain a command with arguments. On windows we must check for shell
503 # scripts specifically otherwise just call the filter command.
504 proc open_cmd_pipe {cmd path} {
505 global env
506 if {![file executable [shellpath]]} {
507 set exe [auto_execok [lindex $cmd 0]]
508 if {[is_shellscript [lindex $exe 0]]} {
509 set run [linsert [auto_execok sh] end -c "$cmd \"\$0\"" $path]
510 } else {
511 set run [concat $exe [lrange $cmd 1 end] $path]
512 }
513 } else {
514 set run [list [shellpath] -c "$cmd \"\$0\"" $path]
515 }
516 return [open |$run r]
517 }
518
519 proc _lappend_nice {cmd_var} {
520 global _nice
521 upvar $cmd_var cmd
522
523 if {![info exists _nice]} {
524 set _nice [_which nice]
525 if {[catch {exec $_nice git version}]} {
526 set _nice {}
527 } elseif {[is_Windows] && [file dirname $_nice] ne [file dirname $::_git]} {
528 set _nice {}
529 }
530 }
531 if {$_nice ne {}} {
532 lappend cmd $_nice
533 }
534 }
535
536 proc git {args} {
537 set fd [eval [list git_read] $args]
538 fconfigure $fd -translation binary -encoding utf-8
539 set result [string trimright [read $fd] "\n"]
540 close $fd
541 if {$::_trace} {
542 puts stderr "< $result"
543 }
544 return $result
545 }
546
547 proc _open_stdout_stderr {cmd} {
548 _trace_exec $cmd
549 if {[catch {
550 set fd [open [concat [list | ] $cmd] r]
551 } err]} {
552 if { [lindex $cmd end] eq {2>@1}
553 && $err eq {can not find channel named "1"}
554 } {
555 # Older versions of Tcl 8.4 don't have this 2>@1 IO
556 # redirect operator. Fallback to |& cat for those.
557 # The command was not actually started, so its safe
558 # to try to start it a second time.
559 #
560 set fd [open [concat \
561 [list | ] \
562 [lrange $cmd 0 end-1] \
563 [list |& cat] \
564 ] r]
565 } else {
566 error $err
567 }
568 }
569 fconfigure $fd -eofchar {}
570 return $fd
571 }
572
573 proc git_read {args} {
574 set opt [list]
575
576 while {1} {
577 switch -- [lindex $args 0] {
578 --nice {
579 _lappend_nice opt
580 }
581
582 --stderr {
583 lappend args 2>@1
584 }
585
586 default {
587 break
588 }
589
590 }
591
592 set args [lrange $args 1 end]
593 }
594
595 set cmdp [_git_cmd [lindex $args 0]]
596 set args [lrange $args 1 end]
597
598 return [_open_stdout_stderr [concat $opt $cmdp $args]]
599 }
600
601 proc git_write {args} {
602 set opt [list]
603
604 while {1} {
605 switch -- [lindex $args 0] {
606 --nice {
607 _lappend_nice opt
608 }
609
610 default {
611 break
612 }
613
614 }
615
616 set args [lrange $args 1 end]
617 }
618
619 set cmdp [_git_cmd [lindex $args 0]]
620 set args [lrange $args 1 end]
621
622 _trace_exec [concat $opt $cmdp $args]
623 return [open [concat [list | ] $opt $cmdp $args] w]
624 }
625
626 proc githook_read {hook_name args} {
627 set pchook [gitdir hooks $hook_name]
628 lappend args 2>@1
629
630 # On Windows [file executable] might lie so we need to ask
631 # the shell if the hook is executable. Yes that's annoying.
632 #
633 if {[is_Windows]} {
634 upvar #0 _sh interp
635 if {![info exists interp]} {
636 set interp [_which sh]
637 }
638 if {$interp eq {}} {
639 error "hook execution requires sh (not in PATH)"
640 }
641
642 set scr {if test -x "$1";then exec "$@";fi}
643 set sh_c [list $interp -c $scr $interp $pchook]
644 return [_open_stdout_stderr [concat $sh_c $args]]
645 }
646
647 if {[file executable $pchook]} {
648 return [_open_stdout_stderr [concat [list $pchook] $args]]
649 }
650
651 return {}
652 }
653
654 proc kill_file_process {fd} {
655 set process [pid $fd]
656
657 catch {
658 if {[is_Windows]} {
659 exec taskkill /pid $process
660 } else {
661 exec kill $process
662 }
663 }
664 }
665
666 proc gitattr {path attr default} {
667 if {[catch {set r [git check-attr $attr -- $path]}]} {
668 set r unspecified
669 } else {
670 set r [join [lrange [split $r :] 2 end] :]
671 regsub {^ } $r {} r
672 }
673 if {$r eq {unspecified}} {
674 return $default
675 }
676 return $r
677 }
678
679 proc sq {value} {
680 regsub -all ' $value "'\\''" value
681 return "'$value'"
682 }
683
684 proc load_current_branch {} {
685 global current_branch is_detached
686
687 set fd [open [gitdir HEAD] r]
688 if {[gets $fd ref] < 1} {
689 set ref {}
690 }
691 close $fd
692
693 set pfx {ref: refs/heads/}
694 set len [string length $pfx]
695 if {[string equal -length $len $pfx $ref]} {
696 # We're on a branch. It might not exist. But
697 # HEAD looks good enough to be a branch.
698 #
699 set current_branch [string range $ref $len end]
700 set is_detached 0
701 } else {
702 # Assume this is a detached head.
703 #
704 set current_branch HEAD
705 set is_detached 1
706 }
707 }
708
709 auto_load tk_optionMenu
710 rename tk_optionMenu real__tkOptionMenu
711 proc tk_optionMenu {w varName args} {
712 set m [eval real__tkOptionMenu $w $varName $args]
713 $m configure -font font_ui
714 $w configure -font font_ui
715 return $m
716 }
717
718 proc rmsel_tag {text} {
719 $text tag conf sel \
720 -background [$text cget -background] \
721 -foreground [$text cget -foreground] \
722 -borderwidth 0
723 $text tag conf in_sel -background lightgray
724 bind $text <Motion> break
725 return $text
726 }
727
728 wm withdraw .
729 set root_exists 0
730 bind . <Visibility> {
731 bind . <Visibility> {}
732 set root_exists 1
733 }
734
735 if {[is_Windows]} {
736 wm iconbitmap . -default $oguilib/git-gui.ico
737 set ::tk::AlwaysShowSelection 1
738 bind . <Control-F2> {console show}
739
740 # Spoof an X11 display for SSH
741 if {![info exists env(DISPLAY)]} {
742 set env(DISPLAY) :9999
743 }
744 } else {
745 catch {
746 image create photo gitlogo -width 16 -height 16
747
748 gitlogo put #33CC33 -to 7 0 9 2
749 gitlogo put #33CC33 -to 4 2 12 4
750 gitlogo put #33CC33 -to 7 4 9 6
751 gitlogo put #CC3333 -to 4 6 12 8
752 gitlogo put gray26 -to 4 9 6 10
753 gitlogo put gray26 -to 3 10 6 12
754 gitlogo put gray26 -to 8 9 13 11
755 gitlogo put gray26 -to 8 11 10 12
756 gitlogo put gray26 -to 11 11 13 14
757 gitlogo put gray26 -to 3 12 5 14
758 gitlogo put gray26 -to 5 13
759 gitlogo put gray26 -to 10 13
760 gitlogo put gray26 -to 4 14 12 15
761 gitlogo put gray26 -to 5 15 11 16
762 gitlogo redither
763
764 image create photo gitlogo32 -width 32 -height 32
765 gitlogo32 copy gitlogo -zoom 2 2
766
767 wm iconphoto . -default gitlogo gitlogo32
768 }
769 }
770
771 ######################################################################
772 ##
773 ## config defaults
774
775 set cursor_ptr arrow
776 font create font_ui
777 if {[lsearch -exact [font names] TkDefaultFont] != -1} {
778 eval [linsert [font actual TkDefaultFont] 0 font configure font_ui]
779 eval [linsert [font actual TkFixedFont] 0 font create font_diff]
780 } else {
781 font create font_diff -family Courier -size 10
782 catch {
783 label .dummy
784 eval font configure font_ui [font actual [.dummy cget -font]]
785 destroy .dummy
786 }
787 }
788
789 font create font_uiitalic
790 font create font_uibold
791 font create font_diffbold
792 font create font_diffitalic
793
794 foreach class {Button Checkbutton Entry Label
795 Labelframe Listbox Message
796 Radiobutton Spinbox Text} {
797 option add *$class.font font_ui
798 }
799 if {![is_MacOSX]} {
800 option add *Menu.font font_ui
801 option add *Entry.borderWidth 1 startupFile
802 option add *Entry.relief sunken startupFile
803 option add *RadioButton.anchor w startupFile
804 }
805 unset class
806
807 if {[is_Windows] || [is_MacOSX]} {
808 option add *Menu.tearOff 0
809 }
810
811 if {[is_MacOSX]} {
812 set M1B M1
813 set M1T Cmd
814 } else {
815 set M1B Control
816 set M1T Ctrl
817 }
818
819 proc bind_button3 {w cmd} {
820 bind $w <Any-Button-3> $cmd
821 if {[is_MacOSX]} {
822 # Mac OS X sends Button-2 on right click through three-button mouse,
823 # or through trackpad right-clicking (two-finger touch + click).
824 bind $w <Any-Button-2> $cmd
825 bind $w <Control-Button-1> $cmd
826 }
827 }
828
829 proc apply_config {} {
830 global repo_config font_descs
831
832 foreach option $font_descs {
833 set name [lindex $option 0]
834 set font [lindex $option 1]
835 if {[catch {
836 set need_weight 1
837 foreach {cn cv} $repo_config(gui.$name) {
838 if {$cn eq {-weight}} {
839 set need_weight 0
840 }
841 font configure $font $cn $cv
842 }
843 if {$need_weight} {
844 font configure $font -weight normal
845 }
846 } err]} {
847 error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
848 }
849 foreach {cn cv} [font configure $font] {
850 font configure ${font}bold $cn $cv
851 font configure ${font}italic $cn $cv
852 }
853 font configure ${font}bold -weight bold
854 font configure ${font}italic -slant italic
855 }
856
857 global use_ttk NS
858 set use_ttk 0
859 set NS {}
860 if {$repo_config(gui.usettk)} {
861 set use_ttk [package vsatisfies [package provide Tk] 8.5]
862 if {$use_ttk} {
863 set NS ttk
864 bind [winfo class .] <<ThemeChanged>> [list InitTheme]
865 pave_toplevel .
866 }
867 }
868 }
869
870 set default_config(branch.autosetupmerge) true
871 set default_config(merge.tool) {}
872 set default_config(mergetool.keepbackup) true
873 set default_config(merge.diffstat) true
874 set default_config(merge.summary) false
875 set default_config(merge.verbosity) 2
876 set default_config(user.name) {}
877 set default_config(user.email) {}
878
879 set default_config(gui.encoding) [encoding system]
880 set default_config(gui.matchtrackingbranch) false
881 set default_config(gui.textconv) true
882 set default_config(gui.pruneduringfetch) false
883 set default_config(gui.trustmtime) false
884 set default_config(gui.fastcopyblame) false
885 set default_config(gui.maxrecentrepo) 10
886 set default_config(gui.copyblamethreshold) 40
887 set default_config(gui.blamehistoryctx) 7
888 set default_config(gui.diffcontext) 5
889 set default_config(gui.diffopts) {}
890 set default_config(gui.commitmsgwidth) 75
891 set default_config(gui.newbranchtemplate) {}
892 set default_config(gui.spellingdictionary) {}
893 set default_config(gui.fontui) [font configure font_ui]
894 set default_config(gui.fontdiff) [font configure font_diff]
895 # TODO: this option should be added to the git-config documentation
896 set default_config(gui.maxfilesdisplayed) 5000
897 set default_config(gui.usettk) 1
898 set default_config(gui.warndetachedcommit) 1
899 set default_config(gui.tabsize) 8
900 set font_descs {
901 {fontui font_ui {mc "Main Font"}}
902 {fontdiff font_diff {mc "Diff/Console Font"}}
903 }
904 set default_config(gui.stageuntracked) ask
905 set default_config(gui.displayuntracked) true
906
907 ######################################################################
908 ##
909 ## find git
910
911 set _git [_which git]
912 if {$_git eq {}} {
913 catch {wm withdraw .}
914 tk_messageBox \
915 -icon error \
916 -type ok \
917 -title [mc "git-gui: fatal error"] \
918 -message [mc "Cannot find git in PATH."]
919 exit 1
920 }
921
922 ######################################################################
923 ##
924 ## version check
925
926 if {[catch {set _git_version [git --version]} err]} {
927 catch {wm withdraw .}
928 tk_messageBox \
929 -icon error \
930 -type ok \
931 -title [mc "git-gui: fatal error"] \
932 -message "Cannot determine Git version:
933
934 $err
935
936 [appname] requires Git 1.5.0 or later."
937 exit 1
938 }
939 if {![regsub {^git version } $_git_version {} _git_version]} {
940 catch {wm withdraw .}
941 tk_messageBox \
942 -icon error \
943 -type ok \
944 -title [mc "git-gui: fatal error"] \
945 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
946 exit 1
947 }
948
949 proc get_trimmed_version {s} {
950 set r {}
951 foreach x [split $s -._] {
952 if {[string is integer -strict $x]} {
953 lappend r $x
954 } else {
955 break
956 }
957 }
958 return [join $r .]
959 }
960 set _real_git_version $_git_version
961 set _git_version [get_trimmed_version $_git_version]
962
963 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
964 catch {wm withdraw .}
965 if {[tk_messageBox \
966 -icon warning \
967 -type yesno \
968 -default no \
969 -title "[appname]: warning" \
970 -message [mc "Git version cannot be determined.
971
972 %s claims it is version '%s'.
973
974 %s requires at least Git 1.5.0 or later.
975
976 Assume '%s' is version 1.5.0?
977 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
978 set _git_version 1.5.0
979 } else {
980 exit 1
981 }
982 }
983 unset _real_git_version
984
985 proc git-version {args} {
986 global _git_version
987
988 switch [llength $args] {
989 0 {
990 return $_git_version
991 }
992
993 2 {
994 set op [lindex $args 0]
995 set vr [lindex $args 1]
996 set cm [package vcompare $_git_version $vr]
997 return [expr $cm $op 0]
998 }
999
1000 4 {
1001 set type [lindex $args 0]
1002 set name [lindex $args 1]
1003 set parm [lindex $args 2]
1004 set body [lindex $args 3]
1005
1006 if {($type ne {proc} && $type ne {method})} {
1007 error "Invalid arguments to git-version"
1008 }
1009 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
1010 error "Last arm of $type $name must be default"
1011 }
1012
1013 foreach {op vr cb} [lrange $body 0 end-2] {
1014 if {[git-version $op $vr]} {
1015 return [uplevel [list $type $name $parm $cb]]
1016 }
1017 }
1018
1019 return [uplevel [list $type $name $parm [lindex $body end]]]
1020 }
1021
1022 default {
1023 error "git-version >= x"
1024 }
1025
1026 }
1027 }
1028
1029 if {[git-version < 1.5]} {
1030 catch {wm withdraw .}
1031 tk_messageBox \
1032 -icon error \
1033 -type ok \
1034 -title [mc "git-gui: fatal error"] \
1035 -message "[appname] requires Git 1.5.0 or later.
1036
1037 You are using [git-version]:
1038
1039 [git --version]"
1040 exit 1
1041 }
1042
1043 ######################################################################
1044 ##
1045 ## configure our library
1046
1047 set idx [file join $oguilib tclIndex]
1048 if {[catch {set fd [open $idx r]} err]} {
1049 catch {wm withdraw .}
1050 tk_messageBox \
1051 -icon error \
1052 -type ok \
1053 -title [mc "git-gui: fatal error"] \
1054 -message $err
1055 exit 1
1056 }
1057 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
1058 set idx [list]
1059 while {[gets $fd n] >= 0} {
1060 if {$n ne {} && ![string match #* $n]} {
1061 lappend idx $n
1062 }
1063 }
1064 } else {
1065 set idx {}
1066 }
1067 close $fd
1068
1069 if {$idx ne {}} {
1070 set loaded [list]
1071 foreach p $idx {
1072 if {[lsearch -exact $loaded $p] >= 0} continue
1073 source [file join $oguilib $p]
1074 lappend loaded $p
1075 }
1076 unset loaded p
1077 } else {
1078 set auto_path [concat [list $oguilib] $auto_path]
1079 }
1080 unset -nocomplain idx fd
1081
1082 ######################################################################
1083 ##
1084 ## config file parsing
1085
1086 git-version proc _parse_config {arr_name args} {
1087 >= 1.5.3 {
1088 upvar $arr_name arr
1089 array unset arr
1090 set buf {}
1091 catch {
1092 set fd_rc [eval \
1093 [list git_read config] \
1094 $args \
1095 [list --null --list]]
1096 fconfigure $fd_rc -translation binary -encoding utf-8
1097 set buf [read $fd_rc]
1098 close $fd_rc
1099 }
1100 foreach line [split $buf "\0"] {
1101 if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
1102 if {[is_many_config $name]} {
1103 lappend arr($name) $value
1104 } else {
1105 set arr($name) $value
1106 }
1107 } elseif {[regexp {^([^\n]+)$} $line line name]} {
1108 # no value given, but interpreting them as
1109 # boolean will be handled as true
1110 set arr($name) {}
1111 }
1112 }
1113 }
1114 default {
1115 upvar $arr_name arr
1116 array unset arr
1117 catch {
1118 set fd_rc [eval [list git_read config --list] $args]
1119 while {[gets $fd_rc line] >= 0} {
1120 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
1121 if {[is_many_config $name]} {
1122 lappend arr($name) $value
1123 } else {
1124 set arr($name) $value
1125 }
1126 } elseif {[regexp {^([^=]+)$} $line line name]} {
1127 # no value given, but interpreting them as
1128 # boolean will be handled as true
1129 set arr($name) {}
1130 }
1131 }
1132 close $fd_rc
1133 }
1134 }
1135 }
1136
1137 proc load_config {include_global} {
1138 global repo_config global_config system_config default_config
1139
1140 if {$include_global} {
1141 _parse_config system_config --system
1142 _parse_config global_config --global
1143 }
1144 _parse_config repo_config
1145
1146 foreach name [array names default_config] {
1147 if {[catch {set v $system_config($name)}]} {
1148 set system_config($name) $default_config($name)
1149 }
1150 }
1151 foreach name [array names system_config] {
1152 if {[catch {set v $global_config($name)}]} {
1153 set global_config($name) $system_config($name)
1154 }
1155 if {[catch {set v $repo_config($name)}]} {
1156 set repo_config($name) $system_config($name)
1157 }
1158 }
1159 }
1160
1161 ######################################################################
1162 ##
1163 ## feature option selection
1164
1165 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
1166 unset _junk
1167 } else {
1168 set subcommand gui
1169 }
1170 if {$subcommand eq {gui.sh}} {
1171 set subcommand gui
1172 }
1173 if {$subcommand eq {gui} && [llength $argv] > 0} {
1174 set subcommand [lindex $argv 0]
1175 set argv [lrange $argv 1 end]
1176 }
1177
1178 enable_option multicommit
1179 enable_option branch
1180 enable_option transport
1181 disable_option bare
1182
1183 switch -- $subcommand {
1184 browser -
1185 blame {
1186 enable_option bare
1187
1188 disable_option multicommit
1189 disable_option branch
1190 disable_option transport
1191 }
1192 citool {
1193 enable_option singlecommit
1194 enable_option retcode
1195
1196 disable_option multicommit
1197 disable_option branch
1198 disable_option transport
1199
1200 while {[llength $argv] > 0} {
1201 set a [lindex $argv 0]
1202 switch -- $a {
1203 --amend {
1204 enable_option initialamend
1205 }
1206 --nocommit {
1207 enable_option nocommit
1208 enable_option nocommitmsg
1209 }
1210 --commitmsg {
1211 disable_option nocommitmsg
1212 }
1213 default {
1214 break
1215 }
1216 }
1217
1218 set argv [lrange $argv 1 end]
1219 }
1220 }
1221 }
1222
1223 ######################################################################
1224 ##
1225 ## execution environment
1226
1227 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1228
1229 # Suggest our implementation of askpass, if none is set
1230 if {![info exists env(SSH_ASKPASS)]} {
1231 set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1232 }
1233
1234 ######################################################################
1235 ##
1236 ## repository setup
1237
1238 set picked 0
1239 if {[catch {
1240 set _gitdir $env(GIT_DIR)
1241 set _prefix {}
1242 }]
1243 && [catch {
1244 # beware that from the .git dir this sets _gitdir to .
1245 # and _prefix to the empty string
1246 set _gitdir [git rev-parse --git-dir]
1247 set _prefix [git rev-parse --show-prefix]
1248 } err]} {
1249 load_config 1
1250 apply_config
1251 choose_repository::pick
1252 set picked 1
1253 }
1254
1255 # we expand the _gitdir when it's just a single dot (i.e. when we're being
1256 # run from the .git dir itself) lest the routines to find the worktree
1257 # get confused
1258 if {$_gitdir eq "."} {
1259 set _gitdir [pwd]
1260 }
1261
1262 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1263 catch {set _gitdir [exec cygpath --windows $_gitdir]}
1264 }
1265 if {![file isdirectory $_gitdir]} {
1266 catch {wm withdraw .}
1267 error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1268 exit 1
1269 }
1270 # _gitdir exists, so try loading the config
1271 load_config 0
1272 apply_config
1273
1274 # v1.7.0 introduced --show-toplevel to return the canonical work-tree
1275 if {[package vcompare $_git_version 1.7.0] >= 0} {
1276 if { [is_Cygwin] } {
1277 catch {set _gitworktree [exec cygpath --windows [git rev-parse --show-toplevel]]}
1278 } else {
1279 set _gitworktree [git rev-parse --show-toplevel]
1280 }
1281 } else {
1282 # try to set work tree from environment, core.worktree or use
1283 # cdup to obtain a relative path to the top of the worktree. If
1284 # run from the top, the ./ prefix ensures normalize expands pwd.
1285 if {[catch { set _gitworktree $env(GIT_WORK_TREE) }]} {
1286 set _gitworktree [get_config core.worktree]
1287 if {$_gitworktree eq ""} {
1288 set _gitworktree [file normalize ./[git rev-parse --show-cdup]]
1289 }
1290 }
1291 }
1292
1293 if {$_prefix ne {}} {
1294 if {$_gitworktree eq {}} {
1295 regsub -all {[^/]+/} $_prefix ../ cdup
1296 } else {
1297 set cdup $_gitworktree
1298 }
1299 if {[catch {cd $cdup} err]} {
1300 catch {wm withdraw .}
1301 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1302 exit 1
1303 }
1304 set _gitworktree [pwd]
1305 unset cdup
1306 } elseif {![is_enabled bare]} {
1307 if {[is_bare]} {
1308 catch {wm withdraw .}
1309 error_popup [strcat [mc "Cannot use bare repository:"] "\n\n$_gitdir"]
1310 exit 1
1311 }
1312 if {$_gitworktree eq {}} {
1313 set _gitworktree [file dirname $_gitdir]
1314 }
1315 if {[catch {cd $_gitworktree} err]} {
1316 catch {wm withdraw .}
1317 error_popup [strcat [mc "No working directory"] " $_gitworktree:\n\n$err"]
1318 exit 1
1319 }
1320 set _gitworktree [pwd]
1321 }
1322 set _reponame [file split [file normalize $_gitdir]]
1323 if {[lindex $_reponame end] eq {.git}} {
1324 set _reponame [lindex $_reponame end-1]
1325 } else {
1326 set _reponame [lindex $_reponame end]
1327 }
1328
1329 set env(GIT_DIR) $_gitdir
1330 set env(GIT_WORK_TREE) $_gitworktree
1331
1332 ######################################################################
1333 ##
1334 ## global init
1335
1336 set current_diff_path {}
1337 set current_diff_side {}
1338 set diff_actions [list]
1339
1340 set HEAD {}
1341 set PARENT {}
1342 set MERGE_HEAD [list]
1343 set commit_type {}
1344 set empty_tree {}
1345 set current_branch {}
1346 set is_detached 0
1347 set current_diff_path {}
1348 set is_3way_diff 0
1349 set is_submodule_diff 0
1350 set is_conflict_diff 0
1351 set selected_commit_type new
1352 set diff_empty_count 0
1353
1354 set nullid "0000000000000000000000000000000000000000"
1355 set nullid2 "0000000000000000000000000000000000000001"
1356
1357 ######################################################################
1358 ##
1359 ## task management
1360
1361 set rescan_active 0
1362 set diff_active 0
1363 set last_clicked {}
1364
1365 set disable_on_lock [list]
1366 set index_lock_type none
1367
1368 proc lock_index {type} {
1369 global index_lock_type disable_on_lock
1370
1371 if {$index_lock_type eq {none}} {
1372 set index_lock_type $type
1373 foreach w $disable_on_lock {
1374 uplevel #0 $w disabled
1375 }
1376 return 1
1377 } elseif {$index_lock_type eq "begin-$type"} {
1378 set index_lock_type $type
1379 return 1
1380 }
1381 return 0
1382 }
1383
1384 proc unlock_index {} {
1385 global index_lock_type disable_on_lock
1386
1387 set index_lock_type none
1388 foreach w $disable_on_lock {
1389 uplevel #0 $w normal
1390 }
1391 }
1392
1393 ######################################################################
1394 ##
1395 ## status
1396
1397 proc repository_state {ctvar hdvar mhvar} {
1398 global current_branch
1399 upvar $ctvar ct $hdvar hd $mhvar mh
1400
1401 set mh [list]
1402
1403 load_current_branch
1404 if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1405 set hd {}
1406 set ct initial
1407 return
1408 }
1409
1410 set merge_head [gitdir MERGE_HEAD]
1411 if {[file exists $merge_head]} {
1412 set ct merge
1413 set fd_mh [open $merge_head r]
1414 while {[gets $fd_mh line] >= 0} {
1415 lappend mh $line
1416 }
1417 close $fd_mh
1418 return
1419 }
1420
1421 set ct normal
1422 }
1423
1424 proc PARENT {} {
1425 global PARENT empty_tree
1426
1427 set p [lindex $PARENT 0]
1428 if {$p ne {}} {
1429 return $p
1430 }
1431 if {$empty_tree eq {}} {
1432 set empty_tree [git mktree << {}]
1433 }
1434 return $empty_tree
1435 }
1436
1437 proc force_amend {} {
1438 global selected_commit_type
1439 global HEAD PARENT MERGE_HEAD commit_type
1440
1441 repository_state newType newHEAD newMERGE_HEAD
1442 set HEAD $newHEAD
1443 set PARENT $newHEAD
1444 set MERGE_HEAD $newMERGE_HEAD
1445 set commit_type $newType
1446
1447 set selected_commit_type amend
1448 do_select_commit_type
1449 }
1450
1451 proc rescan {after {honor_trustmtime 1}} {
1452 global HEAD PARENT MERGE_HEAD commit_type
1453 global ui_index ui_workdir ui_comm
1454 global rescan_active file_states
1455 global repo_config
1456
1457 if {$rescan_active > 0 || ![lock_index read]} return
1458
1459 repository_state newType newHEAD newMERGE_HEAD
1460 if {[string match amend* $commit_type]
1461 && $newType eq {normal}
1462 && $newHEAD eq $HEAD} {
1463 } else {
1464 set HEAD $newHEAD
1465 set PARENT $newHEAD
1466 set MERGE_HEAD $newMERGE_HEAD
1467 set commit_type $newType
1468 }
1469
1470 array unset file_states
1471
1472 if {!$::GITGUI_BCK_exists &&
1473 (![$ui_comm edit modified]
1474 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1475 if {[string match amend* $commit_type]} {
1476 } elseif {[load_message GITGUI_MSG utf-8]} {
1477 } elseif {[run_prepare_commit_msg_hook]} {
1478 } elseif {[load_message MERGE_MSG]} {
1479 } elseif {[load_message SQUASH_MSG]} {
1480 }
1481 $ui_comm edit reset
1482 $ui_comm edit modified false
1483 }
1484
1485 if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1486 rescan_stage2 {} $after
1487 } else {
1488 set rescan_active 1
1489 ui_status [mc "Refreshing file status..."]
1490 set fd_rf [git_read update-index \
1491 -q \
1492 --unmerged \
1493 --ignore-missing \
1494 --refresh \
1495 ]
1496 fconfigure $fd_rf -blocking 0 -translation binary
1497 fileevent $fd_rf readable \
1498 [list rescan_stage2 $fd_rf $after]
1499 }
1500 }
1501
1502 if {[is_Cygwin]} {
1503 set is_git_info_exclude {}
1504 proc have_info_exclude {} {
1505 global is_git_info_exclude
1506
1507 if {$is_git_info_exclude eq {}} {
1508 if {[catch {exec test -f [gitdir info exclude]}]} {
1509 set is_git_info_exclude 0
1510 } else {
1511 set is_git_info_exclude 1
1512 }
1513 }
1514 return $is_git_info_exclude
1515 }
1516 } else {
1517 proc have_info_exclude {} {
1518 return [file readable [gitdir info exclude]]
1519 }
1520 }
1521
1522 proc rescan_stage2 {fd after} {
1523 global rescan_active buf_rdi buf_rdf buf_rlo
1524
1525 if {$fd ne {}} {
1526 read $fd
1527 if {![eof $fd]} return
1528 close $fd
1529 }
1530
1531 if {[package vcompare $::_git_version 1.6.3] >= 0} {
1532 set ls_others [list --exclude-standard]
1533 } else {
1534 set ls_others [list --exclude-per-directory=.gitignore]
1535 if {[have_info_exclude]} {
1536 lappend ls_others "--exclude-from=[gitdir info exclude]"
1537 }
1538 set user_exclude [get_config core.excludesfile]
1539 if {$user_exclude ne {} && [file readable $user_exclude]} {
1540 lappend ls_others "--exclude-from=[file normalize $user_exclude]"
1541 }
1542 }
1543
1544 set buf_rdi {}
1545 set buf_rdf {}
1546 set buf_rlo {}
1547
1548 set rescan_active 2
1549 ui_status [mc "Scanning for modified files ..."]
1550 if {[git-version >= "1.7.2"]} {
1551 set fd_di [git_read diff-index --cached --ignore-submodules=dirty -z [PARENT]]
1552 } else {
1553 set fd_di [git_read diff-index --cached -z [PARENT]]
1554 }
1555 set fd_df [git_read diff-files -z]
1556
1557 fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1558 fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1559
1560 fileevent $fd_di readable [list read_diff_index $fd_di $after]
1561 fileevent $fd_df readable [list read_diff_files $fd_df $after]
1562
1563 if {[is_config_true gui.displayuntracked]} {
1564 set fd_lo [eval git_read ls-files --others -z $ls_others]
1565 fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1566 fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1567 incr rescan_active
1568 }
1569 }
1570
1571 proc load_message {file {encoding {}}} {
1572 global ui_comm
1573
1574 set f [gitdir $file]
1575 if {[file isfile $f]} {
1576 if {[catch {set fd [open $f r]}]} {
1577 return 0
1578 }
1579 fconfigure $fd -eofchar {}
1580 if {$encoding ne {}} {
1581 fconfigure $fd -encoding $encoding
1582 }
1583 set content [string trim [read $fd]]
1584 close $fd
1585 regsub -all -line {[ \r\t]+$} $content {} content
1586 $ui_comm delete 0.0 end
1587 $ui_comm insert end $content
1588 return 1
1589 }
1590 return 0
1591 }
1592
1593 proc run_prepare_commit_msg_hook {} {
1594 global pch_error
1595
1596 # prepare-commit-msg requires PREPARE_COMMIT_MSG exist. From git-gui
1597 # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1598 # empty file but existent file.
1599
1600 set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1601
1602 if {[file isfile [gitdir MERGE_MSG]]} {
1603 set pcm_source "merge"
1604 set fd_mm [open [gitdir MERGE_MSG] r]
1605 fconfigure $fd_mm -encoding utf-8
1606 puts -nonewline $fd_pcm [read $fd_mm]
1607 close $fd_mm
1608 } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1609 set pcm_source "squash"
1610 set fd_sm [open [gitdir SQUASH_MSG] r]
1611 fconfigure $fd_sm -encoding utf-8
1612 puts -nonewline $fd_pcm [read $fd_sm]
1613 close $fd_sm
1614 } else {
1615 set pcm_source ""
1616 }
1617
1618 close $fd_pcm
1619
1620 set fd_ph [githook_read prepare-commit-msg \
1621 [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1622 if {$fd_ph eq {}} {
1623 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1624 return 0;
1625 }
1626
1627 ui_status [mc "Calling prepare-commit-msg hook..."]
1628 set pch_error {}
1629
1630 fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1631 fileevent $fd_ph readable \
1632 [list prepare_commit_msg_hook_wait $fd_ph]
1633
1634 return 1;
1635 }
1636
1637 proc prepare_commit_msg_hook_wait {fd_ph} {
1638 global pch_error
1639
1640 append pch_error [read $fd_ph]
1641 fconfigure $fd_ph -blocking 1
1642 if {[eof $fd_ph]} {
1643 if {[catch {close $fd_ph}]} {
1644 ui_status [mc "Commit declined by prepare-commit-msg hook."]
1645 hook_failed_popup prepare-commit-msg $pch_error
1646 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1647 exit 1
1648 } else {
1649 load_message PREPARE_COMMIT_MSG
1650 }
1651 set pch_error {}
1652 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1653 return
1654 }
1655 fconfigure $fd_ph -blocking 0
1656 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1657 }
1658
1659 proc read_diff_index {fd after} {
1660 global buf_rdi
1661
1662 append buf_rdi [read $fd]
1663 set c 0
1664 set n [string length $buf_rdi]
1665 while {$c < $n} {
1666 set z1 [string first "\0" $buf_rdi $c]
1667 if {$z1 == -1} break
1668 incr z1
1669 set z2 [string first "\0" $buf_rdi $z1]
1670 if {$z2 == -1} break
1671
1672 incr c
1673 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1674 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1675 merge_state \
1676 [encoding convertfrom utf-8 $p] \
1677 [lindex $i 4]? \
1678 [list [lindex $i 0] [lindex $i 2]] \
1679 [list]
1680 set c $z2
1681 incr c
1682 }
1683 if {$c < $n} {
1684 set buf_rdi [string range $buf_rdi $c end]
1685 } else {
1686 set buf_rdi {}
1687 }
1688
1689 rescan_done $fd buf_rdi $after
1690 }
1691
1692 proc read_diff_files {fd after} {
1693 global buf_rdf
1694
1695 append buf_rdf [read $fd]
1696 set c 0
1697 set n [string length $buf_rdf]
1698 while {$c < $n} {
1699 set z1 [string first "\0" $buf_rdf $c]
1700 if {$z1 == -1} break
1701 incr z1
1702 set z2 [string first "\0" $buf_rdf $z1]
1703 if {$z2 == -1} break
1704
1705 incr c
1706 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1707 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1708 merge_state \
1709 [encoding convertfrom utf-8 $p] \
1710 ?[lindex $i 4] \
1711 [list] \
1712 [list [lindex $i 0] [lindex $i 2]]
1713 set c $z2
1714 incr c
1715 }
1716 if {$c < $n} {
1717 set buf_rdf [string range $buf_rdf $c end]
1718 } else {
1719 set buf_rdf {}
1720 }
1721
1722 rescan_done $fd buf_rdf $after
1723 }
1724
1725 proc read_ls_others {fd after} {
1726 global buf_rlo
1727
1728 append buf_rlo [read $fd]
1729 set pck [split $buf_rlo "\0"]
1730 set buf_rlo [lindex $pck end]
1731 foreach p [lrange $pck 0 end-1] {
1732 set p [encoding convertfrom utf-8 $p]
1733 if {[string index $p end] eq {/}} {
1734 set p [string range $p 0 end-1]
1735 }
1736 merge_state $p ?O
1737 }
1738 rescan_done $fd buf_rlo $after
1739 }
1740
1741 proc rescan_done {fd buf after} {
1742 global rescan_active current_diff_path
1743 global file_states repo_config
1744 upvar $buf to_clear
1745
1746 if {![eof $fd]} return
1747 set to_clear {}
1748 close $fd
1749 if {[incr rescan_active -1] > 0} return
1750
1751 prune_selection
1752 unlock_index
1753 display_all_files
1754 if {$current_diff_path ne {}} { reshow_diff $after }
1755 if {$current_diff_path eq {}} { select_first_diff $after }
1756 }
1757
1758 proc prune_selection {} {
1759 global file_states selected_paths
1760
1761 foreach path [array names selected_paths] {
1762 if {[catch {set still_here $file_states($path)}]} {
1763 unset selected_paths($path)
1764 }
1765 }
1766 }
1767
1768 ######################################################################
1769 ##
1770 ## ui helpers
1771
1772 proc mapicon {w state path} {
1773 global all_icons
1774
1775 if {[catch {set r $all_icons($state$w)}]} {
1776 puts "error: no icon for $w state={$state} $path"
1777 return file_plain
1778 }
1779 return $r
1780 }
1781
1782 proc mapdesc {state path} {
1783 global all_descs
1784
1785 if {[catch {set r $all_descs($state)}]} {
1786 puts "error: no desc for state={$state} $path"
1787 return $state
1788 }
1789 return $r
1790 }
1791
1792 proc ui_status {msg} {
1793 global main_status
1794 if {[info exists main_status]} {
1795 $main_status show $msg
1796 }
1797 }
1798
1799 proc ui_ready {{test {}}} {
1800 global main_status
1801 if {[info exists main_status]} {
1802 $main_status show [mc "Ready."] $test
1803 }
1804 }
1805
1806 proc escape_path {path} {
1807 regsub -all {\\} $path "\\\\" path
1808 regsub -all "\n" $path "\\n" path
1809 return $path
1810 }
1811
1812 proc short_path {path} {
1813 return [escape_path [lindex [file split $path] end]]
1814 }
1815
1816 set next_icon_id 0
1817 set null_sha1 [string repeat 0 40]
1818
1819 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1820 global file_states next_icon_id null_sha1
1821
1822 set s0 [string index $new_state 0]
1823 set s1 [string index $new_state 1]
1824
1825 if {[catch {set info $file_states($path)}]} {
1826 set state __
1827 set icon n[incr next_icon_id]
1828 } else {
1829 set state [lindex $info 0]
1830 set icon [lindex $info 1]
1831 if {$head_info eq {}} {set head_info [lindex $info 2]}
1832 if {$index_info eq {}} {set index_info [lindex $info 3]}
1833 }
1834
1835 if {$s0 eq {?}} {set s0 [string index $state 0]} \
1836 elseif {$s0 eq {_}} {set s0 _}
1837
1838 if {$s1 eq {?}} {set s1 [string index $state 1]} \
1839 elseif {$s1 eq {_}} {set s1 _}
1840
1841 if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1842 set head_info [list 0 $null_sha1]
1843 } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1844 && $head_info eq {}} {
1845 set head_info $index_info
1846 } elseif {$s0 eq {_} && [string index $state 0] ne {_}} {
1847 set index_info $head_info
1848 set head_info {}
1849 }
1850
1851 set file_states($path) [list $s0$s1 $icon \
1852 $head_info $index_info \
1853 ]
1854 return $state
1855 }
1856
1857 proc display_file_helper {w path icon_name old_m new_m} {
1858 global file_lists
1859
1860 if {$new_m eq {_}} {
1861 set lno [lsearch -sorted -exact $file_lists($w) $path]
1862 if {$lno >= 0} {
1863 set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1864 incr lno
1865 $w conf -state normal
1866 $w delete $lno.0 [expr {$lno + 1}].0
1867 $w conf -state disabled
1868 }
1869 } elseif {$old_m eq {_} && $new_m ne {_}} {
1870 lappend file_lists($w) $path
1871 set file_lists($w) [lsort -unique $file_lists($w)]
1872 set lno [lsearch -sorted -exact $file_lists($w) $path]
1873 incr lno
1874 $w conf -state normal
1875 $w image create $lno.0 \
1876 -align center -padx 5 -pady 1 \
1877 -name $icon_name \
1878 -image [mapicon $w $new_m $path]
1879 $w insert $lno.1 "[escape_path $path]\n"
1880 $w conf -state disabled
1881 } elseif {$old_m ne $new_m} {
1882 $w conf -state normal
1883 $w image conf $icon_name -image [mapicon $w $new_m $path]
1884 $w conf -state disabled
1885 }
1886 }
1887
1888 proc display_file {path state} {
1889 global file_states selected_paths
1890 global ui_index ui_workdir
1891
1892 set old_m [merge_state $path $state]
1893 set s $file_states($path)
1894 set new_m [lindex $s 0]
1895 set icon_name [lindex $s 1]
1896
1897 set o [string index $old_m 0]
1898 set n [string index $new_m 0]
1899 if {$o eq {U}} {
1900 set o _
1901 }
1902 if {$n eq {U}} {
1903 set n _
1904 }
1905 display_file_helper $ui_index $path $icon_name $o $n
1906
1907 if {[string index $old_m 0] eq {U}} {
1908 set o U
1909 } else {
1910 set o [string index $old_m 1]
1911 }
1912 if {[string index $new_m 0] eq {U}} {
1913 set n U
1914 } else {
1915 set n [string index $new_m 1]
1916 }
1917 display_file_helper $ui_workdir $path $icon_name $o $n
1918
1919 if {$new_m eq {__}} {
1920 unset file_states($path)
1921 catch {unset selected_paths($path)}
1922 }
1923 }
1924
1925 proc display_all_files_helper {w path icon_name m} {
1926 global file_lists
1927
1928 lappend file_lists($w) $path
1929 set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1930 $w image create end \
1931 -align center -padx 5 -pady 1 \
1932 -name $icon_name \
1933 -image [mapicon $w $m $path]
1934 $w insert end "[escape_path $path]\n"
1935 }
1936
1937 set files_warning 0
1938 proc display_all_files {} {
1939 global ui_index ui_workdir
1940 global file_states file_lists
1941 global last_clicked
1942 global files_warning
1943
1944 $ui_index conf -state normal
1945 $ui_workdir conf -state normal
1946
1947 $ui_index delete 0.0 end
1948 $ui_workdir delete 0.0 end
1949 set last_clicked {}
1950
1951 set file_lists($ui_index) [list]
1952 set file_lists($ui_workdir) [list]
1953
1954 set to_display [lsort [array names file_states]]
1955 set display_limit [get_config gui.maxfilesdisplayed]
1956 set displayed 0
1957 foreach path $to_display {
1958 set s $file_states($path)
1959 set m [lindex $s 0]
1960 set icon_name [lindex $s 1]
1961
1962 if {$displayed > $display_limit && [string index $m 1] eq {O} } {
1963 if {!$files_warning} {
1964 # do not repeatedly warn:
1965 set files_warning 1
1966 info_popup [mc "Display limit (gui.maxfilesdisplayed = %s) reached, not showing all %s files." \
1967 $display_limit [llength $to_display]]
1968 }
1969 continue
1970 }
1971
1972 set s [string index $m 0]
1973 if {$s ne {U} && $s ne {_}} {
1974 display_all_files_helper $ui_index $path \
1975 $icon_name $s
1976 }
1977
1978 if {[string index $m 0] eq {U}} {
1979 set s U
1980 } else {
1981 set s [string index $m 1]
1982 }
1983 if {$s ne {_}} {
1984 display_all_files_helper $ui_workdir $path \
1985 $icon_name $s
1986 incr displayed
1987 }
1988 }
1989
1990 $ui_index conf -state disabled
1991 $ui_workdir conf -state disabled
1992 }
1993
1994 ######################################################################
1995 ##
1996 ## icons
1997
1998 set filemask {
1999 #define mask_width 14
2000 #define mask_height 15
2001 static unsigned char mask_bits[] = {
2002 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2003 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2004 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2005 }
2006
2007 image create bitmap file_plain -background white -foreground black -data {
2008 #define plain_width 14
2009 #define plain_height 15
2010 static unsigned char plain_bits[] = {
2011 0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2012 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2013 0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2014 } -maskdata $filemask
2015
2016 image create bitmap file_mod -background white -foreground blue -data {
2017 #define mod_width 14
2018 #define mod_height 15
2019 static unsigned char mod_bits[] = {
2020 0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2021 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2022 0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2023 } -maskdata $filemask
2024
2025 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2026 #define file_fulltick_width 14
2027 #define file_fulltick_height 15
2028 static unsigned char file_fulltick_bits[] = {
2029 0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2030 0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2031 0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2032 } -maskdata $filemask
2033
2034 image create bitmap file_question -background white -foreground black -data {
2035 #define file_question_width 14
2036 #define file_question_height 15
2037 static unsigned char file_question_bits[] = {
2038 0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2039 0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2040 0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2041 } -maskdata $filemask
2042
2043 image create bitmap file_removed -background white -foreground red -data {
2044 #define file_removed_width 14
2045 #define file_removed_height 15
2046 static unsigned char file_removed_bits[] = {
2047 0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2048 0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2049 0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2050 } -maskdata $filemask
2051
2052 image create bitmap file_merge -background white -foreground blue -data {
2053 #define file_merge_width 14
2054 #define file_merge_height 15
2055 static unsigned char file_merge_bits[] = {
2056 0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2057 0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2058 0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2059 } -maskdata $filemask
2060
2061 image create bitmap file_statechange -background white -foreground green -data {
2062 #define file_statechange_width 14
2063 #define file_statechange_height 15
2064 static unsigned char file_statechange_bits[] = {
2065 0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
2066 0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
2067 0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2068 } -maskdata $filemask
2069
2070 set ui_index .vpane.files.index.list
2071 set ui_workdir .vpane.files.workdir.list
2072
2073 set all_icons(_$ui_index) file_plain
2074 set all_icons(A$ui_index) file_plain
2075 set all_icons(M$ui_index) file_fulltick
2076 set all_icons(D$ui_index) file_removed
2077 set all_icons(U$ui_index) file_merge
2078 set all_icons(T$ui_index) file_statechange
2079
2080 set all_icons(_$ui_workdir) file_plain
2081 set all_icons(M$ui_workdir) file_mod
2082 set all_icons(D$ui_workdir) file_question
2083 set all_icons(U$ui_workdir) file_merge
2084 set all_icons(O$ui_workdir) file_plain
2085 set all_icons(T$ui_workdir) file_statechange
2086
2087 set max_status_desc 0
2088 foreach i {
2089 {__ {mc "Unmodified"}}
2090
2091 {_M {mc "Modified, not staged"}}
2092 {M_ {mc "Staged for commit"}}
2093 {MM {mc "Portions staged for commit"}}
2094 {MD {mc "Staged for commit, missing"}}
2095
2096 {_T {mc "File type changed, not staged"}}
2097 {MT {mc "File type changed, old type staged for commit"}}
2098 {AT {mc "File type changed, old type staged for commit"}}
2099 {T_ {mc "File type changed, staged"}}
2100 {TM {mc "File type change staged, modification not staged"}}
2101 {TD {mc "File type change staged, file missing"}}
2102
2103 {_O {mc "Untracked, not staged"}}
2104 {A_ {mc "Staged for commit"}}
2105 {AM {mc "Portions staged for commit"}}
2106 {AD {mc "Staged for commit, missing"}}
2107
2108 {_D {mc "Missing"}}
2109 {D_ {mc "Staged for removal"}}
2110 {DO {mc "Staged for removal, still present"}}
2111
2112 {_U {mc "Requires merge resolution"}}
2113 {U_ {mc "Requires merge resolution"}}
2114 {UU {mc "Requires merge resolution"}}
2115 {UM {mc "Requires merge resolution"}}
2116 {UD {mc "Requires merge resolution"}}
2117 {UT {mc "Requires merge resolution"}}
2118 } {
2119 set text [eval [lindex $i 1]]
2120 if {$max_status_desc < [string length $text]} {
2121 set max_status_desc [string length $text]
2122 }
2123 set all_descs([lindex $i 0]) $text
2124 }
2125 unset i
2126
2127 ######################################################################
2128 ##
2129 ## util
2130
2131 proc scrollbar2many {list mode args} {
2132 foreach w $list {eval $w $mode $args}
2133 }
2134
2135 proc many2scrollbar {list mode sb top bottom} {
2136 $sb set $top $bottom
2137 foreach w $list {$w $mode moveto $top}
2138 }
2139
2140 proc incr_font_size {font {amt 1}} {
2141 set sz [font configure $font -size]
2142 incr sz $amt
2143 font configure $font -size $sz
2144 font configure ${font}bold -size $sz
2145 font configure ${font}italic -size $sz
2146 }
2147
2148 ######################################################################
2149 ##
2150 ## ui commands
2151
2152 set starting_gitk_msg [mc "Starting gitk... please wait..."]
2153
2154 proc do_gitk {revs {is_submodule false}} {
2155 global current_diff_path file_states current_diff_side ui_index
2156 global _gitdir _gitworktree
2157
2158 # -- Always start gitk through whatever we were loaded with. This
2159 # lets us bypass using shell process on Windows systems.
2160 #
2161 set exe [_which gitk -script]
2162 set cmd [list [info nameofexecutable] $exe]
2163 if {$exe eq {}} {
2164 error_popup [mc "Couldn't find gitk in PATH"]
2165 } else {
2166 global env
2167
2168 set pwd [pwd]
2169
2170 if {!$is_submodule} {
2171 if {![is_bare]} {
2172 cd $_gitworktree
2173 }
2174 } else {
2175 cd $current_diff_path
2176 if {$revs eq {--}} {
2177 set s $file_states($current_diff_path)
2178 set old_sha1 {}
2179 set new_sha1 {}
2180 switch -glob -- [lindex $s 0] {
2181 M_ { set old_sha1 [lindex [lindex $s 2] 1] }
2182 _M { set old_sha1 [lindex [lindex $s 3] 1] }
2183 MM {
2184 if {$current_diff_side eq $ui_index} {
2185 set old_sha1 [lindex [lindex $s 2] 1]
2186 set new_sha1 [lindex [lindex $s 3] 1]
2187 } else {
2188 set old_sha1 [lindex [lindex $s 3] 1]
2189 }
2190 }
2191 }
2192 set revs $old_sha1...$new_sha1
2193 }
2194 # GIT_DIR and GIT_WORK_TREE for the submodule are not the ones
2195 # we've been using for the main repository, so unset them.
2196 # TODO we could make life easier (start up faster?) for gitk
2197 # by setting these to the appropriate values to allow gitk
2198 # to skip the heuristics to find their proper value
2199 unset env(GIT_DIR)
2200 unset env(GIT_WORK_TREE)
2201 }
2202 eval exec $cmd $revs "--" "--" &
2203
2204 set env(GIT_DIR) $_gitdir
2205 set env(GIT_WORK_TREE) $_gitworktree
2206 cd $pwd
2207
2208 ui_status $::starting_gitk_msg
2209 after 10000 {
2210 ui_ready $starting_gitk_msg
2211 }
2212 }
2213 }
2214
2215 proc do_git_gui {} {
2216 global current_diff_path
2217
2218 # -- Always start git gui through whatever we were loaded with. This
2219 # lets us bypass using shell process on Windows systems.
2220 #
2221 set exe [list [_which git]]
2222 if {$exe eq {}} {
2223 error_popup [mc "Couldn't find git gui in PATH"]
2224 } else {
2225 global env
2226 global _gitdir _gitworktree
2227
2228 # see note in do_gitk about unsetting these vars when
2229 # running tools in a submodule
2230 unset env(GIT_DIR)
2231 unset env(GIT_WORK_TREE)
2232
2233 set pwd [pwd]
2234 cd $current_diff_path
2235
2236 eval exec $exe gui &
2237
2238 set env(GIT_DIR) $_gitdir
2239 set env(GIT_WORK_TREE) $_gitworktree
2240 cd $pwd
2241
2242 ui_status $::starting_gitk_msg
2243 after 10000 {
2244 ui_ready $starting_gitk_msg
2245 }
2246 }
2247 }
2248
2249 proc do_explore {} {
2250 global _gitworktree
2251 set explorer {}
2252 if {[is_Cygwin] || [is_Windows]} {
2253 set explorer "explorer.exe"
2254 } elseif {[is_MacOSX]} {
2255 set explorer "open"
2256 } else {
2257 # freedesktop.org-conforming system is our best shot
2258 set explorer "xdg-open"
2259 }
2260 eval exec $explorer [list [file nativename $_gitworktree]] &
2261 }
2262
2263 set is_quitting 0
2264 set ret_code 1
2265
2266 proc terminate_me {win} {
2267 global ret_code
2268 if {$win ne {.}} return
2269 exit $ret_code
2270 }
2271
2272 proc do_quit {{rc {1}}} {
2273 global ui_comm is_quitting repo_config commit_type
2274 global GITGUI_BCK_exists GITGUI_BCK_i
2275 global ui_comm_spell
2276 global ret_code use_ttk
2277
2278 if {$is_quitting} return
2279 set is_quitting 1
2280
2281 if {[winfo exists $ui_comm]} {
2282 # -- Stash our current commit buffer.
2283 #
2284 set save [gitdir GITGUI_MSG]
2285 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
2286 file rename -force [gitdir GITGUI_BCK] $save
2287 set GITGUI_BCK_exists 0
2288 } else {
2289 set msg [string trim [$ui_comm get 0.0 end]]
2290 regsub -all -line {[ \r\t]+$} $msg {} msg
2291 if {(![string match amend* $commit_type]
2292 || [$ui_comm edit modified])
2293 && $msg ne {}} {
2294 catch {
2295 set fd [open $save w]
2296 fconfigure $fd -encoding utf-8
2297 puts -nonewline $fd $msg
2298 close $fd
2299 }
2300 } else {
2301 catch {file delete $save}
2302 }
2303 }
2304
2305 # -- Cancel our spellchecker if its running.
2306 #
2307 if {[info exists ui_comm_spell]} {
2308 $ui_comm_spell stop
2309 }
2310
2311 # -- Remove our editor backup, its not needed.
2312 #
2313 after cancel $GITGUI_BCK_i
2314 if {$GITGUI_BCK_exists} {
2315 catch {file delete [gitdir GITGUI_BCK]}
2316 }
2317
2318 # -- Stash our current window geometry into this repository.
2319 #
2320 set cfg_wmstate [wm state .]
2321 if {[catch {set rc_wmstate $repo_config(gui.wmstate)}]} {
2322 set rc_wmstate {}
2323 }
2324 if {$cfg_wmstate ne $rc_wmstate} {
2325 catch {git config gui.wmstate $cfg_wmstate}
2326 }
2327 if {$cfg_wmstate eq {zoomed}} {
2328 # on Windows wm geometry will lie about window
2329 # position (but not size) when window is zoomed
2330 # restore the window before querying wm geometry
2331 wm state . normal
2332 }
2333 set cfg_geometry [list]
2334 lappend cfg_geometry [wm geometry .]
2335 if {$use_ttk} {
2336 lappend cfg_geometry [.vpane sashpos 0]
2337 lappend cfg_geometry [.vpane.files sashpos 0]
2338 } else {
2339 lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2340 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2341 }
2342 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2343 set rc_geometry {}
2344 }
2345 if {$cfg_geometry ne $rc_geometry} {
2346 catch {git config gui.geometry $cfg_geometry}
2347 }
2348 }
2349
2350 set ret_code $rc
2351
2352 # Briefly enable send again, working around Tk bug
2353 # http://sourceforge.net/tracker/?func=detail&atid=112997&aid=1821174&group_id=12997
2354 tk appname [appname]
2355
2356 destroy .
2357 }
2358
2359 proc do_rescan {} {
2360 rescan ui_ready
2361 }
2362
2363 proc ui_do_rescan {} {
2364 rescan {force_first_diff ui_ready}
2365 }
2366
2367 proc do_commit {} {
2368 commit_tree
2369 }
2370
2371 proc next_diff {{after {}}} {
2372 global next_diff_p next_diff_w next_diff_i
2373 show_diff $next_diff_p $next_diff_w {} {} $after
2374 }
2375
2376 proc find_anchor_pos {lst name} {
2377 set lid [lsearch -sorted -exact $lst $name]
2378
2379 if {$lid == -1} {
2380 set lid 0
2381 foreach lname $lst {
2382 if {$lname >= $name} break
2383 incr lid
2384 }
2385 }
2386
2387 return $lid
2388 }
2389
2390 proc find_file_from {flist idx delta path mmask} {
2391 global file_states
2392
2393 set len [llength $flist]
2394 while {$idx >= 0 && $idx < $len} {
2395 set name [lindex $flist $idx]
2396
2397 if {$name ne $path && [info exists file_states($name)]} {
2398 set state [lindex $file_states($name) 0]
2399
2400 if {$mmask eq {} || [regexp $mmask $state]} {
2401 return $idx
2402 }
2403 }
2404
2405 incr idx $delta
2406 }
2407
2408 return {}
2409 }
2410
2411 proc find_next_diff {w path {lno {}} {mmask {}}} {
2412 global next_diff_p next_diff_w next_diff_i
2413 global file_lists ui_index ui_workdir
2414
2415 set flist $file_lists($w)
2416 if {$lno eq {}} {
2417 set lno [find_anchor_pos $flist $path]
2418 } else {
2419 incr lno -1
2420 }
2421
2422 if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2423 if {$w eq $ui_index} {
2424 set mmask "^$mmask"
2425 } else {
2426 set mmask "$mmask\$"
2427 }
2428 }
2429
2430 set idx [find_file_from $flist $lno 1 $path $mmask]
2431 if {$idx eq {}} {
2432 incr lno -1
2433 set idx [find_file_from $flist $lno -1 $path $mmask]
2434 }
2435
2436 if {$idx ne {}} {
2437 set next_diff_w $w
2438 set next_diff_p [lindex $flist $idx]
2439 set next_diff_i [expr {$idx+1}]
2440 return 1
2441 } else {
2442 return 0
2443 }
2444 }
2445
2446 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2447 global current_diff_path
2448
2449 if {$path ne $current_diff_path} {
2450 return {}
2451 } elseif {[find_next_diff $w $path $lno $mmask]} {
2452 return {next_diff;}
2453 } else {
2454 return {reshow_diff;}
2455 }
2456 }
2457
2458 proc select_first_diff {after} {
2459 global ui_workdir
2460
2461 if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2462 [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2463 next_diff $after
2464 } else {
2465 uplevel #0 $after
2466 }
2467 }
2468
2469 proc force_first_diff {after} {
2470 global ui_workdir current_diff_path file_states
2471
2472 if {[info exists file_states($current_diff_path)]} {
2473 set state [lindex $file_states($current_diff_path) 0]
2474 } else {
2475 set state {OO}
2476 }
2477
2478 set reselect 0
2479 if {[string first {U} $state] >= 0} {
2480 # Already a conflict, do nothing
2481 } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2482 set reselect 1
2483 } elseif {[string index $state 1] ne {O}} {
2484 # Already a diff & no conflicts, do nothing
2485 } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2486 set reselect 1
2487 }
2488
2489 if {$reselect} {
2490 next_diff $after
2491 } else {
2492 uplevel #0 $after
2493 }
2494 }
2495
2496 proc toggle_or_diff {mode w args} {
2497 global file_states file_lists current_diff_path ui_index ui_workdir
2498 global last_clicked selected_paths
2499
2500 if {$mode eq "click"} {
2501 foreach {x y} $args break
2502 set pos [split [$w index @$x,$y] .]
2503 foreach {lno col} $pos break
2504 } else {
2505 if {$last_clicked ne {}} {
2506 set lno [lindex $last_clicked 1]
2507 } else {
2508 set lno [expr {int([lindex [$w tag ranges in_diff] 0])}]
2509 }
2510 if {$mode eq "toggle"} {
2511 set col 0; set y 2
2512 } else {
2513 incr lno [expr {$mode eq "up" ? -1 : 1}]
2514 set col 1
2515 }
2516 }
2517
2518 set path [lindex $file_lists($w) [expr {$lno - 1}]]
2519 if {$path eq {}} {
2520 set last_clicked {}
2521 return
2522 }
2523
2524 set last_clicked [list $w $lno]
2525 focus $w
2526 array unset selected_paths
2527 $ui_index tag remove in_sel 0.0 end
2528 $ui_workdir tag remove in_sel 0.0 end
2529
2530 # Determine the state of the file
2531 if {[info exists file_states($path)]} {
2532 set state [lindex $file_states($path) 0]
2533 } else {
2534 set state {__}
2535 }
2536
2537 # Restage the file, or simply show the diff
2538 if {$col == 0 && $y > 1} {
2539 # Conflicts need special handling
2540 if {[string first {U} $state] >= 0} {
2541 # $w must always be $ui_workdir, but...
2542 if {$w ne $ui_workdir} { set lno {} }
2543 merge_stage_workdir $path $lno
2544 return
2545 }
2546
2547 if {[string index $state 1] eq {O}} {
2548 set mmask {}
2549 } else {
2550 set mmask {[^O]}
2551 }
2552
2553 set after [next_diff_after_action $w $path $lno $mmask]
2554
2555 if {$w eq $ui_index} {
2556 update_indexinfo \
2557 "Unstaging [short_path $path] from commit" \
2558 [list $path] \
2559 [concat $after [list ui_ready]]
2560 } elseif {$w eq $ui_workdir} {
2561 update_index \
2562 "Adding [short_path $path]" \
2563 [list $path] \
2564 [concat $after [list ui_ready]]
2565 }
2566 } else {
2567 set selected_paths($path) 1
2568 show_diff $path $w $lno
2569 }
2570 }
2571
2572 proc add_one_to_selection {w x y} {
2573 global file_lists last_clicked selected_paths
2574
2575 set lno [lindex [split [$w index @$x,$y] .] 0]
2576 set path [lindex $file_lists($w) [expr {$lno - 1}]]
2577 if {$path eq {}} {
2578 set last_clicked {}
2579 return
2580 }
2581
2582 if {$last_clicked ne {}
2583 && [lindex $last_clicked 0] ne $w} {
2584 array unset selected_paths
2585 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2586 }
2587
2588 set last_clicked [list $w $lno]
2589 if {[catch {set in_sel $selected_paths($path)}]} {
2590 set in_sel 0
2591 }
2592 if {$in_sel} {
2593 unset selected_paths($path)
2594 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2595 } else {
2596 set selected_paths($path) 1
2597 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2598 }
2599 }
2600
2601 proc add_range_to_selection {w x y} {
2602 global file_lists last_clicked selected_paths
2603
2604 if {[lindex $last_clicked 0] ne $w} {
2605 toggle_or_diff click $w $x $y
2606 return
2607 }
2608
2609 set lno [lindex [split [$w index @$x,$y] .] 0]
2610 set lc [lindex $last_clicked 1]
2611 if {$lc < $lno} {
2612 set begin $lc
2613 set end $lno
2614 } else {
2615 set begin $lno
2616 set end $lc
2617 }
2618
2619 foreach path [lrange $file_lists($w) \
2620 [expr {$begin - 1}] \
2621 [expr {$end - 1}]] {
2622 set selected_paths($path) 1
2623 }
2624 $w tag add in_sel $begin.0 [expr {$end + 1}].0
2625 }
2626
2627 proc show_more_context {} {
2628 global repo_config
2629 if {$repo_config(gui.diffcontext) < 99} {
2630 incr repo_config(gui.diffcontext)
2631 reshow_diff
2632 }
2633 }
2634
2635 proc show_less_context {} {
2636 global repo_config
2637 if {$repo_config(gui.diffcontext) > 1} {
2638 incr repo_config(gui.diffcontext) -1
2639 reshow_diff
2640 }
2641 }
2642
2643 ######################################################################
2644 ##
2645 ## ui construction
2646
2647 set ui_comm {}
2648
2649 # -- Menu Bar
2650 #
2651 menu .mbar -tearoff 0
2652 if {[is_MacOSX]} {
2653 # -- Apple Menu (Mac OS X only)
2654 #
2655 .mbar add cascade -label Apple -menu .mbar.apple
2656 menu .mbar.apple
2657 }
2658 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2659 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2660 if {[is_enabled branch]} {
2661 .mbar add cascade -label [mc Branch] -menu .mbar.branch
2662 }
2663 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2664 .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2665 }
2666 if {[is_enabled transport]} {
2667 .mbar add cascade -label [mc Merge] -menu .mbar.merge
2668 .mbar add cascade -label [mc Remote] -menu .mbar.remote
2669 }
2670 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2671 .mbar add cascade -label [mc Tools] -menu .mbar.tools
2672 }
2673
2674 # -- Repository Menu
2675 #
2676 menu .mbar.repository
2677
2678 if {![is_bare]} {
2679 .mbar.repository add command \
2680 -label [mc "Explore Working Copy"] \
2681 -command {do_explore}
2682 }
2683
2684 if {[is_Windows]} {
2685 .mbar.repository add command \
2686 -label [mc "Git Bash"] \
2687 -command {eval exec [auto_execok start] \
2688 [list "Git Bash" bash --login -l &]}
2689 }
2690
2691 if {[is_Windows] || ![is_bare]} {
2692 .mbar.repository add separator
2693 }
2694
2695 .mbar.repository add command \
2696 -label [mc "Browse Current Branch's Files"] \
2697 -command {browser::new $current_branch}
2698 set ui_browse_current [.mbar.repository index last]
2699 .mbar.repository add command \
2700 -label [mc "Browse Branch Files..."] \
2701 -command browser_open::dialog
2702 .mbar.repository add separator
2703
2704 .mbar.repository add command \
2705 -label [mc "Visualize Current Branch's History"] \
2706 -command {do_gitk $current_branch}
2707 set ui_visualize_current [.mbar.repository index last]
2708 .mbar.repository add command \
2709 -label [mc "Visualize All Branch History"] \
2710 -command {do_gitk --all}
2711 .mbar.repository add separator
2712
2713 proc current_branch_write {args} {
2714 global current_branch
2715 .mbar.repository entryconf $::ui_browse_current \
2716 -label [mc "Browse %s's Files" $current_branch]
2717 .mbar.repository entryconf $::ui_visualize_current \
2718 -label [mc "Visualize %s's History" $current_branch]
2719 }
2720 trace add variable current_branch write current_branch_write
2721
2722 if {[is_enabled multicommit]} {
2723 .mbar.repository add command -label [mc "Database Statistics"] \
2724 -command do_stats
2725
2726 .mbar.repository add command -label [mc "Compress Database"] \
2727 -command do_gc
2728
2729 .mbar.repository add command -label [mc "Verify Database"] \
2730 -command do_fsck_objects
2731
2732 .mbar.repository add separator
2733
2734 if {[is_Cygwin]} {
2735 .mbar.repository add command \
2736 -label [mc "Create Desktop Icon"] \
2737 -command do_cygwin_shortcut
2738 } elseif {[is_Windows]} {
2739 .mbar.repository add command \
2740 -label [mc "Create Desktop Icon"] \
2741 -command do_windows_shortcut
2742 } elseif {[is_MacOSX]} {
2743 .mbar.repository add command \
2744 -label [mc "Create Desktop Icon"] \
2745 -command do_macosx_app
2746 }
2747 }
2748
2749 if {[is_MacOSX]} {
2750 proc ::tk::mac::Quit {args} { do_quit }
2751 } else {
2752 .mbar.repository add command -label [mc Quit] \
2753 -command do_quit \
2754 -accelerator $M1T-Q
2755 }
2756
2757 # -- Edit Menu
2758 #
2759 menu .mbar.edit
2760 .mbar.edit add command -label [mc Undo] \
2761 -command {catch {[focus] edit undo}} \
2762 -accelerator $M1T-Z
2763 .mbar.edit add command -label [mc Redo] \
2764 -command {catch {[focus] edit redo}} \
2765 -accelerator $M1T-Y
2766 .mbar.edit add separator
2767 .mbar.edit add command -label [mc Cut] \
2768 -command {catch {tk_textCut [focus]}} \
2769 -accelerator $M1T-X
2770 .mbar.edit add command -label [mc Copy] \
2771 -command {catch {tk_textCopy [focus]}} \
2772 -accelerator $M1T-C
2773 .mbar.edit add command -label [mc Paste] \
2774 -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2775 -accelerator $M1T-V
2776 .mbar.edit add command -label [mc Delete] \
2777 -command {catch {[focus] delete sel.first sel.last}} \
2778 -accelerator Del
2779 .mbar.edit add separator
2780 .mbar.edit add command -label [mc "Select All"] \
2781 -command {catch {[focus] tag add sel 0.0 end}} \
2782 -accelerator $M1T-A
2783
2784 # -- Branch Menu
2785 #
2786 if {[is_enabled branch]} {
2787 menu .mbar.branch
2788
2789 .mbar.branch add command -label [mc "Create..."] \
2790 -command branch_create::dialog \
2791 -accelerator $M1T-N
2792 lappend disable_on_lock [list .mbar.branch entryconf \
2793 [.mbar.branch index last] -state]
2794
2795 .mbar.branch add command -label [mc "Checkout..."] \
2796 -command branch_checkout::dialog \
2797 -accelerator $M1T-O
2798 lappend disable_on_lock [list .mbar.branch entryconf \
2799 [.mbar.branch index last] -state]
2800
2801 .mbar.branch add command -label [mc "Rename..."] \
2802 -command branch_rename::dialog
2803 lappend disable_on_lock [list .mbar.branch entryconf \
2804 [.mbar.branch index last] -state]
2805
2806 .mbar.branch add command -label [mc "Delete..."] \
2807 -command branch_delete::dialog
2808 lappend disable_on_lock [list .mbar.branch entryconf \
2809 [.mbar.branch index last] -state]
2810
2811 .mbar.branch add command -label [mc "Reset..."] \
2812 -command merge::reset_hard
2813 lappend disable_on_lock [list .mbar.branch entryconf \
2814 [.mbar.branch index last] -state]
2815 }
2816
2817 # -- Commit Menu
2818 #
2819 proc commit_btn_caption {} {
2820 if {[is_enabled nocommit]} {
2821 return [mc "Done"]
2822 } else {
2823 return [mc Commit@@verb]
2824 }
2825 }
2826
2827 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2828 menu .mbar.commit
2829
2830 if {![is_enabled nocommit]} {
2831 .mbar.commit add radiobutton \
2832 -label [mc "New Commit"] \
2833 -command do_select_commit_type \
2834 -variable selected_commit_type \
2835 -value new
2836 lappend disable_on_lock \
2837 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2838
2839 .mbar.commit add radiobutton \
2840 -label [mc "Amend Last Commit"] \
2841 -command do_select_commit_type \
2842 -variable selected_commit_type \
2843 -value amend
2844 lappend disable_on_lock \
2845 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2846
2847 .mbar.commit add separator
2848 }
2849
2850 .mbar.commit add command -label [mc Rescan] \
2851 -command ui_do_rescan \
2852 -accelerator F5
2853 lappend disable_on_lock \
2854 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2855
2856 .mbar.commit add command -label [mc "Stage To Commit"] \
2857 -command do_add_selection \
2858 -accelerator $M1T-T
2859 lappend disable_on_lock \
2860 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2861
2862 .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2863 -command do_add_all \
2864 -accelerator $M1T-I
2865 lappend disable_on_lock \
2866 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2867
2868 .mbar.commit add command -label [mc "Unstage From Commit"] \
2869 -command do_unstage_selection \
2870 -accelerator $M1T-U
2871 lappend disable_on_lock \
2872 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2873
2874 .mbar.commit add command -label [mc "Revert Changes"] \
2875 -command do_revert_selection \
2876 -accelerator $M1T-J
2877 lappend disable_on_lock \
2878 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2879
2880 .mbar.commit add separator
2881
2882 .mbar.commit add command -label [mc "Show Less Context"] \
2883 -command show_less_context \
2884 -accelerator $M1T-\-
2885
2886 .mbar.commit add command -label [mc "Show More Context"] \
2887 -command show_more_context \
2888 -accelerator $M1T-=
2889
2890 .mbar.commit add separator
2891
2892 if {![is_enabled nocommitmsg]} {
2893 .mbar.commit add command -label [mc "Sign Off"] \
2894 -command do_signoff \
2895 -accelerator $M1T-S
2896 }
2897
2898 .mbar.commit add command -label [commit_btn_caption] \
2899 -command do_commit \
2900 -accelerator $M1T-Return
2901 lappend disable_on_lock \
2902 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2903 }
2904
2905 # -- Merge Menu
2906 #
2907 if {[is_enabled branch]} {
2908 menu .mbar.merge
2909 .mbar.merge add command -label [mc "Local Merge..."] \
2910 -command merge::dialog \
2911 -accelerator $M1T-M
2912 lappend disable_on_lock \
2913 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2914 .mbar.merge add command -label [mc "Abort Merge..."] \
2915 -command merge::reset_hard
2916 lappend disable_on_lock \
2917 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2918 }
2919
2920 # -- Transport Menu
2921 #
2922 if {[is_enabled transport]} {
2923 menu .mbar.remote
2924
2925 .mbar.remote add command \
2926 -label [mc "Add..."] \
2927 -command remote_add::dialog \
2928 -accelerator $M1T-A
2929 .mbar.remote add command \
2930 -label [mc "Push..."] \
2931 -command do_push_anywhere \
2932 -accelerator $M1T-P
2933 .mbar.remote add command \
2934 -label [mc "Delete Branch..."] \
2935 -command remote_branch_delete::dialog
2936 }
2937
2938 if {[is_MacOSX]} {
2939 proc ::tk::mac::ShowPreferences {} {do_options}
2940 } else {
2941 # -- Edit Menu
2942 #
2943 .mbar.edit add separator
2944 .mbar.edit add command -label [mc "Options..."] \
2945 -command do_options
2946 }
2947
2948 # -- Tools Menu
2949 #
2950 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2951 set tools_menubar .mbar.tools
2952 menu $tools_menubar
2953 $tools_menubar add separator
2954 $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2955 $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2956 set tools_tailcnt 3
2957 if {[array names repo_config guitool.*.cmd] ne {}} {
2958 tools_populate_all
2959 }
2960 }
2961
2962 # -- Help Menu
2963 #
2964 .mbar add cascade -label [mc Help] -menu .mbar.help
2965 menu .mbar.help
2966
2967 if {[is_MacOSX]} {
2968 .mbar.apple add command -label [mc "About %s" [appname]] \
2969 -command do_about
2970 .mbar.apple add separator
2971 } else {
2972 .mbar.help add command -label [mc "About %s" [appname]] \
2973 -command do_about
2974 }
2975 . configure -menu .mbar
2976
2977 set doc_path [githtmldir]
2978 if {$doc_path ne {}} {
2979 set doc_path [file join $doc_path index.html]
2980
2981 if {[is_Cygwin]} {
2982 set doc_path [exec cygpath --mixed $doc_path]
2983 }
2984 }
2985
2986 if {[file isfile $doc_path]} {
2987 set doc_url "file:$doc_path"
2988 } else {
2989 set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2990 }
2991
2992 proc start_browser {url} {
2993 git "web--browse" $url
2994 }
2995
2996 .mbar.help add command -label [mc "Online Documentation"] \
2997 -command [list start_browser $doc_url]
2998
2999 .mbar.help add command -label [mc "Show SSH Key"] \
3000 -command do_ssh_key
3001
3002 unset doc_path doc_url
3003
3004 # -- Standard bindings
3005 #
3006 wm protocol . WM_DELETE_WINDOW do_quit
3007 bind all <$M1B-Key-q> do_quit
3008 bind all <$M1B-Key-Q> do_quit
3009 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3010 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3011
3012 set subcommand_args {}
3013 proc usage {} {
3014 set s "[mc usage:] $::argv0 $::subcommand $::subcommand_args"
3015 if {[tk windowingsystem] eq "win32"} {
3016 wm withdraw .
3017 tk_messageBox -icon info -message $s \
3018 -title [mc "Usage"]
3019 } else {
3020 puts stderr $s
3021 }
3022 exit 1
3023 }
3024
3025 proc normalize_relpath {path} {
3026 set elements {}
3027 foreach item [file split $path] {
3028 if {$item eq {.}} continue
3029 if {$item eq {..} && [llength $elements] > 0
3030 && [lindex $elements end] ne {..}} {
3031 set elements [lrange $elements 0 end-1]
3032 continue
3033 }
3034 lappend elements $item
3035 }
3036 return [eval file join $elements]
3037 }
3038
3039 # -- Not a normal commit type invocation? Do that instead!
3040 #
3041 switch -- $subcommand {
3042 browser -
3043 blame {
3044 if {$subcommand eq "blame"} {
3045 set subcommand_args {[--line=<num>] rev? path}
3046 } else {
3047 set subcommand_args {rev? path}
3048 }
3049 if {$argv eq {}} usage
3050 set head {}
3051 set path {}
3052 set jump_spec {}
3053 set is_path 0
3054 foreach a $argv {
3055 set p [file join $_prefix $a]
3056
3057 if {$is_path || [file exists $p]} {
3058 if {$path ne {}} usage
3059 set path [normalize_relpath $p]
3060 break
3061 } elseif {$a eq {--}} {
3062 if {$path ne {}} {
3063 if {$head ne {}} usage
3064 set head $path
3065 set path {}
3066 }
3067 set is_path 1
3068 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
3069 if {$jump_spec ne {} || $head ne {}} usage
3070 set jump_spec [list $lnum]
3071 } elseif {$head eq {}} {
3072 if {$head ne {}} usage
3073 set head $a
3074 set is_path 1
3075 } else {
3076 usage
3077 }
3078 }
3079 unset is_path
3080
3081 if {$head ne {} && $path eq {}} {
3082 if {[string index $head 0] eq {/}} {
3083 set path [normalize_relpath $head]
3084 set head {}
3085 } else {
3086 set path [normalize_relpath $_prefix$head]
3087 set head {}
3088 }
3089 }
3090
3091 if {$head eq {}} {
3092 load_current_branch
3093 } else {
3094 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
3095 if {[catch {
3096 set head [git rev-parse --verify $head]
3097 } err]} {
3098 if {[tk windowingsystem] eq "win32"} {
3099 tk_messageBox -icon error -title [mc Error] -message $err
3100 } else {
3101 puts stderr $err
3102 }
3103 exit 1
3104 }
3105 }
3106 set current_branch $head
3107 }
3108
3109 wm deiconify .
3110 switch -- $subcommand {
3111 browser {
3112 if {$jump_spec ne {}} usage
3113 if {$head eq {}} {
3114 if {$path ne {} && [file isdirectory $path]} {
3115 set head $current_branch
3116 } else {
3117 set head $path
3118 set path {}
3119 }
3120 }
3121 browser::new $head $path
3122 }
3123 blame {
3124 if {$head eq {} && ![file exists $path]} {
3125 catch {wm withdraw .}
3126 tk_messageBox \
3127 -icon error \
3128 -type ok \
3129 -title [mc "git-gui: fatal error"] \
3130 -message [mc "fatal: cannot stat path %s: No such file or directory" $path]
3131 exit 1
3132 }
3133 blame::new $head $path $jump_spec
3134 }
3135 }
3136 return
3137 }
3138 citool -
3139 gui {
3140 if {[llength $argv] != 0} {
3141 usage
3142 }
3143 # fall through to setup UI for commits
3144 }
3145 default {
3146 set err "[mc usage:] $argv0 \[{blame|browser|citool}\]"
3147 if {[tk windowingsystem] eq "win32"} {
3148 wm withdraw .
3149 tk_messageBox -icon error -message $err \
3150 -title [mc "Usage"]
3151 } else {
3152 puts stderr $err
3153 }
3154 exit 1
3155 }
3156 }
3157
3158 # -- Branch Control
3159 #
3160 ${NS}::frame .branch
3161 if {!$use_ttk} {.branch configure -borderwidth 1 -relief sunken}
3162 ${NS}::label .branch.l1 \
3163 -text [mc "Current Branch:"] \
3164 -anchor w \
3165 -justify left
3166 ${NS}::label .branch.cb \
3167 -textvariable current_branch \
3168 -anchor w \
3169 -justify left
3170 pack .branch.l1 -side left
3171 pack .branch.cb -side left -fill x
3172 pack .branch -side top -fill x
3173
3174 # -- Main Window Layout
3175 #
3176 ${NS}::panedwindow .vpane -orient horizontal
3177 ${NS}::panedwindow .vpane.files -orient vertical
3178 if {$use_ttk} {
3179 .vpane add .vpane.files
3180 } else {
3181 .vpane add .vpane.files -sticky nsew -height 100 -width 200
3182 }
3183 pack .vpane -anchor n -side top -fill both -expand 1
3184
3185 # -- Working Directory File List
3186
3187 textframe .vpane.files.workdir -height 100 -width 200
3188 tlabel .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
3189 -background lightsalmon -foreground black
3190 ttext $ui_workdir -background white -foreground black \
3191 -borderwidth 0 \
3192 -width 20 -height 10 \
3193 -wrap none \
3194 -takefocus 1 -highlightthickness 1\
3195 -cursor $cursor_ptr \
3196 -xscrollcommand {.vpane.files.workdir.sx set} \
3197 -yscrollcommand {.vpane.files.workdir.sy set} \
3198 -state disabled
3199 ${NS}::scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
3200 ${NS}::scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
3201 pack .vpane.files.workdir.title -side top -fill x
3202 pack .vpane.files.workdir.sx -side bottom -fill x
3203 pack .vpane.files.workdir.sy -side right -fill y
3204 pack $ui_workdir -side left -fill both -expand 1
3205
3206 # -- Index File List
3207 #
3208 textframe .vpane.files.index -height 100 -width 200
3209 tlabel .vpane.files.index.title \
3210 -text [mc "Staged Changes (Will Commit)"] \
3211 -background lightgreen -foreground black
3212 ttext $ui_index -background white -foreground black \
3213 -borderwidth 0 \
3214 -width 20 -height 10 \
3215 -wrap none \
3216 -takefocus 1 -highlightthickness 1\
3217 -cursor $cursor_ptr \
3218 -xscrollcommand {.vpane.files.index.sx set} \
3219 -yscrollcommand {.vpane.files.index.sy set} \
3220 -state disabled
3221 ${NS}::scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
3222 ${NS}::scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
3223 pack .vpane.files.index.title -side top -fill x
3224 pack .vpane.files.index.sx -side bottom -fill x
3225 pack .vpane.files.index.sy -side right -fill y
3226 pack $ui_index -side left -fill both -expand 1
3227
3228 # -- Insert the workdir and index into the panes
3229 #
3230 .vpane.files add .vpane.files.workdir
3231 .vpane.files add .vpane.files.index
3232 if {!$use_ttk} {
3233 .vpane.files paneconfigure .vpane.files.workdir -sticky news
3234 .vpane.files paneconfigure .vpane.files.index -sticky news
3235 }
3236
3237 foreach i [list $ui_index $ui_workdir] {
3238 rmsel_tag $i
3239 $i tag conf in_diff -background [$i tag cget in_sel -background]
3240 }
3241 unset i
3242
3243 # -- Diff and Commit Area
3244 #
3245 if {$have_tk85} {
3246 ${NS}::panedwindow .vpane.lower -orient vertical
3247 ${NS}::frame .vpane.lower.commarea
3248 ${NS}::frame .vpane.lower.diff -relief sunken -borderwidth 1 -height 500
3249 .vpane.lower add .vpane.lower.diff
3250 .vpane.lower add .vpane.lower.commarea
3251 .vpane add .vpane.lower
3252 if {$use_ttk} {
3253 .vpane.lower pane .vpane.lower.diff -weight 1
3254 .vpane.lower pane .vpane.lower.commarea -weight 0
3255 } else {
3256 .vpane.lower paneconfigure .vpane.lower.diff -stretch always
3257 .vpane.lower paneconfigure .vpane.lower.commarea -stretch never
3258 }
3259 } else {
3260 frame .vpane.lower -height 300 -width 400
3261 frame .vpane.lower.commarea
3262 frame .vpane.lower.diff -relief sunken -borderwidth 1
3263 pack .vpane.lower.diff -fill both -expand 1
3264 pack .vpane.lower.commarea -side bottom -fill x
3265 .vpane add .vpane.lower
3266 .vpane paneconfigure .vpane.lower -sticky nsew
3267 }
3268
3269 # -- Commit Area Buttons
3270 #
3271 ${NS}::frame .vpane.lower.commarea.buttons
3272 ${NS}::label .vpane.lower.commarea.buttons.l -text {} \
3273 -anchor w \
3274 -justify left
3275 pack .vpane.lower.commarea.buttons.l -side top -fill x
3276 pack .vpane.lower.commarea.buttons -side left -fill y
3277
3278 ${NS}::button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
3279 -command ui_do_rescan
3280 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3281 lappend disable_on_lock \
3282 {.vpane.lower.commarea.buttons.rescan conf -state}
3283
3284 ${NS}::button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
3285 -command do_add_all
3286 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3287 lappend disable_on_lock \
3288 {.vpane.lower.commarea.buttons.incall conf -state}
3289
3290 if {![is_enabled nocommitmsg]} {
3291 ${NS}::button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
3292 -command do_signoff
3293 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3294 }
3295
3296 ${NS}::button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
3297 -command do_commit
3298 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3299 lappend disable_on_lock \
3300 {.vpane.lower.commarea.buttons.commit conf -state}
3301
3302 if {![is_enabled nocommit]} {
3303 ${NS}::button .vpane.lower.commarea.buttons.push -text [mc Push] \
3304 -command do_push_anywhere
3305 pack .vpane.lower.commarea.buttons.push -side top -fill x
3306 }
3307
3308 # -- Commit Message Buffer
3309 #
3310 ${NS}::frame .vpane.lower.commarea.buffer
3311 ${NS}::frame .vpane.lower.commarea.buffer.header
3312 set ui_comm .vpane.lower.commarea.buffer.frame.t
3313 set ui_coml .vpane.lower.commarea.buffer.header.l
3314
3315 if {![is_enabled nocommit]} {
3316 ${NS}::radiobutton .vpane.lower.commarea.buffer.header.new \
3317 -text [mc "New Commit"] \
3318 -command do_select_commit_type \
3319 -variable selected_commit_type \
3320 -value new
3321 lappend disable_on_lock \
3322 [list .vpane.lower.commarea.buffer.header.new conf -state]
3323 ${NS}::radiobutton .vpane.lower.commarea.buffer.header.amend \
3324 -text [mc "Amend Last Commit"] \
3325 -command do_select_commit_type \
3326 -variable selected_commit_type \
3327 -value amend
3328 lappend disable_on_lock \
3329 [list .vpane.lower.commarea.buffer.header.amend conf -state]
3330 }
3331
3332 ${NS}::label $ui_coml \
3333 -anchor w \
3334 -justify left
3335 proc trace_commit_type {varname args} {
3336 global ui_coml commit_type
3337 switch -glob -- $commit_type {
3338 initial {set txt [mc "Initial Commit Message:"]}
3339 amend {set txt [mc "Amended Commit Message:"]}
3340 amend-initial {set txt [mc "Amended Initial Commit Message:"]}
3341 amend-merge {set txt [mc "Amended Merge Commit Message:"]}
3342 merge {set txt [mc "Merge Commit Message:"]}
3343 * {set txt [mc "Commit Message:"]}
3344 }
3345 $ui_coml conf -text $txt
3346 }
3347 trace add variable commit_type write trace_commit_type
3348 pack $ui_coml -side left -fill x
3349
3350 if {![is_enabled nocommit]} {
3351 pack .vpane.lower.commarea.buffer.header.amend -side right
3352 pack .vpane.lower.commarea.buffer.header.new -side right
3353 }
3354
3355 textframe .vpane.lower.commarea.buffer.frame
3356 ttext $ui_comm -background white -foreground black \
3357 -borderwidth 1 \
3358 -undo true \
3359 -maxundo 20 \
3360 -autoseparators true \
3361 -takefocus 1 \
3362 -highlightthickness 1 \
3363 -relief sunken \
3364 -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
3365 -font font_diff \
3366 -yscrollcommand {.vpane.lower.commarea.buffer.frame.sby set}
3367 ${NS}::scrollbar .vpane.lower.commarea.buffer.frame.sby \
3368 -command [list $ui_comm yview]
3369
3370 pack .vpane.lower.commarea.buffer.frame.sby -side right -fill y
3371 pack $ui_comm -side left -fill y
3372 pack .vpane.lower.commarea.buffer.header -side top -fill x
3373 pack .vpane.lower.commarea.buffer.frame -side left -fill y
3374 pack .vpane.lower.commarea.buffer -side left -fill y
3375
3376 # -- Commit Message Buffer Context Menu
3377 #
3378 set ctxm .vpane.lower.commarea.buffer.ctxm
3379 menu $ctxm -tearoff 0
3380 $ctxm add command \
3381 -label [mc Cut] \
3382 -command {tk_textCut $ui_comm}
3383 $ctxm add command \
3384 -label [mc Copy] \
3385 -command {tk_textCopy $ui_comm}
3386 $ctxm add command \
3387 -label [mc Paste] \
3388 -command {tk_textPaste $ui_comm}
3389 $ctxm add command \
3390 -label [mc Delete] \
3391 -command {catch {$ui_comm delete sel.first sel.last}}
3392 $ctxm add separator
3393 $ctxm add command \
3394 -label [mc "Select All"] \
3395 -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
3396 $ctxm add command \
3397 -label [mc "Copy All"] \
3398 -command {
3399 $ui_comm tag add sel 0.0 end
3400 tk_textCopy $ui_comm
3401 $ui_comm tag remove sel 0.0 end
3402 }
3403 $ctxm add separator
3404 $ctxm add command \
3405 -label [mc "Sign Off"] \
3406 -command do_signoff
3407 set ui_comm_ctxm $ctxm
3408
3409 # -- Diff Header
3410 #
3411 proc trace_current_diff_path {varname args} {
3412 global current_diff_path diff_actions file_states
3413 if {$current_diff_path eq {}} {
3414 set s {}
3415 set f {}
3416 set p {}
3417 set o disabled
3418 } else {
3419 set p $current_diff_path
3420 set s [mapdesc [lindex $file_states($p) 0] $p]
3421 set f [mc "File:"]
3422 set p [escape_path $p]
3423 set o normal
3424 }
3425
3426 .vpane.lower.diff.header.status configure -text $s
3427 .vpane.lower.diff.header.file configure -text $f
3428 .vpane.lower.diff.header.path configure -text $p
3429 foreach w $diff_actions {
3430 uplevel #0 $w $o
3431 }
3432 }
3433 trace add variable current_diff_path write trace_current_diff_path
3434
3435 gold_frame .vpane.lower.diff.header
3436 tlabel .vpane.lower.diff.header.status \
3437 -background gold \
3438 -foreground black \
3439 -width $max_status_desc \
3440 -anchor w \
3441 -justify left
3442 tlabel .vpane.lower.diff.header.file \
3443 -background gold \
3444 -foreground black \
3445 -anchor w \
3446 -justify left
3447 tlabel .vpane.lower.diff.header.path \
3448 -background gold \
3449 -foreground black \
3450 -anchor w \
3451 -justify left
3452 pack .vpane.lower.diff.header.status -side left
3453 pack .vpane.lower.diff.header.file -side left
3454 pack .vpane.lower.diff.header.path -fill x
3455 set ctxm .vpane.lower.diff.header.ctxm
3456 menu $ctxm -tearoff 0
3457 $ctxm add command \
3458 -label [mc Copy] \
3459 -command {
3460 clipboard clear
3461 clipboard append \
3462 -format STRING \
3463 -type STRING \
3464 -- $current_diff_path
3465 }
3466 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3467 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3468
3469 # -- Diff Body
3470 #
3471 textframe .vpane.lower.diff.body
3472 set ui_diff .vpane.lower.diff.body.t
3473 ttext $ui_diff -background white -foreground black \
3474 -borderwidth 0 \
3475 -width 80 -height 5 -wrap none \
3476 -font font_diff \
3477 -takefocus 1 -highlightthickness 1 \
3478 -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3479 -yscrollcommand {.vpane.lower.diff.body.sby set} \
3480 -state disabled
3481 catch {$ui_diff configure -tabstyle wordprocessor}
3482 ${NS}::scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3483 -command [list $ui_diff xview]
3484 ${NS}::scrollbar .vpane.lower.diff.body.sby -orient vertical \
3485 -command [list $ui_diff yview]
3486 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3487 pack .vpane.lower.diff.body.sby -side right -fill y
3488 pack $ui_diff -side left -fill both -expand 1
3489 pack .vpane.lower.diff.header -side top -fill x
3490 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3491
3492 foreach {n c} {0 black 1 red4 2 green4 3 yellow4 4 blue4 5 magenta4 6 cyan4 7 grey60} {
3493 $ui_diff tag configure clr4$n -background $c
3494 $ui_diff tag configure clri4$n -foreground $c
3495 $ui_diff tag configure clr3$n -foreground $c
3496 $ui_diff tag configure clri3$n -background $c
3497 }
3498 $ui_diff tag configure clr1 -font font_diffbold
3499 $ui_diff tag configure clr4 -underline 1
3500
3501 $ui_diff tag conf d_info -foreground blue -font font_diffbold
3502
3503 $ui_diff tag conf d_cr -elide true
3504 $ui_diff tag conf d_@ -font font_diffbold
3505 $ui_diff tag conf d_+ -foreground {#00a000}
3506 $ui_diff tag conf d_- -foreground red
3507
3508 $ui_diff tag conf d_++ -foreground {#00a000}
3509 $ui_diff tag conf d_-- -foreground red
3510 $ui_diff tag conf d_+s \
3511 -foreground {#00a000} \
3512 -background {#e2effa}
3513 $ui_diff tag conf d_-s \
3514 -foreground red \
3515 -background {#e2effa}
3516 $ui_diff tag conf d_s+ \
3517 -foreground {#00a000} \
3518 -background ivory1
3519 $ui_diff tag conf d_s- \
3520 -foreground red \
3521 -background ivory1
3522
3523 $ui_diff tag conf d< \
3524 -foreground orange \
3525 -font font_diffbold
3526 $ui_diff tag conf d= \
3527 -foreground orange \
3528 -font font_diffbold
3529 $ui_diff tag conf d> \
3530 -foreground orange \
3531 -font font_diffbold
3532
3533 $ui_diff tag raise sel
3534
3535 # -- Diff Body Context Menu
3536 #
3537
3538 proc create_common_diff_popup {ctxm} {
3539 $ctxm add command \
3540 -label [mc Refresh] \
3541 -command reshow_diff
3542 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3543 $ctxm add command \
3544 -label [mc Copy] \
3545 -command {tk_textCopy $ui_diff}
3546 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3547 $ctxm add command \
3548 -label [mc "Select All"] \
3549 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3550 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3551 $ctxm add command \
3552 -label [mc "Copy All"] \
3553 -command {
3554 $ui_diff tag add sel 0.0 end
3555 tk_textCopy $ui_diff
3556 $ui_diff tag remove sel 0.0 end
3557 }
3558 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3559 $ctxm add separator
3560 $ctxm add command \
3561 -label [mc "Decrease Font Size"] \
3562 -command {incr_font_size font_diff -1}
3563 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3564 $ctxm add command \
3565 -label [mc "Increase Font Size"] \
3566 -command {incr_font_size font_diff 1}
3567 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3568 $ctxm add separator
3569 set emenu $ctxm.enc
3570 menu $emenu
3571 build_encoding_menu $emenu [list force_diff_encoding]
3572 $ctxm add cascade \
3573 -label [mc "Encoding"] \
3574 -menu $emenu
3575 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3576 $ctxm add separator
3577 $ctxm add command -label [mc "Options..."] \
3578 -command do_options
3579 }
3580
3581 set ctxm .vpane.lower.diff.body.ctxm
3582 menu $ctxm -tearoff 0
3583 $ctxm add command \
3584 -label [mc "Apply/Reverse Hunk"] \
3585 -command {apply_hunk $cursorX $cursorY}
3586 set ui_diff_applyhunk [$ctxm index last]
3587 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3588 $ctxm add command \
3589 -label [mc "Apply/Reverse Line"] \
3590 -command {apply_range_or_line $cursorX $cursorY; do_rescan}
3591 set ui_diff_applyline [$ctxm index last]
3592 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3593 $ctxm add separator
3594 $ctxm add command \
3595 -label [mc "Show Less Context"] \
3596 -command show_less_context
3597 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3598 $ctxm add command \
3599 -label [mc "Show More Context"] \
3600 -command show_more_context
3601 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3602 $ctxm add separator
3603 create_common_diff_popup $ctxm
3604
3605 set ctxmmg .vpane.lower.diff.body.ctxmmg
3606 menu $ctxmmg -tearoff 0
3607 $ctxmmg add command \
3608 -label [mc "Run Merge Tool"] \
3609 -command {merge_resolve_tool}
3610 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3611 $ctxmmg add separator
3612 $ctxmmg add command \
3613 -label [mc "Use Remote Version"] \
3614 -command {merge_resolve_one 3}
3615 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3616 $ctxmmg add command \
3617 -label [mc "Use Local Version"] \
3618 -command {merge_resolve_one 2}
3619 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3620 $ctxmmg add command \
3621 -label [mc "Revert To Base"] \
3622 -command {merge_resolve_one 1}
3623 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3624 $ctxmmg add separator
3625 $ctxmmg add command \
3626 -label [mc "Show Less Context"] \
3627 -command show_less_context
3628 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3629 $ctxmmg add command \
3630 -label [mc "Show More Context"] \
3631 -command show_more_context
3632 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3633 $ctxmmg add separator
3634 create_common_diff_popup $ctxmmg
3635
3636 set ctxmsm .vpane.lower.diff.body.ctxmsm
3637 menu $ctxmsm -tearoff 0
3638 $ctxmsm add command \
3639 -label [mc "Visualize These Changes In The Submodule"] \
3640 -command {do_gitk -- true}
3641 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3642 $ctxmsm add command \
3643 -label [mc "Visualize Current Branch History In The Submodule"] \
3644 -command {do_gitk {} true}
3645 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3646 $ctxmsm add command \
3647 -label [mc "Visualize All Branch History In The Submodule"] \
3648 -command {do_gitk --all true}
3649 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3650 $ctxmsm add separator
3651 $ctxmsm add command \
3652 -label [mc "Start git gui In The Submodule"] \
3653 -command {do_git_gui}
3654 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3655 $ctxmsm add separator
3656 create_common_diff_popup $ctxmsm
3657
3658 proc has_textconv {path} {
3659 if {[is_config_false gui.textconv]} {
3660 return 0
3661 }
3662 set filter [gitattr $path diff set]
3663 set textconv [get_config [join [list diff $filter textconv] .]]
3664 if {$filter ne {set} && $textconv ne {}} {
3665 return 1
3666 } else {
3667 return 0
3668 }
3669 }
3670
3671 proc popup_diff_menu {ctxm ctxmmg ctxmsm x y X Y} {
3672 global current_diff_path file_states
3673 set ::cursorX $x
3674 set ::cursorY $y
3675 if {[info exists file_states($current_diff_path)]} {
3676 set state [lindex $file_states($current_diff_path) 0]
3677 } else {
3678 set state {__}
3679 }
3680 if {[string first {U} $state] >= 0} {
3681 tk_popup $ctxmmg $X $Y
3682 } elseif {$::is_submodule_diff} {
3683 tk_popup $ctxmsm $X $Y
3684 } else {
3685 set has_range [expr {[$::ui_diff tag nextrange sel 0.0] != {}}]
3686 if {$::ui_index eq $::current_diff_side} {
3687 set l [mc "Unstage Hunk From Commit"]
3688 if {$has_range} {
3689 set t [mc "Unstage Lines From Commit"]
3690 } else {
3691 set t [mc "Unstage Line From Commit"]
3692 }
3693 } else {
3694 set l [mc "Stage Hunk For Commit"]
3695 if {$has_range} {
3696 set t [mc "Stage Lines For Commit"]
3697 } else {
3698 set t [mc "Stage Line For Commit"]
3699 }
3700 }
3701 if {$::is_3way_diff
3702 || $current_diff_path eq {}
3703 || {__} eq $state
3704 || {_O} eq $state
3705 || [string match {?T} $state]
3706 || [string match {T?} $state]
3707 || [has_textconv $current_diff_path]} {
3708 set s disabled
3709 } else {
3710 set s normal
3711 }
3712 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3713 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3714 tk_popup $ctxm $X $Y
3715 }
3716 }
3717 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg $ctxmsm %x %y %X %Y]
3718
3719 # -- Status Bar
3720 #
3721 set main_status [::status_bar::new .status]
3722 pack .status -anchor w -side bottom -fill x
3723 $main_status show [mc "Initializing..."]
3724
3725 # -- Load geometry
3726 #
3727 proc on_ttk_pane_mapped {w pane pos} {
3728 bind $w <Map> {}
3729 after 0 [list after idle [list $w sashpos $pane $pos]]
3730 }
3731 proc on_tk_pane_mapped {w pane x y} {
3732 bind $w <Map> {}
3733 after 0 [list after idle [list $w sash place $pane $x $y]]
3734 }
3735 proc on_application_mapped {} {
3736 global repo_config use_ttk
3737 bind . <Map> {}
3738 set gm $repo_config(gui.geometry)
3739 if {$use_ttk} {
3740 bind .vpane <Map> \
3741 [list on_ttk_pane_mapped %W 0 [lindex $gm 1]]
3742 bind .vpane.files <Map> \
3743 [list on_ttk_pane_mapped %W 0 [lindex $gm 2]]
3744 } else {
3745 bind .vpane <Map> \
3746 [list on_tk_pane_mapped %W 0 \
3747 [lindex $gm 1] \
3748 [lindex [.vpane sash coord 0] 1]]
3749 bind .vpane.files <Map> \
3750 [list on_tk_pane_mapped %W 0 \
3751 [lindex [.vpane.files sash coord 0] 0] \
3752 [lindex $gm 2]]
3753 }
3754 wm geometry . [lindex $gm 0]
3755 }
3756 if {[info exists repo_config(gui.geometry)]} {
3757 bind . <Map> [list on_application_mapped]
3758 wm geometry . [lindex $repo_config(gui.geometry) 0]
3759 }
3760
3761 # -- Load window state
3762 #
3763 if {[info exists repo_config(gui.wmstate)]} {
3764 catch {wm state . $repo_config(gui.wmstate)}
3765 }
3766
3767 # -- Key Bindings
3768 #
3769 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3770 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3771 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3772 bind $ui_comm <$M1B-Key-u> {do_unstage_selection;break}
3773 bind $ui_comm <$M1B-Key-U> {do_unstage_selection;break}
3774 bind $ui_comm <$M1B-Key-j> {do_revert_selection;break}
3775 bind $ui_comm <$M1B-Key-J> {do_revert_selection;break}
3776 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3777 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3778 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3779 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3780 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3781 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3782 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3783 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3784 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3785 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3786 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3787 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3788 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3789 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3790 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3791
3792 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3793 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3794 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3795 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3796 bind $ui_diff <$M1B-Key-v> {break}
3797 bind $ui_diff <$M1B-Key-V> {break}
3798 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3799 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3800 bind $ui_diff <$M1B-Key-j> {do_revert_selection;break}
3801 bind $ui_diff <$M1B-Key-J> {do_revert_selection;break}
3802 bind $ui_diff <Key-Up> {catch {%W yview scroll -1 units};break}
3803 bind $ui_diff <Key-Down> {catch {%W yview scroll 1 units};break}
3804 bind $ui_diff <Key-Left> {catch {%W xview scroll -1 units};break}
3805 bind $ui_diff <Key-Right> {catch {%W xview scroll 1 units};break}
3806 bind $ui_diff <Key-k> {catch {%W yview scroll -1 units};break}
3807 bind $ui_diff <Key-j> {catch {%W yview scroll 1 units};break}
3808 bind $ui_diff <Key-h> {catch {%W xview scroll -1 units};break}
3809 bind $ui_diff <Key-l> {catch {%W xview scroll 1 units};break}
3810 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3811 bind $ui_diff <Control-Key-f> {catch {%W yview scroll 1 pages};break}
3812 bind $ui_diff <Button-1> {focus %W}
3813
3814 if {[is_enabled branch]} {
3815 bind . <$M1B-Key-n> branch_create::dialog
3816 bind . <$M1B-Key-N> branch_create::dialog
3817 bind . <$M1B-Key-o> branch_checkout::dialog
3818 bind . <$M1B-Key-O> branch_checkout::dialog
3819 bind . <$M1B-Key-m> merge::dialog
3820 bind . <$M1B-Key-M> merge::dialog
3821 }
3822 if {[is_enabled transport]} {
3823 bind . <$M1B-Key-p> do_push_anywhere
3824 bind . <$M1B-Key-P> do_push_anywhere
3825 }
3826
3827 bind . <Key-F5> ui_do_rescan
3828 bind . <$M1B-Key-r> ui_do_rescan
3829 bind . <$M1B-Key-R> ui_do_rescan
3830 bind . <$M1B-Key-s> do_signoff
3831 bind . <$M1B-Key-S> do_signoff
3832 bind . <$M1B-Key-t> { toggle_or_diff toggle %W }
3833 bind . <$M1B-Key-T> { toggle_or_diff toggle %W }
3834 bind . <$M1B-Key-u> { toggle_or_diff toggle %W }
3835 bind . <$M1B-Key-U> { toggle_or_diff toggle %W }
3836 bind . <$M1B-Key-j> do_revert_selection
3837 bind . <$M1B-Key-J> do_revert_selection
3838 bind . <$M1B-Key-i> do_add_all
3839 bind . <$M1B-Key-I> do_add_all
3840 bind . <$M1B-Key-minus> {show_less_context;break}
3841 bind . <$M1B-Key-KP_Subtract> {show_less_context;break}
3842 bind . <$M1B-Key-equal> {show_more_context;break}
3843 bind . <$M1B-Key-plus> {show_more_context;break}
3844 bind . <$M1B-Key-KP_Add> {show_more_context;break}
3845 bind . <$M1B-Key-Return> do_commit
3846 foreach i [list $ui_index $ui_workdir] {
3847 bind $i <Button-1> { toggle_or_diff click %W %x %y; break }
3848 bind $i <$M1B-Button-1> { add_one_to_selection %W %x %y; break }
3849 bind $i <Shift-Button-1> { add_range_to_selection %W %x %y; break }
3850 bind $i <Key-Up> { toggle_or_diff up %W; break }
3851 bind $i <Key-Down> { toggle_or_diff down %W; break }
3852 }
3853 unset i
3854
3855 set file_lists($ui_index) [list]
3856 set file_lists($ui_workdir) [list]
3857
3858 wm title . "[appname] ([reponame]) [file normalize $_gitworktree]"
3859 focus -force $ui_comm
3860
3861 # -- Warn the user about environmental problems. Cygwin's Tcl
3862 # does *not* pass its env array onto any processes it spawns.
3863 # This means that git processes get none of our environment.
3864 #
3865 if {[is_Cygwin]} {
3866 set ignored_env 0
3867 set suggest_user {}
3868 set msg [mc "Possible environment issues exist.
3869
3870 The following environment variables are probably
3871 going to be ignored by any Git subprocess run
3872 by %s:
3873
3874 " [appname]]
3875 foreach name [array names env] {
3876 switch -regexp -- $name {
3877 {^GIT_INDEX_FILE$} -
3878 {^GIT_OBJECT_DIRECTORY$} -
3879 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3880 {^GIT_DIFF_OPTS$} -
3881 {^GIT_EXTERNAL_DIFF$} -
3882 {^GIT_PAGER$} -
3883 {^GIT_TRACE$} -
3884 {^GIT_CONFIG$} -
3885 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3886 append msg " - $name\n"
3887 incr ignored_env
3888 }
3889 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3890 append msg " - $name\n"
3891 incr ignored_env
3892 set suggest_user $name
3893 }
3894 }
3895 }
3896 if {$ignored_env > 0} {
3897 append msg [mc "
3898 This is due to a known issue with the
3899 Tcl binary distributed by Cygwin."]
3900
3901 if {$suggest_user ne {}} {
3902 append msg [mc "
3903
3904 A good replacement for %s
3905 is placing values for the user.name and
3906 user.email settings into your personal
3907 ~/.gitconfig file.
3908 " $suggest_user]
3909 }
3910 warn_popup $msg
3911 }
3912 unset ignored_env msg suggest_user name
3913 }
3914
3915 # -- Only initialize complex UI if we are going to stay running.
3916 #
3917 if {[is_enabled transport]} {
3918 load_all_remotes
3919
3920 set n [.mbar.remote index end]
3921 populate_remotes_menu
3922 set n [expr {[.mbar.remote index end] - $n}]
3923 if {$n > 0} {
3924 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3925 .mbar.remote insert $n separator
3926 }
3927 unset n
3928 }
3929
3930 if {[winfo exists $ui_comm]} {
3931 set GITGUI_BCK_exists [load_message GITGUI_BCK utf-8]
3932
3933 # -- If both our backup and message files exist use the
3934 # newer of the two files to initialize the buffer.
3935 #
3936 if {$GITGUI_BCK_exists} {
3937 set m [gitdir GITGUI_MSG]
3938 if {[file isfile $m]} {
3939 if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3940 catch {file delete [gitdir GITGUI_MSG]}
3941 } else {
3942 $ui_comm delete 0.0 end
3943 $ui_comm edit reset
3944 $ui_comm edit modified false
3945 catch {file delete [gitdir GITGUI_BCK]}
3946 set GITGUI_BCK_exists 0
3947 }
3948 }
3949 unset m
3950 }
3951
3952 proc backup_commit_buffer {} {
3953 global ui_comm GITGUI_BCK_exists
3954
3955 set m [$ui_comm edit modified]
3956 if {$m || $GITGUI_BCK_exists} {
3957 set msg [string trim [$ui_comm get 0.0 end]]
3958 regsub -all -line {[ \r\t]+$} $msg {} msg
3959
3960 if {$msg eq {}} {
3961 if {$GITGUI_BCK_exists} {
3962 catch {file delete [gitdir GITGUI_BCK]}
3963 set GITGUI_BCK_exists 0
3964 }
3965 } elseif {$m} {
3966 catch {
3967 set fd [open [gitdir GITGUI_BCK] w]
3968 fconfigure $fd -encoding utf-8
3969 puts -nonewline $fd $msg
3970 close $fd
3971 set GITGUI_BCK_exists 1
3972 }
3973 }
3974
3975 $ui_comm edit modified false
3976 }
3977
3978 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3979 }
3980
3981 backup_commit_buffer
3982
3983 # -- If the user has aspell available we can drive it
3984 # in pipe mode to spellcheck the commit message.
3985 #
3986 set spell_cmd [list |]
3987 set spell_dict [get_config gui.spellingdictionary]
3988 lappend spell_cmd aspell
3989 if {$spell_dict ne {}} {
3990 lappend spell_cmd --master=$spell_dict
3991 }
3992 lappend spell_cmd --mode=none
3993 lappend spell_cmd --encoding=utf-8
3994 lappend spell_cmd pipe
3995 if {$spell_dict eq {none}
3996 || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3997 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3998 } else {
3999 set ui_comm_spell [spellcheck::init \
4000 $spell_fd \
4001 $ui_comm \
4002 $ui_comm_ctxm \
4003 ]
4004 }
4005 unset -nocomplain spell_cmd spell_fd spell_err spell_dict
4006 }
4007
4008 lock_index begin-read
4009 if {![winfo ismapped .]} {
4010 wm deiconify .
4011 }
4012 after 1 {
4013 if {[is_enabled initialamend]} {
4014 force_amend
4015 } else {
4016 do_rescan
4017 }
4018
4019 if {[is_enabled nocommitmsg]} {
4020 $ui_comm configure -state disabled -background gray
4021 }
4022 }
4023 if {[is_enabled multicommit] && ![is_config_false gui.gcwarning]} {
4024 after 1000 hint_gc
4025 }
4026 if {[is_enabled retcode]} {
4027 bind . <Destroy> {+terminate_me %W}
4028 }
4029 if {$picked && [is_config_true gui.autoexplore]} {
4030 do_explore
4031 }
4032
4033 # Local variables:
4034 # mode: tcl
4035 # indent-tabs-mode: t
4036 # tab-width: 4
4037 # End: