36795c8bddc597e44f6e2193eab38359725a83d6
[git/git.git] / git-send-email.perl
1 #!/usr/bin/perl -w
2 #
3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
5 #
6 # GPL v2 (See COPYING)
7 #
8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
9 #
10 # Sends a collection of emails to the given email addresses, disturbingly fast.
11 #
12 # Supports two formats:
13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
14 # 2. The original format support by Greg's script:
15 # first line of the message is who to CC,
16 # and second line is the subject of the message.
17 #
18
19 use strict;
20 use warnings;
21 use Term::ReadLine;
22 use Getopt::Long;
23 use Data::Dumper;
24 use Git;
25
26 package FakeTerm;
27 sub new {
28 my ($class, $reason) = @_;
29 return bless \$reason, shift;
30 }
31 sub readline {
32 my $self = shift;
33 die "Cannot use readline on FakeTerm: $$self";
34 }
35 package main;
36
37
38 sub usage {
39 print <<EOT;
40 git-send-email [options] <file | directory>...
41 Options:
42 --from Specify the "From:" line of the email to be sent.
43
44 --to Specify the primary "To:" line of the email.
45
46 --cc Specify an initial "Cc:" list for the entire series
47 of emails.
48
49 --bcc Specify a list of email addresses that should be Bcc:
50 on all the emails.
51
52 --compose Use \$EDITOR to edit an introductory message for the
53 patch series.
54
55 --subject Specify the initial "Subject:" line.
56 Only necessary if --compose is also set. If --compose
57 is not set, this will be prompted for.
58
59 --in-reply-to Specify the first "In-Reply-To:" header line.
60 Only used if --compose is also set. If --compose is not
61 set, this will be prompted for.
62
63 --chain-reply-to If set, the replies will all be to the previous
64 email sent, rather than to the first email sent.
65 Defaults to on.
66
67 --no-signed-off-cc Suppress the automatic addition of email addresses
68 that appear in Signed-off-by: or Cc: lines to the cc:
69 list. Note: Using this option is not recommended.
70
71 --smtp-server If set, specifies the outgoing SMTP server to use.
72 Defaults to localhost.
73
74 --suppress-from Suppress sending emails to yourself if your address
75 appears in a From: line.
76
77 --quiet Make git-send-email less verbose. One line per email
78 should be all that is output.
79
80 --dry-run Do everything except actually send the emails.
81
82 EOT
83 exit(1);
84 }
85
86 # most mail servers generate the Date: header, but not all...
87 sub format_2822_time {
88 my ($time) = @_;
89 my @localtm = localtime($time);
90 my @gmttm = gmtime($time);
91 my $localmin = $localtm[1] + $localtm[2] * 60;
92 my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
93 if ($localtm[0] != $gmttm[0]) {
94 die "local zone differs from GMT by a non-minute interval\n";
95 }
96 if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
97 $localmin += 1440;
98 } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
99 $localmin -= 1440;
100 } elsif ($gmttm[6] != $localtm[6]) {
101 die "local time offset greater than or equal to 24 hours\n";
102 }
103 my $offset = $localmin - $gmtmin;
104 my $offhour = $offset / 60;
105 my $offmin = abs($offset % 60);
106 if (abs($offhour) >= 24) {
107 die ("local time offset greater than or equal to 24 hours\n");
108 }
109
110 return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
111 qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
112 $localtm[3],
113 qw(Jan Feb Mar Apr May Jun
114 Jul Aug Sep Oct Nov Dec)[$localtm[4]],
115 $localtm[5]+1900,
116 $localtm[2],
117 $localtm[1],
118 $localtm[0],
119 ($offset >= 0) ? '+' : '-',
120 abs($offhour),
121 $offmin,
122 );
123 }
124
125 my $have_email_valid = eval { require Email::Valid; 1 };
126 my $smtp;
127
128 sub unique_email_list(@);
129 sub cleanup_compose_files();
130
131 # Constants (essentially)
132 my $compose_filename = ".msg.$$";
133
134 # Variables we fill in automatically, or via prompting:
135 my (@to,@cc,@initial_cc,@bcclist,@xh,
136 $initial_reply_to,$initial_subject,@files,$from,$compose,$time);
137
138 # Behavior modification variables
139 my ($chain_reply_to, $quiet, $suppress_from, $no_signed_off_cc,
140 $dry_run) = (1, 0, 0, 0, 0);
141 my $smtp_server;
142
143 # Example reply to:
144 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
145
146 my $repo = Git->repository();
147 my $term = eval {
148 new Term::ReadLine 'git-send-email';
149 };
150 if ($@) {
151 $term = new FakeTerm "$@: going non-interactive";
152 }
153
154 my $def_chain = $repo->config_boolean('sendemail.chainreplyto');
155 if ($def_chain and $def_chain eq 'false') {
156 $chain_reply_to = 0;
157 }
158
159 @bcclist = $repo->config('sendemail.bcc');
160 if (!@bcclist or !$bcclist[0]) {
161 @bcclist = ();
162 }
163
164 # Begin by accumulating all the variables (defined above), that we will end up
165 # needing, first, from the command line:
166
167 my $rc = GetOptions("from=s" => \$from,
168 "in-reply-to=s" => \$initial_reply_to,
169 "subject=s" => \$initial_subject,
170 "to=s" => \@to,
171 "cc=s" => \@initial_cc,
172 "bcc=s" => \@bcclist,
173 "chain-reply-to!" => \$chain_reply_to,
174 "smtp-server=s" => \$smtp_server,
175 "compose" => \$compose,
176 "quiet" => \$quiet,
177 "suppress-from" => \$suppress_from,
178 "no-signed-off-cc|no-signed-off-by-cc" => \$no_signed_off_cc,
179 "dry-run" => \$dry_run,
180 );
181
182 unless ($rc) {
183 usage();
184 }
185
186 # Verify the user input
187
188 foreach my $entry (@to) {
189 die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
190 }
191
192 foreach my $entry (@initial_cc) {
193 die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
194 }
195
196 foreach my $entry (@bcclist) {
197 die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
198 }
199
200 # Now, let's fill any that aren't set in with defaults:
201
202 my ($author) = $repo->ident_person('author');
203 my ($committer) = $repo->ident_person('committer');
204
205 my %aliases;
206 my @alias_files = $repo->config('sendemail.aliasesfile');
207 my $aliasfiletype = $repo->config('sendemail.aliasfiletype');
208 my %parse_alias = (
209 # multiline formats can be supported in the future
210 mutt => sub { my $fh = shift; while (<$fh>) {
211 if (/^alias\s+(\S+)\s+(.*)$/) {
212 my ($alias, $addr) = ($1, $2);
213 $addr =~ s/#.*$//; # mutt allows # comments
214 # commas delimit multiple addresses
215 $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
216 }}},
217 mailrc => sub { my $fh = shift; while (<$fh>) {
218 if (/^alias\s+(\S+)\s+(.*)$/) {
219 # spaces delimit multiple addresses
220 $aliases{$1} = [ split(/\s+/, $2) ];
221 }}},
222 pine => sub { my $fh = shift; while (<$fh>) {
223 if (/^(\S+)\s+(.*)$/) {
224 $aliases{$1} = [ split(/\s*,\s*/, $2) ];
225 }}},
226 gnus => sub { my $fh = shift; while (<$fh>) {
227 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
228 $aliases{$1} = [ $2 ];
229 }}}
230 );
231
232 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
233 foreach my $file (@alias_files) {
234 open my $fh, '<', $file or die "opening $file: $!\n";
235 $parse_alias{$aliasfiletype}->($fh);
236 close $fh;
237 }
238 }
239
240 my $prompting = 0;
241 if (!defined $from) {
242 $from = $author || $committer;
243 do {
244 $_ = $term->readline("Who should the emails appear to be from? [$from] ");
245 } while (!defined $_);
246
247 $from = $_ if ($_);
248 print "Emails will be sent from: ", $from, "\n";
249 $prompting++;
250 }
251
252 if (!@to) {
253 do {
254 $_ = $term->readline("Who should the emails be sent to? ",
255 "");
256 } while (!defined $_);
257 my $to = $_;
258 push @to, split /,/, $to;
259 $prompting++;
260 }
261
262 sub expand_aliases {
263 my @cur = @_;
264 my @last;
265 do {
266 @last = @cur;
267 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
268 } while (join(',',@cur) ne join(',',@last));
269 return @cur;
270 }
271
272 @to = expand_aliases(@to);
273 @initial_cc = expand_aliases(@initial_cc);
274 @bcclist = expand_aliases(@bcclist);
275
276 if (!defined $initial_subject && $compose) {
277 do {
278 $_ = $term->readline("What subject should the emails start with? ",
279 $initial_subject);
280 } while (!defined $_);
281 $initial_subject = $_;
282 $prompting++;
283 }
284
285 if (!defined $initial_reply_to && $prompting) {
286 do {
287 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ",
288 $initial_reply_to);
289 } while (!defined $_);
290
291 $initial_reply_to = $_;
292 $initial_reply_to =~ s/(^\s+|\s+$)//g;
293 }
294
295 if (!$smtp_server) {
296 $smtp_server = $repo->config('sendemail.smtpserver');
297 }
298 if (!$smtp_server) {
299 foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
300 if (-x $_) {
301 $smtp_server = $_;
302 last;
303 }
304 }
305 $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
306 }
307
308 if ($compose) {
309 # Note that this does not need to be secure, but we will make a small
310 # effort to have it be unique
311 open(C,">",$compose_filename)
312 or die "Failed to open for writing $compose_filename: $!";
313 print C "From $from # This line is ignored.\n";
314 printf C "Subject: %s\n\n", $initial_subject;
315 printf C <<EOT;
316 GIT: Please enter your email below.
317 GIT: Lines beginning in "GIT: " will be removed.
318 GIT: Consider including an overall diffstat or table of contents
319 GIT: for the patch you are writing.
320
321 EOT
322 close(C);
323
324 my $editor = $ENV{EDITOR};
325 $editor = 'vi' unless defined $editor;
326 system($editor, $compose_filename);
327
328 open(C2,">",$compose_filename . ".final")
329 or die "Failed to open $compose_filename.final : " . $!;
330
331 open(C,"<",$compose_filename)
332 or die "Failed to open $compose_filename : " . $!;
333
334 while(<C>) {
335 next if m/^GIT: /;
336 print C2 $_;
337 }
338 close(C);
339 close(C2);
340
341 do {
342 $_ = $term->readline("Send this email? (y|n) ");
343 } while (!defined $_);
344
345 if (uc substr($_,0,1) ne 'Y') {
346 cleanup_compose_files();
347 exit(0);
348 }
349
350 @files = ($compose_filename . ".final");
351 }
352
353
354 # Now that all the defaults are set, process the rest of the command line
355 # arguments and collect up the files that need to be processed.
356 for my $f (@ARGV) {
357 if (-d $f) {
358 opendir(DH,$f)
359 or die "Failed to opendir $f: $!";
360
361 push @files, grep { -f $_ } map { +$f . "/" . $_ }
362 sort readdir(DH);
363
364 } elsif (-f $f) {
365 push @files, $f;
366
367 } else {
368 print STDERR "Skipping $f - not found.\n";
369 }
370 }
371
372 if (@files) {
373 unless ($quiet) {
374 print $_,"\n" for (@files);
375 }
376 } else {
377 print STDERR "\nNo patch files specified!\n\n";
378 usage();
379 }
380
381 # Variables we set as part of the loop over files
382 our ($message_id, $cc, %mail, $subject, $reply_to, $references, $message);
383
384 sub extract_valid_address {
385 my $address = shift;
386 my $local_part_regexp = '[^<>"\s@]+';
387 my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
388
389 # check for a local address:
390 return $address if ($address =~ /^($local_part_regexp)$/);
391
392 if ($have_email_valid) {
393 return scalar Email::Valid->address($address);
394 } else {
395 # less robust/correct than the monster regexp in Email::Valid,
396 # but still does a 99% job, and one less dependency
397 $address =~ /($local_part_regexp\@$domain_regexp)/;
398 return $1;
399 }
400 }
401
402 # Usually don't need to change anything below here.
403
404 # we make a "fake" message id by taking the current number
405 # of seconds since the beginning of Unix time and tacking on
406 # a random number to the end, in case we are called quicker than
407 # 1 second since the last time we were called.
408
409 # We'll setup a template for the message id, using the "from" address:
410 my $message_id_from = extract_valid_address($from);
411 my $message_id_template = "<%s-git-send-email-$message_id_from>";
412
413 sub make_message_id
414 {
415 my $date = time;
416 my $pseudo_rand = int (rand(4200));
417 $message_id = sprintf $message_id_template, "$date$pseudo_rand";
418 #print "new message id = $message_id\n"; # Was useful for debugging
419 }
420
421
422
423 $cc = "";
424 $time = time - scalar $#files;
425
426 sub unquote_rfc2047 {
427 local ($_) = @_;
428 if (s/=\?utf-8\?q\?(.*)\?=/$1/g) {
429 s/_/ /g;
430 s/=([0-9A-F]{2})/chr(hex($1))/eg;
431 }
432 return "$_";
433 }
434
435 sub send_message
436 {
437 my @recipients = unique_email_list(@to);
438 my $to = join (",\n\t", @recipients);
439 @recipients = unique_email_list(@recipients,@cc,@bcclist);
440 my $date = format_2822_time($time++);
441 my $gitversion = '@@GIT_VERSION@@';
442 if ($gitversion =~ m/..GIT_VERSION../) {
443 $gitversion = Git::version();
444 }
445
446 my ($author_name) = ($from =~ /^(.*?)\s+</);
447 if ($author_name && $author_name =~ /\./ && $author_name !~ /^".*"$/) {
448 my ($name, $addr) = ($from =~ /^(.*?)(\s+<.*)/);
449 $from = "\"$name\"$addr";
450 }
451 my $header = "From: $from
452 To: $to
453 Cc: $cc
454 Subject: $subject
455 Date: $date
456 Message-Id: $message_id
457 X-Mailer: git-send-email $gitversion
458 ";
459 if ($reply_to) {
460
461 $header .= "In-Reply-To: $reply_to\n";
462 $header .= "References: $references\n";
463 }
464 if (@xh) {
465 $header .= join("\n", @xh) . "\n";
466 }
467
468 my @sendmail_parameters = ('-i', map { extract_valid_address($_) } @recipients);
469
470 if ($dry_run) {
471 # We don't want to send the email.
472 } elsif ($smtp_server =~ m#^/#) {
473 my $pid = open my $sm, '|-';
474 defined $pid or die $!;
475 if (!$pid) {
476 exec($smtp_server, @sendmail_parameters) or die $!;
477 }
478 print $sm "$header\n$message";
479 close $sm or die $?;
480 } else {
481 require Net::SMTP;
482 $smtp ||= Net::SMTP->new( $smtp_server );
483 $smtp->mail( $from ) or die $smtp->message;
484 $smtp->to( @recipients ) or die $smtp->message;
485 $smtp->data or die $smtp->message;
486 $smtp->datasend("$header\n$message") or die $smtp->message;
487 $smtp->dataend() or die $smtp->message;
488 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
489 }
490 if ($quiet) {
491 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
492 } else {
493 print (($dry_run ? "Dry-" : "")."OK. Log says:\nDate: $date\n");
494 if ($smtp) {
495 print "Server: $smtp_server\n";
496 print "MAIL FROM: $from\n";
497 print "RCPT TO: ".join(',',@recipients)."\n";
498 } else {
499 print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
500 }
501 print "From: $from\nSubject: $subject\nCc: $cc\nTo: $to\n\n";
502 if ($smtp) {
503 print "Result: ", $smtp->code, ' ',
504 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
505 } else {
506 print "Result: OK\n";
507 }
508 }
509 }
510
511 $reply_to = $initial_reply_to;
512 $references = $initial_reply_to || '';
513 make_message_id();
514 $subject = $initial_subject;
515
516 foreach my $t (@files) {
517 open(F,"<",$t) or die "can't open file $t";
518
519 my $author_not_sender = undef;
520 @cc = @initial_cc;
521 @xh = ();
522 my $input_format = undef;
523 my $header_done = 0;
524 $message = "";
525 while(<F>) {
526 if (!$header_done) {
527 if (/^From /) {
528 $input_format = 'mbox';
529 next;
530 }
531 chomp;
532 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
533 $input_format = 'mbox';
534 }
535
536 if (defined $input_format && $input_format eq 'mbox') {
537 if (/^Subject:\s+(.*)$/) {
538 $subject = $1;
539
540 } elsif (/^(Cc|From):\s+(.*)$/) {
541 if ($2 eq $from) {
542 next if ($suppress_from);
543 }
544 elsif ($1 eq 'From') {
545 $author_not_sender = $2;
546 }
547 printf("(mbox) Adding cc: %s from line '%s'\n",
548 $2, $_) unless $quiet;
549 push @cc, $2;
550 }
551 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
552 push @xh, $_;
553 }
554
555 } else {
556 # In the traditional
557 # "send lots of email" format,
558 # line 1 = cc
559 # line 2 = subject
560 # So let's support that, too.
561 $input_format = 'lots';
562 if (@cc == 0) {
563 printf("(non-mbox) Adding cc: %s from line '%s'\n",
564 $_, $_) unless $quiet;
565
566 push @cc, $_;
567
568 } elsif (!defined $subject) {
569 $subject = $_;
570 }
571 }
572
573 # A whitespace line will terminate the headers
574 if (m/^\s*$/) {
575 $header_done = 1;
576 }
577 } else {
578 $message .= $_;
579 if (/^(Signed-off-by|Cc): (.*)$/i && !$no_signed_off_cc) {
580 my $c = $2;
581 chomp $c;
582 push @cc, $c;
583 printf("(sob) Adding cc: %s from line '%s'\n",
584 $c, $_) unless $quiet;
585 }
586 }
587 }
588 close F;
589 if (defined $author_not_sender) {
590 $author_not_sender = unquote_rfc2047($author_not_sender);
591 $message = "From: $author_not_sender\n\n$message";
592 }
593
594 $cc = join(", ", unique_email_list(@cc));
595
596 send_message();
597
598 # set up for the next message
599 if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
600 $reply_to = $message_id;
601 if (length $references > 0) {
602 $references .= "\n $message_id";
603 } else {
604 $references = "$message_id";
605 }
606 }
607 make_message_id();
608 }
609
610 if ($compose) {
611 cleanup_compose_files();
612 }
613
614 sub cleanup_compose_files() {
615 unlink($compose_filename, $compose_filename . ".final");
616
617 }
618
619 $smtp->quit if $smtp;
620
621 sub unique_email_list(@) {
622 my %seen;
623 my @emails;
624
625 foreach my $entry (@_) {
626 if (my $clean = extract_valid_address($entry)) {
627 $seen{$clean} ||= 0;
628 next if $seen{$clean}++;
629 push @emails, $entry;
630 } else {
631 print STDERR "W: unable to extract a valid address",
632 " from: $entry\n";
633 }
634 }
635 return @emails;
636 }