send-email: fix In-Reply-To regression
[git/git.git] / git-send-email.perl
1 #!/usr/bin/perl -w
2 #
3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
5 #
6 # GPL v2 (See COPYING)
7 #
8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
9 #
10 # Sends a collection of emails to the given email addresses, disturbingly fast.
11 #
12 # Supports two formats:
13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
14 # 2. The original format support by Greg's script:
15 # first line of the message is who to CC,
16 # and second line is the subject of the message.
17 #
18
19 use strict;
20 use warnings;
21 use Term::ReadLine;
22 use Getopt::Long;
23 use Data::Dumper;
24 use Term::ANSIColor;
25 use Git;
26
27 package FakeTerm;
28 sub new {
29 my ($class, $reason) = @_;
30 return bless \$reason, shift;
31 }
32 sub readline {
33 my $self = shift;
34 die "Cannot use readline on FakeTerm: $$self";
35 }
36 package main;
37
38
39 sub usage {
40 print <<EOT;
41 git-send-email [options] <file | directory>...
42 Options:
43 --from Specify the "From:" line of the email to be sent.
44
45 --to Specify the primary "To:" line of the email.
46
47 --cc Specify an initial "Cc:" list for the entire series
48 of emails.
49
50 --cc-cmd Specify a command to execute per file which adds
51 per file specific cc address entries
52
53 --bcc Specify a list of email addresses that should be Bcc:
54 on all the emails.
55
56 --compose Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
57 an introductory message for the patch series.
58
59 --subject Specify the initial "Subject:" line.
60 Only necessary if --compose is also set. If --compose
61 is not set, this will be prompted for.
62
63 --in-reply-to Specify the first "In-Reply-To:" header line.
64 Only used if --compose is also set. If --compose is not
65 set, this will be prompted for.
66
67 --chain-reply-to If set, the replies will all be to the previous
68 email sent, rather than to the first email sent.
69 Defaults to on.
70
71 --signed-off-cc Automatically add email addresses that appear in
72 Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
73
74 --identity The configuration identity, a subsection to prioritise over
75 the default section.
76
77 --smtp-server If set, specifies the outgoing SMTP server to use.
78 Defaults to localhost. Port number can be specified here with
79 hostname:port format or by using --smtp-server-port option.
80
81 --smtp-server-port Specify a port on the outgoing SMTP server to connect to.
82
83 --smtp-user The username for SMTP-AUTH.
84
85 --smtp-pass The password for SMTP-AUTH.
86
87 --smtp-ssl If set, connects to the SMTP server using SSL.
88
89 --suppress-cc Suppress the specified category of auto-CC. The category
90 can be one of 'author' for the patch author, 'self' to
91 avoid copying yourself, 'sob' for Signed-off-by lines,
92 'cccmd' for the output of the cccmd, or 'all' to suppress
93 all of these.
94
95 --suppress-from Suppress sending emails to yourself. Defaults to off.
96
97 --thread Specify that the "In-Reply-To:" header should be set on all
98 emails. Defaults to on.
99
100 --quiet Make git-send-email less verbose. One line per email
101 should be all that is output.
102
103 --dry-run Do everything except actually send the emails.
104
105 --envelope-sender Specify the envelope sender used to send the emails.
106
107 --no-validate Don't perform any sanity checks on patches.
108
109 EOT
110 exit(1);
111 }
112
113 # most mail servers generate the Date: header, but not all...
114 sub format_2822_time {
115 my ($time) = @_;
116 my @localtm = localtime($time);
117 my @gmttm = gmtime($time);
118 my $localmin = $localtm[1] + $localtm[2] * 60;
119 my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
120 if ($localtm[0] != $gmttm[0]) {
121 die "local zone differs from GMT by a non-minute interval\n";
122 }
123 if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
124 $localmin += 1440;
125 } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
126 $localmin -= 1440;
127 } elsif ($gmttm[6] != $localtm[6]) {
128 die "local time offset greater than or equal to 24 hours\n";
129 }
130 my $offset = $localmin - $gmtmin;
131 my $offhour = $offset / 60;
132 my $offmin = abs($offset % 60);
133 if (abs($offhour) >= 24) {
134 die ("local time offset greater than or equal to 24 hours\n");
135 }
136
137 return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
138 qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
139 $localtm[3],
140 qw(Jan Feb Mar Apr May Jun
141 Jul Aug Sep Oct Nov Dec)[$localtm[4]],
142 $localtm[5]+1900,
143 $localtm[2],
144 $localtm[1],
145 $localtm[0],
146 ($offset >= 0) ? '+' : '-',
147 abs($offhour),
148 $offmin,
149 );
150 }
151
152 my $have_email_valid = eval { require Email::Valid; 1 };
153 my $smtp;
154 my $auth;
155
156 sub unique_email_list(@);
157 sub cleanup_compose_files();
158
159 # Constants (essentially)
160 my $compose_filename = ".msg.$$";
161
162 # Variables we fill in automatically, or via prompting:
163 my (@to,@cc,@initial_cc,@bcclist,@xh,
164 $initial_reply_to,$initial_subject,@files,$author,$sender,$smtp_authpass,$compose,$time);
165
166 my $envelope_sender;
167
168 # Example reply to:
169 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
170
171 my $repo = Git->repository();
172 my $term = eval {
173 $ENV{"GIT_SEND_EMAIL_NOTTY"}
174 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
175 : new Term::ReadLine 'git-send-email';
176 };
177 if ($@) {
178 $term = new FakeTerm "$@: going non-interactive";
179 }
180
181 # Behavior modification variables
182 my ($quiet, $dry_run) = (0, 0);
183
184 # Variables with corresponding config settings
185 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
186 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_ssl);
187 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
188 my ($no_validate);
189 my (@suppress_cc);
190
191 my %config_bool_settings = (
192 "thread" => [\$thread, 1],
193 "chainreplyto" => [\$chain_reply_to, 1],
194 "suppressfrom" => [\$suppress_from, undef],
195 "signedoffcc" => [\$signed_off_cc, undef],
196 "smtpssl" => [\$smtp_ssl, 0],
197 );
198
199 my %config_settings = (
200 "smtpserver" => \$smtp_server,
201 "smtpserverport" => \$smtp_server_port,
202 "smtpuser" => \$smtp_authuser,
203 "smtppass" => \$smtp_authpass,
204 "to" => \@to,
205 "cccmd" => \$cc_cmd,
206 "aliasfiletype" => \$aliasfiletype,
207 "bcc" => \@bcclist,
208 "aliasesfile" => \@alias_files,
209 "suppresscc" => \@suppress_cc,
210 );
211
212 # Handle Uncouth Termination
213 sub signal_handler {
214
215 # Make text normal
216 print color("reset"), "\n";
217
218 # SMTP password masked
219 system "stty echo";
220
221 # tmp files from --compose
222 if (-e $compose_filename) {
223 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
224 }
225 if (-e ($compose_filename . ".final")) {
226 print "'$compose_filename.final' contains the composed email.\n"
227 }
228
229 exit;
230 };
231
232 $SIG{TERM} = \&signal_handler;
233 $SIG{INT} = \&signal_handler;
234
235 # Begin by accumulating all the variables (defined above), that we will end up
236 # needing, first, from the command line:
237
238 my $rc = GetOptions("sender|from=s" => \$sender,
239 "in-reply-to=s" => \$initial_reply_to,
240 "subject=s" => \$initial_subject,
241 "to=s" => \@to,
242 "cc=s" => \@initial_cc,
243 "bcc=s" => \@bcclist,
244 "chain-reply-to!" => \$chain_reply_to,
245 "smtp-server=s" => \$smtp_server,
246 "smtp-server-port=s" => \$smtp_server_port,
247 "smtp-user=s" => \$smtp_authuser,
248 "smtp-pass:s" => \$smtp_authpass,
249 "smtp-ssl!" => \$smtp_ssl,
250 "identity=s" => \$identity,
251 "compose" => \$compose,
252 "quiet" => \$quiet,
253 "cc-cmd=s" => \$cc_cmd,
254 "suppress-from!" => \$suppress_from,
255 "suppress-cc=s" => \@suppress_cc,
256 "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
257 "dry-run" => \$dry_run,
258 "envelope-sender=s" => \$envelope_sender,
259 "thread!" => \$thread,
260 "no-validate" => \$no_validate,
261 );
262
263 unless ($rc) {
264 usage();
265 }
266
267 # Now, let's fill any that aren't set in with defaults:
268
269 sub read_config {
270 my ($prefix) = @_;
271
272 foreach my $setting (keys %config_bool_settings) {
273 my $target = $config_bool_settings{$setting}->[0];
274 $$target = $repo->config_bool("$prefix.$setting") unless (defined $$target);
275 }
276
277 foreach my $setting (keys %config_settings) {
278 my $target = $config_settings{$setting};
279 if (ref($target) eq "ARRAY") {
280 unless (@$target) {
281 my @values = $repo->config("$prefix.$setting");
282 @$target = @values if (@values && defined $values[0]);
283 }
284 }
285 else {
286 $$target = $repo->config("$prefix.$setting") unless (defined $$target);
287 }
288 }
289 }
290
291 # read configuration from [sendemail "$identity"], fall back on [sendemail]
292 $identity = $repo->config("sendemail.identity") unless (defined $identity);
293 read_config("sendemail.$identity") if (defined $identity);
294 read_config("sendemail");
295
296 # fall back on builtin bool defaults
297 foreach my $setting (values %config_bool_settings) {
298 ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
299 }
300
301 # Set CC suppressions
302 my(%suppress_cc);
303 if (@suppress_cc) {
304 foreach my $entry (@suppress_cc) {
305 die "Unknown --suppress-cc field: '$entry'\n"
306 unless $entry =~ /^(all|cccmd|cc|author|self|sob)$/;
307 $suppress_cc{$entry} = 1;
308 }
309 }
310
311 if ($suppress_cc{'all'}) {
312 foreach my $entry (qw (ccmd cc author self sob)) {
313 $suppress_cc{$entry} = 1;
314 }
315 delete $suppress_cc{'all'};
316 }
317
318 # If explicit old-style ones are specified, they trump --suppress-cc.
319 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
320 $suppress_cc{'sob'} = $signed_off_cc if defined $signed_off_cc;
321
322 # Debugging, print out the suppressions.
323 if (0) {
324 print "suppressions:\n";
325 foreach my $entry (keys %suppress_cc) {
326 printf " %-5s -> $suppress_cc{$entry}\n", $entry;
327 }
328 }
329
330 my ($repoauthor) = $repo->ident_person('author');
331 my ($repocommitter) = $repo->ident_person('committer');
332
333 # Verify the user input
334
335 foreach my $entry (@to) {
336 die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
337 }
338
339 foreach my $entry (@initial_cc) {
340 die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
341 }
342
343 foreach my $entry (@bcclist) {
344 die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
345 }
346
347 my %aliases;
348 my %parse_alias = (
349 # multiline formats can be supported in the future
350 mutt => sub { my $fh = shift; while (<$fh>) {
351 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
352 my ($alias, $addr) = ($1, $2);
353 $addr =~ s/#.*$//; # mutt allows # comments
354 # commas delimit multiple addresses
355 $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
356 }}},
357 mailrc => sub { my $fh = shift; while (<$fh>) {
358 if (/^alias\s+(\S+)\s+(.*)$/) {
359 # spaces delimit multiple addresses
360 $aliases{$1} = [ split(/\s+/, $2) ];
361 }}},
362 pine => sub { my $fh = shift; while (<$fh>) {
363 if (/^(\S+)\t.*\t(.*)$/) {
364 $aliases{$1} = [ split(/\s*,\s*/, $2) ];
365 }}},
366 gnus => sub { my $fh = shift; while (<$fh>) {
367 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
368 $aliases{$1} = [ $2 ];
369 }}}
370 );
371
372 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
373 foreach my $file (@alias_files) {
374 open my $fh, '<', $file or die "opening $file: $!\n";
375 $parse_alias{$aliasfiletype}->($fh);
376 close $fh;
377 }
378 }
379
380 ($sender) = expand_aliases($sender) if defined $sender;
381
382 # Now that all the defaults are set, process the rest of the command line
383 # arguments and collect up the files that need to be processed.
384 for my $f (@ARGV) {
385 if (-d $f) {
386 opendir(DH,$f)
387 or die "Failed to opendir $f: $!";
388
389 push @files, grep { -f $_ } map { +$f . "/" . $_ }
390 sort readdir(DH);
391
392 } elsif (-f $f) {
393 push @files, $f;
394
395 } else {
396 print STDERR "Skipping $f - not found.\n";
397 }
398 }
399
400 if (!$no_validate) {
401 foreach my $f (@files) {
402 my $error = validate_patch($f);
403 $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
404 }
405 }
406
407 if (@files) {
408 unless ($quiet) {
409 print $_,"\n" for (@files);
410 }
411 } else {
412 print STDERR "\nNo patch files specified!\n\n";
413 usage();
414 }
415
416 my $prompting = 0;
417 if (!defined $sender) {
418 $sender = $repoauthor || $repocommitter;
419
420 while (1) {
421 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
422 last if defined $_;
423 print "\n";
424 }
425
426 $sender = $_ if ($_);
427 print "Emails will be sent from: ", $sender, "\n";
428 $prompting++;
429 }
430
431 if (!@to) {
432
433
434 while (1) {
435 $_ = $term->readline("Who should the emails be sent to? ", "");
436 last if defined $_;
437 print "\n";
438 }
439
440 my $to = $_;
441 push @to, split /,/, $to;
442 $prompting++;
443 }
444
445 sub expand_aliases {
446 my @cur = @_;
447 my @last;
448 do {
449 @last = @cur;
450 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
451 } while (join(',',@cur) ne join(',',@last));
452 return @cur;
453 }
454
455 @to = expand_aliases(@to);
456 @to = (map { sanitize_address($_) } @to);
457 @initial_cc = expand_aliases(@initial_cc);
458 @bcclist = expand_aliases(@bcclist);
459
460 if (!defined $initial_subject && $compose) {
461 while (1) {
462 $_ = $term->readline("What subject should the initial email start with? ", $initial_subject);
463 last if defined $_;
464 print "\n";
465 }
466
467 $initial_subject = $_;
468 $prompting++;
469 }
470
471 if ($thread && !defined $initial_reply_to && $prompting) {
472 while (1) {
473 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ", $initial_reply_to);
474 last if defined $_;
475 print "\n";
476 }
477
478 $initial_reply_to = $_;
479 }
480 if (defined $initial_reply_to) {
481 $initial_reply_to =~ s/^\s*<?//;
482 $initial_reply_to =~ s/>?\s*$//;
483 $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
484 }
485
486 if (!defined $smtp_server) {
487 foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
488 if (-x $_) {
489 $smtp_server = $_;
490 last;
491 }
492 }
493 $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
494 }
495
496 if ($compose) {
497 # Note that this does not need to be secure, but we will make a small
498 # effort to have it be unique
499 open(C,">",$compose_filename)
500 or die "Failed to open for writing $compose_filename: $!";
501 print C "From $sender # This line is ignored.\n";
502 printf C "Subject: %s\n\n", $initial_subject;
503 printf C <<EOT;
504 GIT: Please enter your email below.
505 GIT: Lines beginning in "GIT: " will be removed.
506 GIT: Consider including an overall diffstat or table of contents
507 GIT: for the patch you are writing.
508
509 EOT
510 close(C);
511
512 my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
513 system('sh', '-c', '$0 $@', $editor, $compose_filename);
514
515 open(C2,">",$compose_filename . ".final")
516 or die "Failed to open $compose_filename.final : " . $!;
517
518 open(C,"<",$compose_filename)
519 or die "Failed to open $compose_filename : " . $!;
520
521 while(<C>) {
522 next if m/^GIT: /;
523 print C2 $_;
524 }
525 close(C);
526 close(C2);
527
528 while (1) {
529 $_ = $term->readline("Send this email? (y|n) ");
530 last if defined $_;
531 print "\n";
532 }
533
534 if (uc substr($_,0,1) ne 'Y') {
535 cleanup_compose_files();
536 exit(0);
537 }
538
539 @files = ($compose_filename . ".final", @files);
540 }
541
542 # Variables we set as part of the loop over files
543 our ($message_id, %mail, $subject, $reply_to, $references, $message);
544
545 sub extract_valid_address {
546 my $address = shift;
547 my $local_part_regexp = '[^<>"\s@]+';
548 my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
549
550 # check for a local address:
551 return $address if ($address =~ /^($local_part_regexp)$/);
552
553 $address =~ s/^\s*<(.*)>\s*$/$1/;
554 if ($have_email_valid) {
555 return scalar Email::Valid->address($address);
556 } else {
557 # less robust/correct than the monster regexp in Email::Valid,
558 # but still does a 99% job, and one less dependency
559 $address =~ /($local_part_regexp\@$domain_regexp)/;
560 return $1;
561 }
562 }
563
564 # Usually don't need to change anything below here.
565
566 # we make a "fake" message id by taking the current number
567 # of seconds since the beginning of Unix time and tacking on
568 # a random number to the end, in case we are called quicker than
569 # 1 second since the last time we were called.
570
571 # We'll setup a template for the message id, using the "from" address:
572
573 my ($message_id_stamp, $message_id_serial);
574 sub make_message_id
575 {
576 my $uniq;
577 if (!defined $message_id_stamp) {
578 $message_id_stamp = sprintf("%s-%s", time, $$);
579 $message_id_serial = 0;
580 }
581 $message_id_serial++;
582 $uniq = "$message_id_stamp-$message_id_serial";
583
584 my $du_part;
585 for ($sender, $repocommitter, $repoauthor) {
586 $du_part = extract_valid_address(sanitize_address($_));
587 last if (defined $du_part and $du_part ne '');
588 }
589 if (not defined $du_part or $du_part eq '') {
590 use Sys::Hostname qw();
591 $du_part = 'user@' . Sys::Hostname::hostname();
592 }
593 my $message_id_template = "<%s-git-send-email-%s>";
594 $message_id = sprintf($message_id_template, $uniq, $du_part);
595 #print "new message id = $message_id\n"; # Was useful for debugging
596 }
597
598
599
600 $time = time - scalar $#files;
601
602 sub unquote_rfc2047 {
603 local ($_) = @_;
604 my $encoding;
605 if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
606 $encoding = $1;
607 s/_/ /g;
608 s/=([0-9A-F]{2})/chr(hex($1))/eg;
609 }
610 return wantarray ? ($_, $encoding) : $_;
611 }
612
613 # use the simplest quoting being able to handle the recipient
614 sub sanitize_address
615 {
616 my ($recipient) = @_;
617 my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
618
619 if (not $recipient_name) {
620 return "$recipient";
621 }
622
623 # if recipient_name is already quoted, do nothing
624 if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
625 return $recipient;
626 }
627
628 # rfc2047 is needed if a non-ascii char is included
629 if ($recipient_name =~ /[^[:ascii:]]/) {
630 $recipient_name =~ s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
631 $recipient_name =~ s/(.*)/=\?utf-8\?q\?$1\?=/;
632 }
633
634 # double quotes are needed if specials or CTLs are included
635 elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
636 $recipient_name =~ s/(["\\\r])/\\$1/;
637 $recipient_name = "\"$recipient_name\"";
638 }
639
640 return "$recipient_name $recipient_addr";
641
642 }
643
644 sub send_message
645 {
646 my @recipients = unique_email_list(@to);
647 @cc = (grep { my $cc = extract_valid_address($_);
648 not grep { $cc eq $_ } @recipients
649 }
650 map { sanitize_address($_) }
651 @cc);
652 my $to = join (",\n\t", @recipients);
653 @recipients = unique_email_list(@recipients,@cc,@bcclist);
654 @recipients = (map { extract_valid_address($_) } @recipients);
655 my $date = format_2822_time($time++);
656 my $gitversion = '@@GIT_VERSION@@';
657 if ($gitversion =~ m/..GIT_VERSION../) {
658 $gitversion = Git::version();
659 }
660
661 my $cc = join(", ", unique_email_list(@cc));
662 my $ccline = "";
663 if ($cc ne '') {
664 $ccline = "\nCc: $cc";
665 }
666 my $sanitized_sender = sanitize_address($sender);
667 make_message_id() unless defined($message_id);
668
669 my $header = "From: $sanitized_sender
670 To: $to${ccline}
671 Subject: $subject
672 Date: $date
673 Message-Id: $message_id
674 X-Mailer: git-send-email $gitversion
675 ";
676 if ($thread && $reply_to) {
677
678 $header .= "In-Reply-To: $reply_to\n";
679 $header .= "References: $references\n";
680 }
681 if (@xh) {
682 $header .= join("\n", @xh) . "\n";
683 }
684
685 my @sendmail_parameters = ('-i', @recipients);
686 my $raw_from = $sanitized_sender;
687 $raw_from = $envelope_sender if (defined $envelope_sender);
688 $raw_from = extract_valid_address($raw_from);
689 unshift (@sendmail_parameters,
690 '-f', $raw_from) if(defined $envelope_sender);
691
692 if ($dry_run) {
693 # We don't want to send the email.
694 } elsif ($smtp_server =~ m#^/#) {
695 my $pid = open my $sm, '|-';
696 defined $pid or die $!;
697 if (!$pid) {
698 exec($smtp_server, @sendmail_parameters) or die $!;
699 }
700 print $sm "$header\n$message";
701 close $sm or die $?;
702 } else {
703
704 if (!defined $smtp_server) {
705 die "The required SMTP server is not properly defined."
706 }
707
708 if ($smtp_ssl) {
709 $smtp_server_port ||= 465; # ssmtp
710 require Net::SMTP::SSL;
711 $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
712 }
713 else {
714 require Net::SMTP;
715 $smtp ||= Net::SMTP->new((defined $smtp_server_port)
716 ? "$smtp_server:$smtp_server_port"
717 : $smtp_server);
718 }
719
720 if (!$smtp) {
721 die "Unable to initialize SMTP properly. Is there something wrong with your config?";
722 }
723
724 if (defined $smtp_authuser) {
725
726 if (!defined $smtp_authpass) {
727
728 system "stty -echo";
729
730 do {
731 print "Password: ";
732 $_ = <STDIN>;
733 print "\n";
734 } while (!defined $_);
735
736 chomp($smtp_authpass = $_);
737
738 system "stty echo";
739 }
740
741 $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
742 }
743
744 $smtp->mail( $raw_from ) or die $smtp->message;
745 $smtp->to( @recipients ) or die $smtp->message;
746 $smtp->data or die $smtp->message;
747 $smtp->datasend("$header\n$message") or die $smtp->message;
748 $smtp->dataend() or die $smtp->message;
749 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
750 }
751 if ($quiet) {
752 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
753 } else {
754 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
755 if ($smtp_server !~ m#^/#) {
756 print "Server: $smtp_server\n";
757 print "MAIL FROM:<$raw_from>\n";
758 print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
759 } else {
760 print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
761 }
762 print $header, "\n";
763 if ($smtp) {
764 print "Result: ", $smtp->code, ' ',
765 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
766 } else {
767 print "Result: OK\n";
768 }
769 }
770 }
771
772 $reply_to = $initial_reply_to;
773 $references = $initial_reply_to || '';
774 $subject = $initial_subject;
775
776 foreach my $t (@files) {
777 open(F,"<",$t) or die "can't open file $t";
778
779 my $author = undef;
780 my $author_encoding;
781 my $has_content_type;
782 my $body_encoding;
783 @cc = @initial_cc;
784 @xh = ();
785 my $input_format = undef;
786 my $header_done = 0;
787 $message = "";
788 while(<F>) {
789 if (!$header_done) {
790 if (/^From /) {
791 $input_format = 'mbox';
792 next;
793 }
794 chomp;
795 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
796 $input_format = 'mbox';
797 }
798
799 if (defined $input_format && $input_format eq 'mbox') {
800 if (/^Subject:\s+(.*)$/) {
801 $subject = $1;
802
803 } elsif (/^(Cc|From):\s+(.*)$/) {
804 if (unquote_rfc2047($2) eq $sender) {
805 next if ($suppress_cc{'self'});
806 }
807 elsif ($1 eq 'From') {
808 ($author, $author_encoding)
809 = unquote_rfc2047($2);
810 next if ($suppress_cc{'author'});
811 } else {
812 next if ($suppress_cc{'cc'});
813 }
814 printf("(mbox) Adding cc: %s from line '%s'\n",
815 $2, $_) unless $quiet;
816 push @cc, $2;
817 }
818 elsif (/^Content-type:/i) {
819 $has_content_type = 1;
820 if (/charset="?[^ "]+/) {
821 $body_encoding = $1;
822 }
823 push @xh, $_;
824 }
825 elsif (/^Message-Id: (.*)/i) {
826 $message_id = $1;
827 }
828 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
829 push @xh, $_;
830 }
831
832 } else {
833 # In the traditional
834 # "send lots of email" format,
835 # line 1 = cc
836 # line 2 = subject
837 # So let's support that, too.
838 $input_format = 'lots';
839 if (@cc == 0 && !$suppress_cc{'cc'}) {
840 printf("(non-mbox) Adding cc: %s from line '%s'\n",
841 $_, $_) unless $quiet;
842
843 push @cc, $_;
844
845 } elsif (!defined $subject) {
846 $subject = $_;
847 }
848 }
849
850 # A whitespace line will terminate the headers
851 if (m/^\s*$/) {
852 $header_done = 1;
853 }
854 } else {
855 $message .= $_;
856 if (/^(Signed-off-by|Cc): (.*)$/i) {
857 next if ($suppress_cc{'sob'});
858 my $c = $2;
859 chomp $c;
860 next if ($c eq $sender and $suppress_cc{'self'});
861 push @cc, $c;
862 printf("(sob) Adding cc: %s from line '%s'\n",
863 $c, $_) unless $quiet;
864 }
865 }
866 }
867 close F;
868
869 if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
870 open(F, "$cc_cmd $t |")
871 or die "(cc-cmd) Could not execute '$cc_cmd'";
872 while(<F>) {
873 my $c = $_;
874 $c =~ s/^\s*//g;
875 $c =~ s/\n$//g;
876 next if ($c eq $sender and $suppress_from);
877 push @cc, $c;
878 printf("(cc-cmd) Adding cc: %s from: '%s'\n",
879 $c, $cc_cmd) unless $quiet;
880 }
881 close F
882 or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
883 }
884
885 if (defined $author) {
886 $message = "From: $author\n\n$message";
887 if (defined $author_encoding) {
888 if ($has_content_type) {
889 if ($body_encoding eq $author_encoding) {
890 # ok, we already have the right encoding
891 }
892 else {
893 # uh oh, we should re-encode
894 }
895 }
896 else {
897 push @xh,
898 'MIME-Version: 1.0',
899 "Content-Type: text/plain; charset=$author_encoding",
900 'Content-Transfer-Encoding: 8bit';
901 }
902 }
903 }
904
905 send_message();
906
907 # set up for the next message
908 if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
909 $reply_to = $message_id;
910 if (length $references > 0) {
911 $references .= "\n $message_id";
912 } else {
913 $references = "$message_id";
914 }
915 }
916 $message_id = undef;
917 }
918
919 if ($compose) {
920 cleanup_compose_files();
921 }
922
923 sub cleanup_compose_files() {
924 unlink($compose_filename, $compose_filename . ".final");
925
926 }
927
928 $smtp->quit if $smtp;
929
930 sub unique_email_list(@) {
931 my %seen;
932 my @emails;
933
934 foreach my $entry (@_) {
935 if (my $clean = extract_valid_address($entry)) {
936 $seen{$clean} ||= 0;
937 next if $seen{$clean}++;
938 push @emails, $entry;
939 } else {
940 print STDERR "W: unable to extract a valid address",
941 " from: $entry\n";
942 }
943 }
944 return @emails;
945 }
946
947 sub validate_patch {
948 my $fn = shift;
949 open(my $fh, '<', $fn)
950 or die "unable to open $fn: $!\n";
951 while (my $line = <$fh>) {
952 if (length($line) > 998) {
953 return "$.: patch contains a line longer than 998 characters";
954 }
955 }
956 return undef;
957 }