cvsimport: Improve documentation of CVSROOT and CVS module determination
[git/git.git] / git-cvsimport.perl
CommitLineData
a57a9493 1#!/usr/bin/perl -w
9718a00b 2
a57a9493
MU
3# This tool is copyright (c) 2005, Matthias Urlichs.
4# It is released under the Gnu Public License, version 2.
5#
6# The basic idea is to aggregate CVS check-ins into related changes.
7# Fortunately, "cvsps" does that for us; all we have to do is to parse
8# its output.
9#
10# Checking out the files is done by a single long-running CVS connection
11# / server process.
12#
13# The head revision is on branch "origin" by default.
14# You can change that with the '-o' option.
15
16use strict;
17use warnings;
18use Getopt::Std;
79ee456c 19use File::Spec;
7ccd9009 20use File::Temp qw(tempfile tmpnam);
a57a9493
MU
21use File::Path qw(mkpath);
22use File::Basename qw(basename dirname);
23use Time::Local;
2a3e1a85
MU
24use IO::Socket;
25use IO::Pipe;
e49289df 26use POSIX qw(strftime dup2 ENOENT);
0d821d4d 27use IPC::Open2;
a57a9493
MU
28
29$SIG{'PIPE'}="IGNORE";
30$ENV{'TZ'}="UTC";
31
ded9f400 32our ($opt_h,$opt_o,$opt_v,$opt_k,$opt_u,$opt_d,$opt_p,$opt_C,$opt_z,$opt_i,$opt_P, $opt_s,$opt_m,$opt_M,$opt_A,$opt_S,$opt_L, $opt_a);
ffd97f3a 33my (%conv_author_name, %conv_author_email);
a57a9493
MU
34
35sub usage() {
36 print STDERR <<END;
2a3e1a85 37Usage: ${\basename $0} # fetch/update GIT from CVS
ffd97f3a 38 [-o branch-for-HEAD] [-h] [-v] [-d CVSROOT] [-A author-conv-file]
edbe4466
FL
39 [-p opts-for-cvsps] [-P file] [-C GIT_repository] [-z fuzz] [-i] [-k]
40 [-u] [-s subst] [-a] [-m] [-M regex] [-S regex] [-L commitlimit]
41 [CVS_module]
a57a9493
MU
42END
43 exit(1);
44}
45
ffd97f3a
AE
46sub read_author_info($) {
47 my ($file) = @_;
48 my $user;
49 open my $f, '<', "$file" or die("Failed to open $file: $!\n");
50
51 while (<$f>) {
8cd16211 52 # Expected format is this:
ffd97f3a 53 # exon=Andreas Ericsson <ae@op5.se>
8cd16211 54 if (m/^(\S+?)\s*=\s*(.+?)\s*<(.+)>\s*$/) {
ffd97f3a 55 $user = $1;
8cd16211
JH
56 $conv_author_name{$user} = $2;
57 $conv_author_email{$user} = $3;
ffd97f3a 58 }
8cd16211
JH
59 # However, we also read from CVSROOT/users format
60 # to ease migration.
61 elsif (/^(\w+):(['"]?)(.+?)\2\s*$/) {
62 my $mapped;
63 ($user, $mapped) = ($1, $3);
64 if ($mapped =~ /^\s*(.*?)\s*<(.*)>\s*$/) {
65 $conv_author_name{$user} = $1;
66 $conv_author_email{$user} = $2;
67 }
68 elsif ($mapped =~ /^<?(.*)>?$/) {
69 $conv_author_name{$user} = $user;
70 $conv_author_email{$user} = $1;
71 }
72 }
73 # NEEDSWORK: Maybe warn on unrecognized lines?
ffd97f3a
AE
74 }
75 close ($f);
76}
77
78sub write_author_info($) {
79 my ($file) = @_;
80 open my $f, '>', $file or
81 die("Failed to open $file for writing: $!");
82
83 foreach (keys %conv_author_name) {
8cd16211 84 print $f "$_=$conv_author_name{$_} <$conv_author_email{$_}>\n";
ffd97f3a
AE
85 }
86 close ($f);
87}
88
ed35dece
JB
89# convert getopts specs for use by git-repo-config
90sub read_repo_config {
91 # Split the string between characters, unless there is a ':'
92 # So "abc:de" becomes ["a", "b", "c:", "d", "e"]
93 my @opts = split(/ *(?!:)/, shift);
94 foreach my $o (@opts) {
95 my $key = $o;
96 $key =~ s/://g;
97 my $arg = 'git-repo-config';
98 $arg .= ' --bool' if ($o !~ /:$/);
99
100 chomp(my $tmp = `$arg --get cvsimport.$key`);
101 if ($tmp && !($arg =~ /--bool/ && $tmp eq 'false')) {
102 no strict 'refs';
103 my $opt_name = "opt_" . $key;
104 if (!$$opt_name) {
105 $$opt_name = $tmp;
106 }
107 }
108 }
109 if (@ARGV == 0) {
110 chomp(my $module = `git-repo-config --get cvsimport.module`);
111 push(@ARGV, $module);
112 }
113}
114
115my $opts = "haivmkuo:d:p:C:z:s:M:P:A:S:L:";
116read_repo_config($opts);
117getopts($opts) or usage();
a57a9493
MU
118usage if $opt_h;
119
f9714a4a 120@ARGV <= 1 or usage();
a57a9493 121
86d11cf2 122if ($opt_d) {
2a3e1a85 123 $ENV{"CVSROOT"} = $opt_d;
86d11cf2 124} elsif (-f 'CVS/Root') {
f9714a4a
SV
125 open my $f, '<', 'CVS/Root' or die 'Failed to open CVS/Root';
126 $opt_d = <$f>;
127 chomp $opt_d;
128 close $f;
129 $ENV{"CVSROOT"} = $opt_d;
86d11cf2 130} elsif ($ENV{"CVSROOT"}) {
2a3e1a85
MU
131 $opt_d = $ENV{"CVSROOT"};
132} else {
133 die "CVSROOT needs to be set";
134}
135$opt_o ||= "origin";
fbfd60d6 136$opt_s ||= "-";
ded9f400
ML
137$opt_a ||= 0;
138
f9714a4a 139my $git_tree = $opt_C;
2a3e1a85
MU
140$git_tree ||= ".";
141
f9714a4a
SV
142my $cvs_tree;
143if ($#ARGV == 0) {
144 $cvs_tree = $ARGV[0];
145} elsif (-f 'CVS/Repository') {
146 open my $f, '<', 'CVS/Repository' or
147 die 'Failed to open CVS/Repository';
148 $cvs_tree = <$f>;
149 chomp $cvs_tree;
db4b6582 150 close $f;
f9714a4a
SV
151} else {
152 usage();
153}
154
db4b6582
ML
155our @mergerx = ();
156if ($opt_m) {
157 @mergerx = ( qr/\W(?:from|of|merge|merging|merged) (\w+)/i );
158}
159if ($opt_M) {
160 push (@mergerx, qr/$opt_M/);
161}
162
6211988f
ML
163# Remember UTC of our starting time
164# we'll want to avoid importing commits
165# that are too recent
166our $starttime = time();
167
a57a9493
MU
168select(STDERR); $|=1; select(STDOUT);
169
170
171package CVSconn;
172# Basic CVS dialog.
2a3e1a85 173# We're only interested in connecting and downloading, so ...
a57a9493 174
2eb6d82e
SV
175use File::Spec;
176use File::Temp qw(tempfile);
f65ae603
MU
177use POSIX qw(strftime dup2);
178
a57a9493 179sub new {
86d11cf2 180 my ($what,$repo,$subdir) = @_;
a57a9493
MU
181 $what=ref($what) if ref($what);
182
183 my $self = {};
184 $self->{'buffer'} = "";
185 bless($self,$what);
186
187 $repo =~ s#/+$##;
188 $self->{'fullrep'} = $repo;
189 $self->conn();
190
191 $self->{'subdir'} = $subdir;
192 $self->{'lines'} = undef;
193
194 return $self;
195}
196
197sub conn {
198 my $self = shift;
199 my $repo = $self->{'fullrep'};
86d11cf2
JH
200 if ($repo =~ s/^:pserver(?:([^:]*)):(?:(.*?)(?::(.*?))?@)?([^:\/]*)(?::(\d*))?//) {
201 my ($param,$user,$pass,$serv,$port) = ($1,$2,$3,$4,$5);
73bcf533 202
86d11cf2
JH
203 my ($proxyhost,$proxyport);
204 if ($param && ($param =~ m/proxy=([^;]+)/)) {
73bcf533
IA
205 $proxyhost = $1;
206 # Default proxyport, if not specified, is 8080.
207 $proxyport = 8080;
86d11cf2 208 if ($ENV{"CVS_PROXY_PORT"}) {
73bcf533
IA
209 $proxyport = $ENV{"CVS_PROXY_PORT"};
210 }
86d11cf2 211 if ($param =~ m/proxyport=([^;]+)/) {
73bcf533
IA
212 $proxyport = $1;
213 }
214 }
215
a57a9493 216 $user="anonymous" unless defined $user;
2a3e1a85 217 my $rr2 = "-";
86d11cf2 218 unless ($port) {
a57a9493
MU
219 $rr2 = ":pserver:$user\@$serv:$repo";
220 $port=2401;
221 }
222 my $rr = ":pserver:$user\@$serv:$port$repo";
223
86d11cf2 224 unless ($pass) {
a57a9493
MU
225 open(H,$ENV{'HOME'}."/.cvspass") and do {
226 # :pserver:cvs@mea.tmt.tele.fi:/cvsroot/zmailer Ah<Z
86d11cf2 227 while (<H>) {
a57a9493
MU
228 chomp;
229 s/^\/\d+\s+//;
230 my ($w,$p) = split(/\s/,$_,2);
86d11cf2 231 if ($w eq $rr or $w eq $rr2) {
a57a9493
MU
232 $pass = $p;
233 last;
234 }
235 }
236 };
237 }
238 $pass="A" unless $pass;
239
73bcf533 240 my ($s, $rep);
86d11cf2 241 if ($proxyhost) {
73bcf533
IA
242
243 # Use a HTTP Proxy. Only works for HTTP proxies that
244 # don't require user authentication
245 #
246 # See: http://www.ietf.org/rfc/rfc2817.txt
247
248 $s = IO::Socket::INET->new(PeerHost => $proxyhost, PeerPort => $proxyport);
249 die "Socket to $proxyhost: $!\n" unless defined $s;
250 $s->write("CONNECT $serv:$port HTTP/1.1\r\nHost: $serv:$port\r\n\r\n")
251 or die "Write to $proxyhost: $!\n";
252 $s->flush();
253
254 $rep = <$s>;
255
256 # The answer should look like 'HTTP/1.x 2yy ....'
86d11cf2 257 if (!($rep =~ m#^HTTP/1\.. 2[0-9][0-9]#)) {
73bcf533
IA
258 die "Proxy connect: $rep\n";
259 }
260 # Skip up to the empty line of the proxy server output
261 # including the response headers.
262 while ($rep = <$s>) {
263 last if (!defined $rep ||
264 $rep eq "\n" ||
265 $rep eq "\r\n");
266 }
267 } else {
268 $s = IO::Socket::INET->new(PeerHost => $serv, PeerPort => $port);
269 die "Socket to $serv: $!\n" unless defined $s;
270 }
271
a57a9493
MU
272 $s->write("BEGIN AUTH REQUEST\n$repo\n$user\n$pass\nEND AUTH REQUEST\n")
273 or die "Write to $serv: $!\n";
274 $s->flush();
275
73bcf533 276 $rep = <$s>;
a57a9493 277
86d11cf2 278 if ($rep ne "I LOVE YOU\n") {
a57a9493
MU
279 $rep="<unknown>" unless $rep;
280 die "AuthReply: $rep\n";
281 }
282 $self->{'socketo'} = $s;
283 $self->{'socketi'} = $s;
34155390 284 } else { # local or ext: Fork off our own cvs server.
a57a9493
MU
285 my $pr = IO::Pipe->new();
286 my $pw = IO::Pipe->new();
287 my $pid = fork();
288 die "Fork: $!\n" unless defined $pid;
8d0ea311
SV
289 my $cvs = 'cvs';
290 $cvs = $ENV{CVS_SERVER} if exists $ENV{CVS_SERVER};
34155390
SV
291 my $rsh = 'rsh';
292 $rsh = $ENV{CVS_RSH} if exists $ENV{CVS_RSH};
293
294 my @cvs = ($cvs, 'server');
295 my ($local, $user, $host);
296 $local = $repo =~ s/:local://;
297 if (!$local) {
298 $repo =~ s/:ext://;
299 $local = !($repo =~ s/^(?:([^\@:]+)\@)?([^:]+)://);
300 ($user, $host) = ($1, $2);
301 }
302 if (!$local) {
303 if ($user) {
304 unshift @cvs, $rsh, '-l', $user, $host;
305 } else {
306 unshift @cvs, $rsh, $host;
307 }
308 }
309
86d11cf2 310 unless ($pid) {
a57a9493
MU
311 $pr->writer();
312 $pw->reader();
a57a9493
MU
313 dup2($pw->fileno(),0);
314 dup2($pr->fileno(),1);
315 $pr->close();
316 $pw->close();
34155390 317 exec(@cvs);
a57a9493
MU
318 }
319 $pw->writer();
320 $pr->reader();
321 $self->{'socketo'} = $pw;
322 $self->{'socketi'} = $pr;
323 }
324 $self->{'socketo'}->write("Root $repo\n");
325
326 # Trial and error says that this probably is the minimum set
b0921331 327 $self->{'socketo'}->write("Valid-responses ok error Valid-requests Mode M Mbinary E Checked-in Created Updated Merged Removed\n");
a57a9493
MU
328
329 $self->{'socketo'}->write("valid-requests\n");
330 $self->{'socketo'}->flush();
331
332 chomp(my $rep=$self->readline());
86d11cf2 333 if ($rep !~ s/^Valid-requests\s*//) {
a57a9493
MU
334 $rep="<unknown>" unless $rep;
335 die "Expected Valid-requests from server, but got: $rep\n";
336 }
337 chomp(my $res=$self->readline());
338 die "validReply: $res\n" if $res ne "ok";
339
340 $self->{'socketo'}->write("UseUnchanged\n") if $rep =~ /\bUseUnchanged\b/;
341 $self->{'repo'} = $repo;
342}
343
344sub readline {
86d11cf2 345 my ($self) = @_;
a57a9493
MU
346 return $self->{'socketi'}->getline();
347}
348
349sub _file {
350 # Request a file with a given revision.
351 # Trial and error says this is a good way to do it. :-/
86d11cf2 352 my ($self,$fn,$rev) = @_;
a57a9493
MU
353 $self->{'socketo'}->write("Argument -N\n") or return undef;
354 $self->{'socketo'}->write("Argument -P\n") or return undef;
abe05822
ML
355 # -kk: Linus' version doesn't use it - defaults to off
356 if ($opt_k) {
357 $self->{'socketo'}->write("Argument -kk\n") or return undef;
358 }
a57a9493
MU
359 $self->{'socketo'}->write("Argument -r\n") or return undef;
360 $self->{'socketo'}->write("Argument $rev\n") or return undef;
361 $self->{'socketo'}->write("Argument --\n") or return undef;
362 $self->{'socketo'}->write("Argument $self->{'subdir'}/$fn\n") or return undef;
363 $self->{'socketo'}->write("Directory .\n") or return undef;
364 $self->{'socketo'}->write("$self->{'repo'}\n") or return undef;
4f7c0caa 365 # $self->{'socketo'}->write("Sticky T1.0\n") or return undef;
a57a9493
MU
366 $self->{'socketo'}->write("co\n") or return undef;
367 $self->{'socketo'}->flush() or return undef;
368 $self->{'lines'} = 0;
369 return 1;
370}
371sub _line {
372 # Read a line from the server.
373 # ... except that 'line' may be an entire file. ;-)
86d11cf2 374 my ($self, $fh) = @_;
a57a9493
MU
375 die "Not in lines" unless defined $self->{'lines'};
376
377 my $line;
2eb6d82e 378 my $res=0;
86d11cf2 379 while (defined($line = $self->readline())) {
a57a9493
MU
380 # M U gnupg-cvs-rep/AUTHORS
381 # Updated gnupg-cvs-rep/
382 # /daten/src/rsync/gnupg-cvs-rep/AUTHORS
383 # /AUTHORS/1.1///T1.1
384 # u=rw,g=rw,o=rw
385 # 0
386 # ok
387
86d11cf2 388 if ($line =~ s/^(?:Created|Updated) //) {
a57a9493
MU
389 $line = $self->readline(); # path
390 $line = $self->readline(); # Entries line
391 my $mode = $self->readline(); chomp $mode;
392 $self->{'mode'} = $mode;
393 defined (my $cnt = $self->readline())
394 or die "EOF from server after 'Changed'\n";
395 chomp $cnt;
396 die "Duh: Filesize $cnt" if $cnt !~ /^\d+$/;
397 $line="";
55cad842 398 $res = $self->_fetchfile($fh, $cnt);
86d11cf2 399 } elsif ($line =~ s/^ //) {
2eb6d82e
SV
400 print $fh $line;
401 $res += length($line);
86d11cf2 402 } elsif ($line =~ /^M\b/) {
a57a9493 403 # output, do nothing
86d11cf2 404 } elsif ($line =~ /^Mbinary\b/) {
a57a9493
MU
405 my $cnt;
406 die "EOF from server after 'Mbinary'" unless defined ($cnt = $self->readline());
407 chomp $cnt;
408 die "Duh: Mbinary $cnt" if $cnt !~ /^\d+$/ or $cnt<1;
409 $line="";
55cad842 410 $res += $self->_fetchfile($fh, $cnt);
a57a9493
MU
411 } else {
412 chomp $line;
86d11cf2 413 if ($line eq "ok") {
a57a9493
MU
414 # print STDERR "S: ok (".length($res).")\n";
415 return $res;
86d11cf2 416 } elsif ($line =~ s/^E //) {
a57a9493 417 # print STDERR "S: $line\n";
86d11cf2 418 } elsif ($line =~ /^(Remove-entry|Removed) /i) {
8b8840e0
MU
419 $line = $self->readline(); # filename
420 $line = $self->readline(); # OK
421 chomp $line;
422 die "Unknown: $line" if $line ne "ok";
423 return -1;
a57a9493
MU
424 } else {
425 die "Unknown: $line\n";
426 }
427 }
428 }
39ba7d54 429 return undef;
a57a9493
MU
430}
431sub file {
86d11cf2 432 my ($self,$fn,$rev) = @_;
a57a9493
MU
433 my $res;
434
2eb6d82e
SV
435 my ($fh, $name) = tempfile('gitcvs.XXXXXX',
436 DIR => File::Spec->tmpdir(), UNLINK => 1);
437
438 $self->_file($fn,$rev) and $res = $self->_line($fh);
439
440 if (!defined $res) {
39ba7d54
MM
441 print STDERR "Server has gone away while fetching $fn $rev, retrying...\n";
442 truncate $fh, 0;
2eb6d82e 443 $self->conn();
39ba7d54 444 $self->_file($fn,$rev) or die "No file command send";
2eb6d82e 445 $res = $self->_line($fh);
39ba7d54 446 die "Retry failed" unless defined $res;
a57a9493 447 }
c619ad51 448 close ($fh);
a57a9493 449
2eb6d82e 450 return ($name, $res);
a57a9493 451}
55cad842
ML
452sub _fetchfile {
453 my ($self, $fh, $cnt) = @_;
61efa5e3 454 my $res = 0;
55cad842 455 my $bufsize = 1024 * 1024;
86d11cf2 456 while ($cnt) {
55cad842
ML
457 if ($bufsize > $cnt) {
458 $bufsize = $cnt;
459 }
460 my $buf;
461 my $num = $self->{'socketi'}->read($buf,$bufsize);
462 die "Server: Filesize $cnt: $num: $!\n" if not defined $num or $num<=0;
463 print $fh $buf;
464 $res += $num;
465 $cnt -= $num;
466 }
467 return $res;
468}
a57a9493
MU
469
470
471package main;
472
2a3e1a85 473my $cvs = CVSconn->new($opt_d, $cvs_tree);
a57a9493
MU
474
475
476sub pdate($) {
86d11cf2 477 my ($d) = @_;
a57a9493
MU
478 m#(\d{2,4})/(\d\d)/(\d\d)\s(\d\d):(\d\d)(?::(\d\d))?#
479 or die "Unparseable date: $d\n";
480 my $y=$1; $y-=1900 if $y>1900;
481 return timegm($6||0,$5,$4,$3,$2-1,$y);
9718a00b
TM
482}
483
a57a9493 484sub pmode($) {
86d11cf2 485 my ($mode) = @_;
a57a9493
MU
486 my $m = 0;
487 my $mm = 0;
488 my $um = 0;
489 for my $x(split(//,$mode)) {
86d11cf2 490 if ($x eq ",") {
a57a9493
MU
491 $m |= $mm&$um;
492 $mm = 0;
493 $um = 0;
86d11cf2
JH
494 } elsif ($x eq "u") { $um |= 0700;
495 } elsif ($x eq "g") { $um |= 0070;
496 } elsif ($x eq "o") { $um |= 0007;
497 } elsif ($x eq "r") { $mm |= 0444;
498 } elsif ($x eq "w") { $mm |= 0222;
499 } elsif ($x eq "x") { $mm |= 0111;
500 } elsif ($x eq "=") { # do nothing
a57a9493
MU
501 } else { die "Unknown mode: $mode\n";
502 }
503 }
504 $m |= $mm&$um;
505 return $m;
506}
d4f8b390 507
a57a9493
MU
508sub getwd() {
509 my $pwd = `pwd`;
510 chomp $pwd;
511 return $pwd;
d4f8b390
LT
512}
513
e73aefe4
JK
514sub is_sha1 {
515 my $s = shift;
516 return $s =~ /^[a-f0-9]{40}$/;
517}
db4b6582 518
e73aefe4 519sub get_headref ($$) {
db4b6582
ML
520 my $name = shift;
521 my $git_dir = shift;
db4b6582 522
e73aefe4 523 my $f = "$git_dir/refs/heads/$name";
86d11cf2 524 if (open(my $fh, $f)) {
e73aefe4
JK
525 chomp(my $r = <$fh>);
526 is_sha1($r) or die "Cannot get head id for $name ($r): $!";
527 return $r;
db4b6582 528 }
e73aefe4
JK
529 die "unable to open $f: $!" unless $! == POSIX::ENOENT;
530 return undef;
db4b6582
ML
531}
532
a57a9493
MU
533-d $git_tree
534 or mkdir($git_tree,0777)
535 or die "Could not create $git_tree: $!";
536chdir($git_tree);
d4f8b390 537
a57a9493 538my $last_branch = "";
46541669 539my $orig_branch = "";
a57a9493 540my %branch_date;
8a5f2eac 541my $tip_at_start = undef;
a57a9493
MU
542
543my $git_dir = $ENV{"GIT_DIR"} || ".git";
544$git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
545$ENV{"GIT_DIR"} = $git_dir;
79ee456c
SV
546my $orig_git_index;
547$orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
8f732649
ML
548
549my %index; # holds filenames of one index per branch
061303f0 550
86d11cf2 551unless (-d $git_dir) {
5c94f87e 552 system("git-init");
a57a9493
MU
553 die "Cannot init the GIT db at $git_tree: $?\n" if $?;
554 system("git-read-tree");
555 die "Cannot init an empty tree: $?\n" if $?;
556
557 $last_branch = $opt_o;
46541669 558 $orig_branch = "";
a57a9493 559} else {
866d1310 560 -f "$git_dir/refs/heads/$opt_o"
4c24e089
MU
561 or die "Branch '$opt_o' does not exist.\n".
562 "Either use the correct '-o branch' option,\n".
563 "or import to a new repository.\n";
564
8366a10a
PR
565 open(F, "git-symbolic-ref HEAD |") or
566 die "Cannot run git-symbolic-ref: $!\n";
567 chomp ($last_branch = <F>);
568 $last_branch = basename($last_branch);
569 close(F);
86d11cf2 570 unless ($last_branch) {
46541669
MU
571 warn "Cannot read the last branch name: $! -- assuming 'master'\n";
572 $last_branch = "master";
573 }
574 $orig_branch = $last_branch;
8a5f2eac 575 $tip_at_start = `git-rev-parse --verify HEAD`;
a57a9493
MU
576
577 # Get the last import timestamps
1f24c587
AW
578 my $fmt = '($ref, $author) = (%(refname), %(author));';
579 open(H, "git-for-each-ref --perl --format='$fmt' refs/heads |") or
580 die "Cannot run git-for-each-ref: $!\n";
86d11cf2 581 while (defined(my $entry = <H>)) {
1f24c587
AW
582 my ($ref, $author);
583 eval($entry) || die "cannot eval refs list: $@";
584 my ($head) = ($ref =~ m|^refs/heads/(.*)|);
585 $author =~ /^.*\s(\d+)\s[-+]\d{4}$/;
586 $branch_date{$head} = $1;
a57a9493 587 }
1f24c587 588 close(H);
a57a9493
MU
589}
590
591-d $git_dir
592 or die "Could not create git subdir ($git_dir).\n";
593
ffd97f3a
AE
594# now we read (and possibly save) author-info as well
595-f "$git_dir/cvs-authors" and
596 read_author_info("$git_dir/cvs-authors");
597if ($opt_A) {
598 read_author_info($opt_A);
599 write_author_info("$git_dir/cvs-authors");
600}
601
2f57c697
ML
602
603#
604# run cvsps into a file unless we are getting
605# it passed as a file via $opt_P
606#
4083c2fc 607my $cvspsfile;
2f57c697
ML
608unless ($opt_P) {
609 print "Running cvsps...\n" if $opt_v;
610 my $pid = open(CVSPS,"-|");
4083c2fc 611 my $cvspsfh;
2f57c697 612 die "Cannot fork: $!\n" unless defined $pid;
86d11cf2 613 unless ($pid) {
2f57c697
ML
614 my @opt;
615 @opt = split(/,/,$opt_p) if defined $opt_p;
616 unshift @opt, '-z', $opt_z if defined $opt_z;
617 unshift @opt, '-q' unless defined $opt_v;
618 unless (defined($opt_p) && $opt_p =~ m/--no-cvs-direct/) {
619 push @opt, '--cvs-direct';
620 }
621 exec("cvsps","--norc",@opt,"-u","-A",'--root',$opt_d,$cvs_tree);
622 die "Could not start cvsps: $!\n";
df73e9c6 623 }
4083c2fc
ML
624 ($cvspsfh, $cvspsfile) = tempfile('gitXXXXXX', SUFFIX => '.cvsps',
625 DIR => File::Spec->tmpdir());
2f57c697
ML
626 while (<CVSPS>) {
627 print $cvspsfh $_;
211dcac6 628 }
2f57c697
ML
629 close CVSPS;
630 close $cvspsfh;
4083c2fc
ML
631} else {
632 $cvspsfile = $opt_P;
a57a9493
MU
633}
634
4083c2fc 635open(CVS, "<$cvspsfile") or die $!;
2f57c697 636
a57a9493
MU
637## cvsps output:
638#---------------------
639#PatchSet 314
640#Date: 1999/09/18 13:03:59
641#Author: wkoch
642#Branch: STABLE-BRANCH-1-0
643#Ancestor branch: HEAD
644#Tag: (none)
645#Log:
646# See ChangeLog: Sat Sep 18 13:03:28 CEST 1999 Werner Koch
647#Members:
648# README:1.57->1.57.2.1
649# VERSION:1.96->1.96.2.1
650#
651#---------------------
652
653my $state = 0;
654
e73aefe4
JK
655sub update_index (\@\@) {
656 my $old = shift;
657 my $new = shift;
6a1871e1
JK
658 open(my $fh, '|-', qw(git-update-index -z --index-info))
659 or die "unable to open git-update-index: $!";
660 print $fh
661 (map { "0 0000000000000000000000000000000000000000\t$_\0" }
e73aefe4 662 @$old),
6a1871e1 663 (map { '100' . sprintf('%o', $_->[0]) . " $_->[1]\t$_->[2]\0" }
e73aefe4 664 @$new)
6a1871e1
JK
665 or die "unable to write to git-update-index: $!";
666 close $fh
667 or die "unable to write to git-update-index: $!";
668 $? and die "git-update-index reported error: $?";
e73aefe4 669}
a57a9493 670
e73aefe4
JK
671sub write_tree () {
672 open(my $fh, '-|', qw(git-write-tree))
673 or die "unable to open git-write-tree: $!";
674 chomp(my $tree = <$fh>);
675 is_sha1($tree)
676 or die "Cannot get tree id ($tree): $!";
677 close($fh)
a57a9493
MU
678 or die "Error running git-write-tree: $?\n";
679 print "Tree ID $tree\n" if $opt_v;
e73aefe4
JK
680 return $tree;
681}
a57a9493 682
86d11cf2
JH
683my ($patchset,$date,$author_name,$author_email,$branch,$ancestor,$tag,$logmsg);
684my (@old,@new,@skipped,%ignorebranch);
71b08148
ML
685
686# commits that cvsps cannot place anywhere...
687$ignorebranch{'#CVSPS_NO_BRANCH'} = 1;
688
e73aefe4 689sub commit {
c5f448b0
ML
690 if ($branch eq $opt_o && !$index{branch} && !get_headref($branch, $git_dir)) {
691 # looks like an initial commit
5c94f87e 692 # use the index primed by git-init
c5f448b0
ML
693 $ENV{GIT_INDEX_FILE} = '.git/index';
694 $index{$branch} = '.git/index';
695 } else {
696 # use an index per branch to speed up
697 # imports of projects with many branches
698 unless ($index{$branch}) {
699 $index{$branch} = tmpnam();
700 $ENV{GIT_INDEX_FILE} = $index{$branch};
701 if ($ancestor) {
702 system("git-read-tree", $ancestor);
703 } else {
704 system("git-read-tree", $branch);
705 }
706 die "read-tree failed: $?\n" if $?;
707 }
708 }
709 $ENV{GIT_INDEX_FILE} = $index{$branch};
710
e73aefe4
JK
711 update_index(@old, @new);
712 @old = @new = ();
713 my $tree = write_tree();
714 my $parent = get_headref($last_branch, $git_dir);
715 print "Parent ID " . ($parent ? $parent : "(empty)") . "\n" if $opt_v;
716
717 my @commit_args;
718 push @commit_args, ("-p", $parent) if $parent;
719
720 # loose detection of merges
721 # based on the commit msg
722 foreach my $rx (@mergerx) {
723 next unless $logmsg =~ $rx && $1;
724 my $mparent = $1 eq 'HEAD' ? $opt_o : $1;
86d11cf2 725 if (my $sha1 = get_headref($mparent, $git_dir)) {
e73aefe4
JK
726 push @commit_args, '-p', $mparent;
727 print "Merge parent branch: $mparent\n" if $opt_v;
db4b6582 728 }
a57a9493 729 }
e73aefe4
JK
730
731 my $commit_date = strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date));
62bf0d96
JK
732 $ENV{GIT_AUTHOR_NAME} = $author_name;
733 $ENV{GIT_AUTHOR_EMAIL} = $author_email;
734 $ENV{GIT_AUTHOR_DATE} = $commit_date;
735 $ENV{GIT_COMMITTER_NAME} = $author_name;
736 $ENV{GIT_COMMITTER_EMAIL} = $author_email;
737 $ENV{GIT_COMMITTER_DATE} = $commit_date;
e73aefe4 738 my $pid = open2(my $commit_read, my $commit_write,
e73aefe4 739 'git-commit-tree', $tree, @commit_args);
e371046b
MU
740
741 # compatibility with git2cvs
742 substr($logmsg,32767) = "" if length($logmsg) > 32767;
743 $logmsg =~ s/[\s\n]+\z//;
744
5179c8a5
ML
745 if (@skipped) {
746 $logmsg .= "\n\n\nSKIPPED:\n\t";
747 $logmsg .= join("\n\t", @skipped) . "\n";
f396f01f 748 @skipped = ();
5179c8a5
ML
749 }
750
e73aefe4 751 print($commit_write "$logmsg\n") && close($commit_write)
a57a9493 752 or die "Error writing to git-commit-tree: $!\n";
2a3e1a85 753
e73aefe4
JK
754 print "Committed patch $patchset ($branch $commit_date)\n" if $opt_v;
755 chomp(my $cid = <$commit_read>);
756 is_sha1($cid) or die "Cannot get commit id ($cid): $!\n";
a57a9493 757 print "Commit ID $cid\n" if $opt_v;
e73aefe4 758 close($commit_read);
2a3e1a85
MU
759
760 waitpid($pid,0);
761 die "Error running git-commit-tree: $?\n" if $?;
a57a9493 762
42277bc8 763 system("git-update-ref refs/heads/$branch $cid") == 0
a57a9493
MU
764 or die "Cannot write branch $branch for update: $!\n";
765
86d11cf2
JH
766 if ($tag) {
767 my ($in, $out) = ('','');
768 my ($xtag) = $tag;
0d821d4d
PA
769 $xtag =~ s/\s+\*\*.*$//; # Remove stuff like ** INVALID ** and ** FUNKY **
770 $xtag =~ tr/_/\./ if ( $opt_u );
34c99da2 771 $xtag =~ s/[\/]/$opt_s/g;
0d821d4d
PA
772
773 my $pid = open2($in, $out, 'git-mktag');
774 print $out "object $cid\n".
775 "type commit\n".
776 "tag $xtag\n".
94c23343 777 "tagger $author_name <$author_email>\n"
0d821d4d
PA
778 or die "Cannot create tag object $xtag: $!\n";
779 close($out)
780 or die "Cannot create tag object $xtag: $!\n";
781
782 my $tagobj = <$in>;
783 chomp $tagobj;
784
785 if ( !close($in) or waitpid($pid, 0) != $pid or
786 $? != 0 or $tagobj !~ /^[0123456789abcdef]{40}$/ ) {
787 die "Cannot create tag object $xtag: $!\n";
788 }
789
790
791 open(C,">$git_dir/refs/tags/$xtag")
792 or die "Cannot create tag $xtag: $!\n";
793 print C "$tagobj\n"
794 or die "Cannot write tag $xtag: $!\n";
a57a9493 795 close(C)
0d821d4d
PA
796 or die "Cannot write tag $xtag: $!\n";
797
798 print "Created tag '$xtag' on '$branch'\n" if $opt_v;
a57a9493 799 }
a57a9493
MU
800};
801
06918348 802my $commitcount = 1;
86d11cf2 803while (<CVS>) {
a57a9493 804 chomp;
86d11cf2 805 if ($state == 0 and /^-+$/) {
a57a9493 806 $state = 1;
86d11cf2 807 } elsif ($state == 0) {
a57a9493
MU
808 $state = 1;
809 redo;
86d11cf2 810 } elsif (($state==0 or $state==1) and s/^PatchSet\s+//) {
a57a9493
MU
811 $patchset = 0+$_;
812 $state=2;
86d11cf2 813 } elsif ($state == 2 and s/^Date:\s+//) {
a57a9493 814 $date = pdate($_);
86d11cf2 815 unless ($date) {
a57a9493
MU
816 print STDERR "Could not parse date: $_\n";
817 $state=0;
818 next;
819 }
820 $state=3;
86d11cf2 821 } elsif ($state == 3 and s/^Author:\s+//) {
a57a9493 822 s/\s+$//;
94c23343
JH
823 if (/^(.*?)\s+<(.*)>/) {
824 ($author_name, $author_email) = ($1, $2);
ffd97f3a
AE
825 } elsif ($conv_author_name{$_}) {
826 $author_name = $conv_author_name{$_};
827 $author_email = $conv_author_email{$_};
94c23343
JH
828 } else {
829 $author_name = $author_email = $_;
830 }
a57a9493 831 $state = 4;
86d11cf2 832 } elsif ($state == 4 and s/^Branch:\s+//) {
a57a9493 833 s/\s+$//;
fbfd60d6 834 s/[\/]/$opt_s/g;
a57a9493
MU
835 $branch = $_;
836 $state = 5;
86d11cf2 837 } elsif ($state == 5 and s/^Ancestor branch:\s+//) {
a57a9493
MU
838 s/\s+$//;
839 $ancestor = $_;
0fa2824f 840 $ancestor = $opt_o if $ancestor eq "HEAD";
a57a9493 841 $state = 6;
86d11cf2 842 } elsif ($state == 5) {
a57a9493
MU
843 $ancestor = undef;
844 $state = 6;
845 redo;
86d11cf2 846 } elsif ($state == 6 and s/^Tag:\s+//) {
a57a9493 847 s/\s+$//;
86d11cf2 848 if ($_ eq "(none)") {
a57a9493
MU
849 $tag = undef;
850 } else {
851 $tag = $_;
852 }
853 $state = 7;
86d11cf2 854 } elsif ($state == 7 and /^Log:/) {
a57a9493
MU
855 $logmsg = "";
856 $state = 8;
86d11cf2 857 } elsif ($state == 8 and /^Members:/) {
a57a9493 858 $branch = $opt_o if $branch eq "HEAD";
86d11cf2 859 if (defined $branch_date{$branch} and $branch_date{$branch} >= $date) {
a57a9493 860 # skip
9da07f34 861 print "skip patchset $patchset: $date before $branch_date{$branch}\n" if $opt_v;
a57a9493
MU
862 $state = 11;
863 next;
864 }
ded9f400 865 if (!$opt_a && $starttime - 300 - (defined $opt_z ? $opt_z : 300) <= $date) {
6211988f
ML
866 # skip if the commit is too recent
867 # that the cvsps default fuzz is 300s, we give ourselves another
868 # 300s just in case -- this also prevents skipping commits
869 # due to server clock drift
870 print "skip patchset $patchset: $date too recent\n" if $opt_v;
871 $state = 11;
872 next;
873 }
71b08148
ML
874 if (exists $ignorebranch{$branch}) {
875 print STDERR "Skipping $branch\n";
876 $state = 11;
877 next;
878 }
86d11cf2
JH
879 if ($ancestor) {
880 if ($ancestor eq $branch) {
71b08148
ML
881 print STDERR "Branch $branch erroneously stems from itself -- changed ancestor to $opt_o\n";
882 $ancestor = $opt_o;
883 }
86d11cf2 884 if (-f "$git_dir/refs/heads/$branch") {
a57a9493
MU
885 print STDERR "Branch $branch already exists!\n";
886 $state=11;
887 next;
888 }
86d11cf2 889 unless (open(H,"$git_dir/refs/heads/$ancestor")) {
a57a9493 890 print STDERR "Branch $ancestor does not exist!\n";
71b08148 891 $ignorebranch{$branch} = 1;
a57a9493
MU
892 $state=11;
893 next;
894 }
895 chomp(my $id = <H>);
896 close(H);
86d11cf2 897 unless (open(H,"> $git_dir/refs/heads/$branch")) {
a57a9493 898 print STDERR "Could not create branch $branch: $!\n";
71b08148 899 $ignorebranch{$branch} = 1;
a57a9493
MU
900 $state=11;
901 next;
902 }
903 print H "$id\n"
904 or die "Could not write branch $branch: $!";
905 close(H)
906 or die "Could not write branch $branch: $!";
907 }
46e63efc 908 $last_branch = $branch if $branch ne $last_branch;
a57a9493 909 $state = 9;
86d11cf2 910 } elsif ($state == 8) {
a57a9493 911 $logmsg .= "$_\n";
86d11cf2 912 } elsif ($state == 9 and /^\s+(.+?):(INITIAL|\d+(?:\.\d+)+)->(\d+(?:\.\d+)+)\s*$/) {
a57a9493 913# VERSION:1.96->1.96.2.1
2a3e1a85 914 my $init = ($2 eq "INITIAL");
a57a9493 915 my $fn = $1;
f65ae603
MU
916 my $rev = $3;
917 $fn =~ s#^/+##;
5179c8a5
ML
918 if ($opt_S && $fn =~ m/$opt_S/) {
919 print "SKIPPING $fn v $rev\n";
920 push(@skipped, $fn);
921 next;
922 }
923 print "Fetching $fn v $rev\n" if $opt_v;
2eb6d82e 924 my ($tmpname, $size) = $cvs->file($fn,$rev);
86d11cf2 925 if ($size == -1) {
8b8840e0
MU
926 push(@old,$fn);
927 print "Drop $fn\n" if $opt_v;
928 } else {
929 print "".($init ? "New" : "Update")." $fn: $size bytes\n" if $opt_v;
dd27478f
JH
930 my $pid = open(my $F, '-|');
931 die $! unless defined $pid;
932 if (!$pid) {
933 exec("git-hash-object", "-w", $tmpname)
8b8840e0 934 or die "Cannot create object: $!\n";
dd27478f 935 }
8b8840e0
MU
936 my $sha = <$F>;
937 chomp $sha;
938 close $F;
939 my $mode = pmode($cvs->{'mode'});
940 push(@new,[$mode, $sha, $fn]); # may be resurrected!
941 }
2eb6d82e 942 unlink($tmpname);
86d11cf2 943 } elsif ($state == 9 and /^\s+(.+?):\d+(?:\.\d+)+->(\d+(?:\.\d+)+)\(DEAD\)\s*$/) {
f65ae603
MU
944 my $fn = $1;
945 $fn =~ s#^/+##;
946 push(@old,$fn);
8b8840e0 947 print "Delete $fn\n" if $opt_v;
86d11cf2 948 } elsif ($state == 9 and /^\s*$/) {
a57a9493 949 $state = 10;
86d11cf2 950 } elsif (($state == 9 or $state == 10) and /^-+$/) {
4adcea99
LT
951 $commitcount++;
952 if ($opt_L && $commitcount > $opt_L) {
06918348
ML
953 last;
954 }
c4b16f8d 955 commit();
4adcea99
LT
956 if (($commitcount & 1023) == 0) {
957 system("git repack -a -d");
958 }
a57a9493 959 $state = 1;
86d11cf2 960 } elsif ($state == 11 and /^-+$/) {
a57a9493 961 $state = 1;
86d11cf2 962 } elsif (/^-+$/) { # end of unknown-line processing
a57a9493 963 $state = 1;
86d11cf2 964 } elsif ($state != 11) { # ignore stuff when skipping
a57a9493
MU
965 print "* UNKNOWN LINE * $_\n";
966 }
967}
c4b16f8d 968commit() if $branch and $state != 11;
d4f8b390 969
4083c2fc
ML
970unless ($opt_P) {
971 unlink($cvspsfile);
972}
973
efe4abd1
JM
974# The heuristic of repacking every 1024 commits can leave a
975# lot of unpacked data. If there is more than 1MB worth of
976# not-packed objects, repack once more.
977my $line = `git-count-objects`;
978if ($line =~ /^(\d+) objects, (\d+) kilobytes$/) {
979 my ($n_objects, $kb) = ($1, $2);
980 1024 < $kb
981 and system("git repack -a -d");
982}
983
8f732649 984foreach my $git_index (values %index) {
c5f448b0
ML
985 if ($git_index ne '.git/index') {
986 unlink($git_index);
987 }
8f732649 988}
79ee456c 989
210569f9
SV
990if (defined $orig_git_index) {
991 $ENV{GIT_INDEX_FILE} = $orig_git_index;
992} else {
993 delete $ENV{GIT_INDEX_FILE};
994}
995
46541669 996# Now switch back to the branch we were in before all of this happened
86d11cf2 997if ($orig_branch) {
8a5f2eac
JH
998 print "DONE.\n" if $opt_v;
999 if ($opt_i) {
1000 exit 0;
1001 }
1002 my $tip_at_end = `git-rev-parse --verify HEAD`;
1003 if ($tip_at_start ne $tip_at_end) {
cb9594e2 1004 for ($tip_at_start, $tip_at_end) { chomp; }
8a5f2eac
JH
1005 print "Fetched into the current branch.\n" if $opt_v;
1006 system(qw(git-read-tree -u -m),
1007 $tip_at_start, $tip_at_end);
1008 die "Fast-forward update failed: $?\n" if $?;
1009 }
1010 else {
1011 system(qw(git-merge cvsimport HEAD), "refs/heads/$opt_o");
1012 die "Could not merge $opt_o into the current branch.\n" if $?;
1013 }
46541669
MU
1014} else {
1015 $orig_branch = "master";
1016 print "DONE; creating $orig_branch branch\n" if $opt_v;
a541211e 1017 system("git-update-ref", "refs/heads/master", "refs/heads/$opt_o")
46541669 1018 unless -f "$git_dir/refs/heads/master";
8366a10a 1019 system('git-update-ref', 'HEAD', "$orig_branch");
c1c774e7
SV
1020 unless ($opt_i) {
1021 system('git checkout');
1022 die "checkout failed: $?\n" if $?;
1023 }
46541669 1024}