Merge branch 'jc/for-each-ref' into jc/ref-locking
[git/git.git] / configure.ac
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
3
4 AC_PREREQ(2.59)
5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
6
7 AC_CONFIG_SRCDIR([git.c])
8
9 config_file=config.mak.autogen
10 config_append=config.mak.append
11 config_in=config.mak.in
12
13 echo "# ${config_append}. Generated by configure." > "${config_append}"
14
15
16 ## Definitions of macros
17 # GIT_CONF_APPEND_LINE(LINE)
18 # --------------------------
19 # Append LINE to file ${config_append}
20 AC_DEFUN([GIT_CONF_APPEND_LINE],
21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
22 #
23 # GIT_ARG_SET_PATH(PROGRAM)
24 # -------------------------
25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
26 AC_DEFUN([GIT_ARG_SET_PATH],
27 [AC_ARG_WITH([$1],
28 [AS_HELP_STRING([--with-$1=PATH],
29 [provide PATH to $1])],
30 [GIT_CONF_APPEND_PATH($1)],[])
31 ])# GIT_ARG_SET_PATH
32 #
33 # GIT_CONF_APPEND_PATH(PROGRAM)
34 # ------------------------------
35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
36 # Used by GIT_ARG_SET_PATH(PROGRAM)
37 AC_DEFUN([GIT_CONF_APPEND_PATH],
38 [PROGRAM=m4_toupper($1); \
39 if test "$withval" = "no"; then \
40 AC_MSG_ERROR([You cannot use git without $1]); \
41 else \
42 if test "$withval" = "yes"; then \
43 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
44 else \
45 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
46 fi; \
47 fi; \
48 ]) # GIT_CONF_APPEND_PATH
49 #
50 # GIT_PARSE_WITH(PACKAGE)
51 # -----------------------
52 # For use in AC_ARG_WITH action-if-found, for packages default ON.
53 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
54 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
55 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
56 AC_DEFUN([GIT_PARSE_WITH],
57 [PACKAGE=m4_toupper($1); \
58 if test "$withval" = "no"; then \
59 m4_toupper(NO_$1)=YesPlease; \
60 elif test "$withval" = "yes"; then \
61 m4_toupper(NO_$1)=; \
62 else \
63 m4_toupper(NO_$1)=; \
64 GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
65 fi \
66 ])# GIT_PARSE_WITH
67
68
69 ## Site configuration related to programs (before tests)
70 ## --with-PACKAGE[=ARG] and --without-PACKAGE
71 #
72 # Define SHELL_PATH to provide path to shell.
73 GIT_ARG_SET_PATH(shell)
74 #
75 # Define PERL_PATH to provide path to Perl.
76 GIT_ARG_SET_PATH(perl)
77 #
78 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
79 # Define PYTHON_PATH to provide path to Python.
80 AC_ARG_WITH(python,[AS_HELP_STRING([--with-python=PATH], [provide PATH to python])
81 AS_HELP_STRING([--without-python], [don't use python scripts])],
82 [if test "$withval" = "no"; then \
83 NO_PYTHON=YesPlease; \
84 elif test "$withval" = "yes"; then \
85 NO_PYTHON=; \
86 else \
87 NO_PYTHON=; \
88 PYTHON_PATH=$withval; \
89 fi; \
90 ])
91 AC_SUBST(NO_PYTHON)
92 AC_SUBST(PYTHON_PATH)
93
94
95 ## Checks for programs.
96 AC_MSG_NOTICE([CHECKS for programs])
97 #
98 AC_PROG_CC
99 #AC_PROG_INSTALL # needs install-sh or install.sh in sources
100 AC_CHECK_TOOL(AR, ar, :)
101 AC_CHECK_PROGS(TAR, [gtar tar])
102 #
103 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
104 # Define PYTHON_PATH to provide path to Python.
105 if test -z "$NO_PYTHON"; then
106 if test -z "$PYTHON_PATH"; then
107 AC_PATH_PROGS(PYTHON_PATH, [python python2.4 python2.3 python2])
108 fi
109 if test -n "$PYTHON_PATH"; then
110 GIT_CONF_APPEND_LINE([PYTHON_PATH=@PYTHON_PATH@])
111 NO_PYTHON=""
112 fi
113 fi
114
115
116 ## Checks for libraries.
117 AC_MSG_NOTICE([CHECKS for libraries])
118 #
119 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
120 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
121 AC_CHECK_LIB([crypto], [SHA1_Init],
122 [NEEDS_SSL_WITH_CRYPTO=],
123 [AC_CHECK_LIB([ssl], [SHA1_Init],
124 [NEEDS_SSL_WITH_CRYPTO=YesPlease
125 NEEDS_SSL_WITH_CRYPTO=],
126 [NO_OPENSSL=YesPlease])])
127 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
128 AC_SUBST(NO_OPENSSL)
129 #
130 # Define NO_CURL if you do not have curl installed. git-http-pull and
131 # git-http-push are not built, and you cannot use http:// and https://
132 # transports.
133 AC_CHECK_LIB([curl], [curl_global_init],
134 [NO_CURL=],
135 [NO_CURL=YesPlease])
136 AC_SUBST(NO_CURL)
137 #
138 # Define NO_EXPAT if you do not have expat installed. git-http-push is
139 # not built, and you cannot push using http:// and https:// transports.
140 AC_CHECK_LIB([expat], [XML_ParserCreate],
141 [NO_EXPAT=],
142 [NO_EXPAT=YesPlease])
143 AC_SUBST(NO_EXPAT)
144 #
145 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin).
146 # Define NO_ICONV if neither libc nor libiconv support iconv.
147 AC_CHECK_LIB([c], [iconv],
148 [NEEDS_LIBICONV=],
149 AC_CHECK_LIB([iconv], [iconv],
150 [NEEDS_LIBICONV=YesPlease],
151 [NO_ICONV=YesPlease]))
152 AC_SUBST(NEEDS_LIBICONV)
153 AC_SUBST(NO_ICONV)
154 test -n "$NEEDS_LIBICONV" && LIBS="$LIBS -liconv"
155 #
156 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
157 # Patrick Mauritz).
158 AC_CHECK_LIB([c], [socket],
159 [NEEDS_SOCKET=],
160 [NEEDS_SOCKET=YesPlease])
161 AC_SUBST(NEEDS_SOCKET)
162 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
163
164
165 ## Checks for header files.
166
167
168 ## Checks for typedefs, structures, and compiler characteristics.
169 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
170 #
171 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
172 AC_CHECK_MEMBER(struct dirent.d_ino,
173 [NO_D_INO_IN_DIRENT=],
174 [NO_D_INO_IN_DIRENT=YesPlease],
175 [#include <dirent.h>])
176 AC_SUBST(NO_D_INO_IN_DIRENT)
177 #
178 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
179 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
180 AC_CHECK_MEMBER(struct dirent.d_type,
181 [NO_D_TYPE_IN_DIRENT=],
182 [NO_D_TYPE_IN_DIRENT=YesPlease],
183 [#include <dirent.h>])
184 AC_SUBST(NO_D_TYPE_IN_DIRENT)
185 #
186 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
187 # sockaddr_storage.
188 AC_CHECK_TYPE(struct sockaddr_storage,
189 [NO_SOCKADDR_STORAGE=],
190 [NO_SOCKADDR_STORAGE=YesPlease],[
191 #include <sys/types.h>
192 #include <sys/socket.h>
193 ])
194 AC_SUBST(NO_SOCKADDR_STORAGE)
195 #
196 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
197 AC_CHECK_TYPE([struct addrinfo],[
198 AC_CHECK_FUNC([getaddrinfo],
199 [NO_IPV6=],
200 [NO_IPV6=YesPlease])
201 ],[NO_IPV6=YesPlease],[
202 #include <sys/types.h>
203 #include <sys/socket.h>
204 #include <netdb.h>
205 ])
206 AC_SUBST(NO_IPV6)
207 #
208 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
209 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
210 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
211 # some C compilers supported these specifiers prior to C99 as an extension.
212 AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
213 [ac_cv_c_c99_format],
214 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
215 AC_RUN_IFELSE(
216 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
217 [[char buf[64];
218 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
219 exit(1);
220 else if (strcmp(buf, "12345"))
221 exit(2);]])],
222 [ac_cv_c_c99_format=yes],
223 [ac_cv_c_c99_format=no])
224 ])
225 if test $ac_cv_c_c99_format = no; then
226 NO_C99_FORMAT=YesPlease
227 else
228 NO_C99_FORMAT=
229 fi
230 AC_SUBST(NO_C99_FORMAT)
231
232
233 ## Checks for library functions.
234 ## (in default C library and libraries checked by AC_CHECK_LIB)
235 AC_MSG_NOTICE([CHECKS for library functions])
236 #
237 # Define NO_STRCASESTR if you don't have strcasestr.
238 AC_CHECK_FUNC(strcasestr,
239 [NO_STRCASESTR=],
240 [NO_STRCASESTR=YesPlease])
241 AC_SUBST(NO_STRCASESTR)
242 #
243 # Define NO_STRLCPY if you don't have strlcpy.
244 AC_CHECK_FUNC(strlcpy,
245 [NO_STRLCPY=],
246 [NO_STRLCPY=YesPlease])
247 AC_SUBST(NO_STRLCPY)
248 #
249 # Define NO_SETENV if you don't have setenv in the C library.
250 AC_CHECK_FUNC(setenv,
251 [NO_SETENV=],
252 [NO_SETENV=YesPlease])
253 AC_SUBST(NO_SETENV)
254 #
255 # Define NO_MMAP if you want to avoid mmap.
256 #
257 # Define NO_ICONV if your libc does not properly support iconv.
258
259
260 ## Other checks.
261 # Define USE_PIC if you need the main git objects to be built with -fPIC
262 # in order to build and link perl/Git.so. x86-64 seems to need this.
263 #
264 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
265 # Enable it on Windows. By default, symrefs are still used.
266 #
267 # Define WITH_OWN_SUBPROCESS_PY if you want to use with python 2.3.
268 AC_CACHE_CHECK([for subprocess.py],
269 [ac_cv_python_has_subprocess_py],
270 [if $PYTHON_PATH -c 'import subprocess' 2>/dev/null; then
271 ac_cv_python_has_subprocess_py=yes
272 else
273 ac_cv_python_has_subprocess_py=no
274 fi])
275 if test $ac_cv_python_has_subprocess_py != yes; then
276 GIT_CONF_APPEND_LINE([WITH_OWN_SUBPROCESS_PY=YesPlease])
277 fi
278 #
279 # Define NO_ACCURATE_DIFF if your diff program at least sometimes misses
280 # a missing newline at the end of the file.
281
282
283 ## Site configuration (override autodetection)
284 ## --with-PACKAGE[=ARG] and --without-PACKAGE
285 AC_MSG_NOTICE([CHECKS for site configuration])
286 #
287 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
288 # tests. These tests take up a significant amount of the total test time
289 # but are not needed unless you plan to talk to SVN repos.
290 #
291 # Define MOZILLA_SHA1 environment variable when running make to make use of
292 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
293 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
294 # choice) has very fast version optimized for i586.
295 #
296 # Define PPC_SHA1 environment variable when running make to make use of
297 # a bundled SHA1 routine optimized for PowerPC.
298 #
299 # Define ARM_SHA1 environment variable when running make to make use of
300 # a bundled SHA1 routine optimized for ARM.
301 #
302 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
303 # This also implies MOZILLA_SHA1.
304 #
305 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
306 # /foo/bar/include and /foo/bar/lib directories.
307 AC_ARG_WITH(openssl,
308 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
309 AS_HELP_STRING([], [ARG can be prefix for openssl library and headers]),\
310 GIT_PARSE_WITH(openssl))
311 #
312 # Define NO_CURL if you do not have curl installed. git-http-pull and
313 # git-http-push are not built, and you cannot use http:// and https://
314 # transports.
315 #
316 # Define CURLDIR=/foo/bar if your curl header and library files are in
317 # /foo/bar/include and /foo/bar/lib directories.
318 AC_ARG_WITH(curl,
319 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
320 AS_HELP_STRING([], [ARG can be also prefix for curl library and headers]),
321 GIT_PARSE_WITH(curl))
322 #
323 # Define NO_EXPAT if you do not have expat installed. git-http-push is
324 # not built, and you cannot push using http:// and https:// transports.
325 #
326 # Define EXPATDIR=/foo/bar if your expat header and library files are in
327 # /foo/bar/include and /foo/bar/lib directories.
328 AC_ARG_WITH(expat,
329 AS_HELP_STRING([--with-expat],
330 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
331 AS_HELP_STRING([], [ARG can be also prefix for expat library and headers]),
332 GIT_PARSE_WITH(expat))
333 #
334 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
335 # installed in /sw, but don't want GIT to link against any libraries
336 # installed there. If defined you may specify your own (or Fink's)
337 # include directories and library directories by defining CFLAGS
338 # and LDFLAGS appropriately.
339 #
340 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
341 # have DarwinPorts installed in /opt/local, but don't want GIT to
342 # link against any libraries installed there. If defined you may
343 # specify your own (or DarwinPort's) include directories and
344 # library directories by defining CFLAGS and LDFLAGS appropriately.
345 #
346 # Define NO_MMAP if you want to avoid mmap.
347 #
348 # Define NO_ICONV if your libc does not properly support iconv.
349 AC_ARG_WITH(iconv,
350 AS_HELP_STRING([--without-iconv],
351 [if your architecture doesn't properly support iconv])
352 AS_HELP_STRING([--with-iconv=PATH],
353 [PATH is prefix for libiconv library and headers])
354 AS_HELP_STRING([],
355 [used only if you need linking with libiconv]),
356 GIT_PARSE_WITH(iconv))
357
358 ## --enable-FEATURE[=ARG] and --disable-FEATURE
359 #
360 # Define COLLISION_CHECK below if you believe that SHA1's
361 # 1461501637330902918203684832716283019655932542976 hashes do not give you
362 # sufficient guarantee that no collisions between objects will ever happen.
363 #
364 # Define USE_NSEC below if you want git to care about sub-second file mtimes
365 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
366 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
367 # randomly break unless your underlying filesystem supports those sub-second
368 # times (my ext3 doesn't).
369 #
370 # Define USE_STDEV below if you want git to care about the underlying device
371 # change being considered an inode change from the update-cache perspective.
372
373
374 ## Output files
375 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
376 AC_OUTPUT
377
378
379 ## Cleanup
380 rm -f "${config_append}"